Biffdrop

Type
Game
Category
Platform action-adventure
Author
J. D. Casten
Published in
Antic, December 1984 (Vol. 3, No. 8), Game of the Month
Year
1984
Language
Atari BASIC
Requirements
Any Atari 8-bit (any memory size), joystick in port 1, Atari BASIC
Title screen: the word biffdrop in large rainbow-striped lower-case letters, BY JD CASTEN, PRESS TRIGGER, and a little duck standing on a purple platform between green bushes

About the program

J. D. Casten, a 16-year-old high-school senior from Eugene, Oregon, was Antic's star game discovery of 1984. Biffdrop was his fourth game in the magazine that year, after Risky Rescue, Escape From Epsilon and the text adventure Advent X-5. Its hero is Slyvester Biffdrop ("not spelled Sylvester"), Inspector of Mysterious Mishaps for Icked Industries, who had already escaped from Epsilon. The editors admitted that only now had they learned Sly is a duck. They had illustrated Epsilon with an Indiana Jones type of hero.

Sly's holiday at Balogna Beach is cut short. Sea gulls have stolen a valuable ring from the Icked Medfly Museum and are holding it in Gulls' Grotto, a series of eight deadly rooms. In each room Sly must kick every gull egg (touch it with his webbed foot) before the door opens. He has to avoid lasers that switch on and off, the gulls themselves and falls onto spikes. He can climb up ladders but not down. Jelly cubes can be walked and fallen through, hard cubes cannot, and the two look the same. You start with five lives and gain one for each room cleared. Touch the ring in room eight and the time you took is shown, to the nearest minute.

What you need

Any Atari with Atari BASIC and a joystick in port 1. The magazine said it runs on all memory sizes.

Typing it in

This is one of the hardest listings in Antic's early years to type. Almost every line uses special characters: nearly 300 {CTRL-,} (CTRL and comma, the heart), plus {CTRL-letter} (hold CTRL), {INS CHAR} (ESC then CTRL->), {INS LINE} (ESC then SHIFT->), {BACK S}, {UP}, {LEFT}, {CLEAR} (each preceded by ESC) and inverse video ({inv}, the Atari key). The magazine warned in particular about CTRL-B, which prints as a thin bar at the right of its cell and is easy to mistake for part of the next character, as in line 580. Use TYPO or a disk image if you possibly can.

How to play

Press the trigger at the title screen. Move left and right with the joystick and press the trigger to jump. Sly has wings, so he can steer a little in mid-air. Push up to climb a ladder. Casten's advice: get to know Sly's limits, stop in a safe spot when you enter a new room and work out a plan. And please don't phone Antic for the solution.

How it works

  • Constants as variables. Line 5 sets C=0, L=1, E=0.5, G=2, K=10 and T=256, and the rest of the program uses those letters in place of numbers. In tokenized Atari BASIC every numeric constant takes seven bytes but a variable reference takes one, so this trick makes a long program fit in 16K.
  • COM in line 5 is Atari BASIC's rarely seen synonym for DIM.
  • The rooms are drawn from DATA (lines from 10000 on) with PLOT and DRAWTO in a redefined character mode, and LOCATE checks what is around Sly before every move.
  • Sly is drawn with player/missile graphics. Short machine-code routines, kept in strings (D$, V$) and in page 6 at 1536, move the players and run a display-list interrupt.

Listing

1 REM BIFFDROP
2 REM BY J.D. CASTEN
3 REM ANTIC MAGAZINE
5 C=C:L= NOT C:E=0.5:T=256:K=10:G=L+L:COM V$(307),D$(T),S$(7):GRAPHICS 22:A=PEEK(106)-8:POKE 106,A-L:GOTO 500
100 POKE 77,C:SOUND L,T-L,K,C:POKE 53278,C:FOR J=C TO L STEP C:POKE 3,48+X*8:POKE 203,26+Y*8:F=C:R=C
105 POKE 206,159-I*42+14*D:D=C:IF Y<G OR Y>20 OR X=C OR X=19 THEN 800
110 LOCATE X,Y+E,V:IF D$(V,V)>"{CTRL-,}" THEN F=L
115 LOCATE X,Y-G,V:IF D$(V,V)>"{CTRL-A}" THEN R=L
120 LOCATE X-E,Y,H:IF H<>32 THEN GOSUB 230
125 IF PEEK(720) THEN 350
130 V=PEEK(632):IF V=7 THEN 200
135 IF V=11 THEN 215
140 IF V=14 THEN IF H=36 AND  NOT R THEN POKE 53761,134:Y=Y-E:I=L-I:POKE 53761,C
145 IF  NOT F THEN IF  NOT U AND H<>36 THEN Y=Y+E:NEXT J
150 IF U THEN U=U-L:POKE 53763,G*U+160:IF U=5 THEN Y=Y-E
155 IF R+U+PEEK(644)=C AND F THEN U=6:Y=Y-E:I=L-I:POKE 53763,175
160 NEXT J
200 X=X+E:LOCATE X,Y,V:LOCATE X,Y-L,D:IF D$(V,V)>"{CTRL-A}" OR D$(D,D)>"{CTRL-A}" THEN X=X-E
205 D=L:IF F THEN POKE 53761,138:I=L-I:POKE 53761,C
210 GOTO 145
215 X=X-E:LOCATE X-E,Y,V:LOCATE X-E,Y-L,D:IF D$(V,V)>"{CTRL-A}" OR D$(D,D)>"{CTRL-A}" THEN X=X+E
220 D=-L:IF F THEN POKE 53761,138:I=L-I:POKE 53761,C
225 GOTO 145
230 IF H=36 THEN RETURN
231 IF H=40 THEN POP :GOTO 400
232 IF H=35 OR H=166 OR H=167 OR H>36 AND H<131 THEN RETURN
233 IF H=140 THEN GOSUB 300:GOTO 240
234 IF H=170 THEN POP :GOTO 350
235 Y=Y-E:RETURN
240 COLOR 32:PLOT X-E,Y:N=N-L:IF  NOT N THEN RESTORE 10000+K*RO:READ H,V:PLOT H,V:READ H,V:DRAWTO H,V
245 FOR V=G TO L STEP -E:FOR J=15 TO C STEP -V:SOUND G,J,K,J:NEXT J:NEXT V
250 IF N=C THEN FOR J=K*K TO 250 STEP 5:FOR V=G TO G+L:SOUND V,J-V,K,25-J/K:NEXT V:NEXT J
255 POP :GOTO 305
300 RESTORE 5080:FOR J=L TO 6:READ V:S$(J)=V$(V,V):V$(V,V)="{CTRL-,}":NEXT J:POKE 541,T-L:S$(7)=CHR$(PEEK(540)):RETURN
305 RESTORE 5080:FOR J=L TO 6:READ V:V$(V,V)=S$(J):NEXT J:POKE 541,C:POKE 540,ASC(S$(7))+K:GOTO K*K
350 GOSUB 300:POKE 623,17:GOSUB 900:POKE 203,26+INT(Y+E)*8:FOR J=L TO 15 STEP E:SOUND C,J*15,K,J:NEXT J:SL=SL-L
355 FOR J=15 TO C STEP -0.2:SOUND C,J*15,J*15,J:POKE 706,16+J:NEXT J:POKE 706,28:POKE 623,18:IF SL THEN 370
360 FOR J=15 TO C STEP -E:FOR V=J TO C STEP -E:SOUND C,J+V,6,J:POKE 712,J+V:NEXT V:NEXT J
365 ? #6;"{CLEAR}":FOR J=19 TO 28:POKE DL+J,6:NEXT J:POKE 756,224:GOTO 550
370 POSITION 15,K*G:? #6;SL-L;" ":RESTORE 10009+RO*K:GOSUB 620:X=X1:Y=Y1:POKE 540,K:POKE 541,C:GOTO K*K
400 ? #6;"{CLEAR}":POKE 559,C:POKE DL+19,T/G:POKE DL+K*G,23:POKE DL+21,7:COLOR 35:PLOT C,13:DRAWTO C,K-G:POKE 54276,K+G
405 DRAWTO G+G,G+G:DRAWTO 15,G+G:DRAWTO 19,K-G:DRAWTO 19,13:COLOR G+L:PLOT L,13:DRAWTO 18,13:POSITION L,14
410 ? #6;"icked medley museum      TIME: ":POSITION G+G,16:? #6;"{inv}CONGRATULATIONS SLY!    press trigger{/inv}":COLOR 131
415 POKE 206,131:PLOT K,K+G:PLOT K,K+L:PLOT K+L,K:DRAWTO 13,K:DRAWTO 14,K+G:COLOR 168:POKE DL+22,7:PLOT K+G,K+G
420 RESTORE 19999:GOSUB 620:GOSUB 900:FOR J=15 TO C STEP -E:FOR V=C TO J STEP E:SOUND L,V+J,8,J:POKE 712,V+T/G
425 NEXT V:NEXT J:POSITION K+G,15:POKE DL+23,22:POKE 203,122:SOUND C,250,K+G,K:SOUND L,251,K+G,K:POKE 53768,L
430 ? #6;INT((PEEK(18)*T*T+PEEK(19)*T+PEEK(K*G))/4195.365);" MINUTES":POKE 559,62:U=USR(ADR("h{inv}H{CTRL-L}{/inv}{CTRL-X}{inv}P-{CTRL-D}{/inv}{CTRL-B}{inv}Pw{/inv}{CTRL-.}"))
435 GOTO 365
500 GRAPHICS 17:POKE 559,C:POKE 16,C:POKE 53774,C:J=A*T+24:I=3:GOSUB 9000:J=A*T+360:I=G:GOSUB 9000:J=A*T+513:I=G
505 GOSUB 9000:POKE 207,A:POKE 54279,A:POKE 53277,G+L:FOR J=704 TO 711:READ H:POKE J,H:NEXT J:RESTORE 5055
510 V$="{inv}X%{/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{CTRL-,}{inv}P%{/inv}{CTRL-A}{inv}{CTRL-M}{/inv}{CTRL-A}{inv}P%{/inv}{CTRL-C}{inv}{CTRL-M}{/inv}{CTRL-B}{inv}P{CTRL-M}{/inv}{CTRL-C}{inv}P%{/inv}{CTRL-B}{inv}"{/inv}{CTRL-D}{INS LINE}{CTRL-C}{inv}P{/inv}i{CTRL-B}{inv}JPx%{/inv}{CTRL-,}{CTRL-X}i{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-,}{inv}%{/inv}{CTRL-A}{CTRL-X}i{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-A}{inv}%{/inv}{CTRL-B}{CTRL-X}i{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-B}{inv}"{/inv}{CTRL-N}{inv},I{/inv}{CTRL-B}{inv}){/inv}{CTRL-,}{inv}{CTRL-Y}{/inv}{CTRL-,}{CTRL-,}{inv}HJPy"{/inv}{CTRL-N}{inv},J{/inv}{CTRL-B}{inv}{CTRL-Y}{/inv}{CTRL-,}{CTRL-,}{inv}HJPy"{/inv}{CTRL-N}{inv},K{/inv}{CTRL-B}{inv}{CTRL-Y}{/inv}{CTRL-,}{CTRL-,}{inv}HJPy"{/inv}{CTRL-N}{inv},L{/inv}{CTRL-B}{inv}{CTRL-Y}{/inv}{CTRL-,}{CTRL-,}{inv}{CTRL-Y}{/inv}{CTRL-,}{CTRL-,}{inv}HJP{/inv}"
515 V$(105)="{inv}v {/inv}{CTRL-N}{inv}&{/inv}{CTRL-D}{inv}1L{/inv}{INS LINE}{CTRL-,}{CTRL-,}{inv}h{CTRL-H}Pw {/inv}{CTRL-N}{inv}&{/inv}{CTRL-E}{inv}1L{/inv}{INS LINE}{CTRL-,}{CTRL-,}{inv}h{CTRL-H}Pw {/inv}{CTRL-N}{inv}&{/inv}{CTRL-F}{inv}1L{/inv}{INS LINE}{CTRL-,}{CTRL-,}{inv}h{CTRL-H}Pw {/inv}{CTRL-N}{inv}&K1N{/inv}{INS LINE}{CTRL-,}{CTRL-,}{inv}fO1N{/inv}{INS LINE}{CTRL-,}{CTRL-,}{inv}FOh{CTRL-H}Pn%{/inv}{CTRL-D}{inv}{CTRL-M}I{/inv}{CTRL-B}{inv}%{/inv}{CTRL-E}{inv}{CTRL-M}J{/inv}{CTRL-B}{inv}%{/inv}{CTRL-F}{inv}{CTRL-M}K{/inv}{CTRL-B}{inv}%K{CTRL-M}L{/inv}{CTRL-B}{inv}%{/inv}{CTRL-D}{CTRL-X}i{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-D}{inv}%{/inv}{CTRL-E}{CTRL-X}i{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-E}{inv}%{/inv}{CTRL-F}{CTRL-X}"
520 V$(204)="i{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-F}{inv}-{/inv},{CTRL-B}{inv}P{/inv}{CTRL-R}{inv}){/inv}{CTRL-E}{inv}{CTRL-M}{/inv}{LEFT}{CTRL-B}{inv}%L{/inv}{CTRL-X}i{CTRL-N}{inv}I{/inv}T{inv}P{/inv}{CTRL-B}{inv}){/inv}{CTRL-,}{inv}{CTRL-E}L-{/inv}*{CTRL-B}{inv}P{/inv}{DOWN}{inv}){/inv}{CTRL-.}{inv}{CTRL-M}{/inv}{UP}{CTRL-B}{inv}-{/inv};{inv}{CTRL-X}{/inv}I{INS CHAR}{inv}{CTRL-M}{/inv};{inv}{CTRL-X}{CTRL-M}{/inv}<{inv}{CTRL-X} {/inv}{CTRL-H}{inv}9{/inv}/{inv}{CTRL-X}{/inv}I{CTRL-X}{inv}{CTRL-Y}{/inv}/{inv}{CTRL-X}{CTRL-H}Pu-{/inv}{CTRL-F}{inv}P{/inv}{CTRL-M}{CTRL-G}{inv}P{/inv}){CTRL-D}{CTRL-M}{CTRL-N}{inv}P{/inv}{CTRL-M}{CTRL-O}{inv}P{CTRL-M}P{/inv}{CTRL-B}{inv}-{/inv}{CTRL-H}{inv}P{/inv}{CTRL-M}{CTRL-I}{inv}P{/inv}{CTRL-M}{CTRL-J}{inv}P{/inv}{CTRL-M}{CTRL-K}{inv}P{/inv}){inv}|{/inv}{CTRL-M}{inv}P{/inv}{CTRL-B}{inv}{CTRL-M}P{/inv}{CTRL-B}{inv}{CTRL-M}{/inv}"
525 V$(303)="{LEFT}{inv}P{/inv}Lb{inv}d{/inv}":POKE 205,A+G:FOR J=L TO 15:READ X,Y:V$(X,X)=CHR$(A+Y):NEXT J:D$="h{inv}){/inv}{CTRL-G}{inv}"{/inv}{CTRL-,}{inv} {/inv}{CTRL-,}L\{inv}d{/inv}":H=INT(ADR(V$)/T)
530 V=ADR(V$)-H*T:D$(K/G,K/G)=CHR$(H):D$(7,7)=CHR$(V):RESTORE 6000:POKE 206,159:FOR J=1536 TO 1586:READ X
535 POKE J,X:NEXT J:POKE 513,6:POKE 54286,192:U=USR(ADR(D$)):DL=PEEK(560)+T*PEEK(561):POKE 204,C
550 POKE 87,G+L:POKE 559,C:FOR J=K-G TO 17:POKE J+DL,K-G:NEXT J:POKE DL+J,7:POKE DL+K*G,134:N=16:RESTORE 5090
555 COLOR G+L:FOR J=L TO N:READ X,Y,H,V:PLOT X,Y:DRAWTO H,Y:DRAWTO H,V:DRAWTO X,V:DRAWTO X,Y:NEXT J:POKE 87,L
560 POSITION L+G,K-G:? #6;"{inv}by jd casten{/inv}";:GOSUB 620:POSITION L+G,K:? #6;"press trigger":POKE 623,K*G:GOSUB 900
565 SOUND L,T-L,K,L:SOUND G,T-G,K,L:SOUND G+L,7,K*G,C:POKE 53768,K:POKE 203,150:POKE 512,38:COLOR K/G:POKE 712,C
570 PLOT C,K+L:DRAWTO C,14:DRAWTO G+L,17:DRAWTO 6,17:PLOT 6,16:PLOT 13,16:PLOT 13,17:DRAWTO 16,17:DRAWTO 19,14
575 DRAWTO 19,K+L:COLOR 131:PLOT 7,16:DRAWTO K+G,16:X1=K:Y1=C:SL=K/G:RO=C:POKE 203,136:POKE 559,62:COLOR 32
580 U=USR(ADR("h{inv}{CTRL-H}{CTRL-L}{/inv}{CTRL-X}{inv}P-{/inv}{CTRL-K}{inv}T{CTRL-M}{/inv}{CTRL-Y}{inv}P-{CTRL-D}{/inv}{CTRL-B}{inv}Pq{/inv}{CTRL-.}")):PLOT 7,16:DRAWTO K+G,16:GOSUB 900:FOR J=138 TO 240 STEP G*G:POKE 203,J
585 FOR X=L TO K*G:NEXT X:NEXT J:POKE G+L,C:POKE 559,C:FOR J=K-G TO K*G:POKE J+DL,6:NEXT J:POKE DL+K+G,6
590 POKE DL+25,T/G:POKE DL+26,C:POKE DL+27,7:POKE DL+28,7:POKE 512,C:POKE 756,A:? #6;"{CLEAR}":POKE 18,C:POKE 19,C
600 POKE 559,C:GOSUB 300:COLOR K/G:PLOT C,C:DRAWTO C,19:DRAWTO 19,19:DRAWTO 19,C:DRAWTO L,C:RESTORE 10000+RO*K
605 COLOR 137:READ X,Y,H,V:PLOT X,Y:DRAWTO H,V:READ N:COLOR 5:FOR J=L TO N:READ X,Y,H,V:PLOT X,Y:DRAWTO H,V
607 NEXT J:POKE 623,18:READ N:IF N THEN COLOR 36:GOSUB 700
610 READ N:IF N THEN COLOR 167:GOSUB 705
611 READ N:IF N THEN COLOR 166:GOSUB 700
612 READ N:IF N THEN COLOR 170:GOSUB 705
613 READ N:IF N THEN COLOR 168:PLOT 6,18:COLOR 40:PLOT G,18:COLOR 136:PLOT K,18
614 READ N:IF N THEN COLOR 35:GOSUB 710
615 READ N:IF N THEN COLOR 43:GOSUB 710
616 READ N:COLOR 140:FOR J=L TO N:READ X,Y:PLOT X,Y:NEXT J:IF  NOT RO THEN COLOR 32:PLOT 7,C:DRAWTO K+G,C
618 GOSUB 620:X=X1:Y=Y1:U=C:D=C:I=C:D$="{INS CHAR}":D$(T-L)="{INS CHAR}":D$(G)=D$:RESTORE 5075:FOR J=L TO K/G:GOTO 675
620 FOR J=C TO 6:READ X:POKE J,X:NEXT J:READ S$,H,V:RESTORE 5080:FOR J=L TO 6:READ X:V$(X,X)=S$(J,J):NEXT J
625 POKE 53256,H:POKE 53257,V:RETURN
675 READ V:D$(V,V)="{CTRL-,}":NEXT J:D$(16,16)="{CTRL-,}":D$(T/G,T/G)="{CTRL-,}":POSITION G+G,K*G:D$(17,T/G)=D$(16,T/G):D$(36,36)="{CTRL-A}"
680 D$(43,43)="{INS CHAR}":? #6;"SLYVESTERS:";SL-L:POSITION 7,21:? #6;"room ";CHR$(RO+17);:POKE 559,62:POKE 541,C:GOTO K*K
700 FOR J=L TO N:READ X,Y,V:PLOT X,Y:DRAWTO X,V:NEXT J:RETURN
705 FOR J=L TO N:READ X,H,Y:PLOT X,Y:DRAWTO H,Y:NEXT J:RETURN
710 FOR J=L TO N:READ X,Y,H,V:FOR R=X TO H:PLOT R,Y:DRAWTO R,V:NEXT R:NEXT J:RETURN
800 IF Y<G THEN Y=Y+E:NEXT J
805 SL=SL+L:RO=RO+L:IF X=19 THEN X=L
810 IF X=C THEN X=18
815 IF Y>19 THEN Y=G
820 X1=X:Y1=Y:? #6;"{CLEAR}":GOTO 600
900 FOR J=53761 TO 53767:POKE J,C:NEXT J:POKE 53760,K/G:RETURN
4000 DATA {INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}{CTRL-A}{/inv}{INS CHAR}{inv}{CTRL-A}{CTRL-A}{CTRL-A}{/inv}{INS CHAR}{inv}{CTRL-A}{CTRL-A}:{/inv}]{inv}:{/inv}{INS CHAR}{INS CHAR}]{inv}:{/inv}]{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}<{BACK S}<B{inv}{CTRL-A}{CTRL-A}{/inv}B<{inv}C{/inv}{INS CHAR}fBBf{INS CHAR}{inv}C{/inv}""""""w{INS CHAR}
4001 DATA {INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}<{BACK S}{BACK S}{BACK S}{BACK S}<{LEFT}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}8{CTRL-H}{CTRL-,}{CTRL-H}<{BACK S}{CTRL-V}{CTRL-L}{inv}{CTRL-.}{/inv}.{CTRL-H}{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-,}F{/inv}{CTRL-B}{CTRL-P}|8T8x{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{UP}{CTRL-P}{CTRL-,}{CTRL-P}<{BACK S}h0s{CTRL-A}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}
4002 DATA p{CTRL-H}{CTRL-,}{CTRL-H}<{BACK S}{CTRL-V}{CTRL-L}{CTRL-G}t{CTRL-P}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-A}c@{CTRL-H}>{UP}*{UP}{inv}N{CTRL-,}{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-N}{CTRL-P}{CTRL-,}{CTRL-P}<{BACK S}h0{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}
4003 DATA {CTRL-,}{CTRL-N}{UP}{CTRL-N}{LEFT}{UP}{CTRL-F}{CTRL-T}{UP}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-H}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-.}|<8888{CTRL-,}{CTRL-,}{CTRL-,}({CTRL-,}{CTRL-,}p8px8{CTRL-.}(8{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-P}{CTRL-,}{CTRL-,}0g6{LEFT}{UP}{CTRL-L}{CTRL-V}{UP}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-H}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-F}><{UP}{UP}{UP}
4004 DATA {UP}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-T}{CTRL-,}{CTRL-,}{CTRL-L}{inv}f{/inv}lx80h8{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-P}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}
4005 DATA BBBBff<<{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}CC{/inv}{BACK S}{BACK S}<<{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}<<{BACK S}{BACK S}{inv}CC{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-X}{CTRL-X}<<ffBBBB{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}<<{BACK S}{BACK S}
4006 DATA {inv}CC{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}CC{/inv}{BACK S}{BACK S}<<{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}
5050 DATA 110,238,28,134,216,196,56,14
5055 DATA 62,4,74,5,86,3,98,7,101,6,114,4,127,5,140,3,153,6,160,7,243,0,248,0,251,0,256,0,261,0
5075 DATA 140,166,167,168,170
5080 DATA 36,43,50,191,198,205
5090 DATA 5,6,5,7,5,8,7,13,9,8,9,13,12,6,12,13,11,8,13,8,13,6,13,6,16,6,16,13,15,8,17,8,17,6,17,6,21,6,21,7,19,8
5091 DATA 21,13,23,8,25,8,23,8,23,13,27,8,29,13,31,8,33,13,31,14,31,15,128,122,0,112,122,0,0,{CTRL-A}{CTRL-,}{DEL CHAR}{CTRL-,}{CTRL-A}{inv}|{/inv},3,1
6000 DATA 72,152,72,141,10,212,169,82,141,26,208,169,224,141,9,212,160,8,153,255,207,136,208,250,169,90,141,23
6005 DATA 208,169,92,141,22,208,104,168,104,64,72,165,106,105,1,141,10,212,141,9,212,104,64
9000 FOR R=L TO I:READ D$:U=USR(ADR("hh{inv}{CTRL-E}L{/inv}h{inv}{CTRL-E}K{/inv}h{inv}{CTRL-E}N{/inv}h{inv}{CTRL-E}M {/inv}{CTRL-,}{inv}1K{CTRL-Q}MH@{/inv}@{inv}Pw{/inv}{CTRL-.}"),ADR(D$),J):J=J+64:NEXT R:RETURN
10000 DATA 8,19,11,19,17,6,1,6,3,13,1,13,2,2,3,4,3,8,3,13,3,1,7,14,7,14,6,16,4,15,6,16,5,3,8,7,8,14,11,18,11,3,13
10001 DATA 4,13,7,13,7,18,1,14,3,14,12,15,12,18,14,15,17,15,17,16,17,16,1,17,2,17,1,18,2,18,8,1,3,6,12,3,6,17,4
10002 DATA 10,1,10,11,13,11,18,6,13,18,3,15,16,11,15,18,2,14,18,1,18,18,16,3,3,1,2,5,9,18,17,17,18,2,4,6,7,1,2,13
10003 DATA 0,0,0,5,4,2,14,2,2,10,1,16,15,18
10009 DATA 128,104,48,0,82,0,0,{CTRL-A}{CTRL-,}{CTRL-A}{CTRL-,}{INS CHAR}{CTRL-A},0,0
10010 DATA 13,1,13,3,9,7,1,7,4,13,4,13,9,4,3,4,10,8,4,10,4,5,9,13,9,1,13,14,13,15,3,15,16,7,16,14,16,7,17,7,18,8
10011 DATA 6,4,8,11,4,8,1,4,5,3,7,8,1,10,11,8,10,15,10,10,15,6,16,17,2,5,13,12,8,11,19,2,9,10,15,14,14,14,3,5,5,8
10012 DATA 7,10,8,12,12,8,0,1,2,14,5,18,1,2,16,5,16,5,14,11,4,12,14,12,14,15,1,18
10019 DATA 0,172,64,0,92,0,0,{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-A}{BELL},0,3
10020 DATA 19,4,19,7,14,2,3,2,11,4,4,7,4,12,4,15,4,4,5,4,8,15,5,15,14,6,8,13,8,6,9,13,9,6,10,6,13,3,11,4,11,4,12
10021 DATA 4,14,2,14,3,14,6,14,17,14,2,15,2,16,8,15,8,16,2,3,4,10,14,8,18,4,1,1,11,8,12,13,1,1,16,10,12,18,10,6,1
10022 DATA 3,12,1,3,6,5,7,13,5,7,9,13,13,11,13,13,13,13,13,9,18,18,11,18,18,13,18,18,2,8,11,8,4,6,19,0,2,17,8,18
10023 DATA 8,16,15,16,17,2,16,8,16,8,16,18,16,18,5,18,3,3,13,7,13,17,13,18,18
10029 DATA 0,56,88,0,62,0,0,{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-A}{CTRL-B},1,0
10030 DATA 19,17,19,18,10,6,4,7,4,12,4,14,4,7,5,7,16,14,5,14,16,12,7,13,7,5,8,5,18,12,10,13,10,12,13,13,13,8,16
10031 DATA 11,16,2,18,4,16,4,1,4,4,2,7,14,4,6,14,6,8,17,4,8,11,4,15,18,4,3,3,16,15,18,16,4,12,5,6,12,8,9,12,11,12
10032 DATA 2,17,17,0,0,1,8,5,11,15,3,11,7,11,7,10,10,11,10,9,13,11,13,6,1,18,13,6,13,9,13,12,15,9,18,9
10039 DATA 64,72,128,0,128,192,176,{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,},1,1
10040 DATA 15,18,18,15,10,1,3,4,3,4,4,4,5,3,6,4,6,6,6,7,6,9,6,9,18,10,7,11,7,10,10,11,10,10,13,11,13,13,7,13,16
10041 DATA 11,16,11,16,7,2,6,18,5,10,14,8,6,18,8,4,4,13,4,4,18,4,4,18,7,13,2,16,17,19,12,12,16,5,4,1,2,11,8,9,11
10042 DATA 11,12,11,14,15,19,16,17,0,0,5,2,9,2,11,3,7,4,16,5,15,5,16,6,7,7,18,8,10,8,11,6,3,9,4,13,3,16,3,16,3,17
10043 DATA 5,18,6,9,8,9,5,12,7,12,7,15,7,16,6,1,2,18,2,3,5,10,9,10,12,10,16
10049 DATA 76,176,168,0,172,128,0,{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{TAB}{inv}{CTRL-A}{/inv},1,0
10050 DATA 19,8,19,10,4,3,4,18,4,1,8,16,8,3,11,18,11,1,15,16,15,8,2,1,7,17,5,10,2,9,14,17,12,18,7,5,7,12,5,7,7,12
10051 DATA 14,12,12,14,0,0,6,3,6,8,8,11,8,13,16,8,3,6,15,8,11,15,13,16,15,0,0,2,15,3,18,3,1,18,4,18,2,15,2,4,17
10059 DATA 0,0,0,0,56,176,240,{inv}{CTRL-A}{/inv}{TAB}{CTRL-A}{CTRL-,}{CTRL-,}{CTRL-A},3,3
10060 DATA 7,19,10,19,10,2,3,6,3,6,4,6,4,6,5,13,5,13,6,13,11,4,7,4,10,1,11,4,11,11,11,11,14,6,15,17,15,6,11,10,11
10061 DATA 1,15,4,15,5,2,7,9,6,6,8,11,6,8,18,1,18,10,4,4,2,7,10,8,2,16,18,5
10062 DATA 4,18,18,7,18,18,10,18,18,13,18,18,16,18,18,2,4,4,6,6,11,10,0,0,0,10,1,3,14,5,15,7,16,9,12,11,17,11,1
10063 DATA 13,10,14,1,18,17,18
10069 DATA 0,112,192,0,144,64,0,{inv}{CTRL-A}{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{TAB},1,1
10070 DATA 1,16,11,16,6,6,1,6,4,7,4,10,4,4,17,4,18,8,17,8,18,12,4,12,18,2,4,4,4,9,1,4,6,3,7,12,7,4,6,8,13,15,18,6
10071 DATA 9,18,12,15,13,3,6,13,9,12,13,15,18,1,2,4,3,3,2,1,1,3,1,1,4,1,1,3,1,3,18,5,7,18,9,11,18,1,4,2,5,6,6,1,8
10072 DATA 2,13,9,5,11,13,4,8,8,12,9,1,7,2,7,4,5,4,9,5,7,8,7,8,5,8,6,10,7,11,7,2,10,2,13,4,10,8,10,3,13,7,13,9,10
10073 DATA 10,13,9,6,6,1,12,5,9,15,5,15,11,15,17,16,8,16,14,18,18
10079 DATA 160,176,0,0,0,64,176,{CTRL-,}{CTRL-,}{DEL CHAR}{inv}{CTRL-A}{CTRL-A}{/inv}{CTRL-,},1,1
19999 DATA 0,0,0,108,158,170,46,{CTRL-C}{CTRL-B}{DEL CHAR}{CTRL-,}{CTRL-,}{CTRL-,},0,0

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: BIFFDROP.BAS.

Credits