Dimension Wizards

Type
Game
Category
Two-player action game
Author
Bernard Cozier
Published in
Antic, November 1988 (Vol. 7, No. 7)
Year
1988
Language
Atari BASIC (with machine-language routines in strings)
Requirements
48K RAM, Atari BASIC, disk drive (per the magazine), two joysticks
Blue screen titled DIMENSION WIZARDS listing soldier, dead-soldier, shrine and pedestal symbols with their score values, between a dark PLAYER 1 bar at the top and a light PLAYER 2 bar at the bottom, each saying PRESS TRIGGER TO BEGIN TELEPORTATION

About the program

The gods have had enough of a war on Earth. They freeze the two warring colonies, one of black soldiers and one of white, and scatter them across 20 dimensions. Two wizards, one for each side, have to bring their own men home. Dimension Wizards was Antic's Game of the Month for November 1988, and its author Bernard Cozier was the magazine's first contributor from Trinidad, West Indies.

It's a head-to-head game for two joysticks, and both race and fight. Each battlefield is scattered with live (frozen) and dead soldiers of both colours, shrines and pedestals. Touch your own soldiers to teleport them home. Enemy soldiers in your path die at your touch, which helps your side's war back home but annoys the other wizard, who can answer with lightning bolts.

What you need

A 48K Atari 8-bit with Atari BASIC and two joysticks. The magazine listed a disk drive as well.

Typing it in

This is a hard listing. The vertical-blank routine (APM$, lines 2002–2005), the main machine-language routine (ML$, 999 bytes in lines 5420–5540), the character shapes (line 4020) and the player shapes (lines 6069–6071) are all strings of inverse and control characters, spread through the program. The magazine offered a second program to write those lines to LINES.LST; this disk listing already includes them. In the notation, {inv}…{/inv} means inverse (Atari key), {CTRL-x} means CTRL plus the key ({CTRL-,} is ATASCII 0), and {UP}, {LEFT}, {RIGHT}, {CLEAR}, {BELL}, {INS LINE}, {INS CHAR}, {BACK S}, {TAB} are typed as ESC followed by the key. Lines 2006, 5550–5560 and 6072 poke a quotation mark (CHR$(34)) into the strings afterwards, because a " can't be typed inside a string. The program lowers RAMTOP twice (lines 4010 and 6010) and sets the cold-start flag, so pressing RESET reboots the machine. SAVE before you RUN.

How to play

RUN it. Building the character set and machine code takes a while. A legend then shows the pieces and their values, and both players press their triggers to teleport to the first battlefield. Wizard 1 is white, Wizard 2 is black. Your score, strength, lives still to save and bolt charge are shown in your bar: top for player 1, bottom for player 2.

  • Touch your own frozen soldiers (30 points) or dead ones (15) to send them home. Touching an enemy soldier kills it (15 points) and leaves your opponent fewer lives to save.
  • Wizards float over obstacles, but lightning bolts don't pass through them. A bolt hit scores 50 and drains strength on both sides, so hide behind the scenery.
  • A Shrine of Strength adds 2 strength (up to 99) and a Pedestal of Power adds 2 to the bolt charge (up to 9). The charge drops back to 1 after every shot.
  • When one wizard has rescued all his men, he moves on to the next of the 20 dimensions, and the other had better follow.

The game ends when a wizard's strength reaches zero or the 20 dimensions are used up. The higher score wins, so as Cozier noted, you can kill your opponent and still lose. Press START to play again.

How it works

  • A home-made screen. Lines 3005–3040 rebuild the GRAPHICS 1 display list: two lines of 40-column text at the top for player 1's status, 20-column mode 6 lines for the battlefield, and two more text lines at the bottom for player 2. A small display-list interrupt from the DATA in lines 3070–3080 recolours the bottom bar, which is why it's light with dark text.
  • Scenery by POKE. Each battlefield is made by poking character codes straight into screen memory at random empty spots (lines 1030–1080). Different codes (and their inverse versions) are soldiers of each colour, dead soldiers, shrines and pedestals in the redefined font.
  • Players that move themselves. APM$ installs a vertical-blank routine that reads the joysticks and moves the wizards (players 0 and 1) and the bolts (players 2 and 3) within limits stored in page 6, so BASIC never has to move a sprite. ML$, called from the main loop in lines 10–500, handles the touching, scoring and bolts.
  • State on the screen. Scores and counters live in the status bars as screen codes. BASIC reads them back with PEEK: line 20 checks whether a strength display has hit zero, and lines 9021–9022 turn the digits back into numbers for the final result.

Listing

1 REM DIMENSION WIZARDS
2 REM BY BERNARD COZIER
3 REM (c)1988, ANTIC PUBLISHING
5 GOSUB 4000:GOSUB 10000:GOSUB 6000:GOSUB 2000:GOSUB 3000:GOSUB 7000:GOSUB 5000:GOSUB 8000:GOSUB 1000
10 POKE 53278,0:P0$=SH$(PEEK(1547+PEEK(1562))):P1$=SH$(PEEK(1547+PEEK(1563))):I=USR(ADR(ML$)):POKE 53278,0
20 IF PEEK(TW+33)+PEEK(TW+34)=32 OR PEEK(TW+113)+PEEK(TW+114)=32 THEN 520
500 I=USR(ADR(ML$)):IF PEEK(A)<>16 AND PEEK(B)<>16 THEN 10
510 GOSUB 1000:GOTO 10
520 GOSUB 9000:GOSUB 8000:GOSUB 1000:GOTO 10
530 REM
1000 REM TRANSPORT TO NEW BATTLEFIELD
1005 DMNS=DMNS+1:IF DMNS>20 THEN POP :GOTO 520
1010 POKE 559,0:SOUND 2,0,0,0:SOUND 3,0,0,0:SOUND 0,25,10,15:SOUND 1,50,10,15
1020 GOSUB 10500:NP=INT(RND(0)*6)+4:GOTO 1050
1030 L=SC+RND(0)*19+RND(0)*380:IF PEEK(L)<>0 THEN 1030
1040 RETURN
1050 P0$=BL$:P1$=BL$:FOR I=1 TO NP:GOSUB 1030:POKE L,131:GOSUB 1030:POKE L,67:NEXT I:POKE A,NP+16:POKE B,NP+16
1060 FOR I=1 TO RND(0)*6+4:GOSUB 1030:POKE L,1:GOSUB 1030:POKE L,2:NEXT I
1070 FOR I=1 TO RND(0)*3+2:GOSUB 1030:POKE L,197:GOSUB 1030:POKE L,198:NEXT I
1080 FOR I=1 TO RND(0)*3+2:GOSUB 1030:POKE L,132:NEXT I:FOR I=1 TO RND(0)*3+1:GOSUB 1030:POKE L,68:NEXT I
1090 POKE 559,62:POKE 53277,3:GOSUB 1100:GOTO 1130
1100 POKE 53278,0:FOR I=0 TO 1:GOSUB 1150:POKE X+I,N:GOSUB 1160:POKE Y+I,N:NEXT I:N1=INT(RND(0)*4)
1110 P0$=SH$(N1*20+1):N2=INT(RND(0)*4):P1$=SH$(N2*20+1):POKE 1562,7*(N1=0)+11*(N1=1)+14*(N1=2)+13*(N1=3)
1120 POKE 1563,7*(N2=0)+11*(N2=1)+14*(N2=2)+13*(N2=3):RETURN
1130 N=PEEK(53252)+PEEK(53253)+PEEK(53260):IF N<>0 THEN P0$=BL$:P1$=BL$:GOSUB 1100:FOR I=1 TO 10:NEXT I:GOTO 1130
1140 SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
1150 N=RND(0)*154+48:RETURN
1160 N=RND(0)*144+46:RETURN
1170 REM
2000 REM VBI FOR MOVING PLAYERS
2001 DIM APM$(313)
2002 APM$(1,78)="h{inv}%T{/inv}{CTRL-X}i{CTRL-Q}{inv}(%U{/inv}i{CTRL-,}{inv}*){/inv}{CTRL-G}L\{inv}dX"{/inv}{CTRL-,}{inv}=>{/inv}{CTRL-F}{inv}I{/inv}{CTRL-A}{inv}p{/inv}{CTRL-F}{inv}={/inv}x{CTRL-B}{INS LINE}{inv}B{/inv}{CTRL-F}{inv}h{CTRL-.}{/inv}{CTRL-D}{inv}Pn"{/inv}{CTRL-,}{inv}=j{/inv}{CTRL-F}{inv}I{/inv}{CTRL-D}{inv}0{/inv}[{inv}(9B{/inv}{CTRL-F}{inv}I{/inv}{CTRL-E}{inv}p{/inv}{CTRL-V}{inv}I{/inv}{CTRL-F}{inv}p{/inv}{CTRL-R}{inv}I{/inv}{CTRL-G}{inv}p{/inv}{CTRL-N}{inv}I{/inv}{CTRL-I}{inv}p{/inv}{CTRL-Y}{inv}I{/inv}{CTRL-J}{inv}p{/inv}{CTRL-U}{inv}I{/inv}{CTRL-K}{inv}p{/inv}{CTRL-Q}{inv}P{/inv}{LEFT}{inv}={/inv}"
2003 APM$(79,156)="{inv}F{/inv}{CTRL-F}{CTRL-X}{CLEAR}{inv}N{/inv}{CTRL-F}{INS LINE}{inv}F{/inv}{CTRL-F}{inv}]^{/inv}{CTRL-F}{inv}{CTRL-P}{/inv}{CTRL-O}{inv}=F{/inv}{CTRL-F}8{BELL}{inv}N{/inv}{CTRL-F}{INS LINE}{inv}F{/inv}{CTRL-F}{inv}]Z{/inv}{CTRL-F}{inv}{CTRL-P}b9B{/inv}{CTRL-F}{inv}I{/inv}{CTRL-F}{inv}p{/inv}{CTRL-Z}{inv}I{/inv}{CTRL-N}{inv}p{/inv}{CTRL-V}{inv}I{/inv}{CTRL-J}{inv}p{/inv}{CTRL-R}{inv}I{/inv}{CTRL-E}{inv}p{/inv}{DOWN}{inv}I{/inv}{CTRL-M}{inv}p{/inv}{CTRL-Y}{inv}I{/inv}{CTRL-I}{inv}p{/inv}{CTRL-U}{inv}P{/inv} {inv}P{/inv}{CTRL-TAB}{inv}0{/inv}]{inv}=J{/inv}{CTRL-F}8{BELL}{inv}R{/inv}{CTRL-F}{INS LINE}{inv}J{/inv}{CTRL-F}{inv}]b{/inv}{CTRL-F}{inv}0{/inv}{CTRL-O}{inv}={/inv}"
2004 APM$(157,234)="{inv}J{/inv}{CTRL-F}{CTRL-X}{CLEAR}{inv}R{/inv}{CTRL-F}{INS LINE}{inv}J{/inv}{CTRL-F}{inv}]f{/inv}{CTRL-F}{inv}0b=F{/inv}{CTRL-F}{INS LINE}{CTRL-,}{inv}P=n{/inv}{CTRL-F}{inv}{CTRL-E}K=r{/inv}{CTRL-F}{inv}{CTRL-E}L=v{/inv}{CTRL-F}{inv}{CTRL-E}M=z{/inv}{CTRL-F}{inv}{CTRL-E}N<J{/inv}{CTRL-F}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{INS CHAR}{CTRL-F}{inv}{CTRL-X}{/inv}H{inv},{/inv}{INS CHAR}{CTRL-F}{inv}1M{CTRL-M}{/inv}{DEL CHAR}{CTRL-F}h{inv}(-{/inv}{DEL CHAR}{CTRL-F}{inv}{CTRL-Q}KHn{/inv}{INS CHAR}{CTRL-F}{inv}-{/inv}{INS CHAR}{CTRL-F}{inv}]V{/inv}{CTRL-F}{inv}Pch{/inv}"
2005 APM$(235,313)="{inv}{CTRL-.}{/inv}{CTRL-D}{inv}P{CTRL-Z}"{/inv}{CTRL-,}{inv}=B{/inv}{CTRL-F}{inv}I{/inv}{CTRL-O}{inv}p{/inv}{CTRL-C}{INS LINE}{CTRL-Z}{CTRL-F}{inv}={/inv}{CTRL-F}{inv}P{/inv}){CTRL-A}{inv}I{/inv}{CTRL-,}{inv}p{/inv}{CTRL-H}{inv}){/inv}{UP}{INS LINE}{inv}D{/inv}{CTRL-F}{INS LINE}{inv}H{/inv}{CTRL-F}{inv}h{CTRL-.}{/inv}{CTRL-B}{inv}P{CTRL-.}-{/inv}{CTRL-L}{inv}P{/inv}){CTRL-H}{inv}I{/inv}{CTRL-,}{inv}p{/inv}{CTRL-H}{inv}){/inv}{UP}{inv}{CTRL-M}E{/inv}{CTRL-F}{inv}{CTRL-M}I{/inv}{CTRL-F}{inv}-{/inv}{CTRL-M}{inv}P{/inv}){CTRL-D}{inv}I{/inv}{CTRL-,}{inv}p{/inv}{CTRL-H}{inv}){/inv}{UP}{inv}{CTRL-M}D{/inv}{CTRL-F}{inv}{CTRL-M}H{/inv}{CTRL-F}{inv}){/inv}{CTRL-,}{inv}{CTRL-E}{/inv}MLb{inv}d{/inv}"
2006 APM$(136,136)=CHR$(34)
2150 OFF=512+(PEEK(559)=62)*512
2160 OFFSET=128+(PEEK(559)=62)*128
2170 FOR I=0 TO 3:N=PMBASE+OFF+OFFSET*I:GOSUB 2180:POKE 1774+I,LSB:POKE 1778+I,MSB:NEXT I:GOTO 2190
2180 MSB=INT(N/256):LSB=N-256*MSB:RETURN
2190 X=1734:Y=1738:DX=1742:DY=1746:XMIN=1754:XMAX=1758:YMIN=1762:YMAX=1766:IMAGELSB=1782:IMAGEMSB=1786
2200 LENGTH=1750:PLAYER=1770:STIK=1726:PORT=1730:WIDTH=53256:COLOUR=704:POKE 1714,76:POKE 1715,156
2210 FOR I=0 TO 3:POKE PLAYER+I,255:POKE STIK+I,0:POKE DX+I,1:POKE DY+I,1:NEXT I:RETURN
2220 REM
3000 REM CUSTOMIZE GRAPHICS MODE
3005 GRAPHICS 1:POKE 16,64:POKE 53774,64:POKE 712,132:POKE 559,0
3010 POKE 756,CH/256:DL=PEEK(560)+256*PEEK(561):SL=PEEK(DL+4):SH=PEEK(DL+5):TL=PEEK(DL+26):POKE 752,1
3020 TH=PEEK(DL+27):POKE DL+3,66:POKE DL+4,TL:POKE DL+5,TH:POKE DL+6,2:POKE DL+7,70:POKE DL+8,SL:POKE DL+9,SH
3030 FOR I=DL+10 TO DL+27:POKE I,6:NEXT I:POKE DL+29,66:TL=TL+80:TH=TH+(TL>255):TL=TL-256*(TL>255):POKE DL+28,134
3040 POKE DL+30,TL:POKE DL+31,TH:POKE DL+32,2:POKE DL+33,65:POKE DL+34,PEEK(560):POKE DL+35,PEEK(561):POKE 82,0
3050 DIM B$(20):B$=CHR$(32):B$(20)=CHR$(32):B$(2)=B$:POKE 708,40:POKE 709,12:POKE 710,2:POKE 711,54
3060 RESTORE 3000:FOR I=1 TO 16:READ CODE:POKE 1535+I,CODE:NEXT I:POKE 512,0:POKE 513,6:POKE 54286,192:? #6;"  "
3061 POSITION 1,1:? #6;"{inv}dimension wizards{/inv}":? #6:? #6:? #6;" {CTRL-C} : score{CTRL-K}{CTRL-S}{CTRL-P}":? #6;"     {inv}SCORE+15{/inv}"
3062 ? #6:? #6;" {inv}#{/inv} : score{CTRL-K}{CTRL-Q}{CTRL-U}":? #6;"     {inv}SCORE+30{/inv}"
3063 ? #6:? #6;" {CTRL-D} : score{CTRL-K}{CTRL-Q}{CTRL-U}":? #6:? #6;" {inv}${/inv} : {inv}SCORE+15{/inv}"
3064 ? #6:? #6;" {inv}{CTRL-E}{/inv} : STRENGTH+2":? #6:? #6;" {inv}{CTRL-F}{/inv} : BOLT CHARGE+2"
3070 DATA 72,141,10,212,169,12,141,24
3080 DATA 208,169,2,141,23,208,104,64
3090 POKE 559,62:RETURN
3100 REM
4000 REM REDEFINE CHARACTER SET
4010 CH=PEEK(106)-8:POKE 106,CH:CH=CH*256:POKE 580,1:GRAPHICS 0
4011 MOV=ADR("hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}")
4015 I=USR(MOV,57344,CH,1024)
4020 I=ADR("{CTRL-,}0|v^{CTRL-;}?{UP}{CTRL-X}{CTRL-X}{BACK S}{BACK S}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}88{CTRL-P}|{CTRL-P}{CTRL-P}8l{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-H}K{/inv}{TAB}{inv};{CTRL-H}{/inv}{INS CHAR}{inv}gg{CTRL-A}{CTRL-A}gg{/inv}{INS CHAR}{CTRL-P}8{CTRL-P}T{DEL CHAR}T{CTRL-P}8@0{UP}:{LEFT}{CTRL-L}{CTRL-X}{UP}{CTRL-M}{RIGHT}<8{CTRL-X}HD8{CTRL-B}{CTRL-L}8\x0{CTRL-X}8{inv}0x{/inv}<{UP}{CTRL-X}{CTRL-R}'{UP}")
4030 N=USR(MOV,I,CH+8,80)
4120 POKE CH+86,34:RETURN
5000 REM ML ROUTINES
5005 I=ADR("{inv}{CTRL-D}Q,8{/inv}{CTRL-F}{inv}-6{/inv}{CTRL-F}{CTRL-X}q{inv}O{CTRL-Q}O{CTRL-H}-7{/inv}{CTRL-F}q{inv}O{CTRL-Q}OH.9{/inv}{CTRL-F}{inv}1OI{/inv}{CTRL-Z}{inv}{CTRL-P}{/inv}{CTRL-N}8{inv}i{/inv}{CTRL-J}{inv}{CTRL-Q}O{CTRL-H}1O{/inv}{CTRL-X}i{CTRL-A}{inv}{CTRL-Q}OH{CTRL-H}J{CTRL-.}{/inv}{CTRL-,}{inv}Pf$Q{/inv}{CTRL-.}{inv}{CTRL-D}Q,6{/inv}{CTRL-F}{inv}1O{/inv}8{inv}i{/inv}{CTRL-A}{inv}{CTRL-Q}O$Q{/inv}{CTRL-.}{inv}{CTRL-D}Q,6{/inv}{CTRL-F}{inv}){/inv}{CTRL-B}{CTRL-X}q{inv}O{CTRL-Q}OI{/inv}{CTRL-Z}{inv}{CTRL-P}{/inv}{CTRL-D}{inv}){/inv}{CTRL-Y}{inv}{CTRL-Q}O$Q{/inv}{CTRL-.}")
5010 N=USR(MOV,I,1564,92)
5400 REM
5410 DIM ML$(999)
5420 ML$(1,80)="h{inv}-D{/inv}{CTRL-F}{inv}I{/inv}{CTRL-O}{inv}{CTRL-P}{/inv}{CTRL-M}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}0{/inv}{CTRL-F}{inv}{CTRL-M}{/inv}{CTRL-E}{inv}RM0{/inv}{CTRL-F}{inv}p{/inv}{CTRL-Q}{inv}n0{/inv}{CTRL-F}{inv}n0{/inv}{CTRL-F}{inv}-0{/inv}{CTRL-F}{inv}{CTRL-M}{/inv}{CTRL-D}{inv}R){CTRL-L}{CTRL-M}{/inv}{CTRL-E}{inv}R-E{/inv}{CTRL-F}{inv}I{/inv}{CTRL-O}{inv}{CTRL-P}{/inv}{CTRL-M}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}1{/inv}{CTRL-F}{inv}{CTRL-M}{/inv}{CTRL-G}{inv}RM1{/inv}{CTRL-F}{inv}p{/inv}{CTRL-Q}{inv}n1{/inv}{CTRL-F}{inv}n1{/inv}{CTRL-F}{inv}-1{/inv}{CTRL-F}{inv}{CTRL-M}{/inv}{CTRL-F}{inv}R){CTRL-L}{CTRL-M}{/inv}{CTRL-G}{inv}R-{/inv}x{CTRL-B}{inv}I{/inv}{CTRL-O}"
5430 ML$(81,160)="{inv}p{/inv}{CTRL-L}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{CTRL-,}{inv}R){CTRL-H}{CTRL-M}{/inv}{CTRL-A}{inv}RP{/inv}{CTRL-E}{inv}){CTRL-,}{CTRL-M}{/inv}{CTRL-A}{inv}R-{/inv}y{CTRL-B}{inv}I{/inv}{CTRL-O}{inv}p{/inv}{CTRL-L}{inv}){/inv}2{inv}{CTRL-M}{/inv}{CTRL-B}{inv}R){CTRL-H}{CTRL-M}{/inv}{CTRL-C}{inv}RP{/inv}{CTRL-G}{inv}){CTRL-,}{CTRL-M}{/inv}{CTRL-C}{inv}R"{/inv}{CTRL-,}{inv}=F{/inv}{CTRL-F}8{inv}i{/inv}0{inv}{CTRL-E}Q{/inv}F{inv}Q{/inv}F{inv}Q{/inv}F{inv}Q{/inv}){CTRL-B}{inv}I{/inv}{CTRL-,}{inv}p{/inv}{CTRL-B}{inv}fQ%Q{/inv}{INS LINE}{inv}:{/inv}{CTRL-F}{inv}=J{/inv}{CTRL-F}8{inv}i{/inv}.{inv}{CTRL-E}Q{/inv}"
5440 ML$(161,240)="F{inv}Q{/inv}F{inv}Q{/inv}F{inv}Q{/inv}){CTRL-B}{inv}I{/inv}{CTRL-,}{inv}p{/inv}{CTRL-B}{inv}fQ%Q{/inv}{INS LINE}{inv}<{/inv}{CTRL-F}{inv}h{CTRL-.}{/inv}{CTRL-B}{inv}PE"{/inv}{CTRL-,}{inv}=H{/inv}{CTRL-F}{inv}I{/inv}{LEFT}{inv}{CTRL-P}{/inv}{CTRL-Q}{inv}I[0{/inv}{CTRL-M}{inv}=L{/inv}{CTRL-F}{inv}I{/inv}{CTRL-G}{inv}{CTRL-P}{/inv}{CTRL-F}{inv}Ih0{/inv}{CTRL-B}{inv}{CTRL-P}{/inv}K{inv}){/inv}{CTRL-O}{INS LINE}{inv}D{/inv}{CTRL-F}{inv}){/inv}{CTRL-,}{INS LINE}{inv}0{/inv}{CTRL-F}{inv}={CTRL-D}{/inv}{CTRL-B}{inv}I{/inv}{CTRL-,}{inv}P{/inv}:{inv}<2{/inv}{CTRL-F}{inv}1O{/inv}{INS LINE}{inv}4{/inv}{CTRL-F}{inv}){/inv}{CTRL-Q}{inv}{CTRL-Q}O={/inv}"
5450 ML$(241,320)="{inv}p{/inv}{CTRL-F}{inv}{CTRL-E}T=t{/inv}{CTRL-F}{inv}{CTRL-E}U<L{/inv}{CTRL-F}{inv}){/inv}{CTRL-,}{inv}{CTRL-F}Q*{CTRL-Q}THh{CTRL-.}{/inv}{CTRL-T}{inv}Px&Q=F{/inv}{CTRL-F}{INS LINE}{inv}H{/inv}{CTRL-F}{inv}=J{/inv}{CTRL-F}{INS LINE}{inv}L{/inv}{CTRL-F}{inv}={/inv}{CTRL-Z}{CTRL-F}{INS LINE}{inv}D{/inv}{CTRL-F}{inv}h{CTRL-.}{/inv}{CTRL-B}{inv}P{CTRL-X}%{/inv}X{CTRL-X}m{inv}:{/inv}{CTRL-F}{inv}{CTRL-E}T%{/inv}Yi{CTRL-,}{inv}{CTRL-E}U.<{/inv}{CTRL-F}{inv}{CTRL-.}{/inv}{CTRL-,}{inv}p{/inv}{CTRL-R}{inv}%T{/inv}{CTRL-X}i{CTRL-T}{inv}{CTRL-E}T%U{/inv}"
5460 ML$(321,400)="i{CTRL-,}{inv}{CTRL-E}UJEUpj {/inv}{CTRL-,}{inv}1TI{CTRL-C}P{/inv}1{inv})H{CTRL-M}{/inv}{CTRL-,}{inv}R)/{CTRL-M}{/inv}{CTRL-A}{inv}R){CTRL-D}{CTRL-Q}T){/inv}{CTRL-E}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-A}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}{CTRL-Q}{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}){CTRL-J}{CTRL-M}6{/inv}{CTRL-F} R{CTRL-F}{inv}DQp{/inv}+{inv}I{/inv}D{inv}P{/inv}+{inv}){/inv}{CTRL-T}{inv}{CTRL-M}{/inv}{CTRL-,}{inv}R)/{CTRL-M}{/inv}{CTRL-A}{inv}R{/inv}"
5470 ML$(401,480)="{inv}){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}{CTRL-E}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-A}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}{CTRL-Q}{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}DQp{/inv}5{inv}p{CTRL-Z}I{/inv}C{inv}P{/inv}3{inv}){/inv}{CTRL-T}{inv}{CTRL-M}{/inv}{CTRL-,}{inv}R)/{CTRL-M}{/inv}{CTRL-A}{inv}R){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}{CTRL-,}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-C}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}{CTRL-Q}{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}){/inv}:{inv}{CTRL-M}6{/inv}{CTRL-F} "
5480 ML$(481,560)="R{CTRL-F}{inv}DQp{/inv}I{inv}pGIEP{/inv}){inv}){/inv}2{inv}{CTRL-M}{/inv}{CTRL-,}{inv}R)/{CTRL-M}{/inv}{CTRL-A}{inv}R){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}{CTRL-B}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv} {inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-B}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}DQp{/inv}{CTRL-Z}{inv}IFP{/inv}{CTRL-V}{inv}){/inv}2{inv}{CTRL-M}{/inv}{CTRL-,}{inv}R)/{CTRL-M}{/inv}{CTRL-A}{inv}R){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}L{inv}{CTRL-M}6{/inv}{CTRL-F} a{CTRL-F}{inv}@{/inv}"
5490 ML$(561,640)="{CTRL-T}{inv}p{/inv}{CTRL-F}{inv} {/inv}{CTRL-T}{inv}@{/inv}{CTRL-T}{inv}p-%{/inv}X{CTRL-X}m{inv};{/inv}{CTRL-F}{inv}{CTRL-E}T%{/inv}Yi{CTRL-,}{inv}{CTRL-E}U.={/inv}{CTRL-F}{inv}{CTRL-.}{/inv}{CTRL-,}{inv}p{/inv}{CTRL-R}{inv}%T{/inv}{CTRL-X}i{CTRL-T}{inv}{CTRL-E}T%U{/inv}i{CTRL-,}{inv}{CTRL-E}UJEUpj {/inv}{CTRL-,}{inv}1TI{/inv}C{inv}P{/inv}1{inv})H{CTRL-M}{/inv}{CTRL-B}{inv}R)/{CTRL-M}{/inv}{CTRL-C}{inv}R){/inv}D{inv}{CTRL-Q}T){/inv}{CTRL-E}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-A}{inv}{CTRL-M}7{/inv}{CTRL-F}"
5500 ML$(641,720)="{inv}){/inv}a{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}){/inv}:{inv}{CTRL-M}6{/inv}{CTRL-F} R{CTRL-F}{inv}DQp{/inv}+{inv}I{CTRL-D}P{/inv}+{inv}){/inv}{CTRL-T}{inv}{CTRL-M}{/inv}{CTRL-B}{inv}R)/{CTRL-M}{/inv}{CTRL-C}{inv}R){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}{CTRL-E}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-A}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}a{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}DQp{/inv}5{inv}p{CTRL-Z}I{CTRL-C}P{/inv}1{inv}){/inv}{CTRL-T}{inv}{CTRL-M}{/inv}{CTRL-B}"
5510 ML$(721,800)="{inv}R)/{CTRL-M}{/inv}{CTRL-C}{inv}R){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}{CTRL-,}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-C}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}a{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}){CTRL-J}{CTRL-M}6{/inv}{CTRL-F} R{CTRL-F}{inv}DQp{/inv}I{inv}IEP{/inv}+{inv}){/inv}2{inv}{CTRL-M}{/inv}{CTRL-B}{inv}R)/{CTRL-M}{/inv}{CTRL-C}{inv}R){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}{CTRL-B}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}r{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-B}"
5520 ML$(801,880)="{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}DQp{/inv}{UP}{inv}p{CTRL-Z}IFP{/inv}{CTRL-V}{inv}){/inv}2{inv}{CTRL-M}{/inv}{CTRL-B}{inv}R)/{CTRL-M}{/inv}{CTRL-C}{inv}R){/inv}{CTRL-,}{inv}{CTRL-Q}T){/inv}{DEL LINE}{inv}{CTRL-M}6{/inv}{CTRL-F} a{CTRL-F}{inv}@{/inv}{CTRL-T}{inv}p{/inv}{CTRL-F}{inv} {/inv}{CTRL-T}{inv}@{/inv}{CTRL-T}{inv}pZ-{/inv}{CTRL-L}{inv}P{/inv}){CTRL-H}{inv}I{/inv}{CTRL-,}{inv}p{/inv}B{inv} {/inv} {inv}1OM5{/inv}{CTRL-F}{inv}0{/inv}{CTRL-Y}{inv}{CTRL-H}1OI{/inv}{CTRL-P}{inv}P{/inv}{CTRL-G}{inv}H{CTRL-Q}OI{/inv}{CTRL-P}{inv}p{/inv}{CTRL-T}"
5530 ML$(881,960)="8{inv}i{/inv}{CTRL-A}{inv}{CTRL-Q}OH1O{/inv}{CTRL-X}i{CTRL-J}8{inv}m5{/inv}{CTRL-F}{CTRL-X}i{CTRL-P}{inv}{CTRL-Q}O){/inv}{CTRL-,}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-E}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}a{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{inv}-{/inv}{CTRL-M}{inv}P{/inv}){CTRL-D}{inv}I{/inv}{CTRL-,}{inv}p{/inv}B{inv} {/inv}r{inv}1OM4{/inv}{CTRL-F}{inv}0{/inv}{CTRL-Y}{inv}{CTRL-H}1OI{/inv}{CTRL-P}{inv}P{/inv}{CTRL-G}{inv}H{CTRL-Q}OI{/inv}{CTRL-P}{inv}p{/inv}{CTRL-T}8{inv}i{/inv}{CTRL-A}{inv}{CTRL-Q}O{/inv}"
5540 ML$(961,999)="{inv}H1O{/inv}{CTRL-X}i{CTRL-J}8{inv}m4{/inv}{CTRL-F}{CTRL-X}i{CTRL-P}{inv}{CTRL-Q}O){/inv}{CTRL-,}{inv}{CTRL-M}6{/inv}{CTRL-F}{inv}){/inv}{CTRL-E}{inv}{CTRL-M}7{/inv}{CTRL-F}{inv}){/inv}{CTRL-Q}{inv}{CTRL-M}8{/inv}{CTRL-F}{inv}){/inv}{CTRL-D}{inv}{CTRL-M}9{/inv}{CTRL-F} {UP}{CTRL-F}{CTRL-.}"
5550 ML$(518,518)=CHR$(34)
5560 ML$(859,859)=CHR$(34)
5570 RETURN
6000 REM SET UP PM GRAPHICS
6010 PM=PEEK(106)-16:POKE 106,PM:POKE 54279,PM:POKE 559,62:PMBASE=PM*256:POKE 623,1
6015 DIM BL$(80):BL$="{CTRL-,}":BL$(80)="{CTRL-,}":BL$(2)=BL$:FOR I=PMBASE+1024 TO PMBASE+2047 STEP 256
6016 N=USR(ADR("hh{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T){/inv}{CTRL-,}{inv}({CTRL-Q}THP{CTRL-;}{/inv}{CTRL-.}"),I):NEXT I
6020 DIM P0$(20),P1$(20),P2$(20),P3$(20),SH$(80),BT$(20):P0$=BL$:P1$=BL$:P2$=BL$:P3$=BL$:SH$=BL$:BT$=BL$
6030 DATA 1,1,1,0,21,21,21,0,61,41
6069 BT$="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}f<{INS CHAR}<f{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}"
6071 SH$="{CTRL-,}{CTRL-,}@0{UP}:{LEFT}{CTRL-L}{CTRL-X}{UP}{CTRL-M}{RIGHT}<8{CTRL-X}HD8{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-B}{CTRL-L}8\x0{CTRL-X}8{inv}0x{/inv}<{UP}{CTRL-X}{CTRL-R}'{UP}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-P}{CTRL-H}{UP}*>{UP}{CTRL-H}]]>{UP}{UP}{CTRL-H}(${CTRL-X}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-X}$({CTRL-H}{UP}{UP}>]]{CTRL-H}{UP}>*{UP}{CTRL-H}{CTRL-P}{CTRL-,}{CTRL-,}"
6072 SH$(37,37)=CHR$(34)
6080 RESTORE 6030:FOR I=1 TO 10:READ CODE:POKE 1551+I,CODE:NEXT I:RETURN
6090 REM
7000 REM SET UP PLAYERS
7010 FOR I=0 TO 3:POKE XMIN+I,48:POKE XMAX+I,201:POKE YMIN+I,46:POKE YMAX+I,191:POKE PLAYER+I,I:POKE LENGTH+I,20
7015 POKE X+I,48:POKE Y+I,46:NEXT I
7020 N=ADR(P0$):GOSUB 2180:POKE IMAGELSB+0,LSB:POKE IMAGEMSB+0,MSB:N=ADR(P1$):GOSUB 2180:POKE IMAGELSB+1,LSB
7030 POKE IMAGEMSB+1,MSB:POKE COLOUR+0,12:POKE COLOUR+1,2:POKE COLOUR+2,12:POKE COLOUR+3,2:N=ADR(P2$):GOSUB 2180
7040 POKE IMAGELSB+2,LSB:POKE IMAGEMSB+2,MSB:N=ADR(P3$):GOSUB 2180:POKE IMAGELSB+3,LSB:POKE IMAGEMSB+3,MSB
7050 P0$=SH$(20):P1$=SH$(20):P2$=BT$:P3$=BT$:FOR I=2 TO 3:POKE DX+I,2:POKE DY+I,2:POKE XMIN+I,28:POKE XMAX+I,222
7055 POKE YMIN+I,5:POKE YMAX+I,235:POKE X+I,28:POKE Y+I,5:POKE STIK+I,1:POKE PORT+I,15:NEXT I:TW=TL+TH*256-80
7057 A=TW+40+18:B=TW+120+18:TL=TL-80:TH=TH-(TL<0):TL=TL+256*(TL<0):POKE 207,TL:POKE 208,TH
7060 I=USR(ADR(APM$)):BT$="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}f<{INS CHAR}<f{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}":RETURN
7070 REM
8000 REM START NEW GAME
8002 DMNS=0:? CHR$(125);
8004 ? "  PLAYER 1 : PRESS TRIGGER TO BEGIN":? "             TELEPORTATION"
8005 ? "  PLAYER 2 : PRESS TRIGGER TO BEGIN":? "             TELEPORTATION";
8006 IF PEEK(644)<>0 OR PEEK(645)<>0 THEN 8006
8020 POKE 559,0:? CHR$(125);
8030 ? " ' PLAYER 1: 00000     STRENGTH: 12   )  ( LIVES TO SAVE: 0    BOLT CHARGE: 1 *";
8040 ? "  ' PLAYER 2: 00000     STRENGTH: 12   )  ( LIVES TO SAVE: 0    BOLT CHARGE: 1 *";:RETURN
8050 REM
9000 REM GAME OVER
9010 SOUND 2,0,0,0:SOUND 3,0,0,0
9011 IF PEEK(TW+33)+PEEK(TW+34)<>32 THEN 9016
9012 FOR I=1 TO 20:N=RND(0)*16:P0$(N+3,N+3)=CHR$(PEEK(53770)):SOUND 0,PEEK(53770),8,15:NEXT I
9016 IF PEEK(TW+113)+PEEK(TW+114)<>32 THEN 9019
9017 FOR I=1 TO 20:N=RND(0)*16:P1$(N+3,N+3)=CHR$(PEEK(53770)):SOUND 1,PEEK(53770),8,15:NEXT I
9019 SOUND 0,125,10,10:SOUND 1,250,10,15:P0$=BL$:P1$=BL$:GOSUB 10500
9020 POSITION 5,1:? #6;"{inv}game over{/inv}":? #6:? #6:? #6
9021 S1=0:N=10000:FOR I=13 TO 17:S1=S1+(PEEK(TW+I)-16)*N:N=N/10:NEXT I
9022 S2=0:N=10000:FOR I=93 TO 97:S2=S2+(PEEK(TW+I)-16)*N:N=N/10:NEXT I
9023 IF PEEK(TW+33)+PEEK(TW+34)=32 THEN ? #6;" player one killed":? #6:? #6:POKE PLAYER,255
9024 IF PEEK(TW+113)+PEEK(TW+114)=32 THEN ? #6;" {inv}PLAYER TWO KILLED{/inv}":? #6:? #6:POKE PLAYER+1,255
9025 IF S1>S2 THEN ? #6;"  player one wins":? #6:? #6
9026 IF S1<S2 THEN ? #6;"  {inv}PLAYER TWO WINS{/inv}":? #6:? #6
9027 IF S1=S2 THEN ? #6;"    EQUAL SCORES":? #6:? #6
9028 ? #6;"   TELEPORTED <";:DMNS=DMNS-(DMNS>20):? #6;DMNS;">"
9030 POSITION 4,18:? #6;"{inv}press start{/inv}"
9040 IF PEEK(53279)<>6 THEN 9040
9050 GOSUB 10500:POKE PLAYER+0,0:POKE PLAYER+1,1:RETURN
9060 REM
10000 REM INTRODUCTION
10001 GRAPHICS 0:POKE 710,132:POKE 712,132:POKE 752,1:? :GOSUB 4020:POKE 756,CH/256
10005 SOUND 0,125,10,10:SOUND 1,250,10,15:RETURN
10500 SC=PEEK(88)+256*PEEK(89):FOR I=0 TO 19:POSITION 0,I:? #6;B$:NEXT I:RETURN

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: DIMWIZ.BAS.

Credits