Lunar Lander Construction Set
- Type
- Game
- Category
- Lander game with level editor
- Author
- Daniel Deighan (article by Gigi Bisson)
- Published in
- Antic, March 1986 (Vol. 4, No. 11), Game of the Month
- Year
- 1986
- Language
- Atari BASIC
- Requirements
- 32K RAM with disk (16K with cassette), Atari BASIC, one or two joysticks
- Tags
- antic, game-of-the-month, lunar-lander, joystick, construction-set, player-missile, forced-read, self-modifying, two-player, 1986
- Related
- Current Events, Desert Chase!, Rockslide, Warrior 3000, Bats, Biffdrop
About the program
Lunar Lander games go back to text-only programs on mainframe teletypes, and they became staples of every early microcomputer's public-domain library. Gigi Bisson's article fondly recalled their grim humour, with messages such as "You blasted a new lunar crater 347.12 feet deep!". Daniel Deighan's version, Antic's Game of the Month for March 1986, brought the idea up to date. It is joystick-controlled instead of a set of equations, you fly a space shuttle instead of a rocket, and it is also a construction set for building your own landscapes.
The story: Sally Ride was busy making a cereal commercial, so out of hundreds of qualified pilots you've been picked to deliver high explosives to ore miners on several planets. Land very softly, because "the space program hates to lose astronauts".
Typing it in
Lines 1130–1140 contain the trickiest special characters (the landscape templates). In the magazine, Listing 2 created them as a LINES.LST file, but it isn't on the disk. Many other lines contain inverse text ({inv} … {/inv} = press the Atari key before and after) and screen-editing codes: {DEL LINE} is ESC then SHIFT-DELETE, and {CLEAR} is ESC then SHIFT-CLEAR. Never renumber the program, because it rewrites its own lines. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.
How to play
Plug in one or two joysticks and RUN. When the first landscape appears, press START. OPTION sets the number of players and SELECT the gravity, with nine locations from Jupiter's moon Ganymede up to Earth. Press START and hold the button for a second or two to begin. Steer left and right. Push up for the main thrusters and down for the gentler landing thrusters. Aim for the pad marked by flashing lights. A soft landing earns extra points, a very good one bonus fuel, and two successful landings without running out of fuel take you to the next mission. Fly off the top of the screen and you're told "SHIP LEFT ORBIT".
Building your own planets
Press OPTION and SELECT together to enter the construction set. You can alter one of the built-in screens or start from scratch. Choose pieces of lunar turf from the blue templates with the joystick (the cursor is invisible, which makes it tricky) and stamp them onto the landscape with the fire button. The leftmost piece is a solid fill, the first space erases, and the piece with a small blue spot is the five-character landing pad. Press ESC to save the screen to disk or cassette, or to write it into the game in place of an original site.
How it works
The construction set writes BASIC program lines. Using the OS "forced read" mode (POKE 842,13), it prints new DATA lines on the screen, positions the cursor and executes STOP/CONT, so the screen editor reads the lines back in as if they had been typed (lines 505–525). POKE 842,12 switches back to normal. The shuttle is a player moved by string assignment into player-missile memory (P$(Y)=SH$). Player-to-playfield collisions (53252) decide between landing, refuelling and crashing. Flying off the top makes the string index go out of range, and a TRAP turns that error into the "left orbit" message (lines 120 and 160).
Listing
3 REM LUNAR LANDER CONSTRUCTION SET
5 REM BY DANIEL DEIGHAN
6 REM (c) 1985, ANTIC PUBLISHING INC.
10 GRAPHICS N0:GOTO 1030
40 POSITION 0,22:? " ":GOSUB 200
45 Y=Y+DY*0.01:X=X+DX*0.07:P1$=PM$:P$(Y)=SH$:POKE 53248,X:IF PEEK(53252)<>N0 THEN 230
50 POKE 77,0
55 S=STICK(J):IF F<H THEN POKE 53250,H:H=H-1:IF H<76 THEN 820
60 IF S=14 THEN POKE 53249,X:P1$(Y+N10)=FLB$:SOUND N0,75,N8,N10:DY=DY-2.8:F=F-0.1:GOTO N40
70 IF S=13 THEN POKE 53249,X:P1$(Y+N10)=FLT$:SOUND N0,65,N8,N10:DY=DY-0.6:F=F-0.04:GOTO N40
80 IF S=7 THEN POKE 53249,X-N9:P1$(Y+N3)=FLL$:SOUND N0,30,N8,N6:DX=DX+0.5:DY=DY+G:F=F-0.02:GOTO N40
90 IF S=11 THEN POKE 53249,X+N9:P1$(Y+N3)=FLR$:SOUND N0,30,N8,N6:DX=DX-0.5:DY=DY+G:F=F-0.02:GOTO N40
100 IF PEEK(PRT)=N6 THEN POKE 53248,N3:GOTO 860
105 IF STRIG(J)=N0 THEN POKE 77,N0
110 SOUND N0,N0,N0,N0:DY=DY+G:GOTO N40
120 P$=PM$:POKE 53278,N0:X=60:Y=30:DY=N0:DX=N0:TRAP 160:F=H:J=P-N1:POKE 53248,X:P$(Y)=SH$:G=L*0.33
140 POSITION 0,22:? " ":GOSUB 200
145 FOR W=255 TO -65 STEP -N10:FOR I=-N10 TO N10 STEP N2:SOUND N0,ABS(W),N10,ABS(I):NEXT I:NEXT W
150 IF PEEK(53252)<>N0 THEN 860
155 GOTO N40
160 SOUND N0,N0,N0,N0:IF PEEK(195)=5 THEN GOSUB N200:? " SHIP LEFT ORBIT";:FOR W=N1 TO 1000:NEXT W:? "{DEL LINE}"
170 IF PEEK(195)=N3 THEN GOSUB N200:? " YOU GOT LOST";:FOR W=N1 TO 1000:NEXT W:? "{DEL LINE}"
180 IF H<N0 THEN 850
190 GOTO N120
200 POSITION N0,N22:RETURN
210 POSITION N0,N22:? " {DEL LINE}":RETURN
215 GOSUB N1500:POSITION N2,N21:RETURN
220 H=171:FOR W=95 TO N0 STEP -N1:POKE 53250,H-W:SOUND N0,W,N10,N10:NEXT W:RETURN
225 FOR W=N1 TO N200:NEXT W:RETURN
230 IF PEEK(53252)=N8 AND E(P)=N0 THEN GOSUB N200:? "! {inv}l{/inv}O{inv}S{/inv}t {inv}f{/inv}U{inv}E{/inv}l {inv}d{/inv}U{inv}M{/inv}p !":GOSUB 220:GOSUB N210:E(P)=N1:GOTO N120
235 IF PEEK(53252)=N1 AND E(P)=N1 THEN 390
240 IF PEEK(53252)>N2 OR DX>N3 OR DY>N21+L THEN 390
250 FOR I=N0 TO N22-DY:POSITION N12,N21:SC=SC+M*INT(N21+L-DY):? SC:FOR W=-N200 TO N1 STEP 5
260 SOUND N0,ABS(W),N10,N8:NEXT W:NEXT I:IF DY>N8 THEN 300
270 GOSUB N200:? " {inv}bonus fuel{/inv}":GOSUB 225
280 FOR I=N0 TO (N8-DY)*L:H=H+N1:SOUND N0,H,N10,N6:SOUND N1,H+15,N10,N6:IF H=172 THEN 300
290 POKE 53250,H:GOSUB 225:NEXT I
300 GOSUB N210:SOUND N1,N0,N0,N0:SOUND N0,N0,N0,N0:GOSUB N200:IF H<76 THEN 850
310 P$=PM$:IF PL=N2 THEN GOTO 370
320 V=V+N1:POKE 77,N0:IF V/N2=INT(V/N2) OR V=5 THEN POKE 53250,N0:ON V-N1 GOSUB 640,N0,740,540:POKE 53250,H
350 GOTO N120
370 F(P)=H:SC(P)=SC:P=P+(P=N1)-(P=N2):H=F(P):POKE 711,PEEK(1598+P):POKE 53250,H:SC=SC(P):POSITION N12,N21
380 ? SC;" ":POKE 704,PEEK(1598+P):POSITION N9,N21:? P:ON P GOTO 320,N120
390 A=N1:W=N2:GOSUB 480:P$(Y)=E$(A,A+N10):GOSUB 490:GOSUB 500:W=-N2
400 A=A+11:W=W+N2:GOSUB 480:P$(Y)=E$(A,A+N10):GOSUB 470:GOSUB 460
410 A=A+11:W=W+N2:GOSUB 480:P$(Y)=E$(A,A+N10):GOSUB 490:GOSUB 500:IF A<>67 THEN 400
430 P$=PM$:SOUND N1,N0,N0,N0:POKE 704,PEEK(1598+P):POKE 203,150
440 IF H<76 THEN 850
450 GOSUB 225:GOTO N120
460 FOR I=N10 TO N2 STEP -N2:POKE 203,48+I:NEXT I:RETURN
470 FOR I=50 TO 58:POKE 704,I:NEXT I:RETURN
480 SOUND N0,55,N8,14-W:SOUND N1,88,N8,14-W:RETURN
490 FOR I=58 TO 50 STEP -N1:POKE 704,I:NEXT I:RETURN
500 FOR I=N2 TO N10:POKE 203,48+I:NEXT I:RETURN
505 GOSUB 215:? "{LEFT}REPLACE";:GOSUB 2500:FOR X=N1 TO 7:GOSUB N1500
515 POSITION N2,19:? Y+X*N2;" ? ";CHR$(34);:FOR W=N1 TO 103:? CHR$(PEEK(SCR)+32);:SCR=SCR+N1:NEXT W
520 ? CHR$(34);";":POSITION N2,N22:? "CONT";:POKE 842,13:POSITION N2,17:STOP
525 NEXT X:POKE 842,N12:GOSUB N1500:GOSUB N200:? " {inv}save screen?(y/n){/inv}":GOSUB 2200:IF W=78 THEN 1210
530 GOSUB 2000:TRAP 535:LIST L$,Y+N2,Y+14:GOTO 1210
535 ? "{CLEAR}":GOSUB 215:? "{TAB}{TAB}I/O ERROR!{TAB}{TAB} {inv}try again?(y/n){/inv}":GOSUB 2200:IF W=89 THEN 530
537 GOTO 1210
540 POKE 710,58:POKE 709,130:POKE 82,N0:? "{CLEAR}";:M=N6:V=N0
542 ? " 2 X! ";
544 ? " X!! W!!! ^!!! ";
546 ? " 1U !!! H!Z ^!!! W!! ";
548 ? " H!!! H!!Z X!!!! !!!Z ^!!!! 2U ";
550 ? " W!!!I V!!!!X!!FU 2U W!!!!R V!!!!!!!!!Z X!Z H!!!!!I XH";
552 ? "!!!!!!!!O X!!S W!!!!!!!Z W!!!!!!!!!!I H!!!U X!!!!!!!R ^!!!!!!!!!!!I X!!!!Z H";
554 ? "!!!!!!!!S X!!!!!!!!!!!!I H!!!!!I X!!!!!!!!!F H!!!!!!!!!!!!!6!!!!!!!!6!!!!!!!!!!!#$%&'!!!!!!!! ";
600 ? "{BACK S}!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!{inv}(,,,,,),*+*+*+*+*+*+*+*+*+*+*+*+,-,,,,,.{/inv}";
610 POSITION N3,N21:? "SCORE ";P;": ";SC:POSITION 20,N21:? "HIGH SCORE: ";HSC:RETURN
640 M=N21:? "{CLEAR}";
642 ? " !!!!!!!!!!!!!!!!!!!!!!!!!!!! H!!!!!!!!!!!!!!!!!!!!!!!!!!!! !!!!!!!!!!!!";
644 ? "!!!!!!!!!!!!!Y P! V!!!!!!!!!!!!!!!!!!!!!!!!Y P H!!!!!!!!!!!!!<\::K!!!!!!!\ W ";
646 ? " B!!!!!!!!!!!!< :;!!!!Z V K=MM=M=MM<MY: _?!!Z H ";
648 ? " :; W 213U ^ X!!!!G V 184D4C";
650 ? "4D48 V!!!!!!I P H!!!!!!!!!!S 2V!!!!!!!! W X!!!!!!!!!!!I192V!!!!!!!!!Z ";
652 ? " V H!!!!!!!!!!!!!!!!!!!!!!!!!!U ^ H!!!!!!!!!!!!!!!!!!!!!!!!!!!EU H V!!!!!!!!!!!!!!!!";
654 ? "!!!!!!!!!!!!!E HX!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!I H!H!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!#$%&'!! ";
656 GOSUB 600:RETURN
740 M=N40:? "{CLEAR}";
742 ? " ]!!!!!!!!!!!!!!!!!!!!!!!!L!L!L!!!!! ]!!!!!!!!!!!!!!!!!!!!>A ;K!! ]!!!!!!!!!!!!!!!";
744 ? "!YA ;! !!!!!!!!!!!!!!!R ^ !!!!!!!!!!!!!!![ 119 V ";
746 ? " !!!!!!!!!!!!!!Q W'!!I H H!!!!!!!!!!!!!!I ;=!!I V! !!!!!!!!!!!!!!!!G ";
748 ? " P!!S W!! V!!!!!!!!!!!!!!!!!69 ]!#$%&'!! H!!!!!!!!!!!!!!!!!!!S ]!!!!!!! V!!!!!!";
750 ? "!!>>=!!!!!!!!!G ;L!!!!! W!!!!!!NOA :JL!!!!!!!S !!!!! P!!!?O :P!!!@A H";
752 ? "!!!!! A :;Y 3!!!!!! 2357G C!!!!!!! V#!!!'";
754 ? "EG H!!!!!!!! 3C!!!!!!!!F9 2CC!!!!!!!!!0U9 291BV!!!!!!!!!!!!T9 21C!!!!!!!!!!!! ";
765 GOSUB 600:RETURN
820 SOUND N0,N0,N0,N0:GOSUB N200:? " {inv}OUT OF FUEL{/inv}"
830 Y=Y+DY*6E-03:X=X+DX*0.05:P1$=PM$:P$(Y)=SH$:POKE 53248,X:DY=DY+G:IF PEEK(53252)>N0 THEN 230
840 GOTO 830
850 SOUND N0,N0,N0,N0:IF PL=N2 THEN PL=N1:GOTO 370
860 SC(P)=SC:FOR W=N0 TO N10:FOR I=80 TO 94:POKE 203,I:POKE 712,I:NEXT I:SOUND N0,W*N8,N0,N10:NEXT W
870 FOR P=N1 TO N2:IF SC(P)>HSC THEN HSC=SC(P)
880 NEXT P:POSITION 32,N21:? HSC:P=N1:POKE 203,150:POKE 712,N0:SOUND N0,N0,N0,N0:J=N1:POKE 711,142:A=N0
890 IF STRIG(N0)=N0 THEN 940
900 POSITION N0,N22:? RE$(J,J+19):J=J+N1:IF J=242 THEN J=N1
910 POSITION N12,N21:? " ":ON PEEK(PRT) GOTO 3000,920,1000,920,960,940
915 IF PEEK(764)=157 THEN STOP
920 A=A+N1:IF A=N10 THEN P=P+(P=N1)-(P=N2):POSITION N9,N21:? P:A=N0
930 POSITION N12,N21:? SC(P):W=N1^N1:GOTO 890
940 POKE 77,N0:GOSUB N210:POSITION N12,N21:? " ":SC=N0:IF V>N1 THEN GOSUB 540
945 POSITION N9,N21:? N1:E(N1)=N0:E(N2)=N0:V=N0:PL=PN
950 SC(N2)=N0:F(N2)=171:POKE 704,N200:POKE 711,N200:GOSUB 220:P=N1:GOTO N120
960 GOSUB N210:POSITION N2,N22:? "GRAVITY LEVEL: ";L;" DESTINATION-";L$;
970 IF PEEK(PRT)=N6 OR PEEK(PRT)=N3 THEN GOSUB N210:GOTO 890
980 IF PEEK(PRT)=5 THEN L=L+N1:IF L=N10 THEN L=N1
990 RESTORE 5000:FOR A=N1 TO L:READ L$:NEXT A:POSITION 32,N22:? L$;:POSITION 17,N22:? L;:GOTO 970
1000 GOSUB N200:? " ";PL;" PLAYER ":IF PEEK(PRT)=N3 THEN PL=PL+N1:IF PL=N3 THEN PL=N1
1010 IF PEEK(PRT)=5 OR PEEK(PRT)=N6 THEN PN=PL:POSITION N1,N21:? PL:GOTO 890
1020 GOTO 1000
1030 READ N1,N2,N3,N6,N8,N9,N10,N12,N21,N22,N40,N120,N128,N200,N210,N1500,PRT:V=N0:L=N3:P=N1:OPEN #N1,4,N0,"K"
1035 DATA 1,2,3,6,8,9,10,12,21,22,40,120,128,200,210,1500,53279
1040 DIM D$(N1),F$((INT(ADR(D$)/1024)+N1)*1024-ADR(D$)-N1),SH$(13),FLB$(N9),FLL$(N3),FLR$(N3),FLT$(4),GAS$(N10)
1050 SH$="{CTRL-,}{CTRL-,}<B{inv}g{/inv}B<{INS CHAR}{inv}={CTRL-A}{CTRL-A}{/inv}{CTRL-,}{CTRL-,}":FLB$="<{BACK S}{INS CHAR}{BACK S}{BACK S}<<{CTRL-X}{CTRL-X}":FLL$="{CTRL-F}{RIGHT}{CTRL-F}":FLR$="{CTRL-.}{inv}x{/inv}{CTRL-.}":FLT$="<{BACK S}<{CTRL-X}":GAS$="<{INS CHAR}{inv}{CTRL-Y}{/inv}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{inv}{CTRL-Y}{/inv}{INS CHAR}<"
1100 DIM E$(77),L$(15),RE$(378),P$(N128),P1$(N128),P2$(N128),PM$(N128),CHSET$(512),SC(N2),F(N2),E(N2)
1110 E$="{CTRL-,}<B{inv}gC={/inv}{INS CHAR}{inv}={CTRL-A}{/inv}B{CTRL-,}{CTRL-,}{CTRL-,}<BfB{BACK S}{BACK S}<{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-X}$<{CTRL-X}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-X}$${CTRL-X}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}<BBBB<{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}<B{inv}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-A}{/inv}B<{CTRL-,}"
1120 PM$=CHR$(N0):PM$(N128)=CHR$(N0):PM$(N2)=PM$:P$=PM$:P1$=PM$:P2$=PM$
1125 DL=PEEK(560)+256*PEEK(561)+4:FOR I=N2 TO 19:POKE DL+I,4:NEXT I:POKE DL-N1,68:POKE DL+20,132:POKE DL+23,N6
1130 CHSET$="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}yz{/inv}{DEL CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}***o>{CTRL-;}{/inv}{INS CHAR}{INS CHAR}{inv}****k{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{inv}***{CTRL-;}>o{/inv}{INS CHAR}{INS CHAR}o{inv}/?{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{DEL CHAR}{inv}zzzzzz{/inv}{DEL CHAR}{inv}*{/inv}{INS CHAR}{inv}j{/inv}{DEL CHAR}{inv}jj{/inv}{INS CHAR}{inv}**{/inv}{DEL CHAR}{DEL CHAR}{INS CHAR}{INS CHAR}{DEL CHAR}{DEL CHAR}{inv}**{/inv}{DEL CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{DEL CHAR}{inv}*{/inv}"
1132 CHSET$(97)="{inv}*********{/inv}{INS CHAR}{inv}j{/inv}{DEL CHAR}{inv}jjj*?//////?{/inv}{CTRL-,}<{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}<{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}"
1134 CHSET$(137)="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}<{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-C}?{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-C}?{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}?{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-C}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}@{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{inv}|{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{inv}@|{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}@|{/inv}{INS CHAR}{INS CHAR}?{CTRL-C}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}?{CTRL-C}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}?"
1136 CHSET$(231)="{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-C}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}@{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}|{/inv}{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{inv}|@{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}|@{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-C}{CTRL-O}??{INS CHAR}{CTRL-,}{CTRL-C}?{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-O}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}p{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{inv}@|{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{inv}@p||{/inv}{INS CHAR}{CTRL-C}{CTRL-O}{CTRL-O}?"
1138 CHSET$(325)="??{INS CHAR}{INS CHAR}{inv}@pp|||{/inv}{INS CHAR}{INS CHAR}{INS CHAR}??{CTRL-O}{CTRL-C}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}?{CTRL-C}{CTRL-,}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-O}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}p{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}|@{/inv}{CTRL-,}{INS CHAR}{inv}||p@{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{INS CHAR}???{CTRL-O}{CTRL-O}{CTRL-C}{INS CHAR}{INS CHAR}{inv}|||pp@@@pppp||@@@@pppp{/inv}{CTRL-,}{CTRL-,}"
1140 CHSET$(419)="{inv}@@pp||{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}@pp|{/inv}{CTRL-C}{CTRL-C}{CTRL-O}{CTRL-O}{CTRL-O}{CTRL-O}??{CTRL-C}{CTRL-C}{CTRL-C}{CTRL-C}{CTRL-O}{CTRL-O}{CTRL-O}{CTRL-O}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-C}{CTRL-C}{CTRL-O}{CTRL-O}?{inv}|||ppp@@pppp@@@@||pp@@{/inv}{CTRL-,}{CTRL-,}{inv}|pp@{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}??{CTRL-O}{CTRL-O}{CTRL-O}{CTRL-O}{CTRL-C}{CTRL-C}{CTRL-O}{CTRL-O}{CTRL-O}{CTRL-O}{CTRL-C}{CTRL-C}{CTRL-C}{CTRL-C}?{CTRL-O}{CTRL-O}{CTRL-C}{CTRL-C}{CTRL-,}{CTRL-,}{CTRL-,}"
1160 FOR I=N0 TO 64:READ A:POKE 1536+I,A:NEXT I:A=USR(1588):POKE 512,N21:POKE 513,N6:POKE 54286,192
1170 DATA 165,20,69,79,37,78,141,22,208,165,203,69,79,37,78,141,24,208,76,98,228,72,173,196,2,69,79,37,78,141,22
1180 DATA 208,173,198,2,69,79,37,78,141,10,212,141,24,208,169,224,141,9,212,104,64,104,162,6,160,0,169,7,32
1185 DATA 92,228,96,200,70
1190 POKE 756,ADR(CHSET$)/256:POKE 54279,ADR(SH$)/256:POKE 203,150
1210 POKE 16,112:POKE 53774,112:POKE 559,46:POKE 53277,N2:POKE 623,N1:POKE 20,N0:POKE 752,N1:SC(N1)=N0:SC(N2)=N0
1215 POKE 842,N12:PL=N1:POKE 711,142:POKE 704,N200:POKE 705,78:J=N1:GOSUB 540:P2$(90)=GAS$:L$="THE MOON"
1217 GOSUB 5010
1219 GOTO 890
1500 POSITION N2,18:? "{INS LINE}{INS LINE}{INS LINE}{INS LINE}{INS LINE}{INS LINE}":RETURN
2000 TRAP 2000:GOSUB 215:? "FILESPEC (DEV:FILENAME.EXT)":INPUT L$:RETURN
2200 GET #N1,W:IF W<>78 AND W<>89 THEN 2200
2210 RETURN
2500 ? " WHAT SCREEN? {inv}1{/inv}-{inv}2{/inv}-{inv}3{/inv} (ESC=ABORT) {inv}enter selection{/inv}"
2510 GET #N1,W:IF W<>49 AND W<>50 AND W<>51 AND W<>27 THEN 2510
2520 IF W<>27 THEN Y=540+100*(W-49):RETURN
2530 GOSUB 215:? "{DOWN} {inv}abort?(y/n){/inv}":GET #N1,G:IF G=89 THEN POP :GOTO 1210
2540 GOTO 2510
3000 GOSUB 215:? "{LEFT}{inv}1{/inv} ALTER SCREEN, OR {inv}2{/inv} CREATE NEW SCREEN {inv}enter selection{/inv}"
3010 GET #N1,W:IF W<>49 AND W<>50 THEN 3010
3020 IF W=50 THEN GOTO 4000
3030 GOSUB 215:? " ALTER";:GOSUB 2500:GOSUB Y
3060 POKE 53250,N0:GOSUB N1500:RE$=" ":RE$(N128)=" ":RE$(N2)=RE$
3070 RE$(N21)=" !%":FOR W=24 TO 72:RE$(W,W)=CHR$(W+23):NEXT W:RE$(N128)="{CTRL-,}"
3500 X=N8:SCR=PEEK(88)+256*PEEK(89):GOSUB 215:? "{TAB} USE JOYSTICK TO{TAB}{TAB} {inv}select figure{/inv}"
3510 POSITION N6,19:? RE$(X,X+25);:W=PEEK(SCR+779)+N128:POKE SCR+739,W
3520 X=X+(STICK(N0)=7)-(STICK(N0)=11):X=X-(X=60)+(X=7)
3560 IF STRIG(N0)=N1 THEN 3510
3570 X=N3:Y=N3:GOSUB 215:? "{LEFT}<ESC>DONE <SELECT>FIGURE <OPTION>ABORT {inv}design landing site{/inv}"
3700 A=SCR+Y*N40+X:J=PEEK(A):POKE A,W:A=A*A/A:POKE A,J:IF STRIG(N0)=N0 THEN POKE A,W-N128:POKE 77,N0
3710 IF STRIG(N0)=N0 AND W=133 THEN W=N3:FOR G=A-N2 TO A+N2:POKE G,W:W=W+N1:NEXT G:W=133
3720 X=X+(STICK(N0)=7)-(STICK(N0)=11):X=X-(X=N40)*N40+(X=-N1)*N40
3730 Y=Y+(STICK(N0)=13)-(STICK(N0)=14):Y=Y-(Y=18)*18+(Y=-N1)*18
3740 IF PEEK(PRT)=5 THEN GOTO 3500
3750 IF PEEK(764)=28 THEN POKE 764,255:GOTO 505
3760 IF PEEK(PRT)=N3 THEN GOSUB 215:? "{DOWN} {inv}abort?(y/n){/inv}":GET #N1,G:IF G=89 THEN GOSUB N1500:GOTO 3000
3770 GOTO 3700
4000 GOSUB N210:? "{inv}load a screen{/inv}?({inv}y{/inv}/{inv}n{/inv})":GOSUB 2200:IF W=78 THEN ? "{CLEAR}":GOTO 3060
4010 GOSUB 2000:TRAP 4030:GOSUB N1500:POSITION N2,N22:? "RUN";:POKE 842,13:POSITION N2,17:ENTER L$
4030 POKE 842,N12:? "{CLEAR}":POSITION N2,N21:? "I/O ERROR!":GOTO 4000
5000 DATA PHOBOS ,EUROPA ,THE MOON,IO ,TITAN,GANYMEDE,MERCURY ,MARS ,EARTH
5010 RE$(1,87)=" {inv}game over{/inv} {inv}PRESS{/inv} {inv}<start>{/inv} {inv}TO REPLAY{/inv} {inv}lander construction set{/inv} BY {inv}daniel d{/inv}"
5020 RE$(88,174)="{inv}eighan{/inv} {inv}<option>{/inv}-NUMBER OF PLAYERS ... {inv}<select>{/inv}-GRAVITY LEVEL ... {inv}<option><select>{/inv}-"
5030 RE$(175,261)="DESIGN LANDING SITE LAND ON THE PAD AS {inv}softly as possible!!{/inv} {inv}game over{/inv} "
5040 RETURN
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: LANDER.BAS.
Credits
- Program listing: Lunar Lander Construction Set — program listing (Antic, March 1986 (Vol. 4, No. 11), Game of the Month) — Daniel Deighan (article by Gigi Bisson)
- Picture: The first built-in landing site, waiting for OPTION and SELECT settings. — Daniel Deighan (article by Gigi Bisson) (program); screenshot by the site
- Antic, March 1986 - Vol. 4 No. 11: scan of the printed magazine, PDF pages 73-74 (article) — Internet Archive, 1986
- Antic disk, March 1986 - Vol. 4 No. 11: LANDER.BAS (detokenized listing) — Daniel Deighan (article by Gigi Bisson), 1986
