1040 Terminator
- Type
- Game
- Category
- Maze chase game
- Author
- Stephen Stout
- Published in
- Antic, April 1988 (Vol. 6, No. 12)
- Year
- 1988
- Language
- Atari BASIC
- Requirements
- 48K RAM, Atari BASIC, joystick in port 1
- Tags
- antic, maze, chase, joystick, graphics-1, redefined-characters, humour, atari-basic
About the program
Antic's April 1988 issue arrived in the middle of the US tax season, and Stephen Stout turned the new "simplified" tax laws into a maze game. Your discount tax adviser Ed is on the run from a tax-evasion charge, so you're doing your own return. Because you were his client, the IRS has sent its toughest field agent after you: the 1040 Terminator. He never gives up and, the rumour goes, never loses an audit. Collect every dollar sign in the maze to move on. Clear all five mazes and the Terminator is retired and you get a big (simulated) refund.
Stout lived in Everett, Washington. He also wrote Diamond Dave (Antic, August 1987) and the previous month's Adventure Creation Kit. 1040 Terminator is built on the same GRAPHICS 1 character engine as Diamond Dave.
Typing it in
You need 48K. Line 1760 is a machine-language memory-move routine in a string of inverse control characters. The magazine offered a second listing that wrote it to LINES.LST for merging, and the disk version here includes it. The five mazes (DATA lines 700–1720) look frightening, but as the article said, they use only five characters: & (a dollar sign once redefined), space, inverse # (wall), inverse CTRL-D and inverse CTRL-E (the turnstiles). In this notation {inv}…{/inv} means type with the Atari (inverse) key on, and {CTRL-D} means hold CTRL and press D. Each maze row must be exactly 20 characters. After each maze come three DATA lines: your start position and the number of dollars, then the Terminator's start position and direction.
How to play
Press the joystick button at the title screen. Steer your little face round the maze with the joystick and eat all the dollar signs. The Terminator (the small figure) runs about at random, changing direction whenever he bumps into something, and catching you costs one of your two lives.
The loopholes are turnstiles: a round pivot with two bars. Walk into a bar and the turnstile swings round to let you through. The Terminator can't use them, so a turnstile between you and him buys valuable time. As Stout warned, though, it's easy to swing one shut on yourself.
How it works
- Characters as the game world. Line 1780 copies the ROM font to page 144 with the string routine, and lines 1810–1890 redefine six characters: wall, turnstile pivot, turnstile bar, dollar, player and Terminator. The maze is printed as ordinary GRAPHICS 1 text.
- LOCATE for collisions. Every move (lines 30–40 for you, 190–280 for him) LOCATEs the target cell and only moves into a space, a dollar or the other character. Bumping a turnstile bar (code 133) is allowed. Lines 90–150 then redraw the turnstile turned 90 degrees, horizontal to vertical or the other way round, depending on which way you pushed.
- Random pursuit. The Terminator doesn't chase you. When blocked, he picks a random new direction at right angles, and turns back only if both sides are walls. He remembers the character he's standing on (
Z1) so that he doesn't eat the dollars. - Quick screen changes.
POKE 559,0blanks the display while a new maze is printed, andPOKE 559,34switches it back on, so each maze appears all at once.
Variations to try
- Give yourself more lives: change
LIVES=2in line 2010. - Design your own mazes by editing the DATA. Keep each row 20 characters wide and update the dollar count.
Changes from the published listing
One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds a command called MOVE, so it rejected the published lines that use that word as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.
| Published | Now | Lines |
|---|---|---|
MOVE$ |
MOVX$ |
1760, 1780 |
Listing
2 REM 1040 TERMINATOR
4 REM BY STEPHEN STOUT
6 REM (c)1988, ANTIC PUBLISHING
10 GOTO 1750
20 POKE 77,0:ST=STICK(0):IX=(ST=7)-(ST=11):IY=(ST=13)-(ST=14):IF IX=0 AND IY=0 THEN 190
30 LOCATE X+IX,Y+IY,Z
40 IF Z<>32 AND Z<>133 AND Z<>136 AND Z<>38 THEN 190
50 IF Z=133 THEN SOUND 0,150,12,15
60 IF Z=38 THEN SOUND 0,50,10,15:DOTS=DOTS-1
70 POSITION X,Y:? #6;" ":X=X+IX:Y=Y+IY:POSITION X,Y:? #6;"{CTRL-G}"
80 IF Z<>133 THEN 170
90 IF IY<>0 THEN 130
100 D=Y-1:LOCATE X,Y+1,Z:IF Z=132 THEN D=Y+1:POSITION X,D+1:? #6;" ":GOTO 120
110 POSITION X,D-1:? #6;" "
120 POSITION X-1,D:? #6;"{inv}{CTRL-E}{CTRL-D}{CTRL-E}{/inv}":GOTO 160
130 D=X-1:LOCATE X+1,Y,Z:IF Z=132 THEN D=X+1:POSITION D+1,Y:? #6;" ":GOTO 150
140 POSITION D-1,Y:? #6;" "
150 POSITION D,Y-1:? #6;"{inv}{CTRL-E}{/inv}":POSITION D,Y+1:? #6;"{inv}{CTRL-E}{/inv}"
160 SOUND 0,0,0,0:GOTO 190
170 SOUND 0,0,0,0:IF Z=8 THEN 350
180 IF DOTS=0 THEN 470
190 LOCATE X1+IX1,Y1+IY1,Z:IF Z=7 OR Z=32 OR Z=38 THEN 290
200 IF IX1=0 THEN 250
210 IY1=INT(RND(0)*2):IF IY1=0 THEN IY1=-1
220 LOCATE X1,Y1+IY1,Z:IF Z<>32 AND Z<>7 AND Z<>38 THEN IY1=-IY1
230 LOCATE X1,Y1+IY1,Z:IF Z<>32 AND Z<>7 AND Z<>38 THEN IY1=0:IX1=-IX1:GOTO 330
240 IX1=0:GOTO 290
250 IX1=INT(RND(0)*2):IF IX1=0 THEN IX1=-1
260 LOCATE X1+IX1,Y1,Z:IF Z<>32 AND Z<>7 AND Z<>38 THEN IX1=-IX1
270 LOCATE X1+IX1,Y1,Z:IF Z<>32 AND Z<>7 AND Z<>38 THEN IX1=0:IY1=-IY1:GOTO 290
280 IY1=0:GOTO 290
290 LOCATE X1,Y1,Z2:IF Z2=133 THEN Z1=Z2
300 POSITION X1,Y1:? #6;CHR$(Z1)
310 X1=X1+IX1:Y1=Y1+IY1:LOCATE X1,Y1,Z1:POSITION X1,Y1:? #6;"{CTRL-H}"
320 SOUND 0,0,12,15:SOUND 0,0,0,0
330 IF Z=7 THEN 350
340 GOTO 20
350 LIVES=LIVES-1:POSITION 18,0:? #6;LIVES
360 FOR I=15 TO 0 STEP -1:SOUND 0,0,0,I:SOUND 1,0,0,0
370 POSITION X,Y:? #6;"{CTRL-G}":FOR D=1 TO 15:NEXT D:SOUND 1,200,12,I
380 POSITION X,Y:? #6;"{CTRL-H}":FOR D=1 TO 15:NEXT D:NEXT I:SOUND 0,0,0,0:SOUND 1,0,0,0
390 IF Z1=7 THEN Z1=32
400 IF Z2=7 THEN Z2=32
410 IF LIVES=0 THEN 430
420 X=OX:Y=OY:POSITION X,Y:? #6;"{CTRL-G}":GOTO 20
430 POSITION 0,1:? #6;"you lose hit trigger"
440 FOR I=10 TO 250 STEP 2:SOUND 0,I,10,10:NEXT I:SOUND 0,0,0,0
450 POKE 77,0:IF STRIG(0)=1 THEN 450
460 RUN
470 FOR D=1 TO 250:NEXT D
480 IF SCREEN=5 THEN 510
490 SCREEN=SCREEN+1
500 GOTO 540
510 POSITION 0,1:? #6;"you win{CTRL-A} hit trigger"
520 FOR I=250 TO 10 STEP -2:SOUND 0,I,10,10:NEXT I:SOUND 0,0,0,0
530 GOTO 450
540 POKE 559,0:POSITION 0,0:? #6;"{CLEAR}"
550 POSITION 0,0:? #6;" SCREEN:";SCREEN;" LIVES:";LIVES
560 FOR I=2 TO 22:READ SC$:POSITION 0,I:? #6;SC$:NEXT I
570 READ OX,OY:X=OX:Y=OY:POSITION X,Y:? #6;"{CTRL-G}":READ DOTS
580 READ X1,Y1,IX1,IY1:LOCATE X1,Y1,Z1:POSITION X1,Y1:? #6;"{inv}{CTRL-H}{/inv}"
590 POKE 559,34:GOTO 20
600 DATA {inv}####################{/inv}
610 DATA {inv}#{/inv}&&&&& &&&&&& &&&&&{inv}#{/inv}
620 DATA {inv}#{/inv}&{inv}###{CTRL-E}{CTRL-D}{CTRL-E}####{CTRL-E}{CTRL-D}{CTRL-E}###{/inv}&{inv}#{/inv}
630 DATA {inv}#{/inv}&{inv}{CTRL-E}{/inv}&&& &&&&&& &&&{inv}{CTRL-E}{/inv}&{inv}#{/inv}
640 DATA {inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}############{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}
650 DATA {inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&&&&&& &&&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}
660 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}####{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&{inv}#{/inv}
670 DATA {inv}#{/inv}&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&&&& &{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&{inv}#{/inv}
680 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&{inv}####{/inv}&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&{inv}#{/inv}
690 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}####{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
700 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}& {inv}##{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
710 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}####{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
720 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&{inv}####{/inv}&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&{inv}#{/inv}
730 DATA {inv}#{/inv}&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}& &&&&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&{inv}#{/inv}
740 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}####{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&{inv}#{/inv}
750 DATA {inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}&&& &&&&&&{inv}#{/inv}&{inv}{CTRL-E}{/inv}&{inv}#{/inv}
760 DATA {inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}############{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}
770 DATA {inv}#{/inv}&{inv}{CTRL-E}{/inv}&&& &&&&&& &&&{inv}{CTRL-E}{/inv}&{inv}#{/inv}
780 DATA {inv}#{/inv}&{inv}###{CTRL-E}{CTRL-D}{CTRL-E}####{CTRL-E}{CTRL-D}{CTRL-E}###{/inv}&{inv}#{/inv}
790 DATA {inv}#{/inv}&&&&& &&&&&& &&&&&{inv}#{/inv}
800 DATA {inv}####################{/inv}
810 DATA 9,12,156
820 DATA 3,5,0,1
830 DATA {inv}####################{/inv}
840 DATA {inv}#{/inv}&&&&&&&&&&&&&&&&&&{inv}#{/inv}
850 DATA {inv}#{/inv}&{inv}#########{/inv}&{inv}#{/inv}&{inv}######{/inv}
860 DATA {inv}#{/inv}&&&&&&&&&&&{inv}{CTRL-E}{/inv}&&&&&&{inv}#{/inv}
870 DATA {inv}###########{/inv} {inv}{CTRL-D}{/inv} {inv}####{/inv}&{inv}#{/inv}
880 DATA {inv}#{/inv}&&&&&&&&&&&{inv}{CTRL-E}{/inv}&&&&&&{inv}#{/inv}
890 DATA {inv}#{/inv}&{inv}###{/inv}&{inv}#{/inv}&{inv}###{/inv}&{inv}#{/inv}&{inv}######{/inv}
900 DATA {inv}#{/inv}&&&&&{inv}{CTRL-E}{/inv}&&&&&&&&&&&&{inv}#{/inv}
910 DATA {inv}#####{/inv} {inv}{CTRL-D}{/inv} {inv}##########{/inv}&{inv}#{/inv}
920 DATA {inv}#{/inv}&&&&&{inv}{CTRL-E}{/inv}&&&&&&&&&&&&{inv}#{/inv}
930 DATA {inv}#{/inv}&{inv}###{/inv}&{inv}#{/inv}&{inv}###{/inv}&{inv}#{/inv}&{inv}######{/inv}
940 DATA {inv}#{/inv}&&&&&&&&&&&{inv}{CTRL-E}{/inv}&&&&&&{inv}#{/inv}
950 DATA {inv}###########{/inv} {inv}{CTRL-D}{/inv} {inv}####{/inv}&{inv}#{/inv}
960 DATA {inv}#{/inv}&&&&&&&&&&&{inv}{CTRL-E}{/inv}&&&&&&{inv}#{/inv}
970 DATA {inv}#{/inv}&{inv}###{/inv}&{inv}#{/inv}&{inv}###{/inv}&{inv}#{/inv}&{inv}######{/inv}
980 DATA {inv}#{/inv}&&&&&{inv}{CTRL-E}{/inv}&&&&&&&&&&&&{inv}#{/inv}
990 DATA {inv}#####{/inv} {inv}{CTRL-D}{/inv} {inv}##########{/inv}&{inv}#{/inv}
1000 DATA {inv}#{/inv}&&&&&{inv}{CTRL-E}{/inv}&&&&&&&&&&&&{inv}#{/inv}
1010 DATA {inv}##{/inv} {inv}##{/inv}&{inv}#{/inv}&{inv}##########{/inv}&{inv}#{/inv}
1020 DATA {inv}##{/inv} {inv}##{/inv}&&&&&&&&&&&&&&{inv}#{/inv}
1030 DATA {inv}####################{/inv}
1040 DATA 2,21,193
1050 DATA 18,3,-1,0
1060 DATA {inv}####################{/inv}
1070 DATA {inv}#{/inv}&&&&&{inv}#{/inv}&&&{inv}##{/inv}&&&{inv}#{/inv}&&&{inv}#{/inv}
1080 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1090 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}##{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1100 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1110 DATA {inv}#{/inv}&{inv}#{/inv}&&& &&&{inv}##{/inv}& &&&{inv}#{/inv}&{inv}#{/inv}
1120 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1130 DATA {inv}#{/inv}&{inv}#{/inv}&&& &{inv}##{/inv}&&& &&&{inv}#{/inv}&{inv}#{/inv}
1140 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1150 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}##{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1160 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1170 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}##{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1180 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}
1190 DATA {inv}#{/inv}&&& &&&&&{inv}##{/inv}&&& &&&{inv}#{/inv}
1200 DATA {inv}#{/inv}&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&{inv}#{/inv}
1210 DATA {inv}#{/inv}&&& &&&{inv}##{/inv}&&&&& &&&{inv}#{/inv}
1220 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}###{/inv}
1230 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}##{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}###{/inv}
1240 DATA {inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}&&{inv}#{/inv}&{inv}#{/inv}&{inv}#{/inv}& {inv}#{/inv}
1250 DATA {inv}#{/inv}&&&{inv}#{/inv}&&&{inv}##{/inv}&&&{inv}#{/inv}&&&{inv}###{/inv}
1260 DATA {inv}####################{/inv}
1270 DATA 18,20,193
1280 DATA 1,3,0,1
1290 DATA {inv}####################{/inv}
1300 DATA {inv}#{/inv}&&&&&&&&{inv}##{/inv}&&&&&&&&{inv}#{/inv}
1310 DATA {inv}#{/inv}&&&{inv}#{/inv}&&&&&&&&&&{inv}#{/inv}&&&{inv}#{/inv}
1320 DATA {inv}#{/inv}&&& &&&&&&&&&&{inv}{CTRL-E}{/inv}&&&{inv}#{/inv}
1330 DATA {inv}#{/inv}&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&&&&&&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&{inv}#{/inv}
1340 DATA {inv}#{/inv}&&& &&&&&&&&&&{inv}{CTRL-E}{/inv}&&&{inv}#{/inv}
1350 DATA {inv}#{/inv}&&&{inv}#{/inv}&&&&&&&&&&{inv}#{/inv}&&&{inv}#{/inv}
1360 DATA {inv}#{/inv}&&&&&&{inv}#{/inv}&&&&{inv}#{/inv}&&&&&&{inv}#{/inv}
1370 DATA {inv}##{/inv}&&&&&&&&&&{inv}#{/inv}&&&&&&{inv}#{/inv}
1380 DATA {inv}#{/inv}&&&&&&{inv}##{/inv}&&&{inv}#{/inv}&&&&&&{inv}#{/inv}
1390 DATA {inv}#{/inv}&{inv}#{/inv}&&&&&&&&&&&&&&{inv}#{/inv}&{inv}#{/inv}
1400 DATA {inv}#{/inv}&&&&&&{inv}#{/inv}&& {inv}##{/inv}&&&&&&{inv}#{/inv}
1410 DATA {inv}#{/inv}&&&&&&{inv}#{/inv}&&&&&&&&&&{inv}##{/inv}
1420 DATA {inv}#{/inv}&&&&&&{inv}#{/inv}&&&&{inv}#{/inv}&&&&&&{inv}#{/inv}
1430 DATA {inv}#{/inv}&&&{inv}#{/inv}&&&&&&&&&&{inv}#{/inv}&&&{inv}#{/inv}
1440 DATA {inv}#{/inv}&&&{inv}{CTRL-E}{/inv}&&&&&&&&&& &&&{inv}#{/inv}
1450 DATA {inv}#{/inv}&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&&&&&&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&{inv}#{/inv}
1460 DATA {inv}#{/inv}&&&{inv}{CTRL-E}{/inv}&&&&&&&&&& &&&{inv}#{/inv}
1470 DATA {inv}#{/inv}&&&{inv}#{/inv}&&&&&&&&&&{inv}#{/inv}&&&{inv}#{/inv}
1480 DATA {inv}#{/inv}&&&&&&&&{inv}##{/inv}&&&&&&&&{inv}#{/inv}
1490 DATA {inv}####################{/inv}
1500 DATA 10,13,285
1510 DATA 1,21,0,-1
1520 DATA {inv}####################{/inv}
1530 DATA {inv}###{/inv}&&&&&&&&&&&&&&{inv}###{/inv}
1540 DATA {inv}##{/inv}&&{inv}#{/inv}&&&&&&&&&&{inv}#{/inv}&&{inv}##{/inv}
1550 DATA {inv}#{/inv}&&&{inv}{CTRL-E}{/inv}&&&&&&&&&& &&&{inv}#{/inv}
1560 DATA {inv}#{/inv}&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&&&&&&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&{inv}#{/inv}
1570 DATA {inv}#{/inv}&&&{inv}{CTRL-E}{/inv}&&&&&&&&&& &&&{inv}#{/inv}
1580 DATA {inv}#{/inv}&&&{inv}#{/inv}&&{inv}#{/inv}&&&&{inv}#{/inv}&&{inv}#{/inv}&&&{inv}#{/inv}
1590 DATA {inv}#{/inv}&&&&&& &&&&{inv}{CTRL-E}{/inv}&&&&&&{inv}#{/inv}
1600 DATA {inv}#{/inv}&&&&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}##{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&&&&{inv}#{/inv}
1610 DATA {inv}#{/inv}&&&&&& &&&&{inv}{CTRL-E}{/inv}&&&&&&{inv}#{/inv}
1620 DATA {inv}#{/inv}&&&&&&{inv}#{/inv}&&&&{inv}#{/inv}&&&&&&{inv}#{/inv}
1630 DATA {inv}#{/inv}&&&&&&{inv}{CTRL-E}{/inv}&&&& &&&&&&{inv}#{/inv}
1640 DATA {inv}#{/inv}&&&&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}##{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&&&&{inv}#{/inv}
1650 DATA {inv}#{/inv}&&&&&&{inv}{CTRL-E}{/inv}&&&& &&&&&&{inv}#{/inv}
1660 DATA {inv}#{/inv}&&&{inv}#{/inv}&&{inv}#{/inv}&&&&{inv}#{/inv}&&{inv}#{/inv}&&&{inv}#{/inv}
1670 DATA {inv}#{/inv}&&& &&&&&&&&&&{inv}{CTRL-E}{/inv}&&&{inv}#{/inv}
1680 DATA {inv}#{/inv}&{inv}#{CTRL-E}{CTRL-D}{CTRL-E}#{/inv}&&&&&&{inv}#{/inv} {inv}{CTRL-D}{/inv} {inv}#{/inv}&{inv}#{/inv}
1690 DATA {inv}#{/inv}&&& &&&&&&&&&&{inv}{CTRL-E}{/inv}&&&{inv}#{/inv}
1700 DATA {inv}##{/inv}&&{inv}#{/inv}&&&&&&&&&&{inv}#{/inv}&&{inv}##{/inv}
1710 DATA {inv}###{/inv}&&&&&&&&&&&&&&{inv}###{/inv}
1720 DATA {inv}####################{/inv}
1730 DATA 17,20,259
1740 DATA 3,3,1,0
1750 GRAPHICS 0:POKE 559,0:POKE 16,64:POKE 53774,64
1760 DIM MOVX$(56):MOVX$="hh{inv}{CTRL-E}{/inv}{CTRL-B}h{inv}{CTRL-E}{/inv}{CTRL-A}h{inv}{CTRL-E}{/inv}{CTRL-D}h{inv}{CTRL-E}{/inv}{CTRL-C}h{inv}{CTRL-E}{/inv}{CTRL-F}h{inv}{CTRL-E}{/inv}{CTRL-E}{inv} {/inv}{CTRL-,}{inv}p{/inv}{CTRL-P}{inv}1{/inv}{CTRL-A}{inv}{CTRL-Q}{/inv}{CTRL-C}{inv}f{/inv}{CTRL-A}{inv}P{/inv}{CTRL-B}{inv}f{/inv}{CTRL-B}{inv}f{/inv}{CTRL-C}{inv}P{/inv}{CTRL-B}{inv}f{/inv}{CTRL-D}{inv}F{/inv}{CTRL-E}{inv}%{/inv}{CTRL-E}{inv}I{/inv}{INS CHAR}{inv}PhF{/inv}{CTRL-F}{inv}%{/inv}{CTRL-F}{inv}I{/inv}{INS CHAR}{inv}P{CTRL-.}{/inv}{CTRL-.}"
1770 CHSET=144*256
1780 ML=USR(ADR(MOVX$),57344,CHSET,1024)
1790 RESTORE 1830
1800 GOTO 1820
1810 FOR I=0 TO 7:READ D:POKE CHSET+A*8+I,D:NEXT I
1820 READ A:IF A<>-1 THEN GOTO 1810
1830 DATA 3,255,129,189,189,189,189,129,255
1840 DATA 4,60,102,195,153,153,195,102,60
1850 DATA 5,126,255,255,255,255,255,255,126
1860 DATA 6,24,62,96,60,6,124,24,0
1870 DATA 7,60,126,219,255,102,60,36,102
1880 DATA 8,56,56,16,124,186,186,40,40
1890 DATA -1
1900 DIM SC$(20)
1910 GRAPHICS 1+16:POKE 559,0:POKE 16,64:POKE 53774,64
1920 POKE 708,8:POKE 709,196
1930 POSITION 3,0:? #6;"{inv}antic magazine{/inv}":POSITION 6,1:? #6;"{inv}presents{/inv}"
1940 D=PEEK(560)+PEEK(561)*256+4:POKE D+6,7:POKE D+8,7
1950 POSITION 2,5:? #6;"1040 TERMINATOR":POSITION 2,7:? #6;"{inv}BY STEPHEN STOUT{/inv}"
1960 POSITION 2,20:? #6;"trigger to begin"
1970 POKE 559,34
1980 POKE 77,0:IF STRIG(0)<>0 THEN 1980
1990 GRAPHICS 1+16:POKE 16,64:POKE 53774,64
2000 POKE 711,40:POKE 710,116:POKE 708,198:POKE 709,10
2010 POKE 756,CHSET/256:RESTORE 600:SCREEN=1:LIVES=2
2020 GOTO 540
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: TERMINAT.BAS.
Credits
- Program listing: 1040 Terminator — program listing (Antic, April 1988 (Vol. 6, No. 12)) — Stephen Stout
- Picture: Screen 1: the dollars fill the rings, and the orange turnstiles are the loopholes the Terminator can't pass. — Stephen Stout (program); screenshot by the site
- Antic Software Archive — April 1988 - Vol. 6 No. 12 disk: TERMINAT.BAS — Stephen Stout, 1988
- Antic magazine scan (OCR text layer): Antic_Vol_6-12_1988-04_Desktop_Video_Atari_text.pdf — Internet Archive
