Risky Rescue

Type
Game
Category
Cave rescue action game
Author
J. D. Casten
Published in
Antic, April 1984 (Vol. 3, No. 1), Game of the Month
Year
1984
Language
Atari BASIC
Requirements
16K RAM (24K with disk), joystick in port 1, Atari BASIC
A GRAPHICS 1 cave of winding brown rock passages with blue girder ledges, green medicine pots, red arrows flying across, and TIME 25, LEVEL 1, SCORE 0 at the top

About the program

Risky Rescue was the "Game of the Month" in Antic's April 1984 games issue, and the first of four 1984 games by J. D. Casten, a teenager from Eugene, Oregon. Later that year the magazine called it one of the two most popular action games it had printed. You play Igneous, a creature whose arch-enemy, Greedo the goblin, has kidnapped baby Iggy and put him in a trance deep in his caves. To break the spell, land on each of three medicine pots and then touch Iggy, while Greedo fires deadly arrows across the cave. The usual way to survive is to rise and hover while the arrows fly past, but some tight spots need careful timing.

Each rescue leads to a new set of caves, three in all. Then the first cave comes round again with faster, harder arrows. You score for each rescue according to the level and the time left. If the timer runs out, you lose a life. You start with three lives and gain more at 50, 100 and 200 points and so on. A high score lets you enter your initials, and it survives a press of RESET.

What you need

A joystick in port 1. 16K, or 24K on a disk system. The game runs on all Atari computers.

Typing it in

The listing uses inverse video ({inv}…{/inv}, Atari key) and control characters such as {CTRL-C} and {CTRL-G} (hold CTRL and press the letter) for the arrows, pots and cave walls. The caves themselves are PRINTed strings of those characters (lines 610 onward), so every symbol counts. Lines 500–510 load a font and 175 bytes of machine code, so SAVE before running, and check with TYPO, Antic's checksum program, if you can.

How to play

Push left or right to walk or fly sideways. If you go off one side of the screen you come back on the other. To go up, hold the trigger and push the stick forward once for each step up. While the trigger is held you hover at a constant height. Let go and you fall. When the game is over, press the trigger to start again.

How it works

  • The caves are redefined GRAPHICS 1 characters (GRAPHICS 17, no text window), printed a row at a time. LOCATE checks every square before Igneous moves into it. The code that comes back tells the program whether the square is empty, a wall, an arrow, a pot (line 140) or Iggy (line 145).
  • For speed, line 115 reads the joystick straight from the PIA port register (PEEK(54016), where 254 means up) and the trigger from GTIA's TRIG0 (PEEK(53264)), skipping the STICK and STRIG functions.
  • The main loop is FOR Z=0 TO 1 STEP 0, a FOR loop that never ends. GOTO 200+25*MA jumps to the arrow-moving code for the current cave.
  • The arrows are moved by a machine-code routine at 1536, called once per loop with USR(1536).
  • The countdown is 25-PEEK(19), read from the real-time clock. The high score and initials are kept in page 6 (locations 1786–1791), which is why they survive RESET. Line 515 also installs a display-list interrupt from that page.

Listing

1 REM RISKY RESCUE
2 REM BY J.D. CASTEN
3 REM ANTIC MAGAZINE APRIL 1984
5 GOTO 500
100 FOR Z=0 TO 1 STEP 0:OST=ST:IF Y=23 THEN Y=22
105 T=25-PEEK(19):POSITION 1,1:? #6;T;" ":IF T=0 THEN 275
110 IF OX<>X OR OY<>Y THEN COLOR 32:PLOT OX,OY:OX=X:OY=Y
115 COLOR 162:PLOT X,Y:TR=PEEK(53264):ST=PEEK(54016):Y=Y+TR:IF ST<>OST AND ST=254 THEN Y=Y-1:SO=5
120 SO=SO-(SO>0):SOUND 0,18,8,SO+1-TR:IF Y=OY THEN 150
123 LOCATE X,Y,L:IF L=32 OR L=162 THEN GOTO 200+25*MA
125 IF L=8 THEN Y=OY:GOTO 150
130 IF L<47 THEN Y=OY:GOTO 150
135 IF L>128 AND L<136 THEN 300
140 IF L=169 THEN 400
145 IF L=166 THEN 450
150 X=X+(ST=247)-(ST=251):IF X=OX THEN GOTO 200+MA*25
155 IF X<0 OR X=20 THEN X=19-OX:Y=Y+1-2*(X=19)
160 LOCATE X,Y,L:IF L=32 OR L=162 THEN GOTO 200+MA*25+P
165 IF L=8 THEN X=OX:GOTO 200+MA*25
170 IF L>41 AND L<47 THEN X=OX:GOTO 200+MA*25
175 IF L>128 AND L<136 THEN 300
180 IF L=166 THEN 450
200 U=USR(1536):G=G+1:IF G=D/2 THEN COLOR 133:PLOT 2,7
205 IF G=D THEN SOUND 1,8,6,8:G=0:POSITION 2,7:? #6;"{inv}{CTRL-C}{CTRL-G}{/inv}":SOUND 1,0,0,0:IF LE>11 THEN D=INT(RND(0)*(26-LE)+1)*2
210 LOCATE X,Y,L:IF L<>32 AND L<>162 THEN 300
215 LOCATE OX,OY,L:IF L<>32 AND L<>162 THEN OX=X:OY=Y
224 NEXT Z:GOTO 350
225 H=H+HP:COLOR 129:PLOT H,7:IF HP<0 THEN COLOR 32:PLOT H+1,7
227 IF H=4 OR H=13 THEN HP=-HP:SOUND 2,75+HP*5,6,1
230 U=USR(1536):G=G+1:IF G=D/2 THEN COLOR 133:PLOT 2,5
233 IF G=D THEN SOUND 1,8,6,8:G=0:POSITION 2,5:? #6;"{inv}{CTRL-C}{CTRL-G}{/inv}":SOUND 1,0,0,0:IF LE>11 THEN D=INT(RND(0)*(26-LE)+1)*2
235 LOCATE X,Y,L:IF L<>32 AND L<>162 THEN 300
237 LOCATE OX,OY,L:IF L<>32 AND L<>162 THEN OX=X:OY=Y
249 NEXT Z:GOTO 350
250 G=G+1:IF G=D/2 THEN COLOR 133:PLOT 2,3:COLOR H:PLOT 2,16:DRAWTO 4,16:H=40-H:COLOR H:PLOT 2,20:DRAWTO 4,20
253 U=USR(1536)
255 IF G=D THEN SOUND 1,8,6,8:G=0:POSITION 2,3:? #6;"{inv}{CTRL-C}{CTRL-G}{/inv}":SOUND 1,0,0,0:IF LE>11 THEN D=INT(RND(0)*(26-LE)+1)*2
260 U=USR(1663):LOCATE X,Y,L:IF L<>32 AND L<>162 THEN 300
265 LOCATE OX,OY,L:IF L<>32 AND L<>162 THEN OX=X:OY=Y
274 NEXT Z:GOTO 350
275 FOR J=100 TO 0 STEP -1:FOR I=0 TO 3:SOUND I,J+I,10,8:NEXT I:NEXT J:GOSUB 810:L=L-(L-32)*(L=162):GOTO 300
300 COLOR 32:PLOT OX,OY:COLOR 162:PLOT X,Y:FOR J=15 TO 0 STEP -0.25:SOUND 0,J+J,10,J:SOUND 0,0,0,0:POKE 710,J+192
305 NEXT J:COLOR L:PLOT X,Y:W=W-1:POKE 710,196
350 POKE 77,0:COLOR 32:PLOT 19,0:DRAWTO 17,0:X=17:Y=22:OX=X:OY=Y:COLOR 162:IF  NOT W THEN 375
355 IF W>1 THEN FOR J=2 TO W:PLOT J+15,0:NEXT J
360 PLOT X,Y:FOR I=0.5 TO 15 STEP 0.5:FOR J=0 TO 15 STEP I:SOUND 0,J*10,0,15-J:NEXT J:POKE 710,I+192:NEXT I
365 GOSUB 810:POKE 710,196:POKE 19,0:POKE 20,0:GOTO 100
375 POSITION 5,7:? #6;"{inv}GAME{/inv} {inv}OVER{/inv}":POSITION 3,13:? #6;"{inv}press{/inv} {inv}trigger{/inv}"
380 GOSUB 810:IF PEEK(53264)=0 THEN 380
385 IF PEEK(53264)=1 THEN 385
390 GOTO 550
400 FOR J=60 TO 0 STEP -1:SOUND 0,J+60,10,15-J/4:POKE 53760,J:NEXT J:GOSUB 810:COLOR 8:PLOT X,Y:Y=OY:M=M+1:NEXT Z
450 IF M<3 THEN X=OX:Y=OY:FOR J=15 TO 0 STEP -1:SOUND 0,10,6,J:NEXT J:NEXT Z
455 SC=SC+T*LE:LE=LE+1:MA=MA+1:POSITION 12,1:? #6;SC:IF MA=3 THEN MA=0:D=D-4:G=D-1:IF D<10 THEN D=10
460 IF SC>=B AND W<4 THEN B=B*2:W=W+1:FOR H=1 TO 5:FOR J=15 TO 0 STEP -1:SOUND 0,20,10,J:NEXT J:NEXT H:GOTO 460
465 RESTORE 2000:FOR J=0 TO 61:FOR V=0 TO 3:READ N:SOUND V,N,10,6:NEXT V:FOR T=0 TO 12:NEXT T:NEXT J
470 FOR J=165 TO 160 STEP -0.5:FOR I=53761 TO 53767 STEP 2:POKE I,J:NEXT I:NEXT J:GOTO 600
500 GRAPHICS 17:POKE 559,0:U=USR(ADR("h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}K{CTRL-E}M){CTRL-.}{CTRL-E}L%{/inv}j{inv}i{/inv}{CTRL-E}{inv}{CTRL-E}N"{/inv}{CTRL-B}{inv} {/inv}{CTRL-,}{inv}1K{CTRL-Q}M{CTRL-H}PyfLfNJPp{/inv}{CTRL-.}")):A=PEEK(106)-6
505 FOR J=A*256+8 TO A*256+119:READ B:POKE J,B:NEXT J:COM HN$(3),D$(12):H=PEEK(89)-1:FOR J=1536 TO 1710:READ B
510 POKE J,B+H*(B=1 OR B=2):NEXT J:HS=PEEK(1790)+256*PEEK(1791):FOR J=1 TO 3:HN$(J)=CHR$(PEEK(J+1786)):NEXT J
515 POKE 756,A:H=PEEK(560)+256*PEEK(561):POKE H+6,134:POKE 512,167:POKE 513,6:POKE 54286,192:POKE 559,34
550 GOSUB 810:? #6;"{CLEAR}":POKE 708,10:POKE 709,150:POKE 710,196:POKE 711,52:IF SC>HS THEN HS=SC:GOSUB 850
555 G=19:MA=0:W=3:D=20:SC=0:LE=1:B=50:? #6;"{inv}{CTRL-E}{/inv}":? #6;"{inv}{CTRL-D}{/inv}-*. * -*. - - - .":? #6;"+* * * *   * , * *"
560 ? #6;" **, * +*. **. +*,":? #6;" * . *   * * *  *":? #6;" * * * +*, * *  *"
565 ? #6:? #6;"-*. -. -*. -. - . -.* * *  *   *  * * * **, ** +*. *  * * *** . *    * *  * * *"
570 ? #6;"* * +, +*, +, +*, +,":? #6;"    by jd casten"
575 IF HS THEN ? #6:? #6;" {inv}HIGH SCORE:{/inv}";HN$;" ";HS:POKE 1791,INT(HS/256):POKE 1790,HS-256*PEEK(1791)
580 ? #6:? #6;"   {inv}press{/inv} {inv}trigger{/inv}":? #6;"      {inv}to{/inv} {inv}play{/inv}";
585 U=USR(1536):FOR I=0 TO 3:G=G+1:IF G=D/2 THEN COLOR 133:PLOT 0,1
586 IF G=D THEN SOUND 1,8,6,8:G=0:POSITION 0,1:? #6;"{inv}{CTRL-C}{CTRL-G}{/inv}":SOUND 1,0,0,0
595 IF PEEK(53264)=1 THEN NEXT I:GOTO 585
600 POP :GOSUB 810:? #6;"{CLEAR}TIME LEVEL SCORE":? #6;" 25":POSITION 6,1:? #6;LE:POSITION 12,1:? #6;SC:GOSUB 610+MA*50
605 M=0:X=17:Y=22:FOR Z=0 TO 75:SOUND 3,5,10,10:SOUND 3,0,0,0:GOTO 200+MA*25
610 ? #6;"-******************.*{inv}&{/inv}   *       *     *+{CTRL-H}{CTRL-H}. *{inv}){/inv}{CTRL-H}{CTRL-H}**.   -*, *   * +*.*  +. -,   *-**,   +,   +*,  -*,";
615 ? #6;"*{CTRL-G}{inv}{CTRL-E}{/inv}              *  *{CTRL-G}{inv}{CTRL-D}{/inv}-**{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}*.     +*.***, *     ****.   *,    *{inv}){/inv}{CTRL-H}{CTRL-H}. *   *         +****   * +**{CTRL-H}{CTRL-H}";
620 ? #6;"{CTRL-H}{CTRL-H}*.     +{CTRL-H}{CTRL-H}{CTRL-H},   +,    *":? #6;"   +***.":? #6;"       +***.-*.-*****.         +, +,"
625 ? #6;" +***.":? #6;"     +****{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}.           *       *       -{CTRL-H}{CTRL-H}{inv}){/inv}*       +****.  +, +, -***.   *";
630 ? #6;"  *            *   *  +*{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}*. -*{CTRL-H}{CTRL-H}{CTRL-H},";:G=D-1:RETURN
660 ? #6;"-*****.-*********.  *{inv}&{/inv}    **         +*.*{CTRL-H}{CTRL-H}*, +, +*****.   **{CTRL-G}{inv}{CTRL-E}{/inv}            +*, **{CTRL-G}{inv}{CTRL-D}{/inv}-*.             *";
665 ? #6;"****{inv}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{/inv}**{inv}){/inv}{CTRL-H}{CTRL-H}*******      *   +, +, +, *      *            *      *-*.-******, *      +, +,  *";
670 ? #6;"*                  ** -***{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}*****, ***,  *-*.-*.*   *  +,    +, +, +,   *                   +.-*";
675 ? #6;".-*.-**.-*****.  +, +, +,  +, *   *               * * +**********.      *      **    +**, +******, *";
680 ? #6;"+{inv}){/inv}{CTRL-H}.           *   *   +*****. -{CTRL-H}{CTRL-H}{inv}){/inv}*{CTRL-H}{CTRL-H}{CTRL-H},";:H=4:HP=1:G=D-1:RETURN
710 ? #6;"-******************.*{CTRL-G}{inv}{CTRL-C}{/inv}      *    *    **{CTRL-G}{inv}{CTRL-D}{/inv}-***, *{inv}){/inv}{CTRL-H}. * -{CTRL-H}{inv}){/inv}****,     +*** * +****           * *"
715 ? #6;"{inv}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{/inv}   {inv}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{/inv}     {inv}{CTRL-A}{CTRL-A}{/inv}* *           *   {inv}&{/inv}** *           +{CTRL-H}{CTRL-H}{CTRL-H}{CTRL-H}*, +**,":? #6;"           +*.-*.-*.";
720 ? #6;"{CTRL-H}{CTRL-H}{CTRL-H}***.      +, +, +,     *":? #6;"      +*.-*.-.-*.-**.       +, +,+, +, ***{CTRL-H}{CTRL-H}{CTRL-H}.             *";
725 ? #6;"*    +*.-**.-****, *,      +,  +,  *                   *******{CTRL-H}{CTRL-H}{CTRL-H}.-.-.-.-, *         +,+,+,+,  *   -";
730 ? #6;".              *   *+********{CTRL-H}{inv}){/inv}{CTRL-H}*. *{CTRL-H}{CTRL-H}{CTRL-H},";:G=0:H=8:RETURN
810 FOR J=0 TO 3:SOUND J,0,0,0:NEXT J:RETURN
850 ? #6;"{CLEAR}":? #6;"  the score of the":? #6;"game you just played   is highest yet":? #6
855 ? #6;" {inv}please{/inv} {inv}enter{/inv} {inv}three{/inv}":? #6;"    {inv}initials{CTRL-Z}{/inv}___":POSITION 13,6:OPEN #1,4,0,"K":POKE 764,255
860 FOR J=1 TO 3:GET #1,K:? #6;CHR$(K);:POKE 1786+J,K:HN$(J)=CHR$(K):NEXT J:CLOSE #1:GOTO 550
900 DATA 255,60,36,231,36,60,255,0,186,214,124,16,16,124,254,198,188,250,127,112,60,120,251,254,251,120,124,62,54
905 DATA 246,103,197,61,95,254,14,60,30,223,127,0,0,9,6,9,6,15,9,0,0,196,102,127,102,196,0,255,128,65,34,20,8,255
910 DATA 0,255,126,255,231,195,231,255,126,255,191,255,251,223,255,255,117,255,111,59,127,30,29,7,0,255,247,126
915 DATA 220,180,248,232,128,3,7,30,47,59,119,95,250,192,240,124,248,190,250,119,251
1000 DATA 104,160,255,185,127,2,201,199,240,14,76,18,6,169,0,153,127,2,136,208,238,76,65,6,185,147,2,201,0,240,26
1005 DATA 201,130,240,22,185,128,2,201,0,240,7,201,130,240,3,76,13,6,169,199,153,128,2,76,13,6,169,199,153,147,2
1010 DATA 76,13,6,160,255,185,128,1,201,199,240,12,76,82,6,169,0,153,128,1,136,208,238,96,185,148,1,201,0,240,26
1015 DATA 201,130,240,22,185,129,1,201,0,240,7,201,130,240,3,76,77,6,169,199,153,129,1,76,77,6,169,199,153,148,1
1020 DATA 76,77,6,104,160,0,185,12,2,170,169,0,153,12,2,200,192,20,208,5,138,153,11,2,96,185,12,2,201,193,208,8
1025 DATA 153,11,2,169,0,153,12,2,76,139,6,72,169,242,141,22,208,104,64
2000 DATA 60,96,162,193,60,96,162,193,53,0,0,0,53,0,0,0,60,96,162,193,60,96,162,193,64,0,0,0,64,0,0,0,64,96,121
2005 DATA 144,64,96,121,144,60,96,121,144,60,96,121,144,72,96,121,144,72,96,121,144,72,96,121,144,72,96,121,144
2010 DATA 72,91,217,0,72,91,217,0,72,91,144,0,72,91,144,0,72,91,121,0,72,91,121,0,72,0,0,0,81,0,0,0,72,91,128,162
2015 DATA 72,91,128,162,81,0,128,162,81,0,128,162,0,0,144,0,0,0,144,0,0,0,162,0,0,0,162,0,60,96,162,193,60,96,162
2020 DATA 193,64,0,0,0,72,0,0,0,64,0,0,0,72,0,0,0,81,0,0,0,81,0,0,0,72,96,243,0,72,96,243,0,0,96,162,0,0,96,162,0
2025 DATA 81,0,243,0,72,0,243,0,60,96,162,0,60,96,162,0,72,96,243,0,72,96,243,0,72,96,144,0,72,96,162,0,72,96,243
2030 DATA 0,72,96,243,0,72,96,144,0,72,96,162,0,72,96,243,0,72,96,243,0,0,0,144,0,0,0,162,0,0,0,243,0,0,0,243,0

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: RISKY.BAS.

Credits