E-Racer

Type
Game
Category
Side-scrolling racing and jumping game
Author
James Hague
Published in
Antic, December 1988 (Vol. 7, No. 8)
Year
1988
Language
Atari BASIC (with machine-language helpers)
Requirements
32K RAM, Atari BASIC, joystick in port 1; disk drive for the high-score file (optional)
A brown side-on track with a raised plateau carrying a purple flag, the tan-and-pink E-Racer car on the flat ground at left, and a SCORE CARS RUN TRACK status line at the top

About the program

The E-Racer is "the world's fastest car", built in secret by a team of scientists running "one of the most ambitious (and probably useless) research projects ever attempted". It's powered by a highly classified fuel and can drive on land and, briefly, in the air. James Hague, then a computer science and maths student at the University of North Texas and already the author of Antic games such as Uncle Henry's Nuclear Waste Dump, Rockslide and Current Events, wrote it for the December 1988 issue. He said he used "just about every trick in the book" for speed, so that it's hard to tell it isn't all machine code. He also admitted that it took longer than usual to finish because he kept stopping to drive the little rocket car off cliffs.

The idea is unusual. Each run along a track (about three screens long) must beat your previous one on two counts: a faster time and more flags. You can't stop, and you can only drive on level ground, but you can jump.

What you need

A 32K Atari with Atari BASIC and a joystick. It also runs under the Altirra BASIC replacement ROM that many emulators use. A disk drive lets it keep a high-score file (ERACER.HSC). With cassette, saving is switched off automatically.

Typing it in

The magazine marked lines 7070–7080, 7140–7170 and 7260–7280 as hard to type: these are machine-code routines and display lists stored in strings. It offered a second listing to write them to LINES.LST; this disk listing already includes them. In the notation, {inv}…{/inv} is inverse (Atari key), {CTRL-x} is CTRL plus the key, and {INS CHAR}, {DEL CHAR}, {RIGHT} and {TAB} are ESC followed by the key. Hague's reassurance about the track DATA from line 9000 on still applies. It looks daunting, but it contains no control characters, and the only inverse character is the capital Z (solid ground). The disk version has no TYPO II codes.

How to play

Press SELECT on the title screen to choose one of four tracks (track 1 is the easiest), then START or the button. The stick sets your speed: centre is normal, right is fast and left is slow. There's no brake. Press the button on level ground to rocket upwards until you let go (or reach an invisible ceiling halfway up), then steer as you fall. Driving off cliffs is fine as long as you land on level ground. Hitting a hill, water or anything else costs one of your two cars.

Each track has six purple flags, in roughly the same places each game. Five wave to the right and are worth 100 and a "flag". The sixth, chosen at random on each run, waves to the left: it's worth 500 but doesn't count as a flag. At the end of a run you see your time and flags against the last run, and bonus points. You get another run only if you were faster and collected more flags (or all five again). Hague's advice: make your first run slow (15–20 seconds) with one flag, then improve a little each time. Grab the bonus flag early on to make your time easier to beat, but avoid it later. He had managed ten runs.

How it works

  • Numbers as variables. Line 7000 READs 0–10 into C0…C10, and the program uses those everywhere instead of literal numbers. In Atari BASIC a numeric constant takes seven bytes in the program line, while a variable reference takes one.
  • One big string as memory. MEM$ (3,892 bytes, line 7100) is positioned so that its contents start on a 1K boundary. Inside it the program places a character set, the player-missile area, the 97-character-wide scrolling track, and two display lists.
  • Hardware scrolling. The game display list (line 7140) has four GRAPHICS 2 lines with their own memory addresses and the horizontal-scroll bit set. A vertical-blank routine installed in page 6 by lines 7260–7300 fine-scrolls them and moves the car. BASIC mostly just reads the joystick and pokes the speed (location 204) and the car's height.
  • Collisions. The car is players 0 and 1. Its collision register with the playfield (53252) tells the program whether it's resting on ground (value 4) or has hit something else. A short machine-code scan (SCAN) finds which screen byte the car touched, so the program knows which flag to erase (codes 197 and 198).
  • Disk or tape? If opening D:ERACER.HSC fails, line 7060 checks the error code: 170 (file not found) means there's a disk to save to later.

Listing

10 REM E-RACER
20 REM BY JAMES HAGUE
30 REM (c)1988, ANTIC PUBLISHING
100 GOSUB 7000
110 GOSUB 8000
120 GOSUB 5000
125 POKE 53278,C0
130 IF PEEK(CTL) THEN 500
140 IF STICK(C0)>12 THEN SOUND C0,40,C0,C8:POKE SPEED,C1:GOTO 170
150 IF STICK(C0)<C8 THEN SOUND C0,11,C0,C8:POKE SPEED,C2:GOTO 170
160 SOUND C0,90,C0,C8:POKE SPEED,255
170 IF STAT<>C1 THEN 200
180 IF Y<=56 OR STRIG(C0) THEN STAT=C2:GOTO 125
190 Y=Y-C1:POKE YPOS,Y:GOTO 130
200 IF STAT<>C2 THEN 240
210 IF PEEK(53252)=C4 THEN STAT=C0:GOTO 130
220 IF  NOT PEEK(53252) THEN Y=Y+C1:POKE YPOS,Y:GOTO 130
230 GOTO 130
240 IF  NOT STRIG(C0) THEN STAT=C1:GOTO 130
250 IF  NOT PEEK(53252) THEN STAT=C2
260 GOTO 125
500 A=PEEK(20):IF PEEK(DL+20)=76 THEN 1500
505 IF A=PEEK(20) THEN 505
510 A=PEEK(53252):IF A>C7 THEN A=A-C8
520 IF A>C3 THEN A=A-C4
530 IF A THEN 1000
540 A=PEEK(DL+20)+256*PEEK(DL+21)+C4:B=USR(SCAN,A):IF B>SCROLL+388 THEN GOTO 130
570 C=PEEK(B):IF C=197 THEN FLAGS=FLAGS+C1:SCORE=SCORE+100:GOTO 585
580 SCORE=SCORE+500
585 POSITION C0,C1:A=SCORE:GOSUB 6000
590 POKE B,C0:FOR C=15 TO C0 STEP -C1:SOUND C0,24,C2,C:SOUND C1,54,C10,C:NEXT C
600 POKE 53278,C0:POSITION C0,C1:A=SCORE:GOSUB 6000:POKE CTL,C0:GOTO 130
1000 POKE DRAW,255:CARS=CARS-C1:POKE GAME+28,CARS+16:POKE 704,31
1010 FOR A=14 TO C4 STEP -C2:C=C10:FOR B=A TO C0 STEP -C1:SOUND C0,C,C8,B:C=C+C10:POKE 712,B:NEXT B:NEXT A
1020 A=C2:FOR B=C8 TO C1 STEP -C1:SOUND C0,40,C8,B:POKE 704,15+B*C2:GOSUB 6150:NEXT B:SOUND C0,C0,C0,C0
1030 POKE 704,C0:A=60:GOSUB 6150:IF CARS THEN GOTO 120
1040 POSITION C5,C8:? #C6;"game  over":IF SCORE<=HSCORE(TRACK-C1) THEN 1050
1045 HSCORE(TRACK-C1)=SCORE:HRN(TRACK-C1)=RN:CHANGED=TRACK
1050 FOR A=15 TO C4 STEP -C1:FOR B=A TO C0 STEP -C1:SOUND C0,31,C10,B:SOUND C1,60,C10,B:NEXT B:NEXT A
1060 POSITION C5,C8:? #C6;"          ":POKE 53248,C0:POKE 53249,C0:GOTO 110
1500 TIME=PEEK(20)+256*PEEK(19):POSITION C4,C3:? #C6;"{inv}run complete{/inv}"
1510 FOR A=C1 TO C3:FOR B=15 TO C0 STEP -C1:SOUND C0,40,C10,B:SOUND C1,60,C10,B:NEXT B:NEXT A:POKE DRAW,C0:A=30
1520 GOSUB 6150:POSITION C0,C6:IF RN=C1 THEN 1555
1540 ? #C6;"      last run":A=60:GOSUB 6150:? #C6:A=LFLAGS:GOSUB 6200:A=LTIME:GOSUB 6100:? #C6;" SEC  ";
1550 FOR A=C1 TO LFLAGS:? #C6;CHR$(133);:NEXT A:? #C6:? #C6:? #C6:A=90:GOSUB 6150
1555 ? #C6;"      this run":A=60:GOSUB 6150
1560 ? #C6:A=FLAGS:GOSUB 6200:A=TIME:GOSUB 6100:? #C6;" SEC  ";:A=60:GOSUB 6150
1570 IF  NOT FLAGS THEN ? #C6;"{inv}none{/inv}":GOTO 1600
1580 FOR A=C1 TO FLAGS:? #C6;CHR$(133);:FOR B=15 TO C0 STEP -C1:SOUND C0,108,C10,B:SOUND C0,172,C10,B:NEXT B
1590 NEXT A
1600 A=120:GOSUB 6150:STAT=C0
1610 IF RN>C1 THEN 1630
1620 IF FLAGS THEN STAT=C1:GOTO 1640
1630 IF (FLAGS>LFLAGS OR FLAGS=C5) AND TIME<LTIME THEN STAT=C1
1640 LFLAGS=FLAGS:LTIME=TIME:POSITION C4,C3:? #C6;"            ":A=C10:GOSUB 6150:POSITION C0,C3
1650 IF  NOT STAT THEN ? #C6;"      {inv}too  bad{/inv}":GOTO 1676
1660 ? #C6;" ";:B=(1500-TIME)*RN:A=B:GOSUB 6000:? #C6;" {inv}bonus points{/inv}":SCORE=SCORE+B:A=SCORE:POSITION C0,C1
1670 GOSUB 6000:A=C4:FOR B=200 TO 20 STEP -20:SOUND C0,B,C10,C10:SOUND C1,B+25,C10,C10:GOSUB 6150:NEXT B
1675 SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0
1676 IF STRIG(C0) THEN 1676
1677 IF STAT THEN POKE 559,C0
1680 COLOR 32:FOR A=C0 TO 19:PLOT A,C3:DRAWTO A,13:NEXT A:IF  NOT STAT THEN 1040
1690 RN=RN+C1:A=RN:POSITION 12,C1:GOSUB 6050:GOTO 120
5000 POKE 559,C0:POKE 53277,C2:POKE 704,26:POKE 705,74:POKE 708,246:POKE 710,246:POKE 709,116:POKE 711,102
5010 POKE 53261,C0:FLAGS=C0:POKE 77,C0:IF TRACK=C1 THEN RESTORE 9000
5020 IF TRACK=C2 THEN RESTORE 9100
5030 IF TRACK=C3 THEN RESTORE 9200
5040 IF TRACK=C4 THEN RESTORE 9300
5050 A=USR(DP,88,SCROLL+22):POSITION C0,C0:FOR A=C1 TO C3:? #C6;"                    ";:NEXT A:POKE SPEED,C2
5060 FOR A=C0 TO C3:B=USR(DP,88,SCROLL+119+97*A):POSITION C0,C0:FOR B=C1 TO C3:READ A$:? #C6;A$(C2,21);:NEXT B
5070 NEXT A:A=USR(DP,88,GAME):A=USR(DP,560,DL):A=SCROLL:FOR B=DL+20 TO DL+32 STEP C3:C=USR(DP,B,A):A=A+97:NEXT B
5080 IF RN>C1 OR CARS<C2 THEN 5100
5090 POSITION C0,C1:? #C6;"00000  02  001":FOR A=C0 TO C5:READ X,Y,B:FLAG(A)=SCROLL+97*Y+INT(RND(C0)*B+X):NEXT A
5100 B=INT(RND(C0)*C6):FOR A=C0 TO C5:IF A=B THEN POKE FLAG(A),198
5110 IF A<>B THEN POKE FLAG(A),197
5120 NEXT A:Y=97:POKE YPOS,Y:POKE 53248,56:POKE DRAW,255:POKE 559,42
5130 POSITION C1,C7:? #C6;"start your engines":A=20:GOSUB 6150:A=5
5140 FOR B=100 TO C0 STEP -C5:SOUND 0,B,C8,(100-B)/12:GOSUB 6150:NEXT B:POSITION C1,C7:? #C6;"                  "
5150 POSITION C4,C8:? #C6;"get  moving{CTRL-A}":POKE 53249,48:POKE DRAW,C1
5160 FOR B=40 TO 200 STEP C3:SOUND C0,B,C2,14:POKE 712,14*(B=40):NEXT B:SOUND C0,40,C0,C8:POKE 19,C0:POKE 20,C0
5170 FOR B=56 TO 80:POKE 53248,B:POKE 53249,B-C8:NEXT B:POKE 205,C1
5180 POSITION C4,C8:? #C6;"            ":STAT=C0:POKE 208,C0:POKE 53278,C0:POKE SPEED,C1:POKE CTL,C0:RETURN
5999 REM PRINT SCORE (A)
6000 A$=STR$(A)
6010 IF LEN(A$)=C5 THEN 6030
6020 FOR A=C1 TO C5-LEN(A$):? #C6;"0";:NEXT A
6030 ? #C6;A$;:RETURN
6050 IF A<C10 THEN ? #C6;"0";
6060 ? #C6;STR$(A);:RETURN
6100 B=INT(A/60):C=INT((A-B*60)/0.6):IF B<C10 THEN ? #C6;"0";
6110 ? #C6;B;".";:IF C<C10 THEN ? #C6;"0";
6120 ? #C6;C;:RETURN
6150 POKE 20,C0
6160 IF PEEK(20)<A THEN 6160
6170 RETURN
6200 IF  NOT A THEN B=C2:GOTO 6220
6210 B=INT((20-(A+11))/C2)
6220 FOR C=C1 TO B:? #C6;" ";:NEXT C:RETURN
7000 RESTORE :READ C0,C1,C2,C3,C4,C5,C6,C7,C8,C9,C10:GRAPHICS 18:POKE 16,112:POKE 53774,112:POKE 708,C0
7010 POKE 712,136:POSITION C0,C5:? #C6;"  PREPARE YOURSELF":TRACK=C1
7020 DIM MOV$(46),DP$(17),MEM$(3892),A$(22),FLAG(C5),HSCORE(C3),HRN(C3)
7030 TRAP 7050:DISK=C1:CHANGED=C0
7040 OPEN #C1,C4,C0,"D:ERACER.HSC":FOR A=C0 TO C3:INPUT #C1;B:HSCORE(A)=B:GET #C1,B:HRN(A)=B:NEXT A:GOTO 7065
7050 FOR A=C0 TO C3:HSCORE(A)=C0:HRN(A)=C0:NEXT A
7060 IF PEEK(195)<>170 THEN DISK=C0
7065 CLOSE #C1
7070 MOV$="hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}"
7080 DP$="hh{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T {/inv}{CTRL-A}h{inv}{CTRL-Q}T{CTRL-H}{/inv}h{inv}{CTRL-Q}T{/inv}{CTRL-.}"
7090 MOV=ADR(MOV$):DP=ADR(DP$)
7100 MEM$="{CTRL-,}":MEM$(3892)="{CTRL-,}":MEM$(C2)=MEM$:A=ADR(MEM$):B=1024:CH=B-(A-INT(A/B)*B)+A:PM=CH+B:SCROLL=PM
7110 PL0=SCROLL+512:PL1=PL0+128:TDL=PL1+128:DL=TDL+35:TITLE=SCROLL+B:GAME=TITLE+540
7120 A=USR(MOV,57344,CH,768):FOR A=C1 TO 16:READ B:B=CH+B*C8:FOR C=B TO B+C7:READ D:POKE C,D:NEXT C:NEXT A
7130 POKE 756,CH/256:POKE 54279,PM/256:POKE 53256,C0:POKE 53257,C0:POKE 623,C1:POKE 53277,C0:TRAP 40000
7140 A=USR(MOV,ADR("pppF..{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}W..W..W..W..W..A"),DL,35)
7150 A=USR(DP,DL+C4,GAME):A=USR(DP,DL+35,DL):POSITION C0,C0
7160 A=USR(DP,88,GAME):? #C6;"{inv}score cars run track{/inv}00000  00  000   1"
7165 A$="{inv}ZZZZZZZZZZZZZZZZZZZZZZ{/inv}":A=USR(DP,88,SCROLL+388):POSITION C0,C0:? #C6;A$:POSITION C2,C4:? #C6;A$(C8)
7170 A=USR(MOV,ADR("pppF..{CTRL-F}ppF..P{CTRL-D}{CTRL-D}{CTRL-D}{CTRL-D}{CTRL-D}pp{CTRL-B}p{CTRL-B}{CTRL-P}{CTRL-B}{CTRL-B}{CTRL-B}{CTRL-B}p{CTRL-B}p{CTRL-B}A"),TDL,33)
7180 A=USR(DP,TDL+C4,GAME):A=USR(DP,TDL+C10,TITLE):A=USR(DP,TDL+33,TDL)
7190 A=USR(DP,88,TITLE):POKE 87,C1:POSITION C3,C0:? #C6;"{inv}james  hague{CTRL-G}s{/inv}"
7200 ? #C6;"    ----    ---- ---- ---- ---- ----":? #C6;"    -  -    -       - -    -  - -"
7210 ? #C6;"    ---- -- -    ---- -    ---- -":? #C6;"    -       -    -  - -    -    -"
7220 ? #C6;"    ----    -    ---- ---- ---- -":POSITION 15,11:? #C6;"TOP SCORES"
7230 POSITION 11,13:? #C6;"Track  Score  Run":A=USR(DP,88,TITLE+300)
7240 FOR B=C0 TO C3:POSITION 13,B+B:? #C6;B+C1;"    ";:A=HSCORE(B):GOSUB 6000:? #C6;"  0";:A=HRN(B):GOSUB 6050
7250 NEXT B:POSITION C5,C10:? #C6;"{inv} SELECT {/inv} track or {inv} START {/inv} race"
7260 A=USR(MOV,ADR("h{inv} {/inv} {inv}"{/inv}{CTRL-F}{inv}){/inv}{CTRL-G}L\{inv}dp|fca{/inv}{INS CHAR}{INS CHAR}{DEL CHAR}{CTRL-C}{CTRL-,}{CTRL-E}{CTRL-G}{CTRL-A}{CTRL-C}{CTRL-F}{CTRL-O}{RIGHT}>{TAB}{INS CHAR}{inv}X-{/inv}{CTRL-D}{inv}P{/inv}){CTRL-K}{inv}p{/inv}{CTRL-B}{inv}{CTRL-E}K%KP{/inv}C{inv}%L{/inv}{CTRL-P}{CTRL-H}{inv}FM{/inv}{CTRL-P};{inv}){/inv}{CTRL-A}{inv}{CTRL-E}M{CTRL-E}Q%P{/inv}8{inv}eQ{/inv}0{CTRL-B}{inv}P{/inv}{CTRL-E}{CTRL-X}i{CTRL-H}{inv} {/inv}{CTRL-,}{inv}{CTRL-E}P{CTRL-M}{/inv}{CTRL-D}{inv}TP{/inv}"),1538,78)
7270 A=USR(MOV,ADR(" {inv}H"{/inv}{CTRL-E}{inv}1N{/inv}{CTRL-X}i{CTRL-A}{inv}{CTRL-Q}NH1N{/inv}i{CTRL-,}{inv}{CTRL-Q}NHHJPm {/inv}{CTRL-A}{inv}1NI{/inv}L{inv}P{/inv}{CTRL-B}{inv}{CTRL-D}K"{/inv}?{inv}){/inv}{CTRL-,}{INS LINE}{INS CHAR}{INS CHAR}{INS LINE}{INS CHAR}{INS CHAR}{inv}J{/inv}{CTRL-P}{inv}w,{/inv}{CTRL-,}{CTRL-F}{inv}p{/inv}){inv}*,{/inv}{CTRL-A}{CTRL-F}{inv}={/inv}{CTRL-L}{CTRL-F}{inv}{CTRL-Y}{/inv}{INS CHAR}{INS CHAR}{inv}{CTRL-F}Q-{/inv}{CTRL-,}{CTRL-F}0{CTRL-P}{inv}&Lh-{/inv}{CTRL-J}{inv}R{/inv}={CTRL-T}"),1616,76)
7280 A=USR(MOV,ADR("{CTRL-F}{inv}*={/inv}{CTRL-X}{CTRL-F}{inv}{CTRL-Y}{/inv}{INS CHAR}{INS CHAR}{inv}H&Qh{CTRL-.}{/inv}{CTRL-H}{inv}P[{/inv}Lb{inv}dX{/inv}hh{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T {/inv}{CTRL-,}{inv}"{/inv}{CTRL-C}{inv}{CTRL-F}V"{/inv}{CTRL-B}{inv}1TIEp{/inv}{CTRL-V}{inv}IFp{/inv}{CTRL-R}{inv}){/inv}{CTRL-A} {inv}\{/inv}{CTRL-F}{inv}J{/inv}{CTRL-P}{inv}n){/inv}^ {inv}\{/inv}{CTRL-F}{inv}&VJ{/inv}{CTRL-P}{inv}{CTRL-.}{/inv}{CTRL-.}{CTRL-X}e{inv}T{CTRL-E}T%U{/inv}i{CTRL-,}{inv}{CTRL-E}U{/inv}{CTRL-.}"),1692,76)
7290 A=USR(DP,1654,PL0+56):A=USR(DP,1657,PL1+56):A=USR(DP,1675,PL0):A=USR(DP,1698,PL1):A=USR(DP,206,DL+19)
7300 SCAN=1711:CTL=203:SPEED=204:DRAW=1536:YPOS=1537:POKE CTL,C1:POKE DRAW,C0:A=USR(1538):RETURN
7500 DATA 0,1,2,3,4,5,6,7,8,9,10
7510 DATA 3,0,4,12,28,30,124,254,255
7520 DATA 4,0,0,8,24,28,30,62,127
7530 DATA 5,128,254,252,248,240,128,128,128
7540 DATA 6,1,127,63,31,15,1,1,1
7550 DATA 8,0,193,241,251,255,255,255,255
7560 DATA 9,0,129,195,227,233,251,255,255
7570 DATA 10,0,0,0,0,0,8,44,127
7580 DATA 11,0,0,0,0,0,32,105,251
7590 DATA 27,255,95,29,8,0,0,0,0
7600 DATA 13,85,85,85,85,85,85,85,85
7610 DATA 15,0,3,7,7,31,63,63,127
7620 DATA 28,0,0,128,200,248,252,254,254
7630 DATA 29,1,1,3,3,23,31,127,255
7640 DATA 30,192,224,248,252,252,254,254,255
7650 DATA 56,0,255,255,255,255,255,255,255
7660 DATA 58,255,255,255,255,255,255,255,255
8000 POKE 559,C0:A=USR(DP,560,TDL):POKE 708,26:POKE 709,C10:POKE 710,C0:POKE 711,102:POKE 712,C0
8010 A=USR(DP,88,TITLE+300):IF DISK AND CHANGED THEN POSITION C8,C8:? #C6;"Press 'S' to save scores"
8020 IF CHANGED THEN B=CHANGED-C1:POSITION 18,B+B:A=HSCORE(B):GOSUB 6000:? #C6;"  0";:A=HRN(B):GOSUB 6050
8040 POKE 764,255:POKE 559,34
8050 POKE 77,C0:FOR A=C1 TO C10:NEXT A
8060 IF PEEK(53279)=C6 OR  NOT STRIG(C0) THEN SCORE=C0:RN=C1:CARS=C2:RETURN
8070 IF DISK AND CHANGED AND PEEK(764)=62 THEN GOSUB 8500:GOTO 8050
8080 IF PEEK(53279)<>C5 THEN 8060
8090 TRACK=TRACK+C1:IF TRACK>C4 THEN TRACK=C1
8100 POKE GAME+37,TRACK+16
8110 IF PEEK(53279)=C5 THEN 8110
8120 GOTO 8050
8500 TRAP 8530:OPEN #C1,C8,C0,"D:ERACER.HSC":A=C0
8510 ? #C1;HSCORE(A):PUT #C1,HRN(A):A=A+C1:IF A<C4 THEN 8510
8520 CLOSE #C1:TRAP 40000:POSITION C8,C8:? #C6;"                        ":CHANGED=C0:RETURN
8530 CLOSE #C1:TRAP 40000:A=C1:FOR B=15 TO C0 STEP -C1:SOUND C0,90,C10,B:GOSUB 6150:NEXT B:POKE 764,255:RETURN
9000 DATA "                 $  "
9001 DATA "                    "
9002 DATA " +                  "
9003 DATA "                =Z> "
9004 DATA "            /{inv}ZZZZZZZ{/inv}"
9005 DATA "{inv}Z{/inv}Z>                 "
9006 DATA "   /{inv}ZZZZZZZZZZZZZ{/inv}ZZ<"
9007 DATA "        /{inv}ZZZZ{/inv}ZZZZZZZ"
9008 DATA "ZZ{inv}ZZZZZ{/inv}<*=({inv}ZZZ{/inv}      "
9009 DATA "{inv}ZZZZ{/inv}ZZZZZZZZZZZZZZZ{inv}Z{/inv}"
9010 DATA "{inv}ZZZZZZZ{/inv}(ZZZZZZZZZZZZ"
9011 DATA "ZZZZZZZZZZZZZZ{inv}ZZZZZZ{/inv}"
9012 DATA 27,2,4,33,2,4,43,3,5,56,1,6,66,2,3,77,3,4
9100 DATA "                    "
9101 DATA "        $+ #        "
9102 DATA "            =>      "
9103 DATA "  /{inv}ZZZ{/inv}<    /{inv}ZZZZ{/inv}<   "
9104 DATA "       =ZZ){inv}ZZZZZZ{/inv}   "
9105 DATA " /{inv}ZZ{/inv}<      /Z{inv}ZZZZZ{/inv}< "
9106 DATA " /ZZZZZzzzzZZZZZZ(> "
9107 DATA "      /ZZZZZZZZZZxxx"
9108 DATA "xZZZZ $  *=ZZZZZZZZ>"
9109 DATA "{inv}ZZ{/inv}ZZZZZzzzzZZZZZZZ{inv}ZZ{/inv}"
9110 DATA "{inv}ZZZZZZZ{/inv}ZZZZZZZZZZzzz"
9111 DATA "zZZZZ(Z)(ZZZZZZZZZZZ"
9112 DATA 25,1,3,34,1,4,43,3,4,55,1,4,64,1,2,77,1,3
9200 DATA "  +=){inv}ZZZZZ{/inv}     /{inv}ZZZZ{/inv}"
9201 DATA "{inv}ZZ{/inv}                $ "
9202 DATA "  /{inv}ZZZZ{/inv}xxxx>        "
9203 DATA " /ZZZZZZZZ     ZZZZZ"
9204 DATA "ZZ               =Z{inv}Z{/inv}"
9205 DATA "{inv}ZZZ{/inv}ZZZZzzzzZ        "
9206 DATA "=ZZZZZZZZZ  **/ZZZZZ"
9207 DATA "ZZ *+       /{inv}ZZZZZ{/inv}ZZ"
9208 DATA "ZZZZZZZzzzzZ{inv}ZZZZZ{/inv}<  "
9209 DATA "{inv}Z{/inv}ZZZZZZZZZ()ZZZZZZZZ"
9210 DATA "ZZ)ZZ){inv}ZZZZZZZ{/inv}ZZZZZZZ"
9211 DATA "ZZZZZZZzzzzZZZZZZZ(Z"
9212 DATA 27,0,5,38,0,6,49,3,4,55,2,3,65,0,4,76,2,3
9300 DATA "            /{inv}ZZZZZ{/inv}<+"
9301 DATA "                 /{inv}ZZ{/inv}"
9302 DATA "{inv}ZZZ{/inv}<      /{inv}ZZZZ{/inv}(>   "
9303 DATA "      /{inv}ZZZZ{/inv}({inv}ZZZZZZZ{/inv}Z"
9304 DATA "xxxxxxxxx{inv}ZZZ{/inv}<    ;;;"
9305 DATA ";;;;     =ZZZZZZZ>  "
9306 DATA "/{inv}ZZZZZZ{/inv}ZZZZZZZZZZZZZ"
9307 DATA "zzzzzzzzzZZZZ>      "
9308 DATA "        /ZZZZZZZZZ< "
9309 DATA "{inv}Z{/inv}ZZZZZZZZZZZZZZZZZZZ"
9310 DATA "zzzzzzzzzZZZZZ){inv}ZZZZZ{/inv}"
9311 DATA "{inv}ZZZZZZZZZ{/inv}ZZZZZZZZZZ)"
9312 DATA 23,2,4,29,1,4,35,0,5,51,1,3,59,3,8,73,0,4

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: ERACER.BAS.

Credits