Sorcerer's Apprentice (SORCERER.BAS)

Sorcerer's Apprentice, game by Jim Catalano, 67

Description

Sorcerer's Apprentice, game by Jim Catalano, 67

From the Antic disk of September 1988 (Vol. 7 No. 5) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.2 KB

Dialect
Atari BASIC
Lines
137
Variables
PMMODE, GRMODE, PD3, DX, DY, DTX, DTY, PD1, SX, SY, FX, FY, SC, MEN, A, PMMOVE, SHAPE3$, SIZE3, GOOP, EX, EY, E, PD4, SHAPE4$, SIZE4, V, ST, T, FIRE, F, SHAPE1$, SIZE1, PD2, SHAPE2$, SIZE2, SCREAM, D, DEMAT, S, C, CH, MOVE$, CHX$, JUNK, Y, X, PMMOVE$, MT, PAGCLR, PAGES, DMA, PMBASE, K
BASIC listing (137 lines)
10 REM SORCERER'S APPRENTICE
20 REM BY JIM CATALANO
30 REM (c)1988, ANTIC PUBLISHING
35 CLR :POKE 559,0:GOSUB 330:PMMODE=2:GRMODE=18:GOSUB 910:GOSUB 820:GOSUB 725
40 PD3=1:DX=48+INT(RND(0)*145):DY=16+INT(RND(0)*51):DTX=48+INT(RND(0)*145):DTY=16+INT(RND(0)*51)
45 PD1=2:SX=120:SY=82:FX=SX+10:FY=SY-1:SC=0:MEN=5
50 REM MOVE DEMONIC SPIRIT
55 POKE 706,128+INT(RND(0)*15)
60 IF DX<DTX THEN PD3=2:DX=DX+10
65 IF DX>DTX THEN PD3=1:DX=DX-10
70 IF DY<DTY THEN DY=DY+10
75 IF DY>DTY THEN DY=DY-10
80 IF DX<DTX+11 AND DX>DTX-11 AND DY<DTY+11 AND DY>DTY-11 THEN DTX=48+INT(RND(0)*145):DTY=16+INT(RND(0)*51)
85 A=USR(PMMOVE,3,ADR(SHAPE3$(PD3*14-13)),SIZE3,DX,DY)
90 IF GOOP=1 THEN 110
95 A=INT(RND(0)*10):IF A=1 THEN GOOP=1:EX=DX+4:EY=DY+8:E=0
100 GOTO 160
105 REM SPIT ECTOPLASM AT SORCERER
110 E=E+4:EY=EY+E:FOR PD4=1 TO 2:A=USR(PMMOVE,4,ADR(SHAPE4$(PD4*7-6)),SIZE4,EX,EY):NEXT PD4
115 IF PEEK(53263)=1 THEN GOSUB 285:GOTO 160
120 IF EY>90 THEN 135
125 GOTO 160
130 REM ECTOPLASM SPLATTER
135 GOOP=0:EY=101:EX=EX-8:POKE 53259,3:A=USR(PMMOVE,4,ADR(SHAPE4$(2*7-6)),SIZE4,EX,EY)
140 FOR V=INT(RND(0)*15)+1 TO 0 STEP -0.5:SOUND 0,INT(RND(0)*255)+1,8,V:NEXT V
145 IF PEEK(53263)=1 THEN GOSUB 285
150 POKE 53251,0:POKE 53259,0
155 REM MOVE SORCERER
160 ST=STICK(0):T=STRIG(0)
165 IF FIRE=1 THEN 175
170 IF T=0 THEN FIRE=1:F=0:FX=SX-1:IF PD1=2 THEN FX=SX+10
175 IF ST=11 THEN PD1=1:SX=SX-8
180 IF ST=7 THEN PD1=2:SX=SX+8
185 IF SX<54 THEN SX=54
190 IF SX>186 THEN SX=186
195 A=USR(PMMOVE,1,ADR(SHAPE1$(PD1*26-25)),SIZE1,SX,SY)
200 IF FIRE=1 THEN 225
205 IF PD1=1 THEN FX=SX-1
210 IF PD1=2 THEN FX=SX+10
215 FOR PD2=1 TO 2:A=USR(PMMOVE,2,ADR(SHAPE2$(PD2*7-6)),SIZE2,FX,FY):NEXT PD2:GOTO 240
220 REM CAST FIREBALL
225 F=F+4:FY=FY-F:IF FY<0 THEN SOUND 1,0,0,0:POKE 53249,0:FY=SY-1:FIRE=0:GOTO 55
230 FOR PD2=1 TO 2:A=USR(PMMOVE,2,ADR(SHAPE2$(PD2*7-6)),SIZE2,FX,FY):NEXT PD2:SOUND 1,FX*FY,0,5
235 IF PEEK(53261)=4 THEN SOUND 1,0,0,0:POKE 53249,0:FY=SY-1:FIRE=0:GOSUB 250
240 POKE 711,72+INT(RND(0)*7)+1:POKE 53278,0:POKE 77,0:GOTO 55
245 REM DEMON HIT/DEMATERIALIZE IT
250 FOR SCREAM=INT(RND(0)*15)+5 TO 0 STEP -0.5:SOUND 0,SCREAM,SCREAM,SCREAM:NEXT SCREAM:PD3=3:POKE 706,14
255 A=USR(PMMOVE,3,ADR(SHAPE3$(PD3*14-13)),SIZE3,DX,DY):FOR D=1 TO 10:NEXT D
260 DX=DX-4:POKE 53258,3:A=USR(PMMOVE,3,ADR(SHAPE3$(PD3*14-13)),SIZE3,DX,DY)
265 FOR DEMAT=0 TO 15 STEP 0.4:POKE 706,15-DEMAT:SOUND 0,2,8,DEMAT:NEXT DEMAT:SOUND 0,0,0,0
270 POKE 53250,0:POKE 53258,1:DX=48+INT(RND(0)*145):DY=16+INT(RND(0)*51):DTX=48+INT(RND(0)*145)
275 DTY=16+INT(RND(0)*51):SC=SC+75:RETURN
280 REM SORCERER HIT BY ECTOPLASM
285 POKE 53251,0:FOR T=15 TO 0 STEP -1:FOR S=0 TO T:POKE 704,196-S:SOUND 0,S+T,6,T:NEXT S:NEXT T
290 MEN=MEN-1:IF MEN=0 THEN FOR C=15 TO 0 STEP -0.3:POKE 704,C:NEXT C:POKE 53248,0:POKE 53249,0:POP :GOTO 305
295 POKE 704,42:GOOP=0:POKE 53278,0:RETURN
300 REM GAME OVER
305 SOUND 1,0,0,0:FOR A=53248 TO 53251:POKE A,0:NEXT A:POKE 53277,0:? #6;"↰"
310 COLOR 216:PLOT 0,0:DRAWTO 19,0:DRAWTO 19,11:DRAWTO 0,11:DRAWTO 0,0
315 POSITION 5,2:? #6;"GAME OVER":POSITION 7,5:? #6;"SCORE":POSITION 7,7:? #6;SC
320 POKE 19,0:POKE 20,200
321 IF PEEK(19)<2 THEN 321
322 GOTO 1300
325 REM REDEFINE CHARACTER SET
330 CH=PEEK(740)-16:CH=CH*256
335 DIM MOVE$(46),CHX$(512)
340 MOVE$="hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆"
350 JUNK=USR(ADR(MOVE$),57344,CH,1024)
400 CHX$(1,64)="♥♥♥♥♥♥♥♥├▕╱▂↓↓;;♥fff♥♥♥♥♥@@◆x◀◀>♥◢♣♣┴▔▖╲♥♣◢◢┴0p◆├┘┘╲←◀◀↰♥@◆p88\\"
410 CHX$(65,128)="♠wwwwwww?__ov↰♠w▖im╲w♠z↓p┬7an__9↰♠♠wo?_o^nnooooowww▶▶xp◆wo^==↰↰◀"
420 CHX$(129,192)="♥◀fnvf◀♥♥┴xx┴┴◀♥♥|fL┴6◀♥♥◀N┴▘f>♥♥▘↑<l◀▘♥♥◀◆|╱f|♥♥|◆|ff◀♥♥◀f▘┴00♥"
430 CHX$(193,256)="♥<f<ff◀♥♥◀f◀╱▘8♥♥♥┴┴♥┴┴♥g♠▶▶▶▶▶▶g_▶▶▶▶▶▶ow♠==>>▶ooo▶▶→▖╲CCGG╲╲┘┘"
440 CHX$(257,320)="▶lhhssww♥x<ff◀g♥ggs♠mD@@♥◀fppf>♥♥xlffl|♥♥◀◆|◆f◀♥▶w♠♠♠↰↰◀♥◀f◆nf>♥"
450 CHX$(321,384)="▶o___?>◀♥◀┴<┴┴◀♥ggO_7*▕▕B▕┤♥♥@@♥♥p◆◆◆v◀♥♥cw▶kcw♥♥fv◀◀nv♥♥◀ffff◀♥"
455 CHX$(342,342)=CHR$(34)
460 CHX$(385,448)="♥◢┤,┴4<Z>>←↑<|nF♥|ff|lv♥♥◀◆◀╱f◀♥||x8<>wc♥ffff◀|♥♥ffff◀┴♥♥♣ 4┴,<Z"
470 CHX$(449,512)="↰↰↰♥___♥9]-♥←U[♥f[↑jf^5[↰┘▶↓k▶▶▶>@◀8W▶▶▶▶7┬┬OOooCCccaaAACA ♥├┘▕♥"
560 JUNK=USR(ADR(MOVE$),ADR(CHX$),CH,512)
570 RETURN
720 REM DRAW PLAYFIELD
725 POKE 708,52:POKE 709,6:POKE 710,40:POKE 711,72:POKE 712,32
730 FOR Y=0 TO 5:POSITION 1,Y:? #6;"XX  XX      XX  XX":NEXT Y:POSITION 0,6:? #6;"zXXzzXXzzzzzzXXzzXXz"
735 COLOR 217:PLOT 1,0:DRAWTO 2,1:PLOT 1,3:DRAWTO 2,4:DRAWTO 2,5:DRAWTO 1,6:PLOT 6,0:DRAWTO 5,1:DRAWTO 5,2
740 PLOT 6,4:DRAWTO 5,5:DRAWTO 6,6:PLOT 14,0:PLOT 13,2:DRAWTO 14,3:PLOT 13,5:DRAWTO 13,6:PLOT 17,0:PLOT 18,2
745 DRAWTO 17,3:DRAWTO 17,4:PLOT 18,6:COLOR 122:FOR Y=7 TO 11:PLOT 0,Y:DRAWTO 19,Y:NEXT Y
750 POSITION 7,0:? #6;"!#$%&'"
755 POSITION 7,1:? #6;"()*+,-"
760 POSITION 7,2:? #6;"./;<=>"
765 POSITION 7,3:? #6;"?@[\]^"
770 POSITION 7,4:? #6;"_BFHJK"
775 POSITION 7,5:? #6;" pQTw "
780 POSITION 7,6:? #6;"zYYYYz"
785 COLOR 121:FOR T=1 TO 40:X=INT(RND(0)*20):Y=7+INT(RND(0)*5):PLOT X,Y:NEXT T
790 COLOR 120:FOR T=1 TO 15:X=INT(RND(0)*20):Y=7+INT(RND(0)*5):PLOT X,Y:NEXT T
795 COLOR 32:PLOT 1,7:DRAWTO 0,7:DRAWTO 0,8:PLOT 0,11:DRAWTO 4,7:PLOT 1,11:DRAWTO 5,7:PLOT 14,7:DRAWTO 18,11
800 PLOT 15,7:DRAWTO 19,11:PLOT 18,7:DRAWTO 19,7:DRAWTO 19,8:RETURN
805 REM
810 REM
815 REM EVIL SORCERER
820 DIM SHAPE1$(52):SIZE1=26
830 SHAPE1$="╱▕FF00>>77//├├◣◣◣◣␛␛→→→→??◆@bb▘▘||lltt♥♥PPPPXXxxxx||"
835 REM FIREBALL
840 DIM SHAPE2$(14):SIZE2=7
845 SHAPE2$="♣T(F(T♣♥(T8T(♥"
850 REM DEMONIC SPIRIT
855 DIM SHAPE3$(42):SIZE3=14
860 SHAPE3$="┴<VV?wo-3>←←▘┤┴<jj|nw5L|xx0 B$├Z$♥C♥$Z├$B♥"
870 REM ECTOPLASM
875 DIM SHAPE4$(14):SIZE4=7
880 SHAPE4$="♣ 0┴,←▘◢┤(P4x0"
885 POKE 623,1:POKE 53256,1:POKE 53258,1:RETURN
890 REM P/M  SETUP
895 REM DEFINE PMMODE & GRMODE
900 REM BEFORE CALLING ROUTINE
905 REM
910 DIM PMMOVE$(202):PMMOVE=ADR(PMMOVE$)
915 MT=0
916 PAGCLR=ADR("hI▕p♣┐N"♥dNP├◆hhh)♥pth┐Lh┐Khh┐M)♥(*┌KHP♠fLhdMPt◆")
930 PMMOVE$(1,68)="hI┐p─▔♥┤"♥l♥┤P├◆hhh)♥pshhI▗♣▗hhhhhhhh◆┴I♥pr▔┤┤h┐Nh┐Mhh▔┐┤hh▔▕┤hh▔┘┤."
932 PMMOVE$(69,136)="┤┤-▕┤↓▶O◆┐0▕♣┐)♥▔┤┤%OI▕p↑%j┴i┘m┤┤┐L)♥┐K(┌KHP♠-┘┤┐K┴♣A%j┴i├┐L)♥┐K-┤┤p"
934 PMMOVE$(137,202)="▄"♥%K┴i♥┐K%Li♥┐Lhl┤┤Pm ♥┴┌KH@▶Py-┘┤I♥♣├◆eK┐K%Li♥┐L ♥L┐┤p◢1M┌KH┴♣s◆"
940 IF PMMODE=1 THEN PAGES=8:DMA=62:GOTO 955
945 IF PMMODE=2 THEN PAGES=4:DMA=46:GOTO 955
950 RETURN
955 POKE 54279,PEEK(106)-PAGES:POKE 106,PEEK(106)-PAGES:POKE 207,PMMODE
960 GRAPHICS GRMODE:POKE 756,CH/256
965 PMBASE=PEEK(106)*256:POKE 559,DMA:POKE 53277,3:X=USR(PAGCLR,PMBASE,PAGES)
970 REM P/M COLORS
975 POKE 704,42:POKE 705,14:POKE 706,88:POKE 707,218
980 RETURN
985 REM
1030 REM
1300 ? "↰":POKE 752,1:POSITION 14,10:? "   WANT TO   ":POSITION 15,11:? "PLAY AGAIN?":POSITION 18,12:? "(Y/N)"
1310 CLOSE #1:OPEN #1,4,0,"K:"
1320 GET #1,K:IF K=0 THEN 1310
1330 IF K=78 OR K=110 THEN GRAPHICS 0:END
1340 GOTO 35