Starsector Defense

Type
Game
Category
Space rescue shooter
Author
John Wilson
Published in
Antic, July 1984 (Vol. 3, No. 3), Game of the Month
Year
1984
Language
Atari BASIC
Requirements
16K RAM (24K with DOS), joystick in port 1, Atari BASIC
A black GRAPHICS 1 playfield inside a red ladder-like border, with white stars, brown asteroids, small saucers and the player's ship near the central black hole, and SCORE and SHIELDS counters below

About the program

Starsector Defense was Antic's "Game of the Month" in July 1984. It opens with a captain's log. The Nebulus has been lost in an uncharted sector, and your battle cruiser, the Centurion, has been sent to rescue any surviving crew. A mechanical race built long ago to guard the sector attacks with laser-armed saucers. If an alien saucer picks up one of the survivors, you lose five points. The author, John Wilson, was 27, a self-taught BASIC and assembly-language programmer who worked as an electronics technician for Ford.

The physics give the game its character. Your ship collects ions as it flies and turns them into shield energy, so you must keep moving. If the shields reach zero, the next hit destroys you. Flying into a star is fatal, and an asteroid costs 30 percent of your energy. Crossing the screen border "hyperwarps" you to the other side for 40 percent of your energy. The black hole in the centre throws you to a random spot for free, but you might come out on top of a star.

What you need

A joystick in port 1, 16K with cassette or 24K with DOS. Plain Atari BASIC.

Typing it in

Only a few inverse-video words ({inv}…{/inv}, Atari key) appear, in the title and status lines. Most of the listing's length is DATA: a 512-byte character set (lines from 1610 on) and two short machine-code routines placed in page 6 (lines 1540–1590). Typing errors in the font only change the pictures, but errors in the page-6 code can lock up the machine, so SAVE before you RUN.

How to play

Push the stick left or right to rotate. Push forward to thrust in the direction you face. The ship keeps moving after you let go and slowly stops, and pulling back works as a brake. Press the trigger to fire plasma torpedoes, two at a time, worth 10 points per saucer. Picking up a survivor scores 30. After 500 points a fourth saucer joins the attack. Press any key to pause and move the stick to carry on.

How it works

  • Everything is a character in GRAPHICS 17 (GRAPHICS 1 with no text window), POKEd straight into screen memory. SHIP(1) to SHIP(8) are eight characters for the eight directions the ship can face. MOVF(1..8) holds the matching screen offsets (±1, ±20 and the diagonals), so moving is one addition.
  • Collisions are found by PEEKing the target cell before moving. Each code (STAR, ASTER, BH, MAN, ALIEN and the two border characters) has its own handler in lines 280–330.
  • Each saucer compares its row and column with yours (lines 460–620). It moves toward you and fires when you are lined up within eight cells. Line 1400 sets the codes for the objects, partly in inverse or with other colour bits, which is how GRAPHICS 1 gives them different colours.
  • GOSUB PAUSE uses a variable as a line number (PAUSE=1010).

Listing

5 REM STARSECTOR DEFENSE
6 REM BY JOHN WILSON
7 REM ANTIC MAGAZINE
10 Z=0:X=Z:DIM SHIP(8),LS(8),AL(4),MOVF(8),RUBLE(6),EKP(6),PS(6):HSC=Z:SCORE=Z:GOTO 1120
20 IF STMV THEN THRUST=10:THRDIR=Z:POP :GOTO 350
30 SHLD=INT(SHLD*0.6)
40 FOR X=250 TO 80 STEP -3:SOUND 2,X,8,6:SOUND 3,X+2,8,6:SETCOLOR 4,Z,RND(Z)*15:NEXT X
50 FOR X=70 TO 250 STEP 2:SOUND 2,X,8,6:SOUND 3,X-2,8,6:SETCOLOR 4,0,RND(Z)*15:NEXT X
60 SOUND 2,Z,Z,Z:SOUND 3,Z,Z,Z:SETCOLOR 4,Z,Z:RETURN
70 GOSUB 20:IF THRDIR<4 THEN SHPLOC=SHPLOC-17:RETURN
80 SHPLOC=SHPLOC+17:RETURN
90 GOSUB 20:IF THRDIR>2 THEN IF THRDIR<6 THEN SHPLOC=SHPLOC-360:RETURN
100 SHPLOC=SHPLOC+360:RETURN
110 SETCOLOR 4,Z,14:POKE SHLDDMG,INIT:SHLD=INT(SHLD*0.7):SHPLOC=SHPLOC+MOVF(THRDIR)
120 SETCOLOR 4,Z,Z:RETURN
130 SHPLOC=SHPLOC+7*MOVF(INT(RND(Z)*8)+1):IF PEEK(SHPLOC)<>Z THEN 130
140 FOR X=200 TO 75 STEP -1:SOUND 2,X,8,10:NEXT X:SOUND 2,Z,Z,Z:RETURN
150 FOR X=255 TO 140 STEP -15:SOUND 3,X,10,10:NEXT X:SOUND 3,Z,Z,Z:RETURN
160 SHLD=SHLD-1:IF SHLD<Z THEN SHLD=Z
170 POSITION 15,23:? #6;SHLD;" ":RETURN
180 IF MANC<5 THEN IF RND(Z)>0.8 THEN GOSUB 980
190 IF PEEK(764)<>255 THEN GOSUB PAUSE
200 IF STRIG(Z) THEN 230
210 POKE 77,Z:IF F1 THEN F1=Z:GOSUB 150:M1=MOVF(ROTATE):MM1=M1+M1:T1=SHPLOC:GOTO 370
220 IF F2 THEN IF TP1LIM>2 THEN F2=Z:GOSUB 150:M2=MOVF(ROTATE):MM2=M2+M2:T2=SHPLOC:GOTO 410
230 GOSUB 160:P=STICK(Z):THRUST=THRUST+1:IF THRUST>9 OR P=13 OR P=9 OR P=5 THEN THRDIR=Z
240 STMV=1:IF P=14 THEN THRDIR=ROTATE:THRUST=Z:STMV=Z
250 IF P=7 THEN ROTATE=ROTATE+1:IF ROTATE>8 THEN ROTATE=1
260 IF P=11 THEN ROTATE=ROTATE-1:IF ROTATE<1 THEN ROTATE=8
270 POKE SHPLOC,Z:SHPLOC=SHPLOC+MOVF(THRDIR):P=PEEK(SHPLOC):IF P=Z THEN 340
280 IF P=MAN THEN SCORE=SCORE+30:SOUND 2,100,10,10:GOSUB 820:SOUND 2,Z,Z,Z:MANC=MANC-1:GOTO 340
290 SHPLOC=SHPLOC-MOVF(THRDIR):IF P=VERTB THEN GOSUB 70:GOTO 340
300 IF P=HORB THEN GOSUB 90:GOTO 340
310 IF P=BH THEN GOSUB 130
320 IF P=STAR THEN E=SHPLOC:GOSUB 900:GOTO 1030
330 IF P=ASTER THEN GOSUB 110:IF SHLD=Z THEN E=SHPLOC:GOSUB 900:GOTO 1030
340 IF THRDIR THEN SHLD=SHLD+2
350 POKE SHPLOC,SHIP(ROTATE):IF F1 THEN FOR X=1 TO 4:NEXT X:GOTO 390
360 POKE T1,Z:IF TP1LIM>6 THEN F1=1:TP1LIM=Z:GOTO 390
370 T1=T1+MM1:P=PEEK(T1):PP=PEEK(T1-M1):IF P OR PP THEN L1=T1:L2=T1-M1:GOSUB 800:F1=1:TP1LIM=Z:GOTO 390
380 POKE T1,224:TP1LIM=TP1LIM+1
390 IF F2 THEN FOR X=1 TO 4:NEXT X:GOTO 430
400 POKE T2,Z:IF TP2LIM>6 THEN F2=1:TP2LIM=Z:GOTO 430
410 T2=T2+MM2:P=PEEK(T2):PP=PEEK(T2-M2):IF P OR PP THEN L1=T2:L2=T2-M2:GOSUB 800:F2=1:TP2LIM=Z:GOTO 430
420 POKE T2,224:TP2LIM=TP2LIM+1
430 YT=YT+1:IF YT<2 THEN 180
440 YT=Z:NU=NU+1:IF NU>NA THEN NU=1
450 IF PEEK(AL(NU))<>ALIEN THEN GOSUB 770
460 FIRE=Z:POKE AL(NU),Z:XX=(AL(NU)-C)/20:XY=(SHPLOC-C)/20
470 ROW=INT(XX)-INT(XY):COLM=((XX-INT(XX))-(XY-INT(XY)))*20
480 IF ROW>Z THEN 520
490 IF ROW<Z THEN 550
500 IF COLM>Z THEN D=6:GOTO 600
510 D=2:GOTO 600
520 IF COLM>Z THEN D=7:GOTO 620
530 IF COLM<Z THEN D=1:GOTO 620
540 D=8:GOTO 580
550 IF COLM>Z THEN D=5:GOTO 620
560 IF COLM<Z THEN D=3:GOTO 620
570 D=4
580 IF ABS(ROW)<8 THEN FIRE=1
590 GOTO 630
600 IF ABS(COLM)<8 THEN FIRE=1
610 GOTO 630
620 IF ABS(ROW)=ABS(COLM) THEN IF ABS(ROW)<8 THEN FIRE=1
630 AL(NU)=AL(NU)+MOVF(D):P=PEEK(AL(NU)):IF P THEN 740
640 POKE AL(NU),ALIEN:IF FIRE THEN X=AL(NU)+MOVF(D):II=Z:SOUND Z,75,8,8:GOTO 670
650 GOTO 180
660 POKE X,0:X=X+MOVF(D):IF II>5 THEN SOUND Z,Z,Z,Z:GOTO 180
670 P=PEEK(X):IF P=Z THEN POKE X,LS(D):II=II+1:GOTO 660
680 SOUND Z,Z,Z,Z:IF P=224 THEN II=II+1:GOTO 660
690 IF P=60 THEN X=X+5*MOVF(INT(RND(0)*8)+1):GOTO 670
700 SOUND Z,Z,Z,Z:IF P>8 THEN 180
710 FOR X=200 TO 80 STEP -20:POKE SHPLOC-MOVF(D),201+RND(0)*8:SOUND Z,X,8,8:NEXT X:SOUND Z,Z,Z,Z
720 POKE SHPLOC-MOVF(D),Z:SHLD=SHLD-(10-II):GOSUB 160:IF SHLD<1 THEN E=SHPLOC:POKE SHPLOC,Z:GOSUB 900:GOTO 1030
730 GOTO 180
740 IF P=BH THEN 860
750 IF P=MAN THEN SOUND 2,255,10,10:SCORE=SCORE-5:GOSUB 820:MANC=MANC-1:SOUND 2,Z,Z,Z:GOTO 640
760 AL(NU)=AL(NU)-MOVF(D):D=INT(RND(Z)*8)+1:FIRE=Z:GOTO 630
770 AL(NU)=C+22+INT(RND(Z)*18)*20+INT(RND(Z)*18)
780 IF PEEK(AL(NU)) THEN 770
790 FOR X=9 TO 14:POKE AL(NU),128+X:SOUND 3,100-X*3,12,8:NEXT X:POKE AL(NU),ALIEN:SOUND 3,Z,Z,Z:RETURN
800 IF PP=ALIEN THEN I=L2:GOSUB 850:GOTO 820
810 IF P=ALIEN THEN I=L1:GOSUB 850
820 IF SCORE<Z THEN SCORE=Z
830 POSITION 2,23:? #6;SCORE:IF SCORE>500 AND INCFLG=Z THEN NA=4:INCFLG=1:AL(4)=CE
840 RETURN
850 SCORE=SCORE+10:FOR X=9 TO 14:POKE I,192+X:SOUND 3,100+X*5,10,6:NEXT X:POKE I,Z:SOUND 3,Z,Z,Z:RETURN
860 AL(NU)=C+22+INT(RND(Z)*15)*20+INT(RND(Z)*15)
870 IF PEEK(AL(NU))=Z THEN POKE AL(NU),ALIEN:FIRE=Z:GOTO 180
880 GOTO 860
890 REM EXPLOSION ROUTINE
900 SOUND 3,250,8,14:FOR X=1 TO 5:EXFLAG=1:FOR Y=1 TO 6:RUBLE(Y)=INT(7*RND(Z))+201:EKP(Y)=RUBLE(Y):NEXT Y
910 EX1=E+X:EX2=E-X:EX3=E-20*X:EX4=E+20*X:EX5=E+20*X-X:EX6=E-20*X+X
920 PS(1)=PEEK(EX1):PS(2)=PEEK(EX2):PS(3)=PEEK(EX3):PS(4)=PEEK(EX4):PS(5)=PEEK(EX5):PS(6)=PEEK(EX6)
930 POKE EX2,EKP(2):POKE EX1,EKP(1):POKE EX4,EKP(4):POKE EX5,EKP(5)
940 IF EX3>C THEN POKE EX3,EKP(3)
950 IF EX6>C THEN POKE EX6,EKP(6)
960 IF EXFLAG THEN FOR Y=1 TO 6:EKP(Y)=PS(Y):NEXT Y:EXFLAG=Z:GOTO 930
970 NEXT X:SOUND 3,Z,Z,Z:FOR X=1 TO 200:NEXT X:F1=1:F2=1:RETURN
980 MANC=MANC+1
990 X=C+22+INT(RND(Z)*18)*20+INT(RND(Z)*18):IF PEEK(X)<>Z THEN 990
1000 POKE X,MAN:RETURN
1010 POKE 764,255:IF STICK(Z)<>15 THEN SOUND 2,Z,Z,Z:SOUND 3,Z,Z,Z:RETURN
1020 SOUND 2,150,10,2:SOUND 3,152,10,2:GOTO 1010
1030 GRAPHICS 17:POKE 756,BASE:POSITION 5,2:? #6;"GAME  OVER":POSITION 2,6:? #6;"{inv}LAST PILOTS SCORE{/inv}"
1040 X=10-LEN(STR$(SCORE))/2
1050 POSITION X,8:? #6;SCORE:POSITION 5,13:? #6;"{inv}high score{/inv}"
1060 IF SCORE>HSC THEN HSC=SCORE
1070 X=10-LEN(STR$(HSC))/2:POSITION X,15:? #6;HSC
1080 POSITION 4,21:? #6;"            ":SOUND Z,Z,Z,Z:FOR X=1 TO 20:NEXT X
1090 IF STRIG(Z)=Z THEN 1370
1100 POSITION 4,21:? #6;"hit  trigger":SOUND Z,180,10,10:FOR X=1 TO 40:NEXT X:GOTO 1080
1110 REM LET'S INITIALIZE
1120 POKE 106,PEEK(106)-5:GRAPHICS 17:GOSUB 1520:BASE=PEEK(106)+3:BSR=BASE*256
1130 SHLDDMG=1790:INIT=255:POKE SHLDDMG,0:GOSUB 1540:GOSUB 1580:X=USR(1779)
1140 POSITION 3,1:? #6;"STARSECTOR":POSITION 9,3:? #6;"DEFENSE"
1150 POSITION 5,7:? #6;"{inv}by{/inv}":POSITION 6,10:? #6;"john wilson":POSITION 2,23:? #6;"{inv}ONE MOMENT PLEASE{/inv}"
1160 REM GO REDEFINE CHARACTER SET
1170 GOSUB 1600:POKE 756,BASE:POSITION 2,23:? #6;"                 ":SOUND Z,Z,Z,Z:GOSUB 1510:POKE C+264,251
1180 POKE C+256,251:POKE C+418,251:POKE C+425,251:SHPLOC=C+305
1190 POKE SHPLOC+11,189:POKE SHPLOC,3:FOR X=10 TO 1 STEP -1:POKE SHPLOC+X,220:SOUND Z,250-X*10,8,10
1200 FOR Y=1 TO 10:NEXT Y:POKE SHPLOC+X,0:NEXT X:SOUND Z,Z,Z,Z:POKE SHPLOC,Z:E=SHPLOC:GOSUB 900
1210 FOR Y=1 TO 5
1220 POSITION 3,18:? #6;"{inv}BATTLE STATIONS{/inv}":SOUND 1,180,10,5:SOUND Z,183,10,5:FOR X=1 TO 80:NEXT X
1230 POSITION 3,18:? #6;"               ":SOUND 1,250,10,5:SOUND Z,253,10,5:FOR X=1 TO 26:NEXT X:NEXT Y
1240 SOUND Z,Z,Z,Z:SOUND 1,Z,Z,Z
1250 FOR X=1 TO 100:NEXT X
1260 REM READ IN SHIP'S GRAPHIC CHARACTER FOR ALL EIGHT DIRECTIONS
1270 RESTORE 1280:FOR X=1 TO 8:READ D:SHIP(X)=D:NEXT X:Y=50:FOR X=1 TO 10
1280 DATA 2,3,6,4,8,5,7,1
1290 REM READ LASER GRAPHICS
1300 RESTORE 1310:FOR X=1 TO 8:READ D:LS(X)=D+192:NEXT X
1310 DATA 29,28,31,30,29,28,31,30
1320 REM READ IN MOVEMENT FACTORS FOR EIGHT DIRECTIONS
1330 RESTORE 1340:FOR X=Z TO 8:READ D:MOVF(X)=D:NEXT X
1340 DATA 0,-19,1,21,20,19,-1,-21,-20
1350 F1=F2=F3=F4=1:HORB=27+64:VERTB=26+64:Z=0
1360 REM SET UP SCREEN AND FIND UPPER LEFT CORNER
1370 GRAPHICS 17:GOSUB 1520:POKE 756,BASE:GOSUB 1510:CE=C+9*20+9
1380 REM DRAW BORDER AND INITIALIZE VARIABLES ETC.
1390 FOR X=C TO C+19:POKE X,HORB:NEXT X:FOR X=C+400 TO C+419:POKE X,HORB:NEXT X
1400 FOR X=C TO C+400 STEP 20:POKE X,VERTB:POKE X+19,VERTB:NEXT X:ALIEN=61+128:STAR=59+192:BH=60:ASTER=62+64
1410 SHPLOC=CE+4:ROTATE=2:POKE SHPLOC,SHIP(ROTATE):FOR Y=1 TO 5
1420 X=CE+((INT(RND(Z)*2)+2)*2)*MOVF(INT((RND(Z)*8)+1)):IF PEEK(X)<>Z THEN 1420
1430 POKE X,STAR:NEXT Y:PAUSE=1010:POKE 764,255
1440 THRDIR=Z:SHLD=100:SCORE=Z:POKE CE,BH:POSITION 13,22:? #6;"{inv}SHIELDS{/inv}":POSITION Z,22:? #6;"{inv}SCORE{/inv}":GOSUB 820
1450 MAN=63+192:MANC=Z:FOR Y=1 TO 8
1460 X=CE+((INT(RND(Z)*2)+2)*2)*MOVF(INT((RND(Z)*8)+1)):IF PEEK(X)<>Z THEN 1460
1470 POKE X,ASTER:NEXT Y
1480 NA=3:INCFLG=0:FOR X=1 TO NA:AL(X)=CE:NEXT X
1490 REM GO TO START OF LOOP
1500 GOTO 180
1510 C=PEEK(88)+256*PEEK(89):RETURN
1520 SETCOLOR 3,Z,14:SETCOLOR 1,2,8:SETCOLOR Z,7,6:SETCOLOR 2,3,6:RETURN
1530 REM VERT BLANK ROUT ON PAGE SIX
1540 RESTORE 1550:FOR X=1536 TO 1603:READ D:POKE X,D:NEXT X:RETURN
1550 DATA 206,114,6,208,60,169,3,141,114,6,173,254,6,240,50,201,255,208,22,169,15,141,254,6,141
1560 DATA 0,210,141,255,6,169,111,141,1,210,141,115,6,76,65,6,206,254,6,173,255,6,24,105,16
1570 DATA 141,255,6,141,0,210,206,115,6,173,115,6,141,1,210,76,95,228
1580 RESTORE 1590:FOR X=1779 TO 1789:READ D:POKE X,D:NEXT X:RETURN
1590 DATA 104,162,6,160,0,169,6,32,92,228,96
1600 RESTORE 1610:FOR X=Z TO 511:READ D:SOUND Z,130-X/4,8,8:POKE BSR+X,D:NEXT X:RETURN
1610 DATA 0,0,0,0,0,0,0,0,60,36,24,24,36,219,255,153,6,7,43,116,216,172,24,48
1620 DATA 224,96,83,237,237,83,96,224,153,255,219,36,24,24,36,60,7,6,202,183,183,202,6,7
1630 DATA 48,24,172,216,116,43,7,6,96,224,212,46,27,53,24,12,12,24,53,27,46,212,224,96
1640 DATA 0,16,0,66,103,33,8,0,0,136,12,4,112,48,4,128,0,0,12,14,32,48,48,0
1650 DATA 0,24,48,0,0,16,24,48,0,0,132,230,66,0,0,0,0,0,112,96,12,12,8,0
1660 DATA 12,24,8,0,64,12,24,0
1670 DATA 127,99,99,99,99,99,127,0,56,24,24,24,62,62,62,0,127,3,3,127,96,96,127,0
1680 DATA 126,6,6,127,7,7,127,0,112,112,112,112,119,127,7,0,127,96,96,127,3,3,127,0
1690 DATA 124,108,96,127,99,99,127,0,127,3,3,31,24,24,24,0,62,54,54,127,119,119,127,0
1700 DATA 127,99,99,127,7,7,7,0
1710 DATA 129,129,129,255,255,129,129,129,255,0,0,0,0,0,0,255,0,0,0,255,0,0,0,0
1720 DATA 1,2,4,8,16,32,64,128,8,8,8,8,8,8,8,8,128,64,32,16,8,4,2,1
1730 DATA 0,0,24,36,36,24,0,0
1740 DATA 63,51,51,127,115,115,115,0,126,102,102,127,103,103,127,0,127,103,103,96,99,99,127,0
1750 DATA 126,102,102,119,119,119,127,0,127,96,96,127,112,112,127,0,127,96,96,127,112,112,112,0
1760 DATA 127,99,96,111,103,103,127,0,115,115,115,127,115,115,115,0,127,28,28,28,28,28,127,0
1770 DATA 12,12,12,14,14,110,126,0,102,102,108,127,103,103,103,0,48,48,48,112,112,112,126,0
1780 DATA 103,127,127,119,103,103,103,0,103,119,127,111,103,103,103,0,127,99,99,103,103,103,127,0
1790 DATA 127,99,99,127,112,112,112,0,127,99,99,103,103,103,127,7,126,102,102,127,119,119,119,0
1800 DATA 127,96,127,3,115,115,127,0,127,28,28,28,28,28,28,0,103,103,103,103,103,103,127,0
1810 DATA 103,103,103,103,111,62,28,0,103,103,103,111,127,127,103,0,115,115,115,62,103,103,103,0
1820 DATA 103,103,103,127,28,28,28,0,127,102,108,24,55,103,127,0
1830 DATA 16,84,56,254,56,84,16,0,126,195,129,129,129,129,195,126,0,56,40,40,124,40,56,0
1840 DATA 56,62,110,255,187,254,118,60,0,0,16,56,16,40,0,0

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: STARSECT.BAS.

Credits