Sorcerer's Apprentice

Type
Game
Category
Shoot-'em-up
Author
James (Jim) Catalano
Published in
Antic, September 1988 (Vol. 7, No. 5), Game of the Month
Year
1988
Language
Atari BASIC
Requirements
32K RAM, Atari BASIC, joystick in port 1
A dark red stone chamber with brick pillars, a large winged demonic statue on a plinth flanked by pink flames, a blue apparition floating beside it, and the apprentice on the rubble floor holding a sparkling fireball

About the program

You're apprenticed to the dark sorcerer Nymonn, who tries out all his new spells on you. After being turned into an over-ripe radish once too often, you wait until he leaves for the Darkside Sorcerers' Convention. Then you open his forbidden copy of 1001 Spells for Every Occasion and cast a Spell of Summoning to sort the old goat out. It doesn't go to plan. A glowing blue apparition appears above the pentagram and darts around the chamber, spitting green ectoplasm, and every one you blast is instantly replaced by another. All you can do is keep fireballing until your master gets home.

James Catalano, from Chicago, sent Antic more submissions on one disk than the magazine usually got from several people in a month. Sorcerer's Apprentice was the first to be published, and Antic promised two more Catalano games to come. One of them, Saucerian, followed in January 1989.

Typing it in

You need 32K. Many lines hold binary data in strings. Line 340 is a machine-language move routine. Lines 400–455 are 512 bytes of redefined characters for the chamber and statue (line 455 inserts the one quote character that can't go inside a string). Lines 830–875 hold the player shapes for the apprentice, fireball, apparition and ectoplasm. The magazine's second listing wrote the hardest of these to LINES.LST for merging, and the disk version printed here has everything in place. In this notation {inv}…{/inv} means type with the Atari key on, {CTRL-F} means hold CTRL and press F, and cursor and editing codes such as {DOWN}, {BACK S}, {DEL CHAR} and {ESC} are typed by pressing ESC first and then the key (so {ESC} is ESC pressed twice).

How to play

Move the apprentice left and right along the floor with the joystick. He faces the way he last moved. Press the button to cast a fireball, which flies up the screen from his hand. Each apparition you destroy is worth 75 points. The ectoplasm splatters when it hits the floor, so a near miss can still get you. When your lives run out, the score is shown and you are asked whether to play again (Y/N).

How it works

The scene is GRAPHICS 2 (mode 18) with a redefined character set at the top of memory. The statue is literally a block of punctuation characters printed in lines 750–780, and the chamber walls and rubbly floor are more redefined characters, sprinkled with PLOT at random. All the moving objects are player-missile graphics. Player 0 is the apprentice, player 1 the fireball, player 2 the apparition and player 3 the ectoplasm. A machine-language routine (PMMOVQ) copies a shape string into player memory at a given X and Y. Animation is just a matter of passing a different slice of the shape string. For example, SHAPE1$(PD1*26-25) picks the apprentice's left- or right-facing frame.

The apparition drifts towards a random target point, ten pixels at a time, and picks a new target when it gets there. Its colour flickers because line 55 pokes a random luminance into its colour register on every pass. Hits are detected by the hardware collision registers: 53261 for the fireball touching the apparition, 53263 for the goop touching the apprentice. Line 240 clears them with HITCLR (53278) each time round.

Variations to try

  • Make the apparition spit more often: change A=INT(RND(0)*10):IF A=1 in line 95 to a smaller range.
  • Give the fireball a slower start by changing F=F+4 in line 225 to F=F+2.

Changes from the published listing

One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds commands called MOVE, PMMOVE, so it rejected the published lines that use those words as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.

Published Now Lines
MOVE$ MOVX$ 335, 340, 350, 560
PMMOVE PMMOVQ 85, 110, 135, 195, 215, 230, 255, 260, 910
PMMOVE$ PMMOVQ$ 910, 930, 932, 934

Listing

10 REM SORCERER'S APPRENTICE
20 REM BY JIM CATALANO
30 REM (c)1988, ANTIC PUBLISHING
35 CLR :POKE 559,0:GOSUB 330:PMMODE=2:GRMODE=18:GOSUB 910:GOSUB 820:GOSUB 725
40 PD3=1:DX=48+INT(RND(0)*145):DY=16+INT(RND(0)*51):DTX=48+INT(RND(0)*145):DTY=16+INT(RND(0)*51)
45 PD1=2:SX=120:SY=82:FX=SX+10:FY=SY-1:SC=0:MEN=5
50 REM MOVE DEMONIC SPIRIT
55 POKE 706,128+INT(RND(0)*15)
60 IF DX<DTX THEN PD3=2:DX=DX+10
65 IF DX>DTX THEN PD3=1:DX=DX-10
70 IF DY<DTY THEN DY=DY+10
75 IF DY>DTY THEN DY=DY-10
80 IF DX<DTX+11 AND DX>DTX-11 AND DY<DTY+11 AND DY>DTY-11 THEN DTX=48+INT(RND(0)*145):DTY=16+INT(RND(0)*51)
85 A=USR(PMMOVQ,3,ADR(SHAPE3$(PD3*14-13)),SIZE3,DX,DY)
90 IF GOOP=1 THEN 110
95 A=INT(RND(0)*10):IF A=1 THEN GOOP=1:EX=DX+4:EY=DY+8:E=0
100 GOTO 160
105 REM SPIT ECTOPLASM AT SORCERER
110 E=E+4:EY=EY+E:FOR PD4=1 TO 2:A=USR(PMMOVQ,4,ADR(SHAPE4$(PD4*7-6)),SIZE4,EX,EY):NEXT PD4
115 IF PEEK(53263)=1 THEN GOSUB 285:GOTO 160
120 IF EY>90 THEN 135
125 GOTO 160
130 REM ECTOPLASM SPLATTER
135 GOOP=0:EY=101:EX=EX-8:POKE 53259,3:A=USR(PMMOVQ,4,ADR(SHAPE4$(2*7-6)),SIZE4,EX,EY)
140 FOR V=INT(RND(0)*15)+1 TO 0 STEP -0.5:SOUND 0,INT(RND(0)*255)+1,8,V:NEXT V
145 IF PEEK(53263)=1 THEN GOSUB 285
150 POKE 53251,0:POKE 53259,0
155 REM MOVE SORCERER
160 ST=STICK(0):T=STRIG(0)
165 IF FIRE=1 THEN 175
170 IF T=0 THEN FIRE=1:F=0:FX=SX-1:IF PD1=2 THEN FX=SX+10
175 IF ST=11 THEN PD1=1:SX=SX-8
180 IF ST=7 THEN PD1=2:SX=SX+8
185 IF SX<54 THEN SX=54
190 IF SX>186 THEN SX=186
195 A=USR(PMMOVQ,1,ADR(SHAPE1$(PD1*26-25)),SIZE1,SX,SY)
200 IF FIRE=1 THEN 225
205 IF PD1=1 THEN FX=SX-1
210 IF PD1=2 THEN FX=SX+10
215 FOR PD2=1 TO 2:A=USR(PMMOVQ,2,ADR(SHAPE2$(PD2*7-6)),SIZE2,FX,FY):NEXT PD2:GOTO 240
220 REM CAST FIREBALL
225 F=F+4:FY=FY-F:IF FY<0 THEN SOUND 1,0,0,0:POKE 53249,0:FY=SY-1:FIRE=0:GOTO 55
230 FOR PD2=1 TO 2:A=USR(PMMOVQ,2,ADR(SHAPE2$(PD2*7-6)),SIZE2,FX,FY):NEXT PD2:SOUND 1,FX*FY,0,5
235 IF PEEK(53261)=4 THEN SOUND 1,0,0,0:POKE 53249,0:FY=SY-1:FIRE=0:GOSUB 250
240 POKE 711,72+INT(RND(0)*7)+1:POKE 53278,0:POKE 77,0:GOTO 55
245 REM DEMON HIT/DEMATERIALIZE IT
250 FOR SCREAM=INT(RND(0)*15)+5 TO 0 STEP -0.5:SOUND 0,SCREAM,SCREAM,SCREAM:NEXT SCREAM:PD3=3:POKE 706,14
255 A=USR(PMMOVQ,3,ADR(SHAPE3$(PD3*14-13)),SIZE3,DX,DY):FOR D=1 TO 10:NEXT D
260 DX=DX-4:POKE 53258,3:A=USR(PMMOVQ,3,ADR(SHAPE3$(PD3*14-13)),SIZE3,DX,DY)
265 FOR DEMAT=0 TO 15 STEP 0.4:POKE 706,15-DEMAT:SOUND 0,2,8,DEMAT:NEXT DEMAT:SOUND 0,0,0,0
270 POKE 53250,0:POKE 53258,1:DX=48+INT(RND(0)*145):DY=16+INT(RND(0)*51):DTX=48+INT(RND(0)*145)
275 DTY=16+INT(RND(0)*51):SC=SC+75:RETURN
280 REM SORCERER HIT BY ECTOPLASM
285 POKE 53251,0:FOR T=15 TO 0 STEP -1:FOR S=0 TO T:POKE 704,196-S:SOUND 0,S+T,6,T:NEXT S:NEXT T
290 MEN=MEN-1:IF MEN=0 THEN FOR C=15 TO 0 STEP -0.3:POKE 704,C:NEXT C:POKE 53248,0:POKE 53249,0:POP :GOTO 305
295 POKE 704,42:GOOP=0:POKE 53278,0:RETURN
300 REM GAME OVER
305 SOUND 1,0,0,0:FOR A=53248 TO 53251:POKE A,0:NEXT A:POKE 53277,0:? #6;"{CLEAR}"
310 COLOR 216:PLOT 0,0:DRAWTO 19,0:DRAWTO 19,11:DRAWTO 0,11:DRAWTO 0,0
315 POSITION 5,2:? #6;"GAME OVER":POSITION 7,5:? #6;"SCORE":POSITION 7,7:? #6;SC
320 POKE 19,0:POKE 20,200
321 IF PEEK(19)<2 THEN 321
322 GOTO 1300
325 REM REDEFINE CHARACTER SET
330 CH=PEEK(740)-16:CH=CH*256
335 DIM MOVX$(46),CHX$(512)
340 MOVX$="hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}"
350 JUNK=USR(ADR(MOVX$),57344,CH,1024)
400 CHX$(1,64)="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-A}{CTRL-B}{CTRL-F}{CTRL-N}{DOWN}{DOWN};;{CTRL-,}fff{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-,}@@{CTRL-.}{/inv}x{BACK S}{BACK S}{inv}>{/inv}{CTRL-,}{CTRL-H}{CTRL-P}{CTRL-P}{CTRL-X}{CTRL-M}{CTRL-O}{CTRL-G}{CTRL-,}{CTRL-P}{CTRL-H}{CTRL-H}{CTRL-X}{inv}0p{CTRL-.}{/inv}{CTRL-A}{CTRL-C}{CTRL-C}{CTRL-G}{LEFT}{BACK S}{BACK S}{CLEAR}{inv}{CTRL-,}{/inv}@{CTRL-.}p{inv}88\\{/inv}"
410 CHX$(65,128)="{CTRL-;}ww{inv}wwwww?__ov{/inv}{BELL}{inv}{CTRL-;}w{/inv}{CTRL-O}{inv}im{CTRL-G}{/inv}w{inv}{CTRL-;}z{/inv}{INS LINE}{inv}p{CTRL-W}7an_{/inv}_{inv}9{/inv}{BELL}{inv}{CTRL-;}{CTRL-;}w{/inv}o{inv}?_o^nnooooowww{/inv}{INS CHAR}{INS CHAR}{inv}xp{CTRL-.}wo^=={/inv}{CLEAR}{CLEAR}{DEL CHAR}"
420 CHX$(129,192)="{CTRL-,}{DEL CHAR}f{inv}n{/inv}vf{BACK S}{CTRL-,}{CTRL-,}{CTRL-X}xx{CTRL-X}{CTRL-X}{BACK S}{CTRL-,}{CTRL-,}|fL{CTRL-X}6{BACK S}{CTRL-,}{CTRL-,}{BACK S}{inv}N{/inv}{CTRL-X}{CTRL-L}f>{CTRL-,}{CTRL-,}{CTRL-L}{UP}<l{DEL CHAR}{CTRL-L}{CTRL-,}{CTRL-,}{DEL CHAR}{CTRL-.}{inv}|{/inv}{CTRL-F}f|{CTRL-,}{CTRL-,}|{inv}{CTRL-.}{/inv}|{inv}f{/inv}f{BACK S}{CTRL-,}{CTRL-,}{DEL CHAR}f{CTRL-L}{CTRL-X}00{CTRL-,}"
430 CHX$(193,256)="{CTRL-,}<f<{inv}f{/inv}f{DEL CHAR}{CTRL-,}{CTRL-,}{DEL CHAR}f{DEL CHAR}{CTRL-F}{CTRL-L}8{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-X}{CTRL-X}{CTRL-,}{inv}g{CTRL-;}{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}g_{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}ow{/inv}{CTRL-;}{inv}==>>{/inv}{TAB}{inv}ooo{/inv}{INS CHAR}{INS CHAR}{RIGHT}{CTRL-O}{inv}{CTRL-G}CCGG{CTRL-G}{CTRL-G}{CTRL-C}{CTRL-C}{/inv}"
440 CHX$(257,320)="{INS CHAR}{inv}lhhssww{/inv}{CTRL-,}{inv}x{/inv}<ff{BACK S}{inv}g{/inv}{CTRL-,}{inv}ggs{CTRL-;}m{/inv}D@@{CTRL-,}{DEL CHAR}fp{inv}p{/inv}f>{CTRL-,}{CTRL-,}{inv}x{/inv}lf{inv}f{/inv}l|{CTRL-,}{CTRL-,}{DEL CHAR}{CTRL-.}|{inv}{CTRL-.}{/inv}f{BACK S}{CTRL-,}{INS CHAR}{inv}w{CTRL-;}{CTRL-;}{CTRL-;}{/inv}{BELL}{CLEAR}{BACK S}{CTRL-,}{DEL CHAR}f{CTRL-.}{inv}n{/inv}f>{CTRL-,}"
450 CHX$(321,384)="{INS CHAR}{inv}o___?>{/inv}{BACK S}{CTRL-,}{BACK S}{CTRL-X}<{CTRL-X}{CTRL-X}{BACK S}{CTRL-,}{inv}ggO_7{/inv}*{CTRL-B}{CTRL-B}{inv}B{CTRL-B}{/inv}{CTRL-D}{CTRL-,}{inv}{CTRL-,}@{/inv}@{CTRL-,}{CTRL-,}{inv}p{/inv}{CTRL-.}{inv}{CTRL-.}{/inv}{CTRL-.}v{BACK S}{CTRL-,}{CTRL-,}{inv}c{/inv}w{INS CHAR}kcw{CTRL-,}{CTRL-,}{inv}f{/inv}v{BACK S}{BACK S}n{inv}v{/inv}{CTRL-,}{CTRL-,}{DEL CHAR}f{inv}f{/inv}ff{BACK S}{CTRL-,}"
455 CHX$(342,342)=CHR$(34)
460 CHX$(385,448)="{CTRL-,}{CTRL-H}{CTRL-D},{CTRL-X}4<Z>>{LEFT}{UP}<|{inv}nF{/inv}{CTRL-,}{inv}|{/inv}f{inv}f{/inv}|lv{CTRL-,}{CTRL-,}{DEL CHAR}{CTRL-.}{BACK S}{CTRL-F}f{BACK S}{CTRL-,}||x8<>wc{CTRL-,}{inv}f{/inv}f{inv}f{/inv}f{BACK S}|{CTRL-,}{CTRL-,}{inv}f{/inv}f{inv}f{/inv}f{BACK S}{CTRL-X}{CTRL-,}{CTRL-,}{CTRL-P} 4{CTRL-X},<Z"
470 CHX$(449,512)="{BELL}{BELL}{BELL}{CTRL-,}{inv}___{/inv}{CTRL-,}{inv}9]-{/inv}{CTRL-,}{CTRL-TAB}U{inv}[{/inv}{CTRL-,}{inv}f{/inv}[{DEL LINE}j{inv}f{/inv}^{inv}5[{/inv}{CLEAR}{CTRL-C}{TAB}{DOWN}{inv}k{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{inv}>@{/inv}{DEL CHAR}{inv}8W{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}7{CTRL-W}{CTRL-W}{inv}OOooCCccaaAA{/inv}CA {CTRL-,}{CTRL-A}{CTRL-C}{CTRL-B}{CTRL-,}"
560 JUNK=USR(ADR(MOVX$),ADR(CHX$),CH,512)
570 RETURN
720 REM DRAW PLAYFIELD
725 POKE 708,52:POKE 709,6:POKE 710,40:POKE 711,72:POKE 712,32
730 FOR Y=0 TO 5:POSITION 1,Y:? #6;"{inv}XX{/inv}  {inv}XX{/inv}      {inv}XX{/inv}  {inv}XX{/inv}":NEXT Y:POSITION 0,6:? #6;"z{inv}XX{/inv}zz{inv}XX{/inv}zzzzzz{inv}XX{/inv}zz{inv}XX{/inv}z"
735 COLOR 217:PLOT 1,0:DRAWTO 2,1:PLOT 1,3:DRAWTO 2,4:DRAWTO 2,5:DRAWTO 1,6:PLOT 6,0:DRAWTO 5,1:DRAWTO 5,2
740 PLOT 6,4:DRAWTO 5,5:DRAWTO 6,6:PLOT 14,0:PLOT 13,2:DRAWTO 14,3:PLOT 13,5:DRAWTO 13,6:PLOT 17,0:PLOT 18,2
745 DRAWTO 17,3:DRAWTO 17,4:PLOT 18,6:COLOR 122:FOR Y=7 TO 11:PLOT 0,Y:DRAWTO 19,Y:NEXT Y
750 POSITION 7,0:? #6;"!#$%&'"
755 POSITION 7,1:? #6;"()*+,-"
760 POSITION 7,2:? #6;"./;<=>"
765 POSITION 7,3:? #6;"?@[\]^"
770 POSITION 7,4:? #6;"_BFHJK"
775 POSITION 7,5:? #6;" {inv}p{/inv}QT{inv}w{/inv} "
780 POSITION 7,6:? #6;"zYYYYz"
785 COLOR 121:FOR T=1 TO 40:X=INT(RND(0)*20):Y=7+INT(RND(0)*5):PLOT X,Y:NEXT T
790 COLOR 120:FOR T=1 TO 15:X=INT(RND(0)*20):Y=7+INT(RND(0)*5):PLOT X,Y:NEXT T
795 COLOR 32:PLOT 1,7:DRAWTO 0,7:DRAWTO 0,8:PLOT 0,11:DRAWTO 4,7:PLOT 1,11:DRAWTO 5,7:PLOT 14,7:DRAWTO 18,11
800 PLOT 15,7:DRAWTO 19,11:PLOT 18,7:DRAWTO 19,7:DRAWTO 19,8:RETURN
805 REM
810 REM
815 REM EVIL SORCERER
820 DIM SHAPE1$(52):SIZE1=26
830 SHAPE1$="{CTRL-F}{CTRL-B}FF00>>77//{CTRL-A}{CTRL-A}{CTRL-J}{CTRL-J}{CTRL-J}{CTRL-J}{ESC}{ESC}{RIGHT}{RIGHT}{RIGHT}{RIGHT}??{CTRL-.}@bb{CTRL-L}{CTRL-L}||{inv}lltt{CTRL-,}{CTRL-,}{/inv}PPPP{inv}XXxxxx||{/inv}"
835 REM FIREBALL
840 DIM SHAPE2$(14):SIZE2=7
845 SHAPE2$="{CTRL-P}T({inv}F{/inv}(T{CTRL-P}{CTRL-,}(T8T({CTRL-,}"
850 REM DEMONIC SPIRIT
855 DIM SHAPE3$(42):SIZE3=14
860 SHAPE3$="{CTRL-X}<VV?w{inv}o-{/inv}3>{LEFT}{LEFT}{CTRL-L}{CTRL-D}{CTRL-X}<jj{inv}|nw5L{/inv}|xx0 B${inv}{CTRL-A}{/inv}Z${CTRL-,}{inv}C{/inv}{CTRL-,}$Z{inv}{CTRL-A}{/inv}$B{CTRL-,}"
870 REM ECTOPLASM
875 DIM SHAPE4$(14):SIZE4=7
880 SHAPE4$="{CTRL-P} 0{CTRL-X},{LEFT}{CTRL-L}{CTRL-H}{CTRL-D}(P4x0"
885 POKE 623,1:POKE 53256,1:POKE 53258,1:RETURN
890 REM P/M  SETUP
895 REM DEFINE PMMODE & GRMODE
900 REM BEFORE CALLING ROUTINE
905 REM
910 DIM PMMOVQ$(202):PMMOVQ=ADR(PMMOVQ$)
915 MT=0
916 PAGCLR=ADR("h{inv}I{/inv}{CTRL-B}{inv}p{/inv}{CTRL-P}{inv}{CTRL-E}N"{/inv}{CTRL-,}{inv}dNP{/inv}{CTRL-A}{CTRL-.}hh{inv}h){/inv}{CTRL-,}{inv}pt{/inv}h{inv}{CTRL-E}L{/inv}h{inv}{CTRL-E}K{/inv}hh{inv}{CTRL-E}M){/inv}{CTRL-,}{inv}(*{CTRL-Q}KHP{CTRL-;}fLhdMPt{/inv}{CTRL-.}")
930 PMMOVQ$(1,68)="h{inv}I{/inv}{CTRL-E}{inv}p{/inv}{CTRL-R}{inv}{CTRL-M}{/inv}{CTRL-,}{CTRL-D}{inv}"{/inv}{CTRL-,}{inv}l{/inv}{CTRL-,}{CTRL-D}{inv}P{/inv}{CTRL-A}{CTRL-.}hh{inv}h){/inv}{CTRL-,}{inv}ps{/inv}hh{inv}I{/inv}{CTRL-I}{inv}{CTRL-P}{/inv}{CTRL-I}hhhhhhhh{CTRL-.}{CTRL-X}{inv}I{/inv}{CTRL-,}{inv}pr{CTRL-M}{/inv}{CTRL-D}{CTRL-D}h{inv}{CTRL-E}N{/inv}h{inv}{CTRL-E}M{/inv}hh{inv}{CTRL-M}{/inv}{CTRL-E}{CTRL-D}hh{inv}{CTRL-M}{/inv}{CTRL-B}{CTRL-D}hh{inv}{CTRL-M}{/inv}{CTRL-C}{CTRL-D}{inv}.{/inv}"
932 PMMOVQ$(69,136)="{CTRL-D}{CTRL-D}{inv}-{/inv}{CTRL-B}{CTRL-D}{INS LINE}{INS CHAR}{inv}O{CTRL-.}{/inv}{CTRL-E}{inv}0{/inv}{CTRL-B}{inv}{CTRL-P}{/inv}{CTRL-E}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{CTRL-D}{CTRL-D}{inv}%OI{/inv}{CTRL-B}{inv}p{/inv}{UP}{inv}%{/inv}j{CTRL-X}i{CTRL-C}m{CTRL-D}{CTRL-D}{inv}{CTRL-E}L){/inv}{CTRL-,}{inv}{CTRL-E}K({CTRL-Q}KHP{CTRL-;}-{/inv}{CTRL-C}{CTRL-D}{inv}{CTRL-E}K{/inv}{CTRL-X}{inv}{CTRL-P}{/inv}A{inv}%{/inv}j{CTRL-X}i{CTRL-A}{inv}{CTRL-E}L){CTRL-,}{CTRL-E}K-{/inv}{CTRL-D}{CTRL-D}{inv}p{/inv}"
934 PMMOVQ$(137,202)="{CTRL-U}{inv}"{/inv}{CTRL-,}{inv}%K{/inv}{CTRL-X}i{inv}{CTRL-,}{CTRL-E}K%L{/inv}i{CTRL-,}{inv}{CTRL-E}Lhl{/inv}{CTRL-D}{CTRL-D}{inv}Pm {/inv}{CTRL-,}{inv}{CTRL-X}{CTRL-Q}KH@{/inv}{TAB}{inv}Py-{/inv}{CTRL-C}{CTRL-D}{inv}I{CTRL-,}{CTRL-P}{/inv}{CTRL-A}{CTRL-.}e{inv}K{CTRL-E}K%L{/inv}i{CTRL-,}{inv}{CTRL-E}L {/inv}{CTRL-,}{inv}L{/inv}{CTRL-E}{CTRL-D}{inv}p{/inv}{CTRL-H}{inv}1M{CTRL-Q}KH{/inv}{CTRL-X}{inv}{CTRL-P}s{/inv}{CTRL-.}"
940 IF PMMODE=1 THEN PAGES=8:DMA=62:GOTO 955
945 IF PMMODE=2 THEN PAGES=4:DMA=46:GOTO 955
950 RETURN
955 POKE 54279,PEEK(106)-PAGES:POKE 106,PEEK(106)-PAGES:POKE 207,PMMODE
960 GRAPHICS GRMODE:POKE 756,CH/256
965 PMBASE=PEEK(106)*256:POKE 559,DMA:POKE 53277,3:X=USR(PAGCLR,PMBASE,PAGES)
970 REM P/M COLORS
975 POKE 704,42:POKE 705,14:POKE 706,88:POKE 707,218
980 RETURN
985 REM
1030 REM
1300 ? "{CLEAR}":POKE 752,1:POSITION 14,10:? "   WANT TO   ":POSITION 15,11:? "PLAY AGAIN?":POSITION 18,12:? "({inv}Y/N{/inv})"
1310 CLOSE #1:OPEN #1,4,0,"K:"
1320 GET #1,K:IF K=0 THEN 1310
1330 IF K=78 OR K=110 THEN GRAPHICS 0:END
1340 GOTO 35

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: SORCERER.BAS.

Credits