Desert Chase!

Type
Game
Category
Into-the-screen shooting game
Author
Guy Aitchison (article by Charles Jackson)
Published in
Antic, July 1986 (Vol. 5, No. 3), Game of the Month
Year
1986
Language
Atari BASIC
Requirements
16K RAM with cassette or 24K with disk, Atari BASIC, joystick in port 1
Desert Chase start screen: purple sky with small clouds, black mountains on the horizon, green desert in perspective stripes, the player's ship at the bottom, the title in a box, and FUEL 999, SCORE 0, WAVE 1 across the top

About the program

Antic's July 1986 Game of the Month came with a story that owes a lot to The Wizard of Oz. Fred, a Kansas wheat farmer (paid not to grow wheat), is carried off by a tornado with his dog Tito. They land among singing, dancing elves who are being pestered by a band of witches from the desert on the far side of the planet. The elves lend Fred their "brass-plated, sodium-powered, warp-driven, salad-spinning nuclear destructo-blaster space cruiser", and his job is to destroy all the witches.

Guy Aitchison of Illinois wrote the game. The article was by Antic Program Editor Charles Jackson, "known around the office for his hatred of computer games", which says something for Desert Chase. The magazine praised its "well-done perspective effects". The desert seems to rush towards you, and the witch ships swell as they approach from the horizon.

Typing it in

Lines 600–604 and the scenery lines (710, 902, 990–991, 10002) are full of control characters, which are redefined here as pieces of ship, mountains and ground. {inv} … {/inv} means press the Atari (inverse) key before and after, and {CTRL-A} to {CTRL-Z} mean hold CTRL and press the letter. In GRAPHICS 0 with this custom display list, inverse characters show in a different colour, so the inverse marks matter. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program. The magazine's Listing 2, LINES.BAS, was marked "not needed".

How to play

You steer left and right with the joystick. Your weapon is the Sodium-Depleting Instrument (SDI), which drains the fuel from a witch's ship into your own tank. The witch's ship then blows up. Each witch carries 30 gallons. Your cruiser was built for shopping trips, so its tank is small, and when the fuel runs out you crash. The SDI reaches between 100 and 400 metres. Push the stick forward for longer range and pull it back for shorter. The readout at the bottom ("D=") shows how far the next shot will travel. Press the button to fire. The radar warns of witches before they appear on the horizon. Witches come in waves of three screens. Clear all three to reach the next wave. Fail, and they turn you into a toad and blow you up.

How it works

  • The screen is GRAPHICS 0 whose display list has been switched to ANTIC mode 4 (line 12), giving four-colour characters. A redefined character set (DATA read in line 13) draws the mountains, the ground and the witch ships.
  • The rushing desert is pure colour cycling. The ground is drawn in bands of three character colours, and lines 51–53 rotate registers 708, 709 and 711 every pass through the main loop. The stripes seem to stream towards you, although nothing is redrawn.
  • Growing witches. As a ship approaches, the counter YE steps through a set of larger and larger character pairs (lines 600–604), so the ship grows in size as it descends the screen.
  • Your cruiser is two players moved side by side (POKE 53248,X:POKE 53249,X+14).

Listing

1 REM DESERT CHASE!
2 REM BY GUY AITCHISON
3 REM (c) 1986, ANTIC PUBLISHING
9 SE=35:DIM A$(2),B$(2),C$(2),D$(2):YE=10:SK=0:SN=1:POKE 106,PEEK(740)
10 POKE 106,PEEK(106)-5:GRAPHICS 0:DL=(PEEK(106)+1)*256:POKE 756,DL/256+2:DM=PEEK(560)+PEEK(561)*256+6
12 FOR I=0 TO 22:POKE DM+I,4:NEXT I:FOR I=128 TO 500:POKE DL+I,PEEK(57344+I):NEXT I
13 FOR I=1 TO 28:READ O:P=(O+64)*8:FOR A=0 TO 7:READ X:POKE A+P+DL,X:NEXT A:NEXT I:GOSUB 900:VL=0:VH=2
41 POKE DM+5,2:POKE DM+2,5:POKE DM+3,5:POKE DM+6,2:F=999:Q=28:LOCATE 0,0,C:GOSUB 700
47 SOUND 0,255,10,4:SOUND 1,250,10,4:SOUND 2,34,0,4:Z=0
50 C=C+1:IF C>2 THEN C=0:IF STICK(0)=14 OR STICK(0)=13 THEN GOSUB 100
51 IF C=2 THEN POKE 708,Z+4:POKE 709,Z+6:POKE 711,Z+8
52 IF C=1 THEN POKE 709,Z+4:POKE 711,Z+6:POKE 708,Z+8
53 IF C=0 THEN POKE 711,Z+4:POKE 708,Z+6:POKE 709,Z+8
60 S=STICK(0):X=X-3*(S=11 AND X>60)+3*(S=7 AND X<166):POKE 53248,X:POKE 53249,X+14
70 IF STRIG(0)=0 AND FF=0 THEN GOSUB 800
71 IF FF=1 THEN GOSUB 810
80 G=G+1:IF G>SE THEN G=0:GOSUB 600
98 F=F-1:POSITION 11,0:? F;" ":IF F<1 THEN 9999
99 GOTO 50
100 IF STICK(0)=14 THEN W=W+100:IF W>400 THEN W=100
101 IF STICK(0)=13 THEN W=W-100:IF W<100 THEN W=400
102 POSITION 18,22:? "D=";W:RETURN
200 SK=0:SN=4:SE=SE-0.5:GG=GG+1:IF GG>2 THEN GG=0:WA=WA+1:Z=Z+16:IF Z>248 THEN Z=0
202 X1=INT(14*RND(0)+3)*2:X2=INT(14*RND(0)+3)*2:X3=INT(14*RND(0)+3)*2:X4=INT(14*RND(0)+3)*2
203 X5=INT(14*RND(0)+3)*2:IF WA<5 THEN X5=99:SN=3
204 IF WA<3 THEN X4=99:SN=2
205 IF WA<1 THEN X3=99:SN=1
209 YE=10:POSITION 34,0:? WA+1:RETURN
500 COLOR 97:PLOT 1,18:DRAWTO 39,18
501 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,100,4,14
502 RESTORE 1010:FOR I=11 TO 20:READ C:COLOR C+128:PLOT 0,I:DRAWTO 39,I:NEXT I
503 FOR I=1 TO 100:POKE 704,I:POKE 705,I:NEXT I:POKE 53248,0:POKE 53249,0:COLOR 4
504 PLOT 0,18:DRAWTO 39,18:GOTO 9999
600 YE=YE+1:IF YE=11 THEN A$="{inv}{CTRL-M}{CTRL-A}{/inv}":B$="{inv}{CTRL-B}{CTRL-B}{/inv}":C$="{inv}{CTRL-C}{CTRL-C}{/inv}"
601 IF YE=12 THEN A$="{inv}{CTRL-N}{CTRL-B}{/inv}":B$="{inv}{CTRL-C}{CTRL-C}{/inv}":C$="{inv}{CTRL-D}{CTRL-D}{/inv}":D$="{inv}{CTRL-A}{CTRL-A}{/inv}"
602 IF YE=13 THEN A$="{inv}{CTRL-O}{CTRL-P}{/inv}":B$="{inv}{CTRL-D}{CTRL-D}{/inv}":C$="{inv}{CTRL-E}{CTRL-E}{/inv}":D$="{inv}{CTRL-B}{CTRL-B}{/inv}"
603 IF YE=14 THEN A$="{inv}{CTRL-Q}{CTRL-R}{/inv}":B$="{inv}{CTRL-S}{CTRL-T}{/inv}":C$="{inv}{CTRL-F}{CTRL-F}{/inv}":D$="{inv}{CTRL-C}{CTRL-C}{/inv}"
604 IF YE=15 THEN A$="{inv}{CTRL-U}{CTRL-V}{/inv}":B$="{inv}{CTRL-W}{CTRL-X}{/inv}":C$="{inv}{CTRL-Y}{CTRL-Z}{/inv}":D$="{inv}{CTRL-D}{CTRL-D}{/inv}"
605 IF YE=16 THEN 500
606 IF X1<99 THEN POSITION X1,YE:? A$:POSITION X1,YE+1:? B$:POSITION X1,YE+2:? C$:IF YE>11 THEN GOSUB 624
607 IF X2<99 THEN POSITION X2,YE:? A$:POSITION X2,YE+1:? B$:POSITION X2,YE+2:? C$:IF YE>11 THEN GOSUB 620
608 IF X3<99 THEN POSITION X3,YE:? A$:POSITION X3,YE+1:? B$:POSITION X3,YE+2:? C$:IF YE>11 THEN GOSUB 621
609 IF X4<99 THEN POSITION X4,YE:? A$:POSITION X4,YE+1:? B$:POSITION X4,YE+2:? C$:IF YE>11 THEN GOSUB 622
610 IF X5<99 THEN POSITION X5,YE:? A$:POSITION X5,YE+1:? B$:POSITION X5,YE+2:? C$:IF YE>11 THEN GOSUB 623
619 RETURN
620 POSITION X2,YE-1:? D$:RETURN
621 POSITION X3,YE-1:? D$:RETURN
622 POSITION X4,YE-1:? D$:RETURN
623 POSITION X5,YE-1:? D$:RETURN
624 POSITION X1,YE-1:? D$:RETURN
700 POSITION 14,3:? "{inv} DESERT CHASE {/inv}":POSITION 12,4:? "{inv} BY GUY AITCHISON {/inv}"
701 SOUND 0,255,10,14:SOUND 1,254,10,14:SOUND 2,10,10,14:POKE 53768,14
702 C=C+1:IF C>2 THEN C=0
703 IF C=2 THEN POKE 708,Z+4:POKE 709,Z+6:POKE 711,Z+8
704 IF C=1 THEN POKE 709,Z+4:POKE 711,Z+6:POKE 708,Z+8
705 IF C=0 THEN POKE 711,Z+4:POKE 708,Z+6:POKE 709,Z+8
706 Z=Z+16:IF Z>248 THEN Z=0
707 IF STRIG(0)=0 THEN SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:Z=0:GOTO 710
709 GOTO 702
710 POSITION 14,3:? "{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}":POSITION 12,4:? "{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}":POP :GOTO 47
800 FF=1:POKE 53250,X+10:XX=X+10:RESTORE 2000:Y=175
802 IF W=400 THEN SP=8
803 IF W=300 THEN SP=7
804 IF W=200 THEN SP=6
805 IF W=100 THEN SP=5
809 RETURN
810 SP=SP-1:Y=Y-SP:READ N:IF N=256 THEN POKE PM+512+Y+SP,0:FF=0:GOSUB 820:RETURN
812 POKE PM+512+Y,N:POKE PM+512+Y+SP,0:RETURN
820 IF W=400 AND YE=12 OR W=300 AND YE=13 OR W=200 AND YE=14 OR W=100 AND YE=15 THEN 822
821 RETURN
822 H=INT((XX/4)-11):J=H-1:IF H=X1 OR J=X1 THEN HJ=1:GOTO 830
823 IF H=X2 OR J=X2 THEN HJ=2:GOTO 830
824 IF H=X3 OR J=X3 THEN HJ=3:GOTO 830
825 IF H=X4 OR J=X4 THEN HJ=4:GOTO 830
826 IF H=X5 OR J=X5 THEN HJ=5:GOTO 830
829 RETURN
830 POKE 710,14:SOUND 3,20,0,14:IF HJ=1 THEN XC=X1:X1=99
831 IF HJ=2 THEN XC=X2:X2=99
832 IF HJ=3 THEN XC=X3:X3=99
833 IF HJ=4 THEN XC=X4:X4=99
834 IF HJ=5 THEN XC=X5:X5=99
835 RESTORE 1010:FOR I=11 TO 20:READ C:COLOR C+128:PLOT XC,I:PLOT XC+1,I:NEXT I:F=F+30:SOUND 3,0,0,0
836 SK=SK+1:IF SK>SN THEN SK=0:GOSUB 200
837 POKE 710,100:SC=SC+(YE*10):POSITION 23,0:? SC:RETURN
900 POSITION 0,0:? "    ":POKE 710,100:POKE 752,1
901 FOR I=1 TO 5:COLOR 6:PLOT 0,I:DRAWTO 39,I:NEXT I:FOR I=8 TO 10:PLOT 0,I:DRAWTO 39,I:NEXT I
902 POSITION 0,10:? "{CTRL-G}{CTRL-H}{CTRL-I}{CTRL-G}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-H}{CTRL-I}{CTRL-G}{CTRL-H}{CTRL-I}{CTRL-G}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-H}{CTRL-I}{CTRL-G}{CTRL-F}{CTRL-F}{CTRL-G}{CTRL-H}{CTRL-I}{CTRL-H}{CTRL-I}{CTRL-G}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-G}{CTRL-G}{CTRL-F}{CTRL-F}{CTRL-G}{CTRL-H}{CTRL-I}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}{CTRL-F}"
903 FOR I=11 TO 23:READ C:COLOR C+128:PLOT 0,I:DRAWTO 39,I:NEXT I
910 POKE 559,62:POKE 53277,3:PM=INT(PEEK(742)/4-2)*1024:POKE 623,1:POKE 54279,(PM/256)-4
911 RESTORE 1020:FOR I=177 TO 220 STEP 2:READ X:POKE I+PM,X:POKE I+PM+1,X:NEXT I
912 FOR I=177 TO 220 STEP 2:READ X:POKE I+PM+256,X:POKE I+PM+257,X:NEXT I
913 POKE 53248,114:POKE 53249,130:X=114:POKE 53256,1:POKE 53257,1
980 W=100:POSITION 18,22:? "D=";W
989 POSITION 0,6
990 ? " {CTRL-J}{CTRL-L}                 {CTRL-J}{CTRL-K}{CTRL-L}      {CTRL-J}{CTRL-L}"
991 ? "    {CTRL-J}{CTRL-K}{CTRL-J}{CTRL-K}{CTRL-L}   {CTRL-J}{CTRL-K}{CTRL-L}                 {CTRL-J}{CTRL-K}{CTRL-J}{CTRL-K}{CTRL-L}"
992 X1=16:X2=24:X3=99:X4=99:X5=99
997 POSITION 5,0:? "FUEL= 999  SCORE= 0    WAVE= 1 ":POKE 706,28:SP=5:RETURN
1000 DATA 0,0,0,0,0,0,0,0,0,1,0,0,0,170,85,255,170,170,2,85,85,255,255,170,170,170,170,3,85,85,85,85
1001 DATA 255,255,255,255,4,170,170,170,170,170,170,170,170,5,85,85,85,85,85,85,85,85,6,255,255,255,255
1002 DATA 255,255,255,255,7,255,255,255,243,243,192,192,0,8,252,252,252,240,192,192,0,0,9,255,63,15,3,3,0,0,0
1003 DATA 10,1,27,63,63,127,255,62,0,11,128,192,193,227,247,255,12,0,12,0,0,128,128,204,255,224,0
1004 DATA 13,0,16,0,170,69,255,170,170,14,85,85,195,195,170,170,130,170,15,85,80,64,64,255,255,192,255
1005 DATA 16,85,85,21,21,255,255,63,255,17,168,160,160,162,128,170,170,160,18,42,10,10,138,2,170,170,10
1006 DATA 19,64,84,85,85,85,85,85,85,20,1,5,85,85,85,85,85,85
1007 DATA 21,85,85,85,85,85,84,80,64,22,85,85,85,85,85,21,5,1,23,192,192,195,207,0,240,255,255
1008 DATA 24,3,3,195,243,0,15,255,255,25,255,255,192,0,192,255,255,255,26,255,255,3,0,3,255,255,255
1009 DATA 33,170,74,8,162,8,74,170,170
1010 DATA 1,2,3,4,5,6,6,4,4,4,5,5,5,5,5
1020 DATA 1,1,27,50,117,157,235,150,246,103,3,0,0,0,0,0,0,1,19,119,255,247
1021 DATA 128,128,216,76,174,185,215,105,111,230,192,0,0,0,0,0,0,128,200,238,255,239,239
2000 DATA 255,255,255,126,126,60,60,24,24,0,0,256
9999 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0:POSITION 1,6:? "               GAME OVER        "
10000 POKE 709,Z+8:FOR I=512 TO 512+256:POKE PM+I,0:NEXT I:POKE 704,0:POKE 705,0:SC=0:F=999
10001 SE=35:SK=0:SN=1:WA=0:YE=10:Z=0:POSITION 34,0:? "1  ":FF=0
10002 POSITION 0,6:? " {CTRL-J}{CTRL-L}                 {CTRL-J}{CTRL-K}{CTRL-L}      {CTRL-J}{CTRL-L}":X1=15:X2=25:X3=99:X4=99:X5=99
10003 X=114:POKE 53248,114:POKE 53249,130:POSITION 23,0:? "0    ":POSITION 11,0:? "999 ":GOTO 700

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: DESERT.BAS.

Credits