How Nice For You, Dear
- Type
- Game
- Category
- Platform game (contest remake of Escape From Hell!)
- Author
- Gwen Lenker (from Escape From Hell! by Tony Barnes)
- Published in
- Antic, December 1988 (Vol. 7, No. 8), Disk Bonus: Challenge From Hell contest winner
- Year
- 1988
- Language
- Atari BASIC
- Requirements
- 48K RAM, Atari BASIC, joystick in port 1
- Tags
- antic, contest, platform, joystick, graphics-2, redefined-characters, humour, escape-from-hell, disk-bonus, 1988
- Related
- Escape From Hell!, Pencils, Shutdown, 1040 Terminator, Alpha Run, Black Box
About the program
Tony Barnes's Escape From Hell!, Antic's Game of the Month for June 1988, ended with a "Challenge From Hell": readers were invited to give the game new graphics and a new story. The winners were announced in the December 1988 issue. The grand prize went to Gwen Lenker of San Francisco, who had also won Antic's Rebound screen-design contest in August 1987. A REM in line 4 says she had "a little help" from her daughter, Caecile.
In How Nice For You, Dear you are a "hardcopy communications expediter" at Busywork International. You work your way up the company by answering phones, sharpening pencils, shutting down computers, playing games and trampling the potted plants. Your Mom has come to see what you actually do all day. She means well, but if she catches you, it costs you. The editors liked its graphics and sound effects, such as ringing phones and the punch of the time clock, and said every screen had its own character set and its own problems. The game appeared only on that month's disk, as HOWNICE.BAS, so there was no printed listing to type.
Typing it in
You need 48K, because the character set lives at page 152. Most of the listing is ordinary BASIC, but several lines are packed with control and inverse characters that are really machine code or shape data. Line 590 and line 9040 hold the colour-cycling wait-for-trigger routine. Lines 10001 and 10004 are the move and flip routines, lines 10006–10009 hold the character shapes and Mom's two poses, and each level's USR(MOV,...) line (8068, 8128 and so on) carries the shape of that level's item. Type {inv}…{/inv} with the inverse (Atari) key, {CTRL-X} by holding CTRL and pressing X, and {CTRL-,} with CTRL and the comma key. ESC-prefixed codes such as {UP}, {RIGHT}, {TAB}, {BACK S}, {CLEAR}, {INS LINE} and {INS CHAR} are typed by pressing ESC and then the key. One slip in these strings can crash the machine, so SAVE before you RUN. Line 10010's RESTORE 30000 is fine: Atari BASIC moves on to the next DATA line, 30150.
How to play
Press the button to clock in. You're the small figure, and Mom chases you, and she gets faster on the later levels. Move with the joystick and collect every item on the screen before the clock runs out. Each item scores 5 points plus a bonus for the time left. The launch pads throw you upwards, the shaky floor gives way after you've used it once, and arrows push you sideways. If you're stuck, press the button to start the level again at the cost of a life. START goes back to the title.
Each level you clear earns a promotion: Shift Lead, Quality Control, Supervisor, Branch Manager, Vice President and finally President. After each one, Mom has a gentle put-down ready, such as "How nice, dear, but what do you do?" or "Why do they call it the Maine Branch when it's in Ohio?" Make it to the top and you're offered "outplacement".
How it works
The engine is Barnes's original. GRAPHICS 2 uses a redefined character set at 38912 (page 152), and everything you see is a character drawn with COLOR and PLOT. LOCATE checks the cell under or beside each figure. Code 32 means fall, 26 is a launch pad, 175 is an item, 43 and 44 are the two stages of shaky floor, and 173 and 174 are the arrows. Lenker's changes are mostly in the data. The six offices in lines 8020–8325 set each level's item count (MAX), Mom's SPEED, the colours and the rank title, and redefine the item character. Mom moves a fraction of a cell each turn towards your column, and when she changes direction, MOV copies her left- or right-facing shape (from MOM$ or SET$) into her character. Instead of the original's hidden target score, a level is finished when you've collected MAX items. The bonus count, promotion screen and Mom's comment are in lines 540–595.
Variations to try
Take the contest's challenge yourself: redraw the offices in lines 8020–8325, give each level a new item shape, and write Mom some new lines.
Listing
1 REM ESCAPE FROM HELL
2 REM BY TONY BARNES
3 REM (c)1988, ANTIC PUBLISHING
4 REM "HOW NICE FOR YOU, DEAR" MODIFICATIONS BY GWEN LENKER (with a little help from her daughter, CAECILE)
10 GRAPHICS 18:POKE 756,152
12 DIM SET$(120),MOM$(24),RNK$(20),FN$(16)
20 GOSUB 10000:GOTO 9000
110 FOR T=1 TO 20 STEP 4:SOUND 0,40-T,8,T/2:NEXT T:SOUND 0,0,0,0:RETURN
120 FOR T=1 TO 3:FOR D=1 TO 8:SOUND 0,36-D,12,4:SOUND 1,35-D,12,4:NEXT D:NEXT T:SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
130 FOR T=8 TO 0 STEP -1:SOUND 0,20,10,T:SOUND 1,22,10,T:FOR D=1 TO 2:NEXT D:NEXT T:RETURN
140 FOR T=12 TO 32 STEP 2:SOUND 0,T,4,4:FOR D=1 TO 4:NEXT D:SOUND 0,0,0,0:NEXT T:RETURN
150 FOR T=16 TO 1 STEP -1:SOUND 0,80-T,8,T/2:NEXT T:SOUND 0,0,0,0:RETURN
160 SOUND 0,26,10,6:FOR T=1 TO 40:NEXT T:SOUND 0,0,0,0:RETURN
500 GOSUB 100+(SCR*10)
505 SC=SC+5+INT(TMR/100):POSITION 6,11:? #6;SC:BMB=BMB+1:IF BMB>=MAX THEN POP :GOTO 540
510 RETURN
520 POKE 752,1:POKE 709,12:POSITION (19-INT(LEN(RNK$)))/2,6:? #6;RNK$:RETURN
540 FOR T=INT(TMR/10) TO 0 STEP -1:SC=SC+1:POSITION 6,11:? #6;SC:IF T>=10 THEN POSITION 18,11:? #6;T;:GOTO 545
542 POSITION 18,11:? #6;T;" ";
545 SOUND 0,60,10,6:FOR D=1 TO 2:NEXT D:SOUND 0,0,0,0:NEXT T
550 GRAPHICS 1:POKE 710,96:POKE 712,96:POKE 708,12:POSITION 4,0:? #6;"PROMOTED TO:":GOSUB 520:GOTO 550+SCR
551 POSITION 0,14:? #6;CHR$(34);"HOW NICE, DEAR, BUT WHAT DO YOU {inv}do{/inv}?";CHR$(34):GOTO 570
552 POSITION 3,14:? #6;CHR$(34);"IF YOU DON'T CONTROL IT, WILL IT GET OUT OF HAND?";CHR$(34):GOTO 570
553 POSITION 0,14:? #6;CHR$(34);"YOU SHOULDN'T DRINK SO MUCH COFFEE, DEAR.";CHR$(34):GOTO 570
554 POSITION 1,14:? #6;CHR$(34);"WHY DO THEY CALL IT THE MAINE BRANCH WHEN IT'S IN OHIO?";CHR$(34):GOTO 570
555 POSITION 1,14:? #6;CHR$(34);"THAT'S NOT A VERY NICE THING TO BE PRESIDENT OF.";CHR$(34):GOTO 570
556 POSITION 1,14:? #6;CHR$(34);"IS THAT ALL THERE IS TO IT?";CHR$(34):GOTO 700
570 ? "{TAB}PRESS TRIGGER TO CONTINUE"
590 ZQ=USR(ADR("hhh{inv}*-{/inv}{CTRL-K}{inv}T{/inv}{CTRL-X}e{CTRL-T}{CTRL-J}{inv}{CTRL-M}{/inv}{CTRL-J}{inv}T{/inv}{INS LINE}{CTRL-R}{inv}P-{CTRL-D}{/inv}{CTRL-B}{inv}I{/inv}{CTRL-,}{inv}Pl{/inv}{CTRL-.}"),711):SCR=SCR+1
595 GRAPHICS 18:POKE 756,152:GOTO 8000
600 FOR ZQ=1 TO 15:SOUND 0,65-ZQ*2,8,2:SOUND 1,205-ZQ*2,10,ZQ
610 COLOR 134:IF ZQ/2=INT(ZQ/2) THEN COLOR 30
620 PLOT X1,Y1:NEXT ZQ:SOUND 0,0,0,0:SOUND 1,0,0,0:COLOR 31:PLOT X1,Y1
630 FOR ZQ=0 TO 15 STEP 3:COLOR (31-(ZQ/2=INT(ZQ/2))):SOUND 0,50-ZQ,8,ZQ:SOUND 1,180-ZQ,10,ZQ
635 ZQ1=USR(FLIPM,39160,39160,8)
640 PLOT X1,Y1:NEXT ZQ:SOUND 0,0,0,0
650 RETURN
700 RESTORE 705:FOR ZQ=1 TO 11:READ F,L:SOUND 0,F,10,8:FOR T=1 TO L*14:NEXT T:NEXT ZQ:SOUND 0,0,0,0
705 DATA 91,4,96,4,108,4,96,4,91,4,81,4,72,4,91,4,108,4,126,4,121,20
778 SET$=" ! ) PRESS TRIGGER FOR OUTPLACEMENT"
780 GRAPHICS 2:POKE 756,152:POKE 712,96:POKE 710,96:POKE 708,14:POSITION 6,5:? #6;"{inv}president{/inv}":X=1
781 POKE 752,1:POKE 656,2:POKE 657,2:? SET$(X,37);SET$(1,X);:IF X>36 THEN X=1
782 SOUND 0,2,8,4:SOUND 0,0,0,0:FOR D=1 TO 2:NEXT D
785 POKE 711,PEEK(20):IF STRIG(0)=0 THEN POKE 559,0:GRAPHICS 2:GOTO 20
790 POKE 77,0:X=X+1:GOTO 781
800 X=X2+SPEED*(X2<X1)-SPEED*(X2>X1):LOCATE X,Y2,Z:IF Z>128 AND Z<135 THEN SCR=1:GOSUB 600:GOTO 2000
801 IF INT(X2+0.5)>INT(X2P+0.5) THEN ZQ=USR(MOV,ADR(SET$)+48,38968,24)
802 IF INT(X2+0.5)<INT(X2P+0.5) THEN ZQ=USR(MOV,ADR(MOM$),38968,24)
803 X2P=X2
805 IF Z=32 OR (Z>134 AND Z<138) THEN 815
810 X=X2
815 F2=F2+1:IF F2=3 THEN F2=0:ZQ=USR(MOV,FONE+(RND(0)>0.66)*9,39120,8)
820 COLOR 32:PLOT X2,Y2:X2=X:COLOR 135+F2:PLOT X2,Y2:LOCATE X2,Y2+1,Z
825 IF Z=32 THEN COLOR 32:PLOT X2,Y2:Y2=Y2+1:COLOR 135:PLOT X2,Y2
830 IF Z=26 THEN 850
835 RETURN
850 I=Y2+1:COLOR 27:PLOT X2,I:FOR T=1 TO 20:SOUND 0,1,4,2:NEXT T
855 SOUND 0,60-Y2,10,4:LOCATE X2,Y2-1,Z:IF Z<>32 THEN 865
860 COLOR 32:PLOT X2,Y2:Y2=Y2-1:IF Y2=0 THEN 865
862 COLOR 136:PLOT X2,Y2:GOTO 855
865 FOR T=1 TO 20:SOUND 0,60-T,10,2:NEXT T:COLOR 26:PLOT X2,I:SOUND 0,0,0,0:RETURN
1000 POKE 77,0:TMR=TMR-1:POSITION 18,11:? #6;INT(TMR/10);
1001 IF TMR<100 THEN POSITION 18,11:? #6;INT(TMR/10);" ";:IF TMR<=0 THEN GOSUB 600:GOTO 2000
1002 IF PEEK(53279)=6 THEN 9000
1003 SUI=1:IF PEEK(644)=0 THEN SUI=0:FOR T=1 TO 20:SOUND 1,INT(RND(0)*40)+1,2,8:NEXT T:GOTO 2000
1005 GOSUB 800:ST=PEEK(632):IF ST>12 THEN 1040
1010 X=X1+(ST<8)-(ST>8):IF X<0 OR X>19 THEN 1050
1015 LOCATE X,Y1,Z:IF Z=32 THEN 1030
1017 IF Z=175 THEN GOSUB 500:GOTO 1030
1020 X=X1
1030 FRM=1-FRM:COLOR 32:PLOT X1,Y1:X1=X:COLOR (130+2*(ST>8))+FRM:PLOT X1,Y1
1035 SOUND 0,21,8,8:SOUND 0,0,0,0:GOTO 1050
1040 COLOR 134:PLOT X1,Y1
1050 LOCATE X1,Y1+1,Z:IF Z=32 THEN COLOR 32:PLOT X1,Y1:Y1=Y1+1:COLOR 129:PLOT X1,Y1
1055 IF Z=26 THEN 1100
1060 IF Z=175 THEN GOSUB 500:COLOR 32:PLOT X1,Y1+1
1065 IF Z>134 AND Z<138 THEN SCR=1:GOSUB 600:GOTO 2000
1070 IF Z=43 THEN COLOR 44:PLOT X1,Y1+1
1072 IF Z=44 THEN COLOR 32:PLOT X1,Y1+1
1075 IF Z=173 THEN ST=7:GOSUB 800:GOTO 1010
1077 IF Z=174 THEN ST=11:GOSUB 800:GOTO 1010
1090 GOTO 1000
1100 I=Y1+1:COLOR 27:PLOT X1,I:FOR D=1 TO 12:FOR T=1 TO 2:SOUND 0,32,10,8:SOUND 1,23,12,6:NEXT T
1101 ZQ=USR(FLIPM,39128,39128,8)
1102 SOUND 0,0,0,0:SOUND 1,0,0,0:NEXT D
1103 FOR T=124 TO 146 STEP 2:SOUND 0,T,10,4:SOUND 1,146-T,8,2-((T>128)*2):NEXT T:SOUND 1,0,0,0
1105 SOUND 0,116+Y1,10,Y1
1107 LOCATE X1,Y1-1,Z:IF Z<>32 THEN 1120
1110 COLOR 32:PLOT X1,Y1:Y1=Y1-1:IF Y1=0 THEN 1120
1115 COLOR 134:PLOT X1,Y1:GOTO 1105
1120 COLOR 26:PLOT X1,I:SOUND 0,0,0,0:GOTO 1000
1200 REM
2000 COLOR 32:PLOT X1,Y1:SOUND 1,225,10,8:FOR T=1 TO 8:NEXT T
2005 SOUND 1,0,0,0:FOR T=1 TO 20:NEXT T:MN=MN-1:IF MN<0 THEN 2025
2010 GOTO 8000
2025 ? #6;"{CLEAR}":Y1=1:DY=1:GOTO 9000
8000 POKE 559,0:? #6;"{CLEAR}":BMB=0
8002 IF MN>0 THEN FOR T=1 TO MN:POSITION 16+T,0:? #6;"{RIGHT}";:NEXT T
8005 POSITION 0,1:ON SCR GOSUB 8020,8080,8130,8180,8230,8280
8010 POKE 708,6:POKE 709,70:POKE 710,R2:POKE 711,12:POKE 712,178:POKE 559,34:IF SUI THEN TMR=501
8015 POSITION 0,11:? #6;"SCORE=";SC:POSITION 13,11:? #6;"TIME=";:COLOR 134:PLOT X1,Y1:GOTO 1000
8020 ? #6;"*********** ***";
8025 ? #6;"* {inv}/{/inv} {inv}/{/inv} * *";
8030 ? #6;"{inv}/{/inv} **** {CTRL-Z}**{inv}/{/inv} *";
8035 ? #6;"*** ** ** *";
8040 ? #6;"**{inv}/{/inv} **** * {inv}/{/inv}*{inv}/{/inv} {inv}/{/inv}*";
8045 ? #6;"*** {inv}/{/inv} * *** ****";
8050 ? #6;"*{inv}/{/inv} **{inv}/{/inv} * {inv}/{/inv}** *";
8055 ? #6;"*** *** * ** ** *";
8060 ? #6;"*{inv}/{/inv} {inv}/{/inv}*";
8065 ? #6;"****{CTRL-Z}******{CTRL-Z}***{CTRL-Z}****";
8066 SPEED=0.3
8067 MAX=14:X1=8:Y1=4:X2=1:Y2=3:R2=166:RNK$="{inv}shift lead{/inv}"
8068 ZQ=USR(MOV,ADR("{CTRL-,}{CTRL-,}{CTRL-,}{TAB}{CLEAR}{TAB}{TAB}{CTRL-,}"),39032,8):RETURN
8080 ? #6;"****** ******";
8085 ? #6;"* ** ** ** ** *";
8090 ? #6;"*{inv}/{/inv}+ {inv}/{/inv} {inv}/{/inv} +{inv}/{/inv}*";
8095 ? #6;"*++ **** **** ++*";
8100 ? #6;"*** + + ***";
8105 ? #6;"* +{inv}/{/inv} {inv}/{/inv}+ *";
8110 ? #6;"*{inv}/{/inv} {inv}/{/inv}*";
8115 ? #6;"* {inv}/{/inv}*+,++,+*{inv}/{/inv} *";
8120 ? #6;"* {inv}/{/inv} ***{inv}/{/inv} {inv}/{/inv}*** {inv}/{/inv} *";
8125 ? #6;"***{CTRL-Z}{CTRL-Z}* **{CTRL-Z}{CTRL-Z}** *{CTRL-Z}{CTRL-Z}***";
8126 SPEED=0.35
8127 MAX=14:X1=1:Y1=9:X2=10:Y2=1:R2=52:RNK$="{inv}quality control{/inv}"
8128 ZQ=USR(MOV,ADR("{CTRL-,}{CTRL-,}x{BACK S}z{CTRL-;}{CTRL-P}x"),39032,8):RETURN
8130 ? #6;"*** * * ***";
8135 ? #6;"**** **** ****";
8140 ? #6;"*{inv}/{/inv} ** {inv}/{/inv}*";
8145 ? #6;"****{inv}/{/inv} {inv}/{/inv}****";
8150 ? #6;"* {inv}/{/inv}** ** **{inv}/{/inv} *";
8155 ? #6;"* ** ** ** *";
8160 ? #6;"* ** ** ** *";
8165 ? #6;"* *** ** *** *";
8170 ? #6;"* {inv}/{/inv}*{inv}/{/inv} {inv}//{/inv} {inv}/{/inv}*{inv}/{/inv} *";
8175 ? #6;"*{CTRL-Z}***{CTRL-Z}**{CTRL-Z}**{CTRL-Z}**{CTRL-Z}***{CTRL-Z}*";
8176 SPEED=0.5
8177 MAX=12:X1=3:Y1=1:X2=16:Y2=1:R2=136:RNK$="{inv}supervisor{/inv}"
8178 ZQ=USR(MOV,ADR("{CTRL-,}{CTRL-O}{CTRL-M}{CTRL-I}{CTRL-O}{CTRL-X}0{CTRL-.}"),39032,8):RETURN
8180 ? #6;"* {inv}/{/inv} {inv}/{/inv} ***";
8185 ? #6;"** *** *** *";
8190 ? #6;"* {inv}/{/inv}** * * *";
8195 ? #6;"* **{inv}/{/inv} ++{inv}/{/inv}+ {inv}/{/inv} ** *";
8200 ? #6;"* {inv}/{/inv}** {inv}/{/inv}++{inv}/{/inv} * {inv}/{/inv}* *";
8205 ? #6;"* ** ++++ ** *";
8210 ? #6;"* ++{inv}/{/inv}+ *";
8215 ? #6;"*** {inv}/{/inv} **** {inv}/{/inv} *{inv}/{/inv}*";
8220 ? #6;"*{inv}/{/inv} * * * * *{inv}/{/inv}*";
8225 ? #6;"*****{CTRL-Z}*{CTRL-Z}* *{CTRL-Z}*{CTRL-Z}*****";
8226 SPEED=0.5
8227 MAX=15:X1=17:Y1=7:X2=1:Y2=1:R2=246:RNK$="{inv}branch manager{/inv}"
8228 ZQ=USR(MOV,ADR("{CTRL-,}{CTRL-,}{CTRL-,}{BACK S}^{BACK S}{LEFT}{LEFT}"),39032,8):RETURN
8230 ? #6;"*{inv}/{/inv} {inv}/{/inv} {inv}/{/inv} *";
8235 ? #6;"**{inv}/{/inv} ****** ** *";
8240 ? #6;" ** * ** *";
8245 ? #6;"*** ****{inv}/{/inv}* {inv}/{/inv}* *";
8250 ? #6;"* {CTRL-Z}+++ *{inv}/{/inv}* ** *";
8255 ? #6;"* **** *{CTRL-Z}** * * **{inv}/{/inv}*";
8260 ? #6;"* *{inv}/{/inv} {inv}/{/inv}* * {inv}/{/inv}* *";
8265 ? #6;"* *** *** *** ** *";
8270 ? #6;"* {inv}/{/inv} {inv}/{/inv} *";
8275 ? #6;"**{inv}---{/inv}{CTRL-Z}{CTRL-Z}{CTRL-Z}{inv}...{/inv}****{CTRL-Z}**{CTRL-Z}*";
8276 SPEED=0.75
8277 MAX=13:X1=6:Y1=2:X2=16:Y2=1:R2=100:RNK$="{inv}vice president{/inv}"
8278 ZQ=USR(MOV,ADR("{CTRL-,}{CTRL-,}<{CTRL-X}<${BACK S}{BACK S}"),39032,8):RETURN
8280 ? #6;"********************";
8285 ? #6;"* ** *";
8290 ? #6;"* *";
8295 ? #6;"***{inv}/{/inv}**{inv}/{/inv}** **{inv}/{/inv}**{inv}/{/inv}***";
8300 ? #6;"* * * *";
8305 ? #6;"*{inv}/{/inv} + +* *+ + {inv}/{/inv}*";
8310 ? #6;"****++++* *++++****";
8315 ? #6;"* + +* *+ + *";
8320 ? #6;"* {inv}/{/inv} {inv}/{/inv} {inv}/{/inv} {inv}/{/inv} *";
8325 ? #6;"*{inv}--------{/inv}{CTRL-Z}{CTRL-Z}{inv}........{/inv}*";
8326 SPEED=0.75
8327 MAX=10:X1=10:Y1=9:X2=3:Y2=2:R2=54:RNK$="{inv}president{/inv}"
8328 ZQ=USR(MOV,ADR("{CTRL-,}{CTRL-,}{BACK S}BB{BACK S}<{BACK S}"),39032,8):RETURN
9000 GRAPHICS 2:POKE 559,0:POKE 756,152:POKE 710,96:POKE 752,1:POKE 708,4:SUI=1:IF SC>HS THEN HS=SC
9001 POKE 709,10:? :? ,"BY TONY BARNES":IF SC<100 THEN ? "YOUR SCORE = ";SC,"HIGH SCORE = ";HS:GOTO 9006
9002 IF SC<1000 THEN ? "YOUR SCORE = ";SC;" HIGH SCORE = ";HS:GOTO 9006
9003 ? "YOUR SCORE = ";SC;" HIGH SCORE = ";HS
9006 ? #6;" {inv}how{/inv}"
9007 ? #6;" {inv}nice{/inv}"
9008 ? #6;" {inv}for{/inv}"
9009 ? #6;" {inv}you{/inv}"
9010 ? #6;" {CTRL-I} {inv}dear{/inv}"
9012 ? #6;" *** "
9014 ? #6;" *** {CTRL-A} "
9016 ? #6;" *** *** "
9018 ? #6;" *** *** "
9020 ? #6;" ****************"
9025 POKE 711,96:POKE 712,96:POKE 559,34
9030 RESTORE 9035:FOR T=1 TO 11:READ F,L:SOUND 0,F,10,8:FOR D=1 TO L*5:NEXT D:NEXT T:SOUND 0,0,0,0
9035 DATA 81,4,96,4,91,4,85,4,81,4,121,4,108,4,121,3,0,1,121,16,126,12
9039 ? " PRESS THE TRIGGER TO CLOCK IN";
9040 ZQ=USR(ADR("hhh{inv}*-{/inv}{CTRL-K}{inv}T{/inv}{CTRL-X}e{CTRL-T}{CTRL-J}{inv}{CTRL-M}{/inv}{CTRL-J}{inv}T{/inv}{INS LINE}{CTRL-R}{inv}P-{CTRL-D}{/inv}{CTRL-B}{inv}I{/inv}{CTRL-,}{inv}Pl{/inv}{CTRL-.}"),711):FOR T=15 TO 0 STEP -3:SOUND 0,26,8,T:SOUND 1,7,10,T:NEXT T
9050 FOR T=1 TO 60:NEXT T:GRAPHICS 18:POKE 756,152:SC=0:SCR=1:MN=3:GOTO 8000
10000 POKE 559,0:CHR=38912:I=256*224
10001 MOV=ADR("hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}"):REM FM,TO,KNT
10004 FLIPM=ADR("hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p"{/inv}{CTRL-H}{CTRL-X}{CTRL-J}f{inv}KJPy%K{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnP_Fo{/inv}{CTRL-P}{inv}[{/inv}{CTRL-.}")
10006 SET$(1,60)="{CTRL-X}{CTRL-X}B<{CTRL-X}{CTRL-X}$f{CTRL-X}{CTRL-X}{CTRL-,}<Z{CTRL-X}$6{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-P}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-H}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-,}<Z{CTRL-X}$l{CTRL-X}{CTRL-X}{CTRL-,}<Z{CTRL-X}$f00@0(p{inv}x{/inv}P{CTRL-X}{CTRL-X} {CTRL-X}"
10007 SET$(61,120)="{CTRL-T}8|{CTRL-P}{CTRL-L}{CTRL-L}{CTRL-P}{CTRL-L}{CTRL-J}{UP}>{CTRL-T}{CTRL-,}{TAB}{TAB}c{TAB}{TAB}{TAB}{TAB}{inv} {/inv}H{inv}4{/inv}( {inv}|{/inv}x0{CTRL-,}{CTRL-,}{CTRL-,}4*{inv}|{/inv}x2{INS CHAR}{inv}w{CTRL-C}{CTRL-A}{CTRL-C}w{/inv}{INS CHAR}{CTRL-,}{INS CHAR}{inv}oA{CTRL-A}Ao{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{TAB}{CLEAR}{TAB}{TAB}{CTRL-,}"
10008 FONE=ADR("{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}[{/inv}<n{BACK S}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}[{/inv}<v{BACK S}{CTRL-,}")
10009 MOM$="{CTRL-L}{CTRL-L}{CTRL-B}{CTRL-L}{CTRL-T}{CTRL-N}{RIGHT}{CTRL-J}{CTRL-X}{CTRL-X}{CTRL-D}{CTRL-X}({UP}>{CTRL-H}00{CTRL-H}0P8|("
10010 POKE 204,152:POKE 206,224:I=USR(MOV,I,CHR,512):RESTORE 30000:FLG=0
10018 ZQ=USR(MOV,ADR(SET$),38920,120)
10020 READ I:IF I=-1 THEN RETURN
10030 FOR Z=0 TO 7:READ T:POKE (CHR+I*8)+Z,T:NEXT Z
10040 GOTO 10020
30150 DATA 26,0,0,0,255,219,60,110,126
30160 DATA 27,0,30,118,192,216,60,110,126
30170 DATA 30,0,126,68,92,76,92,252,0
30175 DATA 31,0,63,34,46,38,46,126,0
30180 DATA -1
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: HOWNICE.BAS.
Credits
- Program listing: How Nice For You, Dear — program listing (Antic, December 1988 (Vol. 7, No. 8), Disk Bonus: Challenge From Hell contest winner) — Gwen Lenker (from Escape From Hell! by Tony Barnes)
- Picture: The first level, Shift Lead, a few seconds after clocking in. — Gwen Lenker (from Escape From Hell! by Tony Barnes) (program); screenshot by the site
- Antic magazine scan (OCR text layer), December 1988, pp. 6 and 29: Hell! Contest Winners, by Gregg Pearlman — James Hague; Internet Archive, 1988
- Antic Software Archive — December 1988 - Vol. 7 No. 8 disk (side B): HOWNICE.BAS — Gwen Lenker (from Escape From Hell! by Tony Barnes), 1988
