Uncle Henry's Nuclear Waste Dump
- Type
- Game
- Category
- Puzzle-action game
- Author
- James Hague
- Published in
- Antic, December 1986 (Vol. 5, No. 8), Game of the Month
- Year
- 1986
- Language
- Atari BASIC (with machine-language strings)
- Requirements
- Any Atari 8-bit computer, any memory size, Atari BASIC, joystick in port 1; disk or cassette
About the program
Uncle Henry is always after a fast buck. When he found out how many corporations needed somewhere to dump their nuclear waste, he spent six months thinking and then opened the Nuclear Waste Dump behind the local Sloppy Joe Hut. Business boomed, there was too much waste for one man, and you answered his advert. "I hope you've got insurance," he says, as you put on your yellow rubber suit.
James Hague's Antic Game of the Month for December 1986 came seven months after his Rockslide. Like that game it is a puzzle wearing an arcade game's clothes. The dump uses "the most advanced method of waste disposal known to man", which is dumping the stuff in a pit.
Typing it in
Lines 9040, 9050 and 9085 hold machine-language routines as strings full of inverse and control characters ({inv} … {/inv} means press the Atari key before and after, {CTRL-E} means hold CTRL and press E, and {CTRL-,}/{CTRL-.} are CTRL with comma/full stop). The magazine's Listing 2 wrote those three lines to a file for you, but it isn't on the disk ("not needed" for disk owners), so type them with care. A few other lines contain short inverse words. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.
How to play
At the title screen, SELECT sets the speed from 1 (easy) to 5 (hard). START or the fire button begins. Uncle Henry hands you a can. Move it along the rim of the pit with the joystick and press the button to drop it. The can falls and bounces down the pile until it settles.
- There are three kinds of waste, each with its own shape and colour. A can must never come to rest on or beside a can of the same kind, or it's "the end of your little corner of the world". A same-type can may bounce off one on the way down, as long as it ends up somewhere else.
- A timer at the top right counts down while you hold a can. When it reaches zero a buzzer sounds and you drop the can where you are.
- Each can safely dumped is worth 10 points. Pile one can as high as the rim of the pit for a 1,000-point bonus, some special effects and early retirement.
Hague's tip: when a can has the choice of rolling left or right, it always goes left. Uncle Henry also offers words of wisdom along the way.
How it works
The pit is a character screen. As a can falls, line 470 uses three LOCATEs to look left, right and below it, and compares the codes with the can's own character to spot a fatal match. Like Rockslide, the program reads its common constants into variables C0–C9 to save memory. BOOM$ and RAINBOW$ are machine-language routines for the explosion and the winning colour effect, and line 9085 copies the character set. Line 900 contains a leftover REM DEBUG line that disables BREAK.
Listing
10 REM UNCLE HENRY'S NUCLEAR WASTE DUMP
20 REM BY JAMES HAGUE
30 REM (c) 1986, ANTIC PUBLISHING
40 BRK=1:IF PEEK(53279)=5 THEN BRK=0
100 GOSUB 9000:REM MAIN INIT.
110 GOSUB 8000:REM TITLE SCREEN
120 GOSUB 7000:REM GAME INIT.
195 REM MAIN GAME LOOP
200 GOSUB 6000:LAST1=A
210 GOSUB 6000:IF LAST1=A THEN 210
220 LAST2=A
230 TIME=C6-SPEED:POSITION 18,C0:? #C6;TIME
240 GOSUB 6000:IF A=LAST1 OR A=LAST2 THEN 240
250 LAST2=LAST1:LAST1=A:CHAR=A
260 X=C9:Y=C3:PLOT X,Y
270 POKE 20,C0
275 REM DECIDE WHERE TO DUMP WASTE
280 IF PEEK(20)>=90 THEN 360
290 B=STICK(C0)
300 IF B=11 AND X>C3 THEN A=X-C1:GOTO 340
310 IF B=C7 AND X<16 THEN A=X+C1:GOTO 340
320 IF NOT STRIG(C0) THEN 390
330 GOTO 280
340 COLOR C32:PLOT X,Y:COLOR CHAR:PLOT A,Y:X=A
350 SOUND C0,RND(C0)*C10+C10,C2,C6:FOR A=C1 TO C10:NEXT A:SOUND C0,C0,C0,C0:GOTO 280
360 TIME=TIME-C1:POSITION 18,C0:? #C6;TIME
370 IF TIME>C0 THEN 270
380 SOUND C0,30,12,C15:FOR A=C1 TO 200:NEXT A:SOUND C0,C0,C0,C0
385 REM HANDLE FALLING WASTE
390 A=Y+C1:COLOR C32:PLOT X,Y:COLOR CHAR:PLOT X,A:Y=A
400 LOCATE X,Y+C1,A:IF A<>C32 THEN 430
410 SOUND C0,Y+200,C10,C8:SOUND C1,Y+200,C10,C8:A=C2:GOSUB 6100
420 GOTO 390
430 FOR A=C10 TO C15:SOUND C0,50,C8,A:SOUND C1,150,C8,A:NEXT A
440 FOR A=C15 TO C0 STEP -C1:SOUND C0,40,C8,A:SOUND C1,125,C8,A:NEXT A
450 LOCATE X-C1,Y+C1,A:IF A=C32 THEN A=-C1:GOTO 550
460 LOCATE X+C1,Y+C1,A:IF A=C32 THEN A=C1:GOTO 550
470 LOCATE X-C1,Y,A:LOCATE X+C1,Y,B:LOCATE X,Y+C1,C:IF A=CHAR OR B=CHAR OR C=CHAR THEN 700:REM LOSE!
480 SCORE=SCORE+C10:POSITION C7,C0:? #C6;SCORE
490 IF SCORE>HIGH THEN HIGH=SCORE
500 IF Y=C7 THEN 1000:REM WIN!
510 IF PEEK(633)=13 THEN COLOR 78:PLOT C1,C6:COLOR 90:PLOT 18,C6
520 GOTO 230
550 A=X+A:COLOR C32:PLOT X,Y:COLOR CHAR:PLOT A,Y:X=A
560 A=C5:GOSUB 6100:GOTO 390
695 REM END OF THE WORLD
700 POSITION C7,C3:? #C6;"{inv}OH NO!{/inv}"
710 FOR A=C1 TO C3
720 FOR B=48 TO C0 STEP -C1:SOUND C0,B,C8,C15:SOUND C0,B*C3,C8,C15:POKE 712,B:NEXT B:NEXT A
730 SOUND C0,50,C8,C15:GRAPHICS 18:A=USR(ADR(BOOM$))
740 GRAPHICS C0:POKE 559,C0:POKE 710,C0:POKE 752,C1:SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0
750 POSITION C4,12:? CHR$(34);"Good help is so hard to find.";CHR$(34):POSITION 22,14:? "-Uncle Henry"
760 COLOR 14:PLOT C0,23:DRAWTO 39,23
770 COLOR 160:FOR A=C0 TO C2:PLOT 28,21+A:DRAWTO 30,21+A:NEXT A:PLOT 30,23
780 POSITION 28,20:? "{inv}RIP{/inv}":POSITION 28,19:? "{CTRL-H}{inv} {/inv}{CTRL-J}"
790 COLOR 124:PLOT 29,18:COLOR 19:PLOT 29,17
800 POKE 559,34:A=240:GOSUB 6100
810 GOTO 110
900 IF BRK THEN POKE 16,112:POKE 53774,112:REM DEBUG
910 RETURN
995 REM YOU WIN!
1000 POSITION C7,C3:? #C6;"YAHOO!"
1010 FOR A=200 TO C10 STEP -C10:FOR B=C15 TO C10 STEP -C1:SOUND C0,A,C10,B:SOUND C0,A+25,C10,B:NEXT B:NEXT A
1015 SOUND C0,243,C10,C10:SOUND C1,193,C10,C10:SOUND C2,162,C10,C10
1020 GRAPHICS 18:POKE 708,C0
1030 POSITION C1,C5:? #C6;"1000 BONUS POINTS!":A=USR(ADR(RAINBOW$))
1035 FOR A=C0 TO C2:SOUND A,C0,C0,C0:NEXT A
1040 SCORE=SCORE+1000:IF SCORE>HIGH THEN HIGH=SCORE
1050 GRAPHICS C0:POKE 559,C0:POKE 710,C0:POKE 752,C1
1060 POSITION C2,C10:? CHR$(34);"Not bad, but why are you glowing?";CHR$(34)
1070 POSITION 24,12:? "-Uncle Henry"
1080 POKE 559,34:A=240:GOSUB 6100
1090 GOTO 110
5995 REM RETURN RANDOM WASTE CHAR (A)
6000 A=INT(RND(C0)*C3)
6010 IF NOT A THEN A=38:GOTO 6040
6020 IF A=C1 THEN A=167:GOTO 6040
6030 A=136
6040 COLOR A
6050 GOSUB 900
6060 RETURN
6095 REM WAIT 1-255 JIFFIES (A)
6100 GOSUB 900:POKE 20,C0
6110 IF PEEK(20)<A THEN 6110
6120 RETURN
6995 REM GAME INIT.
7000 GRAPHICS C0:POKE 559,C0:POKE 710,C0:POKE 752,C1:SCORE=C0
7010 POSITION C5,C10:? CHR$(34);"I hope you've got insurance.";CHR$(34)
7020 POSITION 22,12:? "-Uncle Henry"
7030 POKE 559,34:A=180:GOSUB 6100
7040 GRAPHICS 17:POKE 559,C0:POKE 756,CHSET/C256
7050 POKE 708,26:POKE 709,38:POKE 710,202:POKE 711,134:POKE 712,C0
7060 POSITION C1,C0:? #C6;"{inv}SCORE:{/inv}0 {inv}SPD:{/inv}";SPEED;" 0"
7070 COLOR C5:FOR A=C0 TO C2:PLOT A,C7:DRAWTO A,23:PLOT 17+A,C7:DRAWTO 17+A,23:NEXT A
7080 PLOT C3,22:DRAWTO 16,22:PLOT C3,23:DRAWTO 16,23
7090 COLOR C3:PLOT C2,C7:COLOR C4:PLOT 17,C7
7100 GOSUB 6000:PLOT C3,21:B=A
7110 FOR C=C4 TO 16
7120 GOSUB 6000:IF A=B THEN 7120
7130 PLOT C,21:B=A:NEXT C
7140 POKE 559,34:A=30:GOSUB 6100
7150 POSITION C6,C3:? #C6;"READY..."
7160 A=60:GOSUB 6100
7170 POSITION C6,C3:? #C6;" "
7180 POSITION C7,C4:? #C6;"SET..."
7190 GOSUB 6100
7200 POSITION C7,C4:? #C6;" "
7210 POSITION C2,C5:? #C6;"{inv}DUMP THAT WASTE!{/inv}"
7220 FOR A=C1 TO C4:FOR B=C10 TO C0 STEP -C1:SOUND C0,C15,C10,B:SOUND C1,31,C10,B:SOUND C2,64,C10,B:NEXT B:NEXT A
7230 COLOR 32:PLOT C2,C5:DRAWTO 17,C5
7240 RETURN
7995 REM TITLE SCREEN
8000 POKE 559,C0
8010 POKE 708,134:POKE 709,C10:POKE 710,C0:POKE 711,38:POKE 712,C0
8020 POKE 560,C0:POKE 561,C6
8030 FOR A=C0 TO C3:POKE TITLE+11+A,16:POKE TITLE+22+A,16:NEXT A
8040 A$=STR$(SCORE):B=LEN(A$)
8050 FOR A=C1 TO B:POKE 14-B+TITLE+A,ASC(A$(A,A))-C32:NEXT A
8060 A$=STR$(HIGH):B=LEN(A$)
8070 FOR A=C1 TO B:POKE 25-B+TITLE+A,ASC(A$(A,A))-C32:NEXT A
8080 POKE TITLE+34,SPEED+16
8090 POKE 559,34
8100 IF PEEK(53279)=C6 OR NOT STRIG(C0) THEN RETURN
8110 FOR A=C1 TO 25:NEXT A
8120 IF PEEK(53279)<>C5 THEN 8100
8130 SPEED=SPEED+C1:IF SPEED>C5 THEN SPEED=C1
8140 POKE TITLE+34,SPEED+16
8150 IF PEEK(53279)=C5 THEN 8150
8160 GOTO 8090
8995 REM MAIN INIT.
9000 RESTORE 9500:READ C0,C1,C2,C3,C4,C5,C6,C7,C8,C9,C10,C15,C32,C256,C512
9010 GRAPHICS 18:POKE 708,C0:POKE 712,56:POSITION C3,C5:? #C6;"OH NO! IT'S..."
9020 SPEED=C3:GOSUB 900
9030 DIM MEM$(1324),BOOM$(18),RAINBOW$(17),A$(40)
9040 BOOM$="h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-T}{inv}-{/inv}{CTRL-J}{inv}R{CTRL-M}{/inv}{CTRL-Z}{inv}P%{/inv}{CTRL-T}{inv}I{/inv}x{inv}{CTRL-P}t{/inv}{CTRL-.}"
9050 RAINBOW$="h{inv}){/inv}{CTRL-A}{inv}{CTRL-E}{/inv}{CTRL-T}{inv}{CTRL-L}{/inv}{CTRL-J}{inv}T{CTRL-L}{/inv}{CTRL-Z}{inv}PH%{/inv}{CTRL-T}{inv}Pu{/inv}{CTRL-.}"
9060 MEM$="{CTRL-,}":MEM$(1324)="{CTRL-,}":MEM$(C2)=MEM$
9070 A=ADR(MEM$):CHSET=C512-(A-INT(A/C512)*C512)+A:TITLE=CHSET+C512
9080 POKE 203,C0:POKE 204,CHSET/C256
9085 A=USR(ADR("h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}M(){CTRL-.}{CTRL-E}N1M{CTRL-Q}KHPyfLfN%NIbPo{/inv}{CTRL-.}"))
9090 FOR A=C0 TO 47:READ B:POKE CHSET+24+A,B:NEXT A
9100 FOR A=C0 TO 29:READ B:POKE 1536+A,B:NEXT A:POKE 1540,C0:POKE 1541,TITLE/C256
9110 READ A:IF A=-1 THEN RETURN
9120 READ A$
9130 FOR B=C1 TO LEN(A$):C=ASC(A$(B,B))
9140 IF C<96 THEN C=C-C32
9150 POKE TITLE+A+B-C1,C:NEXT B
9160 GOTO 9110
9495 REM CONSTANTS
9500 DATA 0,1,2,3,4,5,6,7,8,9,10,15,32,256,512
9525 REM CHARACTER DATA
9530 DATA 248,254,255,255,255,255,255,255
9540 DATA 31,127,255,255,255,255,255,255
9545 DATA 255,255,255,255,255,255,255,255
9550 DATA 0,254,124,56,16,56,124,254
9560 DATA 0,124,254,254,238,254,254,124
9570 DATA 0,254,130,186,170,186,130,254
9575 REM TITLE DISPLAY LIST
9580 DATA 112,112,112,66,0,0,112,112,112,6,7,112,2,112,112,112,6,6,112,112,112,2,7,112,112,112,2,65,0,6
9585 REM TITLE TEXT
9590 DATA 5,SCORE:XXXX HIGH:XXXX SPEED:
9600 DATA 43,UNCLE HENRY'S
9610 DATA 61,{inv}nuclear waste dump{/inv}
9620 DATA 89,OVER 50 BILLION SERVED
9630 DATA 123,START TO BEGIN
9640 DATA 142,SELECT FOR SPEED
9650 DATA 161,another game from the demented mind of
9660 DATA 204,{inv}james hague{/inv}
9670 DATA 227,(c) 1986 Antic Publishing
9680 DATA -1
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: NUCWASTE.BAS.
Credits
- Program listing: Uncle Henry's Nuclear Waste Dump — program listing (Antic, December 1986 (Vol. 5, No. 8), Game of the Month) — James Hague
- Picture: The start of a game at speed 3. The bottom row is already alternating can types. — James Hague (program); screenshot by the site
- Antic, December 1986 - Vol. 5 No. 8: article (atarimagazines.com) — James Hague, 1986
- Antic disk, December 1986 - Vol. 5 No. 8: NUCWASTE.BAS (detokenized listing) — AtariMagazines.com (Kevin Savetz), 1986
