Escape From Epsilon

Type
Game
Category
Flick-screen platform game
Author
J. D. Casten
Published in
Antic, June 1984 (Vol. 3, No. 2), Game of the Month
Year
1984
Language
Atari BASIC
Requirements
16K RAM (24K for disk systems), joystick in port 1, Atari BASIC
A GRAPHICS 1 dungeon screen of brown and dark red brick shaped like a goblet, a small figure at top left, blue spikes along the bottom, and SCREENS TO GO:5 with two spare lives below

About the program

J. D. Casten's second Game of the Month for Antic introduced the hero who would return in Biffdrop at the end of the year. Slyvester Biffdrop has been locked in the lowest of five deadly dungeons, named Alpha to Epsilon, and you must help him escape from each one in turn. In every level Sly starts at the far left and must reach the far right edge, travelling from screen to screen, collecting keys and opening locked doors. Each door uses up one key, and the keys you carry are shown at the bottom of the screen. Antic later reported that this and Risky Rescue were the two most popular action games it had printed. (The magazine's artist drew Sly as an adventurer in a hat. Only at Biffdrop time did the editors learn that he is a duck.)

The dungeons are full of hazards:

  • Spikes, which kill Sly at a touch.
  • Under-footers, moving footways that are often all that lies between Sly and the spikes. Run along the top or jump over them.
  • Vacuum swings, hanging from the ceiling. Jump up under one to grab it, and push the stick to let go.
  • Vanishing bridges, which come and go without warning, and sliding bridges, which move back and forth over the spikes.

What you need

A joystick in port 1, 16K (24K with a disk drive). It runs on all Atari computers.

Typing it in

The screens are built from redefined characters, so the listing has many inverse-video ({inv}…{/inv}, Atari key) and control characters ({CTRL-L}, {CTRL-J}, {CTRL-,} and others: hold CTRL and press the key). Copy them exactly, since each one is a piece of the dungeon. SAVE before running.

How to play

Move left and right with the joystick and press the trigger to jump. When Sly escapes from a level, the time it took is shown in minutes. To pick a different starting level, press SELECT and then START.

How it works

  • The same engine as Risky Rescue: GRAPHICS 1 characters, with LOCATE checking the squares Sly is about to enter. Sly is two characters tall, so lines 120–125 check both his head and his feet, and the sum of the two codes tells whether the way is clear.
  • The joystick is read directly from the PIA (PEEK(54016)) and the trigger from GTIA (PEEK(53264)).
  • COLOR 162.5-1.5*D gives 161 or 164, depending on whether Sly's direction D is 1 or -1, so one statement picks the right- or left-facing head. The feet use the same trick, plus R to alternate two walking frames.
  • Each moving object has its own small subroutine: the swing that carries Sly along the top row (line 200), a moving platform (line 210) and the vanishing bridge (line 220). The main loop calls only the ones on the current screen, using flags TM, GI and DI.

Listing

10 REM ESCAPE FROM EPSILON
20 REM BY J.D. CASTEN
30 REM ANTIC MAGAZINE
40 GOTO 500
100 FOR Z=0 TO 1 STEP 0:IF OX<>X THEN COLOR 32:PLOT OX,OY:PLOT OX,OY+1:OX=X:R=1-R
105 IF OY<Y THEN COLOR 32:PLOT OX,OY:OY=Y
110 IF OY>Y THEN COLOR 32:PLOT OX,OY+1:OY=Y
115 COLOR 162.5-1.5*D:PLOT X,Y:COLOR 3.5-1.5*D+R:PLOT X,Y+1:ST=PEEK(54016):TR=PEEK(53264)
120 IF ST=247 THEN D=1:X=X+1:LOCATE X,Y,Q:LOCATE X,Y+1,Q1:IF Q+Q1<>64 THEN 300
125 IF ST=251 THEN D=-1:X=X-1:LOCATE X,Y,Q:LOCATE X,Y+1,Q1:IF Q+Q1<>64 THEN 300
130 IF  NOT I AND TR=0 AND T<>32 THEN I=5:Y=Y-1:R=1-R:LOCATE X,Y,Q:IF Q<>32 THEN Y=OY:I=0
135 IF  NOT I THEN 150
140 IF I THEN I=I-1:SOUND 1,5,6,I:IF  NOT I THEN 150
145 GOTO 160
150 LOCATE X,Y+2,T:IF T<>32 THEN 325
155 Y=Y+1
160 U=USR(1536):IF TM THEN GOSUB 200
165 IF GI THEN GOSUB 210
170 IF DI THEN GOSUB 220
175 LOCATE X,Y+1,Q:IF Q<>32 THEN IF Q<160 THEN IF Q>6 THEN 375
180 NEXT Z
200 OTX=TX:COLOR 32:PLOT OTX,1:COLOR 11:TX=TX+DX:PLOT TX,1:IF TX=6 OR TX=13 THEN DX=-DX
202 IF X=OTX AND Y=2 THEN X=TX:I=5:D=DX:POKE 53762,6
204 RETURN
210 IF WX<0 THEN COLOR 32:PLOT GX,5+OP
212 COLOR 9:GX=GX+WX:PLOT GX,5+OP:IF GX=6 OR GX=14-INT(LE/1.5) THEN WX=-WX
214 RETURN
220 DT=DT+1:IF DT=20-LE*3 THEN DT=0:COLOR DR:PLOT 6,5:DRAWTO 13,5:DR=41-DR
222 RETURN
300 IF Q1=174 THEN 450
305 IF Q1=175 THEN IF MY THEN MY=0:GOTO 460
310 X=OX:GOTO 150
325 IF T=10 THEN 375
330 IF OX<>X THEN POKE 53767,135:POKE 53767,0
335 GOTO 160
350 OY=Y:OX=X:FOR J=1 TO ME:COLOR 161:PLOT J+10,22:COLOR 3:PLOT J+10,23:NEXT J:COLOR 32:PLOT J+9,22:PLOT J+9,23
355 IF ME=0 THEN 2000
360 GOTO 100
375 COLOR 32:PLOT OX,OY:PLOT OX,OY+1:COLOR 162.5-1.5*D:PLOT X,Y+1:ME=ME-1:FOR J=30 TO 100:SOUND 1,J,10,6
380 SOUND 2,J+1,10,6:NEXT J:GOSUB 850:X=1+17*(X>9):Y=3+6*(Y>6)+7*(Y>13):D=1-2*(X=18):GOTO 600
400 TRAP 400:SC=SC+1-2*(X<0):X=19-OX:GOTO 600
450 COLOR 32:PLOT KX,KY:MY=1:COLOR 174:PLOT 9,22:KE=0
455 RESTORE 5000:FOR J=1 TO 13:READ B,U:SOUND 1,B,10,8:FOR T=0 TO 25*U:NEXT T:SOUND 1,0,0,0:NEXT J:NEXT Z
460 COLOR 32:PLOT 19,1:DRAWTO 19,4:PLOT 19,8:DRAWTO 19,10:PLOT 19,15:DRAWTO 19,17:PLOT 9,22:RESTORE 4000+KH
465 READ KE,KH:RESTORE 5050:FOR J=1 TO 17:READ B,U:SOUND 1,B,10,8:FOR T=0 TO 25*U:NEXT T:SOUND 1,0,0,0:NEXT J
470 NEXT Z
500 A=PEEK(106)-6:GRAPHICS 17:POKE 559,0:U=USR(ADR("hh{inv}{CTRL-E}L{/inv}h{inv}{CTRL-E}K{/inv}h{inv}{CTRL-E}N{/inv}h{inv}{CTRL-E}M"{/inv}{CTRL-B}{inv} {/inv}{CTRL-,}{inv}1K{CTRL-Q}M{CTRL-H}PyfLfNJPp{/inv}{CTRL-.}"),57344,A*256):LE=1
505 FOR J=A*256+8 TO A*256+127:READ B:POKE J,B:NEXT J:COM SC$(80),L$(7):Z=PEEK(89):FOR J=1536 TO 1630:READ B
510 POKE J,B+Z*(B=1):NEXT J
550 GOSUB 850:GRAPHICS 17:GOSUB 810:DL=PEEK(560)+256*PEEK(561):POKE DL+10,7:POKE DL+13,7:POKE 710,0:POSITION 0,5
555 ? #6;"{inv}ESCAPE FROM EPSILON{/inv}":FOR J=0 TO 10 STEP 0.5:POKE 710,J*1.2:FOR I=0 TO 3:SOUND I,170+I,10,J:NEXT I
560 NEXT J:U=USR(ADR("h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}{/inv}{CTRL-T}{inv}{CTRL-E}{/inv}{CTRL-S}i{CTRL-A}{inv}h{CTRL-N}{/inv}{CTRL-Z}{inv}P{CTRL-N}{/inv}{CTRL-J}{inv}TE{/inv}{CTRL-S}{inv}Pu{/inv}{CTRL-.}")):POSITION 3,8:? #6;"by jd casten":FOR J=9 TO 0 STEP -0.2
565 FOR I=0 TO 3:SOUND I,170+I,10,J:NEXT I:NEXT J:POSITION 0,12:? #6;"press start to play"
570 RESTORE 6000+LE:READ L$,EN,KE,KH,SC$:POSITION 3,10:? #6;"SELECT:";L$:IF U=LE-1 THEN FOR J=0 TO 50:NEXT J
575 U=PEEK(53279):IF U=5 THEN LE=LE+1-5*(LE=5):U=LE-1
580 IF U<>6 THEN 570
585 SC=1:X=2:Y=3:D=1:R=0:MY=0:ME=3:SOUND 3,5,0,0:TRAP 400:POKE 18,0:POKE 19,0:POKE 20,0
600 SOUND 1,0,0,0:IF SC=EN THEN 700
601 GRAPHICS 17:GOSUB 810:POKE DL+26,134:NU=ASC(SC$(SC))
602 OP=0:IF KH=SC THEN COLOR 168:PLOT 19,1:DRAWTO 19,16:COLOR 175:PLOT 19,4:PLOT 19,10:PLOT 19,17
603 COLOR 39:PLOT 0,0:DRAWTO 19,0:PLOT 0,5:DRAWTO 19,5:PLOT 5,8:DRAWTO 14,8:PLOT 0,11:PLOT 1,11:PLOT 18,11
604 PLOT 19,11:PLOT 0,14:DRAWTO 19,14:PLOT 0,20:DRAWTO 19,20:PLOT 0,18:PLOT 1,18:PLOT 18,18:PLOT 19,18:PLOT 0,7
605 DRAWTO 19,7:PLOT 0,21:DRAWTO 19,21:IF SC=1 THEN PLOT 0,0:DRAWTO 0,21
606 COLOR 136:PLOT 0,6:DRAWTO 19,6:PLOT 6,7:DRAWTO 13,7:COLOR 10:PLOT 0,13:DRAWTO 19,13:PLOT 0,20:DRAWTO 19,20
607 POSITION 1,22:? #6;"{inv}screens{/inv}":? #6;"{inv} to go{CTRL-Z}{/inv}";EN-SC:TM=0:IF NU<128 THEN 615
611 NU=NU-128:COLOR 8:PLOT 6,0:DRAWTO 13,0:COLOR 32:PLOT 7,5:DRAWTO 12,5:PLOT 6,6:DRAWTO 13,6:COLOR 10
612 PLOT 6,7:DRAWTO 13,7:COLOR 39:PLOT 5,6:PLOT 14,6:COLOR 11:PLOT 13,1:TM=1:TX=13:OTX=5:DX=-1
613 IF LE>2 THEN COLOR 32:PLOT 6,5:PLOT 13,5:IF LE=5 THEN PLOT 5,5:PLOT 14,5
615 GI=0:IF NU<64 THEN 620
616 NU=NU-64:COLOR 32:PLOT 6,5:DRAWTO 13,5:PLOT 6,6:DRAWTO 13,6:COLOR 10:PLOT 6,7:DRAWTO 13,7:COLOR 39
617 PLOT 5,6:PLOT 5,7:PLOT 14,6:PLOT 14,7:GI=1:GX=6:OGX=6:WX=1
620 DI=0:IF NU<32 THEN 630
621 NU=NU-32:COLOR 39:PLOT 5,6:PLOT 14,6:COLOR 32:PLOT 6,5:DRAWTO 13,5:PLOT 6,6:DRAWTO 13,6:COLOR 10:PLOT 6,7
622 DRAWTO 13,7:DI=1:DT=4:DR=9
630 IF NU<16 THEN 640
631 NU=NU-16:IF TM=0 THEN 635
632 COLOR 39:PLOT 6,0:DRAWTO 13,0:PLOT 6,5:DRAWTO 13,5:PLOT 9,15:DRAWTO 9,18:PLOT 10,18:DRAWTO 10,15:COLOR 32
633 PLOT 13,1:COLOR 136:PLOT 5,6:DRAWTO 14,6:PLOT 6,7:DRAWTO 13,7:TM=0:GOTO 640
635 COLOR 39:PLOT 5,6:DRAWTO 14,6:PLOT 5,7:DRAWTO 14,7:COLOR 32:PLOT 12,6:PLOT 13,6:PLOT 6,5:PLOT 7,5:PLOT 6,6
636 PLOT 7,6:PLOT 9,5:DRAWTO 9,8:PLOT 10,5:DRAWTO 10,8:PLOT 12,5:PLOT 13,5:COLOR 10:PLOT 6,7:PLOT 7,7:PLOT 12,7
637 PLOT 13,7
640 IF NU<8 THEN 645
641 NU=NU-8:COLOR 32:FOR J=5 TO 8:PLOT J,J:DRAWTO 19-J,J:NEXT J:COLOR 39:PLOT 5,6:PLOT 6,7:PLOT 14,6:PLOT 13,7
642 OP=1
645 Q=0:IF NU<4 THEN 650
646 NU=NU-4:COLOR 39:PLOT 6,9:DRAWTO 8,11:DRAWTO 10,11:DRAWTO 8,9:COLOR 136:PLOT 5,7:DRAWTO 8,10:Q=1
650 IF NU<2 THEN 655
651 NU=NU-2:COLOR 39:PLOT 11,9:DRAWTO 9,11:DRAWTO 11,11:DRAWTO 13,9:COLOR 136:PLOT 14,7:DRAWTO 11,10:Q=Q+1
652 IF Q=2 THEN PLOT 8,9:DRAWTO 11,9:PLOT 9,10:PLOT 10,10
655 EL=0:IF NU<1 THEN 660
656 NU=NU-2:COLOR 32:PLOT 3,12:DRAWTO 16,12:PLOT 4,13:DRAWTO 15,13:PLOT 5,14:DRAWTO 14,14:COLOR 136:PLOT 3,14
657 EL=1:DRAWTO 1,12:PLOT 0,13:PLOT 1,13:PLOT 16,14:DRAWTO 18,12:PLOT 19,13:PLOT 18,13:FOR J=5 TO 9:PLOT J,25-J
658 DRAWTO 19-J,25-J:NEXT J:COLOR 39:PLOT 0,11:PLOT 1,11:DRAWTO 5,15:DRAWTO 5,15:DRAWTO 0,14:PLOT 19,11
659 PLOT 18,11:DRAWTO 14,15:DRAWTO 19,14:PLOT 5,20:PLOT 5,19:DRAWTO 9,15:PLOT 10,15:DRAWTO 14,19:PLOT 14,20
660 IF GI THEN COLOR 9:PLOT 6,5
661 IF EL THEN 664
662 COLOR 172:PLOT 19,12:DRAWTO 12+LE,12:PLOT 9,12:DRAWTO 2+LE,12:PLOT 0,19:DRAWTO 7-LE,19:PLOT 10,19
663 PLOT 0,19:DRAWTO 7-LE,19:PLOT 10,19:DRAWTO 17-LE,19
664 IF Q+EL=3 THEN COLOR 136:PLOT 9,11:PLOT 10,11:COLOR 39:PLOT 9,12:DRAWTO 9,14:PLOT 10,14:DRAWTO 10,12
690 IF KE=SC THEN RESTORE 3000+KE:READ KX,KY:COLOR 174:PLOT KX,KY
691 IF MY THEN COLOR 174:PLOT 9,22
692 IF TM+GI<2 THEN 694
693 COLOR 39:PLOT 6,0:DRAWTO 13,0:PLOT 9,1:DRAWTO 9,6:PLOT 10,6:DRAWTO 10,1:COLOR 32:PLOT 13,1:PLOT 6,5:GI=0:TM=0
694 POKE 77,0:GOTO 350
700 GRAPHICS 17:GOSUB 810:POKE 711,200:POKE 712,130:COLOR 39:PLOT 0,5:DRAWTO 2,5:PLOT 0,11:DRAWTO 2,11:PLOT 0,18
705 DRAWTO 2,18:COLOR 136:PLOT 6,5:DRAWTO 5,5:DRAWTO 5,18:PLOT 4,11:PLOT 6,11:PLOT 8,18:DRAWTO 8,11:DRAWTO 10,11
710 FOR J=0 TO 4 STEP 4:PLOT J+14,18:DRAWTO J+12,18:DRAWTO J+12,11:DRAWTO J+14,11:DRAWTO J+14,15:PLOT J+13,15
715 NEXT J:POSITION 8,5:RESTORE 6000+LE:READ L$:? #6;L$:COLOR 161:PLOT 0,Y:COLOR 3:PLOT 0,Y+1:POSITION 8,7
720 ? #6;"TIME:";INT((PEEK(18)*65536+PEEK(19)*256+PEEK(20))/3595.3646+0.5):POSITION 8,9:? #6;"{inv}PRESS{/inv} {inv}START{/inv}"
725 RESTORE 5100:FOR J=0 TO 31:READ B,U:SOUND 0,B,10,6:SOUND 1,U,10,6:FOR T=0 TO 6:GOSUB 800:NEXT T:NEXT J
730 FOR J=0 TO 500:GOSUB 800:NEXT J:GOTO 725
800 IF PEEK(53279)=6 THEN POP :GOTO 550
805 RETURN
810 POKE 708,246:POKE 709,122:POKE 710,12:POKE 711,50:POKE 756,A:POKE 512,79:POKE 513,6:POKE 54286,192:RETURN
850 FOR J=0 TO 2:SOUND J,0,0,0:NEXT J:RETURN
900 DATA 0,0,48,104,126,60,16,56,40,100,56,120,112,56,112,120,104,54,56,120,108,230,140,206,0,0,12,22,126,60,8,28
905 DATA 20,38,28,30,14,28,14,30,22,108,28,30,54,103,49,115,255,189,255,223,251,255,191,236,255,255,255,255,255
910 DATA 255,255,255,255,16,40,68,130,1,255,0,34,34,34,34,34,34,119,255,56,16,16,16,16,124,254,130,255,129,129
915 DATA 255,0,0,0,0,124,92,92,92,68,124,16,254,0,0,0,224,160,190,170,234,255,255,231,195,195,231,231,255,104,160
920 DATA 0,190,112,1,169,0,153,112,1,200,192,20,208,7,138,153,111,1,76,41,6,185,112,1,201,140,208,8,153,111,1,169
925 DATA 0,153,112,1,76,11,6,160,20,190,251,1,169,0,153,251,1,136,192,0,208,5,138,153,252,1,96,185,251,1,201,140
930 DATA 208,8,153,252,1,169,0,153,251,1,76,51,6,72,169,28,141,10,212,141,22,208,169,78,141,25,208,104,64
2000 POSITION 1,22:? #6;"    {inv}game over{/inv}":? #6;"    PRESS START":RESTORE 5150:U=1:Z=1:FOR Q=1 TO 27:GOSUB 800:U=U-1
2005 IF U=0 THEN SOUND 0,0,0,0:READ B,U:SOUND 0,B,10,6
2010 Z=Z-1:IF Z=0 THEN SOUND 1,0,0,0:READ B,Z:SOUND 1,B,10,6
2015 FOR T=0 TO 25:NEXT T:NEXT Q:GOSUB 850:FOR Q=0 TO 300:GOSUB 800:NEXT Q:GOTO 2000
3002 DATA 19,17
3003 DATA 18,10
3004 DATA 1,10
3005 DATA 18,10
3006 DATA 1,10
3009 DATA 18,17
3011 DATA 1,10
3016 DATA 18,17
3039 DATA 1,10
3042 DATA 18,10
3056 DATA 1,10
3060 DATA 15,4
3076 DATA 18,10
4007 DATA 0,0
4008 DATA 9,15
4009 DATA 11,14
4012 DATA 13,25
4014 DATA 19,20
4015 DATA 16,22
4022 DATA 29,30
4025 DATA 28,34
4030 DATA 39,41
4034 DATA 38,40
4041 DATA 42,50
4050 DATA 56,57
4057 DATA 60,63
4063 DATA 64,71
4071 DATA 76,80
4080 DATA 0,0
5000 DATA 60,2,72,2,60,4,60,2,72,2,60,4,53,2,60,2,64,2,72,2,81,2,72,2,64,4
5050 DATA 60,2,91,2,91,1,91,1,91,2,91,1,81,1,72,1,64,1,60,4,60,2,81,2,81,2,64,2,72,2,81,2,91,4
5100 DATA 47,121,53,121,60,121,53,121,47,121,45,121,40,121,40,121,45,108,40,108,47,121,45,121,53,128,45,128,60
5103 DATA 144,53,128,47,121,53,121,60,121,53,121,47,121,45,121,40,121,40,121,45,108,40,108,47,121,45,121,53,162
5107 DATA 53,128,60,121,0,0
5150 DATA 72,2,121,8,91,4,71,2,91,3,144,4,91,1,108,1,128,1,121,3,144,3,91,1,144,1,91,1,144,1,91,1,144,1,91,1,144
5163 DATA 1,72,1,121,1,72,1,121,1,81,2,128,2,91,3,144,3
6001 DATA {inv}ALPHA  {/inv},6,2,5,{CTRL-G}{inv}{CTRL-,}{/inv} {inv}{CTRL-,}{/inv}{CTRL-J}
6002 DATA {inv}BETA {/inv},11,5,7,{CTRL-A}{inv}{CTRL-,}{/inv} @{CTRL-J}@{inv}{CTRL-G}{/inv}{CTRL-I}{inv}{CTRL-,}{/inv}P
6003 DATA {inv}GAMMA{/inv},21,4,9,{inv}I{/inv}{CTRL-L}@{CTRL-L} {inv}A{CTRL-,}{/inv}{CTRL-J}{CTRL-G}@{CTRL-L}@{CTRL-G}{CTRL-P}{inv}@{/inv}{CTRL-L}  {CTRL-L}{inv}{CTRL-G}{/inv}
6004 DATA {inv}DELTA{/inv},41,3,12,{CTRL-G}{inv}{CTRL-,}{/inv}{CTRL-J}{inv}{CTRL-,}{CTRL-P}{CTRL-A}L{/inv}@A@{inv}{CTRL-P}{/inv}@{inv}{CTRL-Z}{/inv} !{inv}{CTRL-P}{/inv} !  0  {inv}@{/inv}{CTRL-L}{inv}{CTRL-,}{/inv}@&{inv}{CTRL-,}{/inv}A {inv}{CTRL-,}{/inv}{CTRL-J}{inv}@L{/inv}{CTRL-L}@{CTRL-L}'{inv}H{/inv}
6005 DATA {inv}EPSILON{/inv},81,6,8,'P{inv}@{/inv}{CTRL-L}{inv}{CTRL-G}{/inv}F{inv}{CTRL-A}{/inv}P{inv}{CTRL-Z}H{/inv}{CTRL-J}{CTRL-L}F{CTRL-L}{inv}A{CTRL-P}{/inv}@{CTRL-J}{inv}{CTRL-A}{CTRL-P}{/inv}A2{inv}@{/inv}{CTRL-L}{inv}{CTRL-G}{/inv}0{inv}@{/inv}{CTRL-L}{CTRL-L}'{inv}I{/inv}{CTRL-L}{CTRL-L}'{inv}H{/inv}@{CTRL-L}'{CTRL-L}'{inv}H{/inv}{CTRL-J}{inv}@{/inv}{CTRL-J}{inv}LJLJ{/inv}{CTRL-L}'{inv}H{/inv}{CTRL-L}'{inv}H{/inv}{CTRL-L}{CTRL-L}{inv}{CTRL-G}{/inv}P{inv}{CTRL-F}A{/inv}{CTRL-J}G{CTRL-H}{inv}F{/inv}{CTRL-J}{inv}{CTRL-A}{CTRL-P}{/inv}!{CTRL-L}{CTRL-A}{inv}{CTRL-,}{/inv}&{inv}I{CTRL-Z}{/inv}A{CTRL-J}{CTRL-J}{inv}{CTRL-A}F{/inv}{CTRL-A}

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: ESCAPE.BAS.

Credits