game (ERACER.BAS)
game by James Hague, 80
Description
game by James Hague, 80
From the Antic disk of December 1988 (Vol. 7 No. 8) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 9.8 KB
- Dialect
- Atari BASIC
- Lines
- 216
- Variables
C0,CTL,C8,SPEED,C1,C2,STAT,Y,YPOS,C4,A,DL,C7,C3,B,SCAN,SCROLL,C,FLAGS,SCORE,C10,DRAW,CARS,GAME,C5,C6,HSCORE(,TRACK,HRN(,RN,CHANGED,TIME,LFLAGS,LTIME,DP,A$,X,FLAG(,C9,MOV$,DP$,MEM$,DISK,MOV,CH,PM,PL0,PL1,TDL,TITLE,D
BASIC listing (216 lines)
10 REM E-RACER
20 REM BY JAMES HAGUE
30 REM (c)1988, ANTIC PUBLISHING
100 GOSUB 7000
110 GOSUB 8000
120 GOSUB 5000
125 POKE 53278,C0
130 IF PEEK(CTL) THEN 500
140 IF STICK(C0)>12 THEN SOUND C0,40,C0,C8:POKE SPEED,C1:GOTO 170
150 IF STICK(C0)<C8 THEN SOUND C0,11,C0,C8:POKE SPEED,C2:GOTO 170
160 SOUND C0,90,C0,C8:POKE SPEED,255
170 IF STAT<>C1 THEN 200
180 IF Y<=56 OR STRIG(C0) THEN STAT=C2:GOTO 125
190 Y=Y-C1:POKE YPOS,Y:GOTO 130
200 IF STAT<>C2 THEN 240
210 IF PEEK(53252)=C4 THEN STAT=C0:GOTO 130
220 IF NOT PEEK(53252) THEN Y=Y+C1:POKE YPOS,Y:GOTO 130
230 GOTO 130
240 IF NOT STRIG(C0) THEN STAT=C1:GOTO 130
250 IF NOT PEEK(53252) THEN STAT=C2
260 GOTO 125
500 A=PEEK(20):IF PEEK(DL+20)=76 THEN 1500
505 IF A=PEEK(20) THEN 505
510 A=PEEK(53252):IF A>C7 THEN A=A-C8
520 IF A>C3 THEN A=A-C4
530 IF A THEN 1000
540 A=PEEK(DL+20)+256*PEEK(DL+21)+C4:B=USR(SCAN,A):IF B>SCROLL+388 THEN GOTO 130
570 C=PEEK(B):IF C=197 THEN FLAGS=FLAGS+C1:SCORE=SCORE+100:GOTO 585
580 SCORE=SCORE+500
585 POSITION C0,C1:A=SCORE:GOSUB 6000
590 POKE B,C0:FOR C=15 TO C0 STEP -C1:SOUND C0,24,C2,C:SOUND C1,54,C10,C:NEXT C
600 POKE 53278,C0:POSITION C0,C1:A=SCORE:GOSUB 6000:POKE CTL,C0:GOTO 130
1000 POKE DRAW,255:CARS=CARS-C1:POKE GAME+28,CARS+16:POKE 704,31
1010 FOR A=14 TO C4 STEP -C2:C=C10:FOR B=A TO C0 STEP -C1:SOUND C0,C,C8,B:C=C+C10:POKE 712,B:NEXT B:NEXT A
1020 A=C2:FOR B=C8 TO C1 STEP -C1:SOUND C0,40,C8,B:POKE 704,15+B*C2:GOSUB 6150:NEXT B:SOUND C0,C0,C0,C0
1030 POKE 704,C0:A=60:GOSUB 6150:IF CARS THEN GOTO 120
1040 POSITION C5,C8:? #C6;"game over":IF SCORE<=HSCORE(TRACK-C1) THEN 1050
1045 HSCORE(TRACK-C1)=SCORE:HRN(TRACK-C1)=RN:CHANGED=TRACK
1050 FOR A=15 TO C4 STEP -C1:FOR B=A TO C0 STEP -C1:SOUND C0,31,C10,B:SOUND C1,60,C10,B:NEXT B:NEXT A
1060 POSITION C5,C8:? #C6;" ":POKE 53248,C0:POKE 53249,C0:GOTO 110
1500 TIME=PEEK(20)+256*PEEK(19):POSITION C4,C3:? #C6;"run complete"
1510 FOR A=C1 TO C3:FOR B=15 TO C0 STEP -C1:SOUND C0,40,C10,B:SOUND C1,60,C10,B:NEXT B:NEXT A:POKE DRAW,C0:A=30
1520 GOSUB 6150:POSITION C0,C6:IF RN=C1 THEN 1555
1540 ? #C6;" last run":A=60:GOSUB 6150:? #C6:A=LFLAGS:GOSUB 6200:A=LTIME:GOSUB 6100:? #C6;" SEC ";
1550 FOR A=C1 TO LFLAGS:? #C6;CHR$(133);:NEXT A:? #C6:? #C6:? #C6:A=90:GOSUB 6150
1555 ? #C6;" this run":A=60:GOSUB 6150
1560 ? #C6:A=FLAGS:GOSUB 6200:A=TIME:GOSUB 6100:? #C6;" SEC ";:A=60:GOSUB 6150
1570 IF NOT FLAGS THEN ? #C6;"none":GOTO 1600
1580 FOR A=C1 TO FLAGS:? #C6;CHR$(133);:FOR B=15 TO C0 STEP -C1:SOUND C0,108,C10,B:SOUND C0,172,C10,B:NEXT B
1590 NEXT A
1600 A=120:GOSUB 6150:STAT=C0
1610 IF RN>C1 THEN 1630
1620 IF FLAGS THEN STAT=C1:GOTO 1640
1630 IF (FLAGS>LFLAGS OR FLAGS=C5) AND TIME<LTIME THEN STAT=C1
1640 LFLAGS=FLAGS:LTIME=TIME:POSITION C4,C3:? #C6;" ":A=C10:GOSUB 6150:POSITION C0,C3
1650 IF NOT STAT THEN ? #C6;" too bad":GOTO 1676
1660 ? #C6;" ";:B=(1500-TIME)*RN:A=B:GOSUB 6000:? #C6;" bonus points":SCORE=SCORE+B:A=SCORE:POSITION C0,C1
1670 GOSUB 6000:A=C4:FOR B=200 TO 20 STEP -20:SOUND C0,B,C10,C10:SOUND C1,B+25,C10,C10:GOSUB 6150:NEXT B
1675 SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0
1676 IF STRIG(C0) THEN 1676
1677 IF STAT THEN POKE 559,C0
1680 COLOR 32:FOR A=C0 TO 19:PLOT A,C3:DRAWTO A,13:NEXT A:IF NOT STAT THEN 1040
1690 RN=RN+C1:A=RN:POSITION 12,C1:GOSUB 6050:GOTO 120
5000 POKE 559,C0:POKE 53277,C2:POKE 704,26:POKE 705,74:POKE 708,246:POKE 710,246:POKE 709,116:POKE 711,102
5010 POKE 53261,C0:FLAGS=C0:POKE 77,C0:IF TRACK=C1 THEN RESTORE 9000
5020 IF TRACK=C2 THEN RESTORE 9100
5030 IF TRACK=C3 THEN RESTORE 9200
5040 IF TRACK=C4 THEN RESTORE 9300
5050 A=USR(DP,88,SCROLL+22):POSITION C0,C0:FOR A=C1 TO C3:? #C6;" ";:NEXT A:POKE SPEED,C2
5060 FOR A=C0 TO C3:B=USR(DP,88,SCROLL+119+97*A):POSITION C0,C0:FOR B=C1 TO C3:READ A$:? #C6;A$(C2,21);:NEXT B
5070 NEXT A:A=USR(DP,88,GAME):A=USR(DP,560,DL):A=SCROLL:FOR B=DL+20 TO DL+32 STEP C3:C=USR(DP,B,A):A=A+97:NEXT B
5080 IF RN>C1 OR CARS<C2 THEN 5100
5090 POSITION C0,C1:? #C6;"00000 02 001":FOR A=C0 TO C5:READ X,Y,B:FLAG(A)=SCROLL+97*Y+INT(RND(C0)*B+X):NEXT A
5100 B=INT(RND(C0)*C6):FOR A=C0 TO C5:IF A=B THEN POKE FLAG(A),198
5110 IF A<>B THEN POKE FLAG(A),197
5120 NEXT A:Y=97:POKE YPOS,Y:POKE 53248,56:POKE DRAW,255:POKE 559,42
5130 POSITION C1,C7:? #C6;"start your engines":A=20:GOSUB 6150:A=5
5140 FOR B=100 TO C0 STEP -C5:SOUND 0,B,C8,(100-B)/12:GOSUB 6150:NEXT B:POSITION C1,C7:? #C6;" "
5150 POSITION C4,C8:? #C6;"get moving├":POKE 53249,48:POKE DRAW,C1
5160 FOR B=40 TO 200 STEP C3:SOUND C0,B,C2,14:POKE 712,14*(B=40):NEXT B:SOUND C0,40,C0,C8:POKE 19,C0:POKE 20,C0
5170 FOR B=56 TO 80:POKE 53248,B:POKE 53249,B-C8:NEXT B:POKE 205,C1
5180 POSITION C4,C8:? #C6;" ":STAT=C0:POKE 208,C0:POKE 53278,C0:POKE SPEED,C1:POKE CTL,C0:RETURN
5999 REM PRINT SCORE (A)
6000 A$=STR$(A)
6010 IF LEN(A$)=C5 THEN 6030
6020 FOR A=C1 TO C5-LEN(A$):? #C6;"0";:NEXT A
6030 ? #C6;A$;:RETURN
6050 IF A<C10 THEN ? #C6;"0";
6060 ? #C6;STR$(A);:RETURN
6100 B=INT(A/60):C=INT((A-B*60)/0.6):IF B<C10 THEN ? #C6;"0";
6110 ? #C6;B;".";:IF C<C10 THEN ? #C6;"0";
6120 ? #C6;C;:RETURN
6150 POKE 20,C0
6160 IF PEEK(20)<A THEN 6160
6170 RETURN
6200 IF NOT A THEN B=C2:GOTO 6220
6210 B=INT((20-(A+11))/C2)
6220 FOR C=C1 TO B:? #C6;" ";:NEXT C:RETURN
7000 RESTORE :READ C0,C1,C2,C3,C4,C5,C6,C7,C8,C9,C10:GRAPHICS 18:POKE 16,112:POKE 53774,112:POKE 708,C0
7010 POKE 712,136:POSITION C0,C5:? #C6;" PREPARE YOURSELF":TRACK=C1
7020 DIM MOV$(46),DP$(17),MEM$(3892),A$(22),FLAG(C5),HSCORE(C3),HRN(C3)
7030 TRAP 7050:DISK=C1:CHANGED=C0
7040 OPEN #C1,C4,C0,"D:ERACER.HSC":FOR A=C0 TO C3:INPUT #C1;B:HSCORE(A)=B:GET #C1,B:HRN(A)=B:NEXT A:GOTO 7065
7050 FOR A=C0 TO C3:HSCORE(A)=C0:HRN(A)=C0:NEXT A
7060 IF PEEK(195)<>170 THEN DISK=C0
7065 CLOSE #C1
7070 MOV$="hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆"
7080 DP$="hh┐Uh┐T ├h┌T◢h┌T◆"
7090 MOV=ADR(MOV$):DP=ADR(DP$)
7100 MEM$="♥":MEM$(3892)="♥":MEM$(C2)=MEM$:A=ADR(MEM$):B=1024:CH=B-(A-INT(A/B)*B)+A:PM=CH+B:SCROLL=PM
7110 PL0=SCROLL+512:PL1=PL0+128:TDL=PL1+128:DL=TDL+35:TITLE=SCROLL+B:GAME=TITLE+540
7120 A=USR(MOV,57344,CH,768):FOR A=C1 TO 16:READ B:B=CH+B*C8:FOR C=B TO B+C7:READ D:POKE C,D:NEXT C:NEXT A
7130 POKE 756,CH/256:POKE 54279,PM/256:POKE 53256,C0:POKE 53257,C0:POKE 623,C1:POKE 53277,C0:TRAP 40000
7140 A=USR(MOV,ADR("pppF..╱╱╱╱╱╱╱╱╱╱╱╱╱W..W..W..W..W..A"),DL,35)
7150 A=USR(DP,DL+C4,GAME):A=USR(DP,DL+35,DL):POSITION C0,C0
7160 A=USR(DP,88,GAME):? #C6;"score cars run track00000 00 000 1"
7165 A$="ZZZZZZZZZZZZZZZZZZZZZZ":A=USR(DP,88,SCROLL+388):POSITION C0,C0:? #C6;A$:POSITION C2,C4:? #C6;A$(C8)
7170 A=USR(MOV,ADR("pppF..╱ppF..P┤┤┤┤┤pp▕p▕♣▕▕▕▕p▕p▕A"),TDL,33)
7180 A=USR(DP,TDL+C4,GAME):A=USR(DP,TDL+C10,TITLE):A=USR(DP,TDL+33,TDL)
7190 A=USR(DP,88,TITLE):POKE 87,C1:POSITION C3,C0:? #C6;"james hague╲s"
7200 ? #C6;" ---- ---- ---- ---- ---- ----":? #C6;" - - - - - - - -"
7210 ? #C6;" ---- -- - ---- - ---- -":? #C6;" - - - - - - -"
7220 ? #C6;" ---- - ---- ---- ---- -":POSITION 15,11:? #C6;"TOP SCORES"
7230 POSITION 11,13:? #C6;"Track Score Run":A=USR(DP,88,TITLE+300)
7240 FOR B=C0 TO C3:POSITION 13,B+B:? #C6;B+C1;" ";:A=HSCORE(B):GOSUB 6000:? #C6;" 0";:A=HRN(B):GOSUB 6050
7250 NEXT B:POSITION C5,C10:? #C6;" SELECT track or START race"
7260 A=USR(MOV,ADR("h "╱)╲L\dp|fca▶▶◀┘♥┐╲├┘╱▖→>▶▶X-┤P)▝p▕┐K%KPC%L♣◢FM♣;)├┐M┐Q%P8eQ0▕P┐┴i◢ ♥┐P▔┤TP"),1538,78)
7270 A=USR(MOV,ADR(" H"┐1N┴i├┌NH1Ni♥┌NHHJPm ├1NILP▕┤K"?)♥↓▶▶↓▶▶J♣w,♥╱p)*,├╱=▘╱▌▶▶╱Q-♥╱0♣&Lh-◣R=●"),1616,76)
7280 A=USR(MOV,ADR("╱*=┴╱▌▶▶H&Qh◆◢P[LbdXhh┐Uh┐T ♥"┘╱V"▕1TIEp▎IFp─)├ \╱J♣n)^ \╱&VJ♣◆◆┴eT┐T%Ui♥┐U◆"),1692,76)
7290 A=USR(DP,1654,PL0+56):A=USR(DP,1657,PL1+56):A=USR(DP,1675,PL0):A=USR(DP,1698,PL1):A=USR(DP,206,DL+19)
7300 SCAN=1711:CTL=203:SPEED=204:DRAW=1536:YPOS=1537:POKE CTL,C1:POKE DRAW,C0:A=USR(1538):RETURN
7500 DATA 0,1,2,3,4,5,6,7,8,9,10
7510 DATA 3,0,4,12,28,30,124,254,255
7520 DATA 4,0,0,8,24,28,30,62,127
7530 DATA 5,128,254,252,248,240,128,128,128
7540 DATA 6,1,127,63,31,15,1,1,1
7550 DATA 8,0,193,241,251,255,255,255,255
7560 DATA 9,0,129,195,227,233,251,255,255
7570 DATA 10,0,0,0,0,0,8,44,127
7580 DATA 11,0,0,0,0,0,32,105,251
7590 DATA 27,255,95,29,8,0,0,0,0
7600 DATA 13,85,85,85,85,85,85,85,85
7610 DATA 15,0,3,7,7,31,63,63,127
7620 DATA 28,0,0,128,200,248,252,254,254
7630 DATA 29,1,1,3,3,23,31,127,255
7640 DATA 30,192,224,248,252,252,254,254,255
7650 DATA 56,0,255,255,255,255,255,255,255
7660 DATA 58,255,255,255,255,255,255,255,255
8000 POKE 559,C0:A=USR(DP,560,TDL):POKE 708,26:POKE 709,C10:POKE 710,C0:POKE 711,102:POKE 712,C0
8010 A=USR(DP,88,TITLE+300):IF DISK AND CHANGED THEN POSITION C8,C8:? #C6;"Press 'S' to save scores"
8020 IF CHANGED THEN B=CHANGED-C1:POSITION 18,B+B:A=HSCORE(B):GOSUB 6000:? #C6;" 0";:A=HRN(B):GOSUB 6050
8040 POKE 764,255:POKE 559,34
8050 POKE 77,C0:FOR A=C1 TO C10:NEXT A
8060 IF PEEK(53279)=C6 OR NOT STRIG(C0) THEN SCORE=C0:RN=C1:CARS=C2:RETURN
8070 IF DISK AND CHANGED AND PEEK(764)=62 THEN GOSUB 8500:GOTO 8050
8080 IF PEEK(53279)<>C5 THEN 8060
8090 TRACK=TRACK+C1:IF TRACK>C4 THEN TRACK=C1
8100 POKE GAME+37,TRACK+16
8110 IF PEEK(53279)=C5 THEN 8110
8120 GOTO 8050
8500 TRAP 8530:OPEN #C1,C8,C0,"D:ERACER.HSC":A=C0
8510 ? #C1;HSCORE(A):PUT #C1,HRN(A):A=A+C1:IF A<C4 THEN 8510
8520 CLOSE #C1:TRAP 40000:POSITION C8,C8:? #C6;" ":CHANGED=C0:RETURN
8530 CLOSE #C1:TRAP 40000:A=C1:FOR B=15 TO C0 STEP -C1:SOUND C0,90,C10,B:GOSUB 6150:NEXT B:POKE 764,255:RETURN
9000 DATA " $ "
9001 DATA " "
9002 DATA " + "
9003 DATA " =Z> "
9004 DATA " /ZZZZZZZ"
9005 DATA "ZZ> "
9006 DATA " /ZZZZZZZZZZZZZZZ<"
9007 DATA " /ZZZZZZZZZZZ"
9008 DATA "ZZZZZZZ<*=(ZZZ "
9009 DATA "ZZZZZZZZZZZZZZZZZZZZ"
9010 DATA "ZZZZZZZ(ZZZZZZZZZZZZ"
9011 DATA "ZZZZZZZZZZZZZZZZZZZZ"
9012 DATA 27,2,4,33,2,4,43,3,5,56,1,6,66,2,3,77,3,4
9100 DATA " "
9101 DATA " $+ # "
9102 DATA " => "
9103 DATA " /ZZZ< /ZZZZ< "
9104 DATA " =ZZ)ZZZZZZ "
9105 DATA " /ZZ< /ZZZZZZ< "
9106 DATA " /ZZZZZzzzzZZZZZZ(> "
9107 DATA " /ZZZZZZZZZZxxx"
9108 DATA "xZZZZ $ *=ZZZZZZZZ>"
9109 DATA "ZZZZZZZzzzzZZZZZZZZZ"
9110 DATA "ZZZZZZZZZZZZZZZZZzzz"
9111 DATA "zZZZZ(Z)(ZZZZZZZZZZZ"
9112 DATA 25,1,3,34,1,4,43,3,4,55,1,4,64,1,2,77,1,3
9200 DATA " +=)ZZZZZ /ZZZZ"
9201 DATA "ZZ $ "
9202 DATA " /ZZZZxxxx> "
9203 DATA " /ZZZZZZZZ ZZZZZ"
9204 DATA "ZZ =ZZ"
9205 DATA "ZZZZZZZzzzzZ "
9206 DATA "=ZZZZZZZZZ **/ZZZZZ"
9207 DATA "ZZ *+ /ZZZZZZZ"
9208 DATA "ZZZZZZZzzzzZZZZZZ< "
9209 DATA "ZZZZZZZZZZ()ZZZZZZZZ"
9210 DATA "ZZ)ZZ)ZZZZZZZZZZZZZZ"
9211 DATA "ZZZZZZZzzzzZZZZZZZ(Z"
9212 DATA 27,0,5,38,0,6,49,3,4,55,2,3,65,0,4,76,2,3
9300 DATA " /ZZZZZ<+"
9301 DATA " /ZZ"
9302 DATA "ZZZ< /ZZZZ(> "
9303 DATA " /ZZZZ(ZZZZZZZZ"
9304 DATA "xxxxxxxxxZZZ< ;;;"
9305 DATA ";;;; =ZZZZZZZ> "
9306 DATA "/ZZZZZZZZZZZZZZZZZZZ"
9307 DATA "zzzzzzzzzZZZZ> "
9308 DATA " /ZZZZZZZZZ< "
9309 DATA "ZZZZZZZZZZZZZZZZZZZZ"
9310 DATA "zzzzzzzzzZZZZZ)ZZZZZ"
9311 DATA "ZZZZZZZZZZZZZZZZZZZ)"
9312 DATA 23,2,4,29,1,4,35,0,5,51,1,3,59,3,8,73,0,4
