Diver

Type
Game
Category
Underwater treasure-hunt game
Author
Steve May
Published in
Antic, October 1984 (Vol. 3, No. 6), bonus game
Year
1984
Language
Atari BASIC
Requirements
Any Atari 8-bit, joystick in port 1, Atari BASIC
A GRAPHICS 1 sea scene: blue sky at the top with the diving bell on the surface, green bands of water, dark reefs at the bottom with five yellow treasure chests, and SCORE, DIVERS, TREASURE CHESTS and an OXYGEN bar in the text window

About the program

Diver was the bonus game in Antic's October 1984 issue. It runs on any Atari, whatever its memory. You command Diver, a small one-man diving bell, exploring dangerous reefs for chests of treasure. Some chests hold only sand and seaweed. Steve May filled the sea with trouble:

  • The reef itself destroys Diver at a touch.
  • Octopi chase you relentlessly. The only safe place is on the surface.
  • Sea mines appear with a countdown timer in the middle. At zero, everything under water is destroyed, so surface quickly.
  • Submarines need a couple of seconds for their sonar to find you, then fire a laser that never misses. The sonar can't see through the reef, though, so you are safe below its highest point (or on the surface).

Your oxygen, shown as a bar at the bottom of the screen, runs down while you are submerged. Surfacing refills it and reveals what your chests contained.

What you need

A joystick in port 1 and Atari BASIC.

Typing it in

The oxygen bar in line 900 is a run of 20 {CTRL-T} characters (hold CTRL and press T, the ball symbol). Diver himself is an inverse @ ({inv}…{/inv}, Atari key). Line 30000 holds a machine-code routine inside a string, which copies the character set to RAM. Its inverse and {CTRL-…} characters must be exact. The magazine asked readers to check the listing with TYPO and to SAVE a backup before running.

How to play

Press START at the title screen. The joystick moves Diver up, down, left and right. To pick up a chest, stop directly above it and press the button. To surface, go to the top and press the button. Press it again to dive. Each chest is worth 10 points when you take it, and its contents (0 to 150 points) are added when you surface. One point is taken off for each unit of oxygen you used. Clearing a reef takes you to the next one. Each new skill level brings a free Diver if you have fewer than three.

How it works

  • The sea is GRAPHICS 1 with a custom font. The reefs are drawn from DATA with COLOR 43 and PLOT/DRAWTO (lines 1000–1146), so each reef "pixel" is really a character.
  • LOCATE does all the collision work. Before each move, line 300 reads the character in the target cell: a blank is safe, a chest (code 234) blocks the way, and anything else destroys the bell.
  • The octopus, mine and submarine appear at random (lines 600–670) and each has its own subroutine (2000, 2200, 2300). Flags make sure only the active hazards use processing time.
  • The article included a full "take-apart" table of line ranges and variables, a good model for documenting a BASIC program.

Listing

5 REM DIVER
6 REM BY STEVE MAY
7 REM ANTIC MAGAZINE
10 GOSUB 1500:GRAPHICS 1:GOSUB 1400:GOSUB 1000:GOSUB 1300:DV=3:OX=20:GOSUB 900:DX=9:DY=0:DV=3:DIM X(20),Y(20)
20 DIM S$(3):S$="{inv}(>){/inv}"
30 POSITION DX,DY:? #6;"{inv}@{/inv}";:F6=1:GOTO 430
100 GOSUB 600:S=STICK(0)
105 IF STRIG(0)=0 THEN 400
110 IF (S=7 AND DX<19) THEN NDX=1:NDY=0:GOTO 300
120 IF (S=11 AND DX>0) THEN NDX=-1:NDY=0:GOTO 300
130 IF (S=13 AND DY<19) THEN NDX=0:NDY=1:GOTO 300
140 IF S=14 THEN NDX=0:NDY=-1:GOTO 300
200 GOTO 100
300 SOUND 0,40+DY*2.5,6,2:LOCATE DX+NDX,DY+NDY,CHR:IF CHR=32 THEN 310
303 IF CHR=234 THEN 100
305 GOTO 500
310 POSITION DX,DY:? #6;" ";:DX=DX+NDX:DY=DY+NDY:POSITION DX,DY:? #6;"{inv}@{/inv}";:GOTO 100
400 LOCATE DX,DY+1,CHR:IF CHR<>234 THEN 420
410 GOSUB 3000:POSITION DX,DY+1:? #6;" ";:SC=SC+10:TC=TC+1:OB=OB+1:GOSUB 910:GOTO 100
420 IF DY<>1 THEN 100
425 SOUND 0,0,0,0
430 FOR X=1 TO 50:NEXT X:SC=SC-OX:F2=1:OC=0:OX=20:POSITION DX,DY:? #6;" ";:POSITION DX,0:? #6;"{inv}@{/inv}";
431 IF F6=0 THEN GOSUB 3010
432 IF SC<0 THEN SC=0
435 F6=0:GOSUB 910:IF TC>0 THEN 460
440 GOSUB 600:IF STRIG(0)<>0 THEN 440
450 FOR X=1 TO 50:NEXT X:GOSUB 3010:POSITION DX,0:DY=1:? #6;"_";:POSITION DX,DY:? #6;"{inv}@{/inv}";:F2=0:GOTO 100
460 SOUND 0,0,0,0:POSITION 0,2:? #6;"THE TREASURE CHEST";:IF TC>1 THEN ? #6;"S ";:GOTO 466
464 ? #6;"  ";
466 ? #6;"CONTAINED:":? #6
470 FOR X=1 TO TC:Y=INT(RND(0)*17):? #6;TR$(Y*10+1,Y*10+10);" ";PT(Y);" PTS.":SC=SC+PT(Y):TC=TC-1:GOSUB 910:NEXT X
475 IF OB=5 THEN 800
480 FOR X=1 TO 2000:NEXT X
490 POSITION 0,2:FOR X=0 TO 7:? #6;"                    ";:NEXT X:TC=0:GOSUB 910:GOTO 440
500 IF CHR=95 THEN 100
510 GOSUB 3020:SOUND 0,0,0,0:C=0:FOR N=1 TO 20:X(N)=0:Y(N)=0:NEXT N
520 LOCATE DX,DY+1,CHR:IF CHR=32 THEN 540
530 GOSUB 3040:FOR N=1 TO C:POSITION X(N),Y(N):? #6;" ";:NEXT N:POSITION 0,0:? #6;"_";
532 FOR N=0 TO 2:SOUND N,0,0,0:NEXT N
535 POSITION DX,DY:? #6;" ";:DX=9:DY=0:DV=DV-1:TC=0:OC=0:OX=20:F2=0:GOSUB 910:IF OB=5 THEN POSITION 0,3:GOTO 800
538 GOTO 30
540 IF DY=19 THEN 530
550 C=C+1:X(C)=DX:Y(C)=DY:POSITION DX,DY:? #6;"/";:GOSUB 3050:DY=DY+1:POSITION DX,DY:? #6;"{inv}@{/inv}";
560 FOR X=1 TO 150:NEXT X:GOTO 520
570 GOTO 520
600 IF F2=1 THEN 620
610 OC=OC+1:IF OC=10 THEN OC=0:OX=OX-1:GOSUB 910:IF OX=0 THEN GOTO 510
620 IF F3=1 THEN 640
630 IF INT((RND(0)*20)/(SK+1))=1 THEN F3=1:OCX=INT(RND(0)*20):OCY=4
640 IF F1=1 THEN 660
650 IF INT((RND(0)*200)/(SK+1))=1 THEN F1=1:BX=INT(RND(0)*18):BY=5:TICKER=5:C2=0
660 IF F4=1 THEN 700
670 IF INT((RND(0)*OX*15)/(SK+1))=1 THEN F4=1:C3=0:SX=0:SY=8
700 IF F3<>1 THEN 720
710 C1=C1+1:IF C1=ABS(3-SK) THEN C1=0:GOSUB 2000
720 IF F4=1 THEN 2300
730 IF F1=1 THEN 2200
740 RETURN
800 ? #6:? #6;"all{inv} THE treasure IS        GONE.{/inv}":OB=0:CR=CR+1:IF CR=5 THEN GOTO 850
805 ? #6:? #6;"    {inv}ADVANCING TO{/inv}":? #6;"   coral  reef #";CR+1;:GOTO 820
810 TC=0:OC=0:OX=20:F2=0:DX=9:DY=0:F1=0:F3=0:F4=0:RETURN
820 GOSUB 810:FOR X=1 TO 1000:NEXT X
840 GOSUB 1000:GOSUB 905:GOTO 30
850 GOSUB 810:CR=0:SK=SK+1:? #6;"{inv}YOU HAVE ADVANCED TO   {/inv}SKILL  LEVEL ";SK+1;
860 IF DV<3 THEN DV=DV+1:GOTO 820
870 GOTO 820
900 DIM OX$(21),DV$(3),TC$(6):OX$=" {CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}{CTRL-T}":DV$=" @@":TC$=" JJJJJ"
905 POKE 82,0:POKE 752,1:? CHR$(125):? CHR$(28);
910 IF DV=0 THEN GOTO 1200
920 ? "SCORE:";SC;" ";:POKE 657,23:? "HIGH SCORE:";HSC:POKE 656,1:POKE 657,0:? "DIVERS:";DV$(1,DV);" ";
930 POKE 657,12:? "TREASURE CHESTS:";TC$(1,TC+1);"     ";:POKE 656,2:POKE 657,6:? "OXYGEN:";OX$(1,OX+1);" ";
940 POKE 656,0:POKE 657,0:RETURN
1000 POKE 752,1:? #6;CHR$(125):? "{CLEAR}":POKE 708,162:POKE 709,202:POKE 710,10:POKE 711,30:POKE 712,116
1005 POKE 756,PEEK(106)+1:POSITION 0,0:? #6;"____________________";
1010 COLOR 43:RESTORE 1100+CR*10:READ X1:FOR N=1 TO X1:READ Z,Y,Z1,X:PLOT Z,Y:DRAWTO Z1,X:NEXT N
1030 COLOR 234:FOR N=1 TO 5:READ Z,Y:PLOT Z,Y:NEXT N:READ HT:RETURN
1100 DATA 8,0,16,0,18,1,17,1,18,0,19,19,19,6,17,8,17,5,18,8,18,15,16,15,16,15,17,16,17,14,18,17,18
1102 DATA 1,16,7,16,9,18,14,17,18,18,16
1110 DATA 16,0,15,5,15,0,16,1,16,0,17,0,17,5,15,5,18,4,18,4,18,0,19,2,19,7,19,7,18,8,19,8,17,9,19,9,14
1112 DATA 10,19,10,15,11,16,11,16
1114 DATA 11,19,19,19,15,18,19,18,16,17,17,17,16,16,16,16,19,17,19,14
1116 DATA 4,17,18,17,7,17,11,18,19,13,14
1120 DATA 18,0,12,0,19,1,12,1,15,1,18,1,19,2,12,2,13,3,12,4,12,3,15,3,19,4,14,4,14,4,15,6,15,4,18,4,19
1122 DATA 6,16,7,16,6,17,11,17,5,19,19,19,16,14,16,14,15,15,16,15,14,16,15,16,13,17,15,17,13,18,16,18
1124 DATA 19,18,19,18,1,17,2,19,4,17,16,17,18,18,12
1130 DATA 25,0,15,5,15,0,16,0,18,0,19,19,19,1,18,1,18,3,18,3,18,3,16,3,16,6,17,6,18,7,16,7,18,8,14,8,16
1132 DATA 10,16,10,16,11,16,11,18,12,18,12,18,10,14,12,14,13,11,13,16,16,14,16,17,15,13,16,13,18,11,18,18
1134 DATA 19,11,19,18,14,11,17,11,14,16,14,17,0,13,0,13,0,14,2,14,10,18,10,18,12,13,12,13,16,10,19,10
1136 DATA 1,17,6,16,8,18,13,18,15,17,10
1140 DATA 18,0,11,2,11,0,17,0,18,1,14,1,14,2,12,2,17,3,12,4,12,3,13,7,13,4,15,4,15,4,16,5,16,5,17,6,17
1142 DATA 5,18,7,18,0,19,19,19,7,14,13,14,7,15,9,15,8,16,9,16,9,17,10,17,12,15,13,15,12,16,14,16,13,17,17,17
1144 DATA 1,13,0,16,4,18,5,15,10,16,11
1200 GRAPHICS 17:POSITION 5,3:? #6;"game over";:POSITION 5,5:? #6;"SCORE:";SC
1205 IF SC>HSC THEN HSC=SC
1210 SC=0:DV=3:F1=0:F2=0:F3=0:F4=0:TICKER=5:C=0:C1=0:C2=0:TC=0:OB=0:DX=9:DY=0:OX=20:OC=0:C3=0:CR=0:SK=0
1220 ? #6:? #6;"PRESS {inv}START{/inv} TO PLAY";
1230 IF PEEK(53279)<>6 THEN 1230
1240 GRAPHICS 1:GOSUB 1400:GOSUB 1000:GOSUB 905:GOTO 30
1300 DIM TR$(180)
1305 TR$="GOLD BARS DIAMONDS  EMERALDS  GOLD COINSSWORDS    SEAWEED   SAND      TRINKETS  PEARLS    SILVER    "
1308 TR$(101)="WEAPONS   ARTIFACTS NECKLACES RINGS     CAPT. LOG RARE CORALDEAD FISH "
1310 DIM PT(17):RESTORE 1320:FOR X=0 TO 16:READ PT:PT(X)=PT:NEXT X:RETURN
1320 DATA 150,125,115,105,30,0,0,55,85,70,40,65,75,60,15,80,10
1400 POKE 559,0:DL=PEEK(560)+PEEK(561)*256
1410 RESTORE 1420:POKE DL+3,198:FOR A=1 TO 5:READ B:POKE DL+B,134:NEXT A
1420 DATA 8,13,17,21,24
1430 RESTORE 1440:FOR A=1536 TO 1590:READ B:POKE A,B:NEXT A
1440 DATA 72,138,72,174,49,6,142,10,212,224,5,240,9,189,50,6,141,26,208,76,35,6,169,0,141,26,208,141,24,208
1450 DATA 169,14,141,23,208,232,224,6,208,2,162,0,142,49,6,104,170,104,64,0,200,198,196,194,192
1460 POKE 512,0:POKE 513,6:POKE 54286,192:POKE 559,34:RETURN
1500 POKE 106,PEEK(106)-5:GRAPHICS 0:POKE 752,1:START=(PEEK(106)+1)*256:Z1=1024
1505 GRAPHICS 0:POKE 559,0:DL=PEEK(560)+PEEK(561)*256:POKE DL+10,7:POKE DL+11,7:POKE DL+27,65
1510 POKE DL+28,PEEK(560):POKE DL+29,PEEK(561):SETCOLOR 2,0,0:POKE 752,1:SETCOLOR 1,0,15:SETCOLOR 0,6,8
1520 POSITION 7,5:? "DIVER":POSITION 9,6:? "Written & designed by":POSITION 15,7:? "Steve May"
1530 POSITION 17,8:? "1984":POSITION 7,10:? "Initializing, please wait"
1540 POKE 559,34:GOSUB 30000
1550 POSITION 10,14:? "Press {inv}START{/inv} to play"
1560 IF PEEK(53279)<>6 THEN 1560
1570 RETURN
2000 POSITION OCX,OCY:? #6;"q";
2010 IF DY<>OCY THEN 2040
2020 IF DX<OCX THEN NOCX=-1:NOCY=0:GOTO 2060
2030 IF DX>OCX THEN NOCX=1:NOCY=0:GOTO 2060
2040 IF DY<OCY THEN NOCY=-1:NOCX=0:GOTO 2060
2050 IF DY>OCY THEN NOCY=1:NOCX=0:GOTO 2060
2060 TRAP 2090:LOCATE OCX+NOCX,OCY+NOCY,CHR
2070 IF CHR<>32 THEN 2100
2080 POSITION OCX,OCY:? #6;" ";:OCX=OCX+NOCX:OCY=OCY+NOCY:POSITION OCX,OCY:? #6;"q";:RETURN
2090 GOTO 720
2100 IF CHR=192 AND F2=0 THEN 510
2110 NOCX=0:NOCY=0:GOTO 2080
2200 POSITION BX,BY:? #6;"!<$";:POSITION BX,BY+1:? #6;"%";TICKER;"&";:POSITION BX,BY+2:? #6;"'*=";
2210 C2=C2+1:IF C2<>ABS(10-(SK*2)) THEN RETURN
2220 C2=0:TICKER=TICKER-1:SOUND 1,0,1,15:SOUND 1,0,0,0
2230 IF TICKER=0 THEN POSITION BX+1,BY+1:? #6;TICKER;:GOTO 2250
2240 RETURN
2250 FOR X1=10 TO 1 STEP -1:GOSUB 3030:FOR X=0 TO 15
2252 A=X*16+14:POKE 1586,A:POKE 1587,A:POKE 1588,A:POKE 1589,A:POKE 1590,A
2254 NEXT X:NEXT X1
2256 POKE 1586,200:POKE 1587,198:POKE 1588,196:POKE 1589,194:POKE 1590,192:SOUND 0,0,0,0:SOUND 1,0,0,0
2260 POSITION BX,BY:? #6;"   ";:POSITION BX,BY+1:? #6;"   ":POSITION BX,BY+2:? #6;"   ";
2270 IF F3=1 THEN POSITION OCX,OCY:? #6;" ";
2275 IF F4=1 THEN POSITION SX,SY:? #6;"   ";:F4=0:C3=0
2280 IF F2=0 THEN F1=0:F3=0:C2=0:TICKER=5:GOTO 510
2290 F1=0:F3=0:C2=0:TICKER=5:RETURN
2300 POSITION SX,SY:? #6;S$;:IF F1=1 THEN GOSUB 2200
2310 C3=C3+1:IF ((C3=3-SK) OR (SK>2)) THEN C3=0:POSITION SX,SY:? #6;"   ";:SX=SX+1:POSITION SX,SY:? #6;S$;
2320 IF SX=17 THEN POSITION SX,SY:? #6;"   ";:C3=0:F4=0:RETURN
2330 IF SX<5 THEN 2400
2340 IF DY<HT AND F2=0 THEN 2360
2350 GOTO 2400
2360 COLOR 45:PLOT SX+3,SY:DRAWTO DX,DY:GOSUB 3060:COLOR 32:PLOT SX+3,SY:DRAWTO DX,DY
2370 POSITION DX,DY:? #6;"{inv}@{/inv}";
2380 POSITION SX,SY:? #6;"   ";:SX=SX+1:IF SX<16 THEN ? #6;S$;:GOTO 2380
2390 POSITION SX,SY:? #6;"    ";:F4=0:C3=0:GOTO 510
2400 RETURN
3000 FOR X=1 TO 20:SOUND 2,X,0,X:NEXT X:SOUND 2,0,0,0:RETURN
3010 FOR X=10 TO 1 STEP -1:FOR Y=1 TO 10:NEXT Y:SOUND 0,X*1.5,0,X
3015 NEXT X:FOR Y=1 TO 25:NEXT Y:SOUND 0,0,0,0:RETURN
3020 FOR X=1 TO 10:SOUND 0,X,6,8:SOUND 1,200,8,14:SOUND 2,240,4,15:NEXT X:SOUND 1,0,0,0:SOUND 2,0,0,0:RETURN
3030 SOUND 0,20,0,X1*1.5:SOUND 1,255,10,X1*1.5:RETURN
3040 FOR X=10 TO 1 STEP -1:SOUND 2,175,8,X:SOUND 0,120,8,X:SOUND 1,140,8,X:SOUND 2,170,8,X:NEXT X:RETURN
3050 FOR X=1 TO 10:SOUND 0,X*DY,10,6:NEXT X:SOUND 0,0,0,0:RETURN
3060 FOR X=1 TO 30 STEP 3:SOUND 3,X,2,12:NEXT X:SOUND 3,0,0,0:RETURN
30000 Z=USR(ADR("h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}K{CTRL-E}M){CTRL-.}{CTRL-E}N%{/inv}j{CTRL-X}i{CTRL-A}{inv}{CTRL-E}L {/inv}{CTRL-,}{inv}1M{CTRL-Q}KHPyfLfN%NIdPm{/inv}{CTRL-.}")):RESTORE 30100
30010 POSITION 17,12:? " ";
30030 READ X:IF X=-1 THEN RESTORE :RETURN
30040 FOR Y=0 TO 7:READ Z:POKE X+Y+START,Z:NEXT Y:GOTO 30030
30100 DATA 8,1,0,12,7,3,119,31,15
30101 DATA 120,224,167,229,7,0,28,20,28
30102 DATA 32,128,0,48,224,192,238,248,240
30103 DATA 40,222,60,60,252,252,60,60,222
30104 DATA 48,123,60,60,63,63,60,60,123
30105 DATA 56,15,31,119,3,7,12,0,1
30106 DATA 80,0,195,255,255,255,126,219,153
30107 DATA 88,255,255,255,255,255,255,255,255
30108 DATA 224,153,219,126,255,255,255,195,0
30109 DATA 232,240,248,238,192,224,48,0,128
30110 DATA 256,126,195,129,129,195,126,102,195
30111 DATA 336,0,126,129,231,255,255,255,0
30112 DATA 64,0,0,0,64,63,95,7,0
30113 DATA 240,3,3,3,3,255,255,255,127
30114 DATA 392,60,106,60,84,146,146,73,10
30115 DATA 72,128,192,192,192,255,255,254,252
30116 DATA 992,0,0,0,0,0,48,76,131,-1

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: DIVER.BAS.

Credits