Rockslide

Type
Game
Category
Puzzle-action game (one or two players)
Author
James Hague
Published in
Antic, May 1986 (Vol. 5, No. 1), Game of the Month
Year
1986
Language
Atari BASIC (with small machine-language routines)
Requirements
16K RAM with cassette or 24K with disk, Atari BASIC, one or two joysticks
Rockslide board 1: a maze of round blue boulders inside an orange frame labelled PLAYER 1 and PRESS BUTTON, with three darker rocks that are the diamonds

About the program

"Another one of those games that require the mentality of an ice cube?" Antic asked of the arcade games of 1986, before pointing to its May Game of the Month as the cure. Rockslide was the first Antic program by James Hague of Richardson, Texas, a "strategic Pongo-type arcade experience" that rewards both speed and smarts. (Hague returned later the same year with Uncle Henry's Nuclear Waste Dump.)

You're the Rockbuster, a noisy orange creature in a maze of blue or green boulders. Three of the rocks are flashing diamonds. Slide them about until all three touch in a horizontal or vertical row. The clock is running, and a careless push can jam a diamond in a corner for good.

Typing it in

Most special characters are inverse-video words on the score screens: {inv} … {/inv} means press the Atari (inverse) key before and after. {CTRL-M} is CTRL with M, used here as a spacer. Line 15020 is a machine-language string (XFR$) that copies the character set. {CTRL-E} and {CTRL-Q} mean hold CTRL and press the letter, and {CTRL-,}/{CTRL-.} are CTRL with comma/full stop. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.

How to play

"ANTIC PRESENTS" appears while the game sets itself up. At the title screen, SELECT chooses one or two players, OPTION chooses board 1, 2 or 3, and START begins. Board 1 is open and roomy, board 2 is a standard maze, and board 3 is "a rock crusher's delight".

  • Move with the joystick (no diagonals).
  • Slide a rock: stand next to it, press the button first, then push the stick. The rock slides until something stops it, unless there's another rock right behind it.
  • Smash a rock: hold the button while pushing against a rock that can't slide. Try it on a diamond and the computer razzes you.
  • If you're hopelessly stuck, press START to forfeit.

When the diamonds line up you hear an explosion and see your time. With two players, player two then takes a turn on joystick 2 and the faster time wins. Best times for each board are kept. Hague's own record on board 1 was 8.11 seconds.

How it works

  • Constants as variables. Lines 10100–10110 read 0–10 and 15 into variables called C0…C9, and the program uses those everywhere (POSITION C4,C8, #C6) instead of number constants. In Atari BASIC every numeric constant takes 7 bytes in memory, but a variable takes only one, so this keeps a large program small enough for 16K.
  • Flashing diamonds. A 16-byte vertical-blank routine (DATA 10160–10170) changes a colour register every frame, so the diamonds flash without any work from BASIC.
  • The X/Y offset tables in lines 10130–10140 turn joystick values into moves. The routines at 295 (slide), 425 (check for a line of diamonds) and 495 (crush) work on the screen through LOCATE and the redefined characters.

Listing

10 REM ROCKSLIDE
20 REM BY JAMES HAGUE
30 REM (c) 1986, ANTIC PUBLISHING
40 POKE 106,PEEK(740)-5:GRAPHICS 18:CHSET=(PEEK(106)+1)*256:POKE 752,1
45 POKE 712,66:POKE 708,152
50 ? #6:? #6:? #6;"    ANTIC":? #6:? #6;"    PRESENTS..."
100 GOSUB 15000:REM REDEFINE C-SET
110 GOSUB 10000:REM INITS.
120 GOSUB 7000:REM TITLE SCREEN
140 PL=C0
150 GOSUB 5000:REM SET-UP LEVEL
160 POKE 18,C0:POKE 19,C0:POKE 20,C0
165 REM MAIN LOOP
170 IF PEEK(53279)=C6 THEN TIME(PL)=-C1:GOTO 1100
175 POKE 16,112:POKE 53774,112
180 S=STICK(PL):IF S=15 THEN 170
190 IF  NOT STRIG(PL) THEN 260
195 REM PROCESS MOVE
200 TX=PX+XDIR(S):TY=PY+YDIR(S)
210 LOCATE TX,TY,A:IF A<>32 THEN 170
220 COLOR 32:PLOT PX,PY:PX=TX:PY=TY
230 COLOR 34:PLOT PX,PY
240 SOUND C0,40,C2,C8:FOR A=C1 TO C10:NEXT A:SOUND C0,C0,C0,C0
250 POKE 77,C0:GOTO 170
255 REM HANDLE TRIGGER PRESS
260 OX=PX+XDIR(S):OY=PY+YDIR(S):LOCATE OX,OY,A
270 IF A<>C3 AND A<>166 THEN 170
280 LOCATE OX+XDIR(S),OY+YDIR(S),B
290 IF B<>32 THEN 500
295 REM SLIDE ROUTINE
300 IF A=C3 THEN C=C3:GOTO 330
310 FOR A=C0 TO C2:IF XBOX(A)=OX AND YBOX(A)=OY THEN BOX=A
320 NEXT A:C=166
330 B=5
340 SOUND C0,B*5,C10,C8:B=B+1
350 TX=OX+XDIR(S):TY=OY+YDIR(S)
360 LOCATE TX,TY,A:IF A<>32 THEN 400
370 COLOR 32:PLOT OX,OY:OX=TX:OY=TY
380 COLOR C:PLOT OX,OY
390 GOTO 340
400 SOUND C0,C0,C0,C0
410 IF C<>166 THEN 170
420 XBOX(BOX)=OX:YBOX(BOX)=OY
425 REM CHECK BOXES
430 IF XBOX(C0)<>XBOX(C1) OR XBOX(C0)<>XBOX(C2) THEN 460
440 A=YBOX(C0)-YBOX(C1):B=YBOX(C0)-YBOX(C2):C=ABS(A):D=ABS(B)
450 IF ((C=1 AND D=1) OR A+B=3 OR A+B=-3) AND (C<3 AND D<3) THEN 1000
460 IF YBOX(C0)<>YBOX(C1) OR YBOX(C0)<>YBOX(C2) THEN 170
470 A=XBOX(C0)-XBOX(C1):B=XBOX(C0)-XBOX(C2):C=ABS(A):D=ABS(B)
480 IF ((C=1 AND D=1) OR A+B=3 OR A+B=-3) AND (C<3 AND D<3) THEN 1000
490 GOTO 170
495 REM CRUSH ROUTINE
500 IF A=C3 THEN 520
510 SOUND C0,150,C10,C8:FOR A=C1 TO 25:NEXT A:SOUND C0,C0,C0,C0:GOTO 170
520 SOUND C0,50,C2,C8:COLOR C4:PLOT OX,OY:FOR A=C1 TO 25:NEXT A
530 SOUND C0,70,C2,C8:COLOR C5:PLOT OX,OY:FOR A=C1 TO 25:NEXT A
540 COLOR 32:PLOT OX,OY
550 SOUND C0,C0,C0,C0:GOTO 170
997 REM BOARD DONE SCREEN
999 REM BOARD END EFFECTS
1000 TIME(PL)=PEEK(19)*256+PEEK(20)
1005 FOR A=C8 TO C0 STEP -C1
1010 FOR B=C15 TO C0 STEP -C1
1020 SOUND C0,B*5,C8,A+C2
1030 SETCOLOR C4,B,A
1040 NEXT B:NEXT A
1050 SETCOLOR C4,C0,C0
1060 SOUND C0,C0,C0,C0
1099 REM BOARD END SCREEN
1100 GOSUB 2500
1110 POSITION C3,C4:? #C6;"time: ";
1120 B=TIME(PL):GOSUB 2000
1130 POSITION C3,C5:? #C6;"best: ";
1140 B=BEST(BOARD-C1):GOSUB 2000
1150 IF TIME(PL)>B OR TIME(PL)=-1 THEN 1180
1160 POSITION C4,C8:? #C6;"{inv}A NEW RECORD{/inv}":BEST(BOARD-C1)=TIME(PL)
1170 FOR A=50 TO 150:SOUND C0,A,C10,C8:NEXT A:SOUND C0,C0,C0,C0
1180 POSITION C4,11:? #C6;"PRESS{inv}{CTRL-M}{/inv}BUTTON"
1190 IF STRIG(PL) THEN 1190
1200 GOSUB 2500
1210 IF PLAYERS=C2 AND PL=C0 THEN PL=C1:GOTO 150
1220 IF PLAYERS=C1 THEN GOTO 120
1230 REM FINAL SCREEN
1240 POSITION C5,C0:? #C6;"GAME{inv}{CTRL-M}{CTRL-M}{/inv}OVER"
1250 POSITION C3,C3:? #C6;"{inv}pl{/inv}.{inv}1{/inv}: ";
1260 B=TIME(C0):GOSUB 2000
1270 POSITION C3,C4:? #C6;"{inv}pl{/inv}.{inv}2{/inv}: ";
1280 B=TIME(C1):GOSUB 2000
1290 POSITION C3,C5:? #C6;"{inv}best{/inv}: ";
1300 B=BEST(BOARD-C1):GOSUB 2000
1310 POSITION C1,C8
1320 IF TIME(C0)=-1 AND TIME(C1)=-1 THEN ? #C6;"  {inv}DOUBLE FORFEIT{/inv}":GOTO 1400
1330 IF TIME(C0)=TIME(C1) THEN ? #C6;"    {inv}IT'S A TIE{/inv}":GOTO 1400
1340 IF (TIME(C0)<TIME(C1) AND TIME(C0)<>-1) OR TIME(C1)=-1 THEN ? #C6;"  {inv}PLAYER 1 WINS!{/inv}":GOTO 1360
1350 ? #C6;"  {inv}PLAYER 2 WINS!{/inv}"
1360 POSITION C5,C10
1370 IF TIME(C0)=-1 OR TIME(C1)=-1 THEN POSITION C5,C9:? #6;"{inv}BY FORFEIT{/inv}"
1400 IF STRIG(C0) AND STRIG(C1) THEN 1400
1410 GOTO 120
1997 REM ASSORTED ROUTINES
1999 REM TIME CONVERTER (B)
2000 IF B=-C1 THEN ? #C6;"ABORTED":RETURN
2010 MIN=INT(B/3600)
2020 SEC=INT((B-3600*MIN)/60)
2030 TEN=INT((B-(MIN*3600+SEC*60))/0.6)
2040 IF MIN<C10 THEN ? #C6;"0";
2050 ? #C6;MIN;":";
2060 IF SEC<C10 THEN ? #C6;"0";
2070 ? #C6;SEC;".";
2080 IF TEN<C10 THEN ? #C6;"0";
2090 ? #C6;TEN
2100 RETURN
2499 REM SCREEN CLEARER
2500 FOR A=C3 TO C0 STEP -C3
2510 FOR B=C1 TO C10
2520 COLOR A:PLOT C1,B:DRAWTO 18,B
2530 NEXT B:NEXT A
2540 RETURN
4998 REM LEVEL INITIALIZATION
5000 GRAPHICS 18:POKE 756,CHSET/256
5010 POKE 708,56:POKE 709,C0:POKE 711,28
5020 COLOR 141:PLOT C1,C0:DRAWTO 18,C0:PLOT C1,11:DRAWTO 18,11
5030 COLOR 136:PLOT C0,C1:DRAWTO C0,C10:PLOT 19,C1:DRAWTO 19,C10
5040 COLOR 137:PLOT C0,C0:COLOR 138:PLOT 19,C0:COLOR 139:PLOT C0,11:COLOR 140:PLOT 19,11
5050 COLOR C3:ON BOARD GOSUB 5700,5800,5900
5060 IF PL THEN 5121
5070 A=INT(RND(C0)*C5+C2):B=INT(RND(C0)*C8+C2):LOCATE A,B,C:IF C=32 THEN 5070
5080 XBO(C0)=A:YBO(C0)=B
5090 A=INT(RND(C0)*C5+C8):B=INT(RND(C0)*C8+C2):LOCATE A,B,C:IF C=32 THEN 5090
5100 XBO(C1)=A:YBO(C1)=B
5110 A=INT(RND(C0)*C4+14):B=INT(RND(C0)*C8+C2):LOCATE A,B,C:IF C=32 THEN 5110
5120 XBO(C2)=A:YBO(C2)=B
5121 FOR A=C0 TO C2:XBOX(A)=XBO(A):YBOX(A)=YBO(A):NEXT A
5130 POSITION C6,C0:? #6;"PLAYER{inv}{CTRL-M}{/inv}";PL+1
5135 FOR A=1 TO 100:NEXT A
5140 IF  NOT PL THEN C=7:GOTO 5160
5150 C=12
5160 FOR A=0 TO 8:SETCOLOR 1,C,A:FOR B=1 TO 10:NEXT B:NEXT A:FOR B=C1 TO 100:NEXT B
5170 COLOR 166
5180 FOR A=C0 TO C2:PLOT XBOX(A),YBOX(A):FOR B=C15 TO C0 STEP -C1:SOUND C0,50,C10,B:NEXT B:C=C^C1:NEXT A
5190 POSITION C4,11:? #6;"PRESS{inv}{CTRL-M}{/inv}BUTTON"
5200 IF STRIG(PL) THEN 5200
5202 COLOR 141:PLOT C1,11:DRAWTO 18,11
5210 PX=C9:PY=C6:COLOR 34:PLOT PX,PY
5230 RESTORE 5250:FOR A=C0 TO 18:READ B:SOUND C0,B,C10,C15:FOR B=C0 TO C5:NEXT B:NEXT A
5240 RETURN
5245 REM MUSIC DATA
5250 DATA 85,0,64,0,50,0,42,0,0,50,0,42,42,42,42,42,42,42,0
5699 REM BOARD 1
5700 PLOT C8,C4:DRAWTO 11,C4:DRAWTO 11,C7:DRAWTO C8,C7:DRAWTO C8,C4
5710 PLOT C8,C2:DRAWTO C2,C2:DRAWTO C2,C9:DRAWTO C8,C9
5720 PLOT 11,C2:DRAWTO 17,C2:DRAWTO 17,C9:DRAWTO 11,C9
5730 PLOT C5,C8:DRAWTO C5,C5:DRAWTO C7,C5:PLOT 14,C3:DRAWTO 14,C6:DRAWTO 12,C6
5740 PLOT C3,C3:PLOT 16,C8:PLOT C1,C8:PLOT 18,C3
5750 RETURN
5799 REM BOARD 2
5800 PLOT C4,C1:PLOT C5,C3:PLOT C5,C2:DRAWTO C2,C2:DRAWTO C2,C9:DRAWTO C4,C9:DRAWTO C4,C6:DRAWTO C8,C6
5810 PLOT C10,C6:PLOT 11,C6:DRAWTO 11,C4:DRAWTO 14,C4:DRAWTO 14,C2:PLOT 13,C5:DRAWTO C15,C5:DRAWTO C15,C10
5820 DRAWTO C6,C10:PLOT C10,C9:PLOT 13,C7:PLOT 13,C8:DRAWTO C6,C8:PLOT 16,C7:PLOT 17,C7:DRAWTO 17,C9:PLOT C9,C3
5830 PLOT 12,C1:PLOT 12,C2:DRAWTO C7,C2:PLOT C9,C4:DRAWTO C3,C4:PLOT 18,C1
5840 DRAWTO 16,C1:DRAWTO 16,C3:PLOT 17,C3:DRAWTO 17,C5
5850 RETURN
5899 REM BOARD 3
5900 FOR A=C1 TO C10:PLOT C1,A:DRAWTO 18,A:NEXT A:COLOR 32
5910 PLOT C1,C1:DRAWTO 18,C1:DRAWTO 18,C10:DRAWTO C1,C10:DRAWTO C1,C1
5920 PLOT C9,C2:DRAWTO C9,C5:DRAWTO 17,C5
5930 PLOT C2,C6:DRAWTO C10,C6:DRAWTO C10,C9
5940 PLOT C2,C2:PLOT 17,C2:PLOT C2,C9:PLOT 17,C9
5950 RETURN
6998 REM TITLE SCREEN, ETC.
7000 GRAPHICS 17:POKE 756,CHSET/256
7010 DL=PEEK(560)+PEEK(561)*256
7020 POKE DL+C9,C7:POKE DL+28,C0
7030 POKE 708,40:POKE 709,88
7040 POKE 711,202
7050 POSITION C3,C3:? #C6;"james  hague's"
7060 FOR A=C1 TO 100:NEXT A
7070 POSITION C5,C4:? #C6;"{inv}ROCKSLIDE!{/inv}"
7080 POSITION C3,C5:? #C6;"COPYRIGHT 1986"
7090 COLOR 141:PLOT C1,C2:DRAWTO 18,C2:PLOT C1,C6:DRAWTO 18,C6
7100 COLOR 136:PLOT C1,C3:DRAWTO C1,C5:PLOT 18,C3:DRAWTO 18,C5
7105 COLOR 137:PLOT C1,C2:COLOR 138:PLOT 18,C2:COLOR 139:PLOT C1,C6:COLOR 140:PLOT 18,C6
7110 POSITION C1,13:? #C6;"option for board"
7120 POSITION C2,14:? #C6;"select for players"
7130 POSITION C3,C15:? #C6;"start to begin"
7140 POSITION C5,17:? #C6;"{inv}best times{/inv}"
7150 FOR A=C0 TO C2:POSITION C1,18+A:? #C6;">{inv}board{/inv} ";A+C1;": ";
7160 B=BEST(A):GOSUB 2000:NEXT A
7170 POSITION C5,C10:? #C6;"PLAYERS: ";PLAYERS
7180 POSITION C5,C9:? #C6;"BOARD  : ";BOARD
7185 FOR A=C1 TO 25:NEXT A
7190 IF PEEK(53279)=C6 OR  NOT STRIG(0) THEN RETURN
7200 IF PEEK(53279)<>C5 THEN 7220
7210 PLAYERS=PLAYERS+C1:IF PLAYERS=C3 THEN PLAYERS=C1
7220 IF PEEK(53279)<>C3 THEN 7240
7230 BOARD=BOARD+C1:IF BOARD=C4 THEN BOARD=C1
7240 GOTO 7170
9998 REM MAIN INITIALIZATION
10000 DIM XDIR(15),YDIR(15),XBOX(2),YBOX(2),TIME(1),BEST(2),XBO(2),YBO(2)
10010 RESTORE 10110:READ C0,C1,C2,C3,C4,C5,C6,C7,C8,C9,C10,C15
10020 PLAYERS=C2:BOARD=C1:BEST(C0)=3600:BEST(C1)=3600:BEST(C2)=3600
10030 FOR A=C1 TO C15:READ B:XDIR(A)=B:NEXT A
10040 FOR A=C1 TO C15:READ B:YDIR(A)=B:NEXT A
10050 FOR A=C0 TO C15:READ B:POKE 1664+A,B:NEXT A:A=USR(1664)
10060 RETURN
10100 REM CONSTANTS
10110 DATA 0,1,2,3,4,5,6,7,8,9,10,15
10120 REM X & Y OFFSETS
10130 DATA 0,0,0,0,0,0,1,0,0,0,-1,0,0,0,0
10140 DATA 0,0,0,0,0,0,0,0,0,0,0,0,1,-1,0
10150 REM VBI FLASH ROUTINE
10160 DATA 104,162,6,160,138,169,7,76
10170 DATA 92,228,238,198,2,76,98,228
14998 REM REDEFINE CHARACTERS
15000 CHI=CHSET/256:CLO=0:POKE 203,CLO:POKE 204,CHI
15010 DIM XFR$(28)
15020 XFR$="h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}M(){CTRL-.}{CTRL-E}N1M{CTRL-Q}KHPyfLfN%NIdPo{/inv}{CTRL-.}"
15040 XFR=USR(ADR(XFR$))
15050 RESTORE 15090
15060 READ A:IF A=-1 THEN RETURN
15070 FOR Z=0 TO 7:READ J:POKE CHSET+A*8+Z,J:NEXT Z
15080 GOTO 15060
15100 DATA 2,60,126,219,219,255,102,126,231
15110 DATA 3,0,124,254,254,254,254,254,124
15120 DATA 4,0,0,56,124,124,124,56,0
15130 DATA 5,0,0,0,56,56,56,0,0
15140 DATA 6,0,56,124,238,198,238,124,56
15150 DATA 13,0,0,255,255,255,255,0,0
15160 DATA 8,60,60,60,60,60,60,60,60
15170 DATA 9,0,0,31,63,63,63,62,60
15180 DATA 10,0,0,248,252,252,252,124,60
15190 DATA 11,60,62,63,63,63,31,0,0
15200 DATA 12,60,124,252,252,252,248,0,0
15210 DATA -1

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: ROCKSLDE.BAS.

Credits