Current Events
- Type
- Game
- Category
- Two-player territory race
- Author
- James Hague
- Published in
- Antic, February 1988 (Vol. 6, No. 10), Game of the Month
- Year
- 1988
- Language
- Atari BASIC (with machine-language routines in strings)
- Requirements
- 32K RAM, Atari BASIC, two joysticks (ports 1 and 2)
About the program
Antic's subtitle said most players can't take it for more than 45 seconds. Every Sunday night, the two founders of Ice Cubes International ("famous for its line of monogrammed cubes") settle who gets the company computer by yanking circuits out of it. In the game, two players each steer a "Thing" around a white grid-shaped circuit. Wherever you go, the circuit turns your colour with a pulsing trail, including stretches your opponent has already claimed. When time runs out, the program counts the cells and declares who "reigns supreme".
James Hague was a computer science student at North Texas State University. He had already given Antic the "impressively demented" games Rockslide (May 1986) and Uncle Henry's Nuclear Waste Dump (December 1986), and the Rainbow Screen Customizer utility (March 1987).
Typing it in
You'll need 32K. Several lines hold machine code or character data as strings packed with inverse and control characters: 9025–9030, 9080–9100, 9120 and 9180–9186. In this notation, {inv}…{/inv} means type with the Atari key on, {CTRL-E} means hold CTRL and press E, {CTRL-,} is CTRL-comma, and {BACK S}, {INS CHAR} and the like are ESC followed by that key. The magazine supplied a helper listing that wrote these lines to LINES.LST for you to ENTER over the main program. The disk listing here has them merged in. Hold SELECT while typing RUN if you want BREAK to keep working (lines 100 and 7000).
How to play
Plug in two joysticks. On the title screen, SELECT sets the game length in 15-second steps from 15 seconds to two minutes, and START (or either fire button) begins. Player 1 (blue) starts bottom left and player 2 (yellow) top right.
- Push the stick to set off. You keep moving until you hit the edge of the circuit, and you can't reverse. To go back, you have to go round the block.
- The red arrows on the left and right edges are transporters. Drive into one and you jump to the other side, and it vanishes. There are only four.
- If the two Things collide, both go back to their corners and set off in random directions.
- Five red ? boxes are scattered around. Each hides one of five events, and each event happens only once per game: nothing; a blue splatter or a yellow splatter that paints the area around it; a position switcher that swaps both players' places and directions; or the disrupter, which shorts out the display so that for six seconds you can't see which colour anything is.
The article's strategy advice: painting fresh white or enemy circuit is worth far more than going over your own trail, and a collision or even the disrupter can be used to your advantage.
How it works
The circuit is a GRAPHICS 2 screen with a redefined character set. Lines 9050 and 9110 put the character set and player-missile memory inside one big string, MEM$, rounded up to a 2K boundary. Each cell of the circuit is a character, and its top two bits (+0 or +192, see lines 250 and 500) record which player owns it. That's why the final count in lines 3040–3070 just PEEKs screen memory and sorts values below 64 from those above 192. The Things are players 0 and 1, moved vertically by a small machine-language routine (VMOVE). Another routine (JOY) reads both sticks, and a third (CHOP) picks the right trail character.
The countdown is kept by a machine-language routine installed in page 6 and started by USR(1536) in line 9190, so it ticks away on its own while BASIC runs the game. BASIC hands it the time as packed BCD in locations 204–205. The main loop ends when both bytes reach zero (line 130). The disrupter just pokes a 360-frame count (six seconds) into 206–207 (line 590), and the interrupt does the rest.
Variations to try
- Allow longer games: change the 120-second limit in line 8050.
- Add more event boxes. The
FOR A=1 TO 5loop in line 2140 places them, but there are only five events in theEVENT()table, so extra boxes need a sixth event or a "nothing" fallback.
Changes from the published listing
One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds a command called DIR, so it rejected the published lines that use that word as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.
| Published | Now | Lines |
|---|---|---|
DIR |
DRN |
150, 170, 180, 190, 200, 565, 1530, 2060, 9020 |
Listing
10 REM CURRENT EVENTS
20 REM BY JAMES HAGUE
30 REM (c)1987, ANTIC PUBLISHING
100 BRK=1:IF PEEK(53279)=5 THEN BRK=0
110 GOSUB 9000
120 GOSUB 8000:GOSUB 2000:PL=1
130 PL= NOT PL:IF NOT PEEK(204) AND NOT PEEK(205) THEN GOTO 3000
140 D=USR(JOY,PL):IF NOT D THEN 180
150 IF D=OPDIR(DRN(PL)) OR D=DRN(PL) THEN 180
160 POS=POS(PL)+ADD(D):IF POS<MIN OR POS>MAX THEN 180
170 A=PEEK(POS):IF A THEN DRN(PL)=D:GOTO 210
180 D=DRN(PL):IF NOT D THEN 130
190 POS=POS(PL)+ADD(D):IF POS<MIN OR POS>MAX THEN DRN(PL)=0:GOTO 130
200 A=PEEK(POS):IF NOT A THEN DRN(PL)=0:GOTO 130
210 IF POS=POS( NOT PL) THEN 1500
220 IF A=156 OR A=157 THEN 1000
230 SOUND 0,50+X,8,8:POS(PL)=POS:B=YP(PL):YP(PL)=YP(PL)+YPA(D):XP(PL)=XP(PL)+XPA(D):C=USR(VMOVE,PL,B,YP(PL))
240 POKE 53248+PL,XP(PL):POKE 53761,0:IF A=158 THEN 500
250 A=USR(CHOP,A):IF PL THEN A=A+192
260 POKE POS,A:GOTO 130
499 REM EVENT HANDLER
500 A=0:IF PL THEN A=192
510 POKE POS,27+A
520 B=INT(RND(0)*5):IF EVENT(B) THEN 520
530 EVENT(B)=1:ON B+1 GOTO 560,590,600
540 A=0:IF B=4 THEN A=192
550 POKE POS-2,7+A:POKE POS-1,7+A:POKE POS-20,6+A:POKE POS+1,7+A:POKE POS+2,7+A:POKE POS+20,6+A:GOTO 600
560 A=USR(VMOVE,0,YP(0),0):A=USR(VMOVE,1,YP(1),0)
565 A=DRN(0):DRN(0)=DRN(1):DRN(1)=A:A=POS(0):POS(0)=POS(1):POS(1)=A
570 POKE 53248,XP(1):A=USR(VMOVE,0,YP(0),YP(1)):POKE 53249,XP(0):A=USR(VMOVE,1,YP(1),YP(0))
580 A=XP(0):XP(0)=XP(1):XP(1)=A:A=YP(0):YP(0)=YP(1):YP(1)=A
585 POKE POS(0),USR(CHOP,PEEK(POS(0))):POKE POS(1),USR(CHOP,PEEK(POS(1)))+192:GOTO 600
590 POKE 206,104:POKE 207,1:GOTO 130
600 A=1:FOR B=15 TO 0 STEP -1:SOUND 0,60,10,B:SOUND 1,45,10,B:GOSUB 7100:NEXT B:GOTO 130
999 REM TRANSPORT HANDLER
1000 A=0:IF PL THEN A=192
1010 IF XP(PL)=56 THEN XP(PL)=192:POKE 53248+PL,192:POKE POS,0:POKE POS+1,12+A:POS=POS+18:POKE POS+1,0:GOTO 1030
1020 XP(PL)=56:POKE 53248+PL,56:POKE POS,0:POKE POS-1,13+A:POS=POS-18:POKE POS-1,0
1030 POS(PL)=POS:IF POS=POS( NOT PL) THEN POKE POS,PEEK(POS)-14-(XP(PL)=56):GOTO 1500
1040 IF XP(PL)=56 THEN POKE POS,12+A:GOTO 1060
1050 POKE POS,13+A
1060 FOR A=3 TO 15:SOUND 0,20,2,A:NEXT A:GOTO 130
1499 REM PLAYER COLLISION
1500 FOR A=250 TO 0 STEP -10:POKE 712,A/10:SOUND 0,A,8,14:NEXT A
1505 A=USR(VMOVE,0,YP(0),0):A=USR(VMOVE,1,YP(1),0)
1510 POS(0)=SCREEN+221:XP(0)=56:POKE 53248,56:A=USR(VMOVE,0,YP(0),208):YP(0)=208:POKE POS(0),10
1520 POS(1)=SCREEN+38:XP(1)=192:POKE 53249,192:A=USR(VMOVE,1,YP(1),48):YP(1)=48:POKE POS(1),201
1530 DRN(0)=INT(RND(0)*2)+1:DRN(1)=INT(RND(0)*2)+3:GOTO 130
1999 REM LEVEL SET-UP
2000 FOR B=201 TO 192 STEP -1:POKE 709,B:A=1:GOSUB 7100:NEXT B:GRAPHICS 18:GOSUB 7000:POKE 559,0
2010 POKE 756,CHSET/256:POKE 709,0:POKE 710,38:POKE 704,0:POKE 705,0
2015 SCREEN=PEEK(88)+256*PEEK(89):MIN=SCREEN+20:MAX=SCREEN+239
2020 A=INT(TIME/60):POKE 205,(A<>0)*A:IF A*60=TIME THEN POKE 204,0:GOTO 2040
2030 A$=STR$(TIME-A*60):POKE 204,VAL(A$(1,1))*16+VAL(A$(2))
2040 POKE 206,0:POKE 207,0
2050 POS(0)=SCREEN+221:XP(0)=56:YP(0)=208:POS(1)=SCREEN+38:XP(1)=192:YP(1)=48
2060 FOR A=0 TO 1:POKE 53248+A,XP(A):B=USR(VMOVE,A,0,YP(A)):DRN(A)=0:NEXT A
2070 FOR A=0 TO 4:EVENT(A)=0:NEXT A
2080 COLOR 6:PLOT 1,2:DRAWTO 1,10:PLOT 18,2:DRAWTO 18,10
2090 FOR A=1 TO 11 STEP 2:COLOR 27:PLOT 1,A:PLOT 18,A:COLOR 7:PLOT 2,A:DRAWTO 17,A:NEXT A
2100 FOR A=5 TO 14 STEP 3:COLOR 14:PLOT A,1:COLOR 15:PLOT A,11:COLOR 6:PLOT A,2:DRAWTO A,10:COLOR 27:PLOT A,3
2110 PLOT A,5:PLOT A,7:PLOT A,9:NEXT A:COLOR 8:PLOT 1,1:COLOR 9:PLOT 18,1
2120 COLOR 10:PLOT 1,11:COLOR 11:PLOT 18,11
2130 POKE 53277,2:POKE 559,62
2140 COLOR 190:FOR A=1 TO 5
2150 B=INT(RND(0)*4)*3+5:C=INT(RND(0)*4)*2+3:LOCATE B,C,D:IF D=190 THEN 2150
2160 PLOT B,C:FOR B=15 TO 0 STEP -1:SOUND 0,100,10,B:NEXT B:NEXT A
2170 FOR B=0 TO 8:POKE 704,128+B:POKE 705,16+B:A=2:GOSUB 7100:NEXT B
2180 FOR B=0 TO 10:POKE 709,B:GOSUB 7100:NEXT B
2190 FOR A=3 TO 9 STEP 2:COLOR 188:PLOT 0,A:COLOR 189:PLOT 19,A:NEXT A
2200 POSITION 5,0:? #6;"time ";:B=160:GOSUB 7050:A=40:GOSUB 7100:POSITION 9,6:? #6;"G{inv}o{/inv}"
2210 FOR A=1 TO 12:FOR B=15 TO 0 STEP -2:SOUND 0,80,10,B:NEXT B:FOR B=15 TO 0 STEP -2:SOUND 0,50,10,B:NEXT B
2220 NEXT A:POSITION 9,6:? #6;" ":COLOR 42:PLOT 1,11
2230 COLOR 137:PLOT 18,1:POKE 203,60:SOUND 0,0,0,0:RETURN
2999 REM END GAME
3000 POKE 203,255:POKE 709,10:POKE 53765,0:POKE 53767,0
3010 FOR A=0 TO 1:B=USR(VMOVE,A,YP(A),0):NEXT A:POKE 53277,0
3020 SOUND 0,46,12,14:SOUND 1,48,12,14:A=90:GOSUB 7100:POKE 53761,0:POKE 53763,0
3030 POSITION 2,0:? #6;"PL1:{inv}000{/inv} {inv}pl{/inv}";CHR$(146);CHR$(154);"{inv}000{/inv}"
3040 COLOR 32:P1=0:P2=P1:FOR B=1 TO 11:D=SCREEN+B*20:FOR C=D+1 TO D+18
3045 D=PEEK(C):IF NOT D THEN 3070
3050 IF D<64 THEN P1=P1+1
3060 IF D>192 THEN P2=P2+1
3070 NEXT C:A=P1:POSITION 6,0:GOSUB 3200:A=P2:POSITION 15,0:GOSUB 3200
3080 PLOT 0,B:DRAWTO 19,B:FOR C=15 TO 0 STEP -0.6:SOUND 0,50,2,C:NEXT C:NEXT B
3120 IF P1=P2 THEN POSITION 3,5:? #6;"{inv}THE BATTLE HAS{/inv}":POSITION 3,6:? #6;"{inv}ENDED IN A{/inv} tie":GOTO 3160
3130 POSITION 6,4:IF P1>P2 THEN ? #6;"PLAYER 1":GOTO 3150
3140 ? #6;"{inv}player{/inv} ";CHR$(146)
3150 POSITION 3,6:? #6;"{inv}REIGNS SUPREME{/inv}"
3160 FOR B=15 TO 0 STEP -1:FOR A=250 TO 10 STEP -20:SOUND 0,A,10,B:SOUND 0,A/2,10,B:NEXT A:NEXT B:GOTO 120
3200 IF A<10 THEN ? #6;CHR$(176);
3210 IF A<100 THEN ? #6;CHR$(176);
3220 A$=STR$(A):FOR A=1 TO LEN(A$):? #6;CHR$(VAL(A$(A,A))+176);:NEXT A:RETURN
7000 IF BRK THEN POKE 16,112:POKE 53774,112:REM DEBUG
7010 RETURN
7049 REM TIME PRINTER
7050 A=INT(TIME/60):? #6;CHR$(16+B);CHR$(16+A+B);CHR$(26);:IF A*60=TIME THEN ? #6;CHR$(16+B);CHR$(16+B):RETURN
7060 A$=STR$(TIME-A*60):? #6;CHR$(VAL(A$(1,1))+16+B);CHR$(VAL(A$(2))+16+B):RETURN
7099 REM WAIT ROUTINE (A)
7100 POKE 20,0
7110 IF PEEK(20)<A THEN 7110
7120 RETURN
7999 REM TITLE SCREEN
8000 POKE 559,0:POKE 560,TDLL:POKE 561,TDLH:POKE 709,250:POKE 710,0:POKE 712,0:POKE 88,0:POKE 89,TITLE/256
8010 POSITION 10,3:B=0:GOSUB 7050:POKE 559,34:POKE 77,0:POKE 756,224
8020 IF PEEK(53279)=6 OR NOT STRIG(0) OR NOT STRIG(1) THEN RETURN
8030 FOR A=1 TO 20:NEXT A
8040 IF PEEK(53279)<>5 THEN 8010
8050 TIME=TIME+15:IF TIME>120 THEN TIME=15
8060 POSITION 10,3:GOSUB 7050
8070 IF PEEK(53279)=5 THEN 8070
8080 GOTO 8010
8999 REM INITIALIZATION
9000 GRAPHICS 18
9010 GOSUB 7000
9020 DIM MEM$(3811),XPA(4),YPA(4),OPDIR(4),EVENT(4),JOY$(34),ADD(4),POS(1),XP(1),YP(1),DRN(1),A$(3)
9025 DIM MOV$(46):MOV$="hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}":MOV=ADR(MOV$)
9030 JOY$="hh{inv}{CTRL-E}U{/inv}h{inv}*={/inv}x{CTRL-B}{inv}"{/inv}{CTRL-D}{inv}I{/inv}{CTRL-K}{inv}p{/inv}{CTRL-P}{inv}JI{/inv}{CTRL-M}{inv}p{/inv}{CTRL-K}{inv}JI{/inv}{CTRL-G}{inv}p{/inv}{CTRL-F}{inv}JI{/inv}{CTRL-N}{inv}p{/inv}{CTRL-A}{inv}J{CTRL-F}T{/inv}{CTRL-.}":JOY=ADR(JOY$)
9040 RESTORE 9500:FOR A=0 TO 4:READ B,C,D,E:ADD(A)=B:XPA(A)=C:YPA(A)=D:OPDIR(A)=E:NEXT A
9050 MEM$="{CTRL-,}":MEM$(3811)="{CTRL-,}":MEM$(2)=MEM$:A=ADR(MEM$):CHSET=2048-(A-INT(A/2048)*2048)+A:PM=CHSET:TITLE=PM+1536
9060 TDL=TITLE+200:TDLH=INT(TDL/256):TDLL=TDL-TDLH*256
9070 POKE 203,C0:POKE 204,CHSET/256
9080 A=USR(ADR("h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}M(){CTRL-.}{CTRL-E}N1M{CTRL-Q}KHPyfLfN%NIbPo{/inv}{CTRL-.}"))
9090 A=USR(MOV,ADR("<<<<<<<<{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{RIGHT}???<<{CTRL-,}{CTRL-,}{inv}x|||{/inv}<<<<???{RIGHT}{CTRL-,}{CTRL-,}<<{inv}|||x{/inv}{CTRL-,}{CTRL-,}<>????>"),CHSET+48,55)
9093 A=USR(MOV,ADR("<<|{inv}||||{/inv}|<{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{BACK S}<<{BACK S}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}"),CHSET+102,25)
9100 A=USR(MOV,ADR("<{BACK S}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{BACK S}<{CTRL-,}{CTRL-C}{CTRL-O}?{INS CHAR}?{CTRL-O}{CTRL-C}{CTRL-,}{inv}@p|{/inv}{INS CHAR}{inv}|p@{/inv}{BACK S}{inv}C[sw{/inv}{INS CHAR}{inv}w{/inv}{BACK S}"),CHSET+216,32)
9110 POKE 54279,PM/256:POKE 53256,0:POKE 53257,0:POKE 623,1
9120 A=USR(MOV,ADR("pppppppG{CTRL-,}{CTRL-,}p{CTRL-F}p{CTRL-G}pp{CTRL-F}p{CTRL-B}{CTRL-,}{CTRL-B}pp{CTRL-B}A"),TDL,25)
9125 A=INT(TITLE/256):B=TITLE-A*256:POKE TDL+8,B:POKE TDL+9,A
9130 POKE TDL+25,TDLL:POKE TDL+26,TDLH:POKE 88,B:POKE 89,A:POKE 87,1
9140 POSITION 4,0:? #6;"JAMES {inv}hague{/inv}"
9150 POSITION 6,1:? #6;"presents"
9160 POSITION 3,2:? #6;"C{inv}u{/inv}R{inv}r{/inv}E{inv}n{/inv}T {inv}e{/inv}V{inv}e{/inv}N{inv}t{/inv}S":POSITION 5,3:? #6;"time":TIME=30
9170 POSITION 8,4:? #6;"Press {CTRL-H}{inv} START {CTRL-H}{/inv} to begin":POSITION 5,6:? #6;"Press {CTRL-H}{inv} SELECT {CTRL-H}{/inv} to alter time"
9175 POSITION 4,8:? #6;"Copyright 1987 Antic Publishing"
9180 A=USR(MOV,ADR("h{inv} {/inv}{CTRL-J}{inv}"{/inv}{CTRL-F}{inv}){/inv}{CTRL-G}L\{inv}d%K{/inv}0e{inv}FKP{/inv}'{inv}){/inv}<{inv}{CTRL-E}Kx%Lp{/inv}{CTRL-E}8{inv}i{/inv}{CTRL-A}{CTRL-P}{CTRL-K}{inv}%Mp{/inv}{CTRL-U}8{inv}i{/inv}{CTRL-A}{inv}{CTRL-E}M){/inv}Y{inv}{CTRL-E}L {/inv}{CTRL-J}{inv}%M{/inv} {inv}{CTRL-Z}{/inv}{CTRL-F}{inv}%L{/inv} {inv}{CTRL-Z}{/inv}{CTRL-F}{inv}X%NP{/inv}{CTRL-G}{inv}(){/inv}{CTRL-J}{inv}&Op{/inv}{CTRL-Z}{inv}%N{/inv}8{inv}i{/inv}{CTRL-A}{inv}{CTRL-E}{/inv}"),1536,75)
9182 A=USR(MOV,ADR("{inv}N%Oi{/inv}{CTRL-,}{inv}{CTRL-E}O"{CTRL-H} {/inv}({inv}-{/inv}{CTRL-J}{inv}R{CTRL-M}D{/inv}{CTRL-B}{inv}{CTRL-M}G{/inv}{CTRL-B}{inv}{CTRL-M}E{/inv}{CTRL-B}){CTRL-O}{inv}{CTRL-M}{/inv}{CTRL-D}{inv}R{CTRL-M}{/inv}{CTRL-F}{inv}R{CTRL-N}{/inv}{CTRL-E}{inv}R{CTRL-L}{/inv}{CTRL-G}{inv}R{CTRL-J}P{/inv}${inv}N.{/inv}{CTRL-F}{inv}P{/inv}{RIGHT}{inv}){/inv}{CTRL-B}{inv}{CTRL-M}.{/inv}{CTRL-F}{inv}%P{CTRL-M}D{/inv}{CTRL-B}{inv}%QfPFQ{CTRL-M}G{/inv}{CTRL-B}{inv}I{/inv}{CTRL-P}{inv}P{/inv}{CTRL-H}{inv}){/inv}{RIGHT}{inv}{CTRL-E}Q){CTRL-,}{CTRL-E}{/inv}"),1611,75)
9184 A=USR(MOV,ADR("{inv}P{/inv}Lb{inv}d{/inv}HJJJJ{CTRL-I}{inv}{CTRL-P}{CTRL-Q}{/inv}X{inv}H{/inv}h){CTRL-O}{CTRL-I}{inv}{CTRL-P}{CTRL-Q}{/inv}X{inv}HH{/inv}{CTRL-.}{CTRL-B}hh{inv}{CTRL-E}U{/inv}h)?{inv}{CTRL-E}T{/inv}{CTRL-.}hh{inv}{CTRL-E}T{/inv}h{CTRL-X}i{CTRL-,}i{CTRL-D}{inv}{CTRL-E}U{/inv}hh{inv}("{/inv}{CTRL-O}{inv}){/inv}{CTRL-,}{inv}{CTRL-Q}THJ{/inv}{CTRL-P}{inv}z{/inv}h{inv}*{/inv}h{inv}p{/inv}{CTRL-L}{inv}(=d{/inv}{CTRL-F}{inv}{CTRL-Q}THh{CTRL-.}{/inv}{CTRL-P}"),1686,75)
9186 A=USR(MOV,ADR("{inv}Pu{/inv}{CTRL-.}<{BACK S}{INS CHAR}{inv}gCCg{/inv}{INS CHAR}{INS CHAR}{inv}gCCg{/inv}{INS CHAR}{BACK S}<"),1761,19)
9188 POKE 1728,PM/256:CHOP=1711:VMOVE=1721
9190 POKE 203,255:POKE 208,128:POKE 209,31:A=USR(1536):POKE 53761,0:POKE 53763,0:POKE 53765,0:RETURN
9499 REM DIRECTIONAL DATA
9500 DATA 0,0,0,0
9510 DATA -20,0,-16,3
9520 DATA 1,8,0,4
9530 DATA 20,0,16,1
9540 DATA -1,-8,0,2
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: CURRENT.BAS.
Credits
- Program listing: Current Events — program listing (Antic, February 1988 (Vol. 6, No. 10), Game of the Month) — James Hague
- Picture: The title screen, with its own display list mixing large and small text. SELECT changes the game time. — James Hague (program); screenshot by the site
- Antic, February 1988 - Vol. 6 No. 10 — article: Current Events, game by James Hague — James Hague, 1988
- Antic Software Archive — February 1988 - Vol. 6 No. 10 disk: CURRENT.BAS — AtariMagazines.com (Kevin Savetz), 1988
