Shutdown

Type
Game
Category
Platform game
Author
Tony Barnes
Published in
Antic, April 1989 (Vol. 7, No. 12)
Year
1989
Language
Atari BASIC
Requirements
48K RAM, Atari BASIC, joystick in port 1; disk or cassette
Blue lattice girders on a black background with grey plug-shaped generators, coloured lift blocks set into the girders, a green robot on a platform and the green figure of Jake on the floor; SCORE 0 and MEN 2 at the bottom

About the program

Mechanical aliens have taken over all seven power stations on the planet Xena 5. You're Jake Retron, an elite trooper of the Galactic Marine Corps, and your job is to go into each station and shut it down. The robots can detect metal, so you go in without weapons. The only way between platforms is the lifts, and the aliens have reprogrammed them, so you're never quite sure where one will take you.

Shutdown was the Game of the Month in Antic's April 1989 issue. It was Tony Barnes' second Antic game, after Escape From Hell (June 1988), and he followed it two months later with Doomed. Each station is one GRAPHICS 2 screen of girders drawn with redefined characters.

What you need

An Atari 8-bit with at least 48K, a joystick and Atari BASIC. The listing here also runs under the Altirra BASIC replacement used by many emulators (see Changes from the published listing).

Typing it in

Line 8 says do not renumber: the levels are reached with ON SCR GOSUB and the music with a computed RESTORE. The magazine marked lines 21010–21012 (the display-list interrupt), 23010–23012 (two machine-code routines) and 30100–30140 (the character shapes in RDC$) as hard to type, and offered a second listing that wrote them to LINES.LST for merging. The disk listing here is complete and has no TYPO II codes.

The station maps (lines 4100–4510) are mostly ordinary characters. @ is girder, / marks the gaps that lifts travel through (step into one and you fall), and inverse ., ,, - and + are the four kinds of lift. {CTRL-TAB}, the generator, is typed as ESC then CTRL-TAB, as the REM in line 4099 reminds you. Each map line must be exactly 20 characters. {inv}…{/inv} is inverse (Atari key), and {CTRL-x} is CTRL plus the key.

How to play

Press the joystick button at the title screen. Walk Jake left and right with the stick; the button and up/down do nothing.

  • Touch a generator to switch it off (5 points). When the last one in a station is off, the lights go down and you move on to the next station, with a bonus.
  • Robots patrol the girders, turning back at walls and edges. Touch one and you lose a man.
  • Lifts: step onto one and it carries you up, down, left or right until it hits something.
  • Don't walk off the edge of a girder.
  • If you're trapped, press START to restart the station, at the cost of a life.

You start with three men. Clear all seven stations for an extra man and another round.

How it works

  • Collision by LOCATE. Each step, line 1010 LOCATEs the square ahead (code 158 is a generator) and line 1020 the square below: a space means a fall. The kind of lift (codes 171–174) picks one of four movement loops in lines 1100–1280, each of which calls the robot routine as it goes, so the robots keep moving during the ride.
  • Three robots, one routine. Line 200 moves only one robot per call, taking turns through X(), Y() and D(). That keeps the BASIC loop fast enough for all three.
  • Colour bands. Lines 20000–20040 set the interrupt bit on four display-list lines, and DLI$ changes the colours there, so each band of girders has its own colour scheme. The generator colour also changes as you switch them off (line 1060).
  • Redefined characters. CH$ copies the ROM font to 38912, and MOV$ then moves the custom shapes from RDC$ into four ranges of the set (lines 23015–23030).

Variations to try

  • Add stations: copy the pattern of lines 4100–4155 (ten 20-character rows, then MAX, Jake's start position and the robots' start positions) extend the ON SCR GOSUB in line 4020, and raise the SCR=8 test in lines 2130 and 3085.
  • Start with more men: change MN=3 in line 10110.

Changes from the published listing

One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds a command called MOVE, so it rejected the published lines that use that word as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.

Published Now Lines
MOVE MOVX 23012, 23020, 23030

Listing

2 REM SHUTDOWN
4 REM BY TONY BARNES
6 REM (c)1988, ANTIC PUBLISHING INC.
8 REM (DO NOT RENUMBER THIS PROGRAM!)
10 GRAPHICS 18:POKE 559,0:GOSUB 21000:GOSUB 20000:POKE 756,152:GOSUB 23000
20 DIM A$(20),X(2),Y(2),D(2)
25 FOR T=0 TO 2:X(T)=0:Y(T)=0:D(T)=1:NEXT T
30 GOTO 10000
100 FOR X=10 TO 2 STEP -0.5:POSITION X-1,TY:? #6;A$(X,X);:POKE 708,PEEK(20)
110 POSITION 20-X,TY:? #6;A$(21-X,21-X):SOUND 0,42,6,X:SOUND 1,X,0,X
115 NEXT X:SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
120 FOR X=2 TO 10:POSITION X-1,TY:? #6;" )";:POSITION 19-X,TY
130 ? #6;") ";:POKE 708,PEEK(20):SOUND 0,42,6,X:SOUND 1,X,0,X
135 NEXT X:SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
200 EN=EN+1:IF EN>2 THEN EN=0
205 COLOR 32:PLOT X(EN),Y(EN):X=X(EN)+D(EN):LOCATE X,Y(EN),Z
210 IF Z>0 AND Z<8 THEN 2000
215 IF Z<>32 THEN X=X(EN):D(EN)=-D(EN):COLOR 27:PLOT X,Y(EN):RETURN
220 LOCATE X,Y(EN)+1,Z:IF Z=32 OR Z=47 THEN X=X(EN):D(EN)=-D(EN):COLOR 27:PLOT X,Y(EN):RETURN
225 COLOR 8+2*(D(EN)=-1):X(EN)=X:PLOT X(EN),Y(EN):RETURN
1000 ST=PEEK(632):POKE 77,0:GOSUB 200:IF PEEK(53279)<>7 THEN 2000
1002 IF ST>11 THEN COLOR 7:PLOT X1,Y1:X=X1:GOTO 1020
1005 COLOR 32:PLOT X1,Y1:X=X1+(ST<8)*(X1<19)-(ST>8)*(X1>0)
1010 LOCATE X,Y1,Z:IF Z=158 THEN 1050
1015 IF Z<>32 THEN X=X1
1020 LOCATE X,Y1+1,Z:IF Z=32 OR Z=47 THEN 2000
1025 IF Z>170 AND Z<175 THEN 1100
1027 IF ST>12 THEN 1000
1030 WL=WL+1:IF WL>3 THEN WL=0
1035 X1=X:SOUND 3,100,8,6:IF ST<8 THEN COLOR 1+WL-2*(WL=3):PLOT X1,Y1
1040 IF ST>8 THEN COLOR 4+WL-2*(WL=3):PLOT X1,Y1
1045 SOUND 3,0,0,0:GOTO 1000
1050 FOR T=15 TO 0 STEP -3:SOUND 0,50,10,T:SOUND 1,T+INT(RND(0)*10),10,T
1055 NEXT T:COLOR 159:PLOT X,Y1:SC=SC+5:POSITION 5,11:? #6;SC
1060 MAX=MAX-1:POKE 708,112+(MAX*2):IF MAX<0 THEN 2100
1065 GOTO 1000
1100 X1=X:SOUND 0,47,2,4:SOUND 1,162,10,4:IF Z<>173 THEN 1150
1105 LOCATE X1,Y1-1,Z:IF Z=47 THEN 1120
1110 COLOR 32:PLOT X1,Y1+1:Y1=Y1-1:COLOR 7:PLOT X1,Y1:COLOR 173
1115 PLOT X1,Y1+1:GOSUB 200:GOTO 1105
1120 Y1=Y1-1:COLOR 32:PLOT X1,Y1+1:PLOT X1,Y1+2:Y1=Y1-1:COLOR 7
1125 PLOT X1,Y1:COLOR 186:PLOT X1,Y1+1:FOR T=4 TO 0 STEP -0.3
1130 SOUND 0,47,2,T:SOUND 1,162,10,T:NEXT T:X=X1:GOTO 1000
1150 IF Z<>174 THEN 1200
1155 LOCATE X1,Y1+2,Z:IF Z=47 THEN 1170
1160 COLOR 32:PLOT X1,Y1:Y1=Y1+1:COLOR 7:PLOT X1,Y1:COLOR 174
1165 PLOT X1,Y1+1:GOSUB 200:GOTO 1155
1170 COLOR 32:PLOT X1,Y1:Y1=Y1+1:COLOR 7:PLOT X1,Y1:COLOR 186
1175 PLOT X1,Y1+1:FOR T=4 TO 0 STEP -0.3:SOUND 0,47,2,T:SOUND 1,162,10,T
1180 NEXT T:X=X1:GOTO 1000
1200 IF Z<>171 THEN 1250
1205 LOCATE X1-1,Y1+1,Z:IF Z=47 THEN 1220
1210 COLOR 32:PLOT X1,Y1:PLOT X1,Y1+1:X1=X1-1:COLOR 7:PLOT X1,Y1:COLOR 171
1215 PLOT X1,Y1+1:GOSUB 200:GOTO 1205
1220 COLOR 32:PLOT X1,Y1:PLOT X1,Y1+1:X1=X1-1:COLOR 7:PLOT X1,Y1:COLOR 186
1225 PLOT X1,Y1+1:FOR T=4 TO 0 STEP -0.3:SOUND 0,47,2,T:SOUND 1,162,10,T
1230 NEXT T:X=X1:GOTO 1000
1250 LOCATE X1+1,Y1+1,Z:IF Z=47 THEN 1270
1255 COLOR 32:PLOT X1,Y1:PLOT X1,Y1+1:X1=X1+1:COLOR 7:PLOT X1,Y1:COLOR 172
1260 PLOT X1,Y1+1:GOSUB 200:GOTO 1250
1270 COLOR 32:PLOT X1,Y1:PLOT X1,Y1+1:X1=X1+1:COLOR 7:PLOT X1,Y1:COLOR 186
1275 PLOT X1,Y1+1:FOR T=4 TO 0 STEP -0.3:SOUND 0,47,2,T:SOUND 1,162,10,T
1280 NEXT T:X=X1:GOTO 1000
2000 COLOR 32:PLOT X1,Y1:X1=X
2005 POSITION 0,11:? #6;"{inv} INTRUDER DESTROYED {/inv}";:FOR T=100 TO 255 STEP 5
2010 SOUND 0,T,10,5:SOUND 1,T,12,5:POKE 709,PEEK(20)
2015 COLOR 7+2*(T/3=INT(T/3)):PLOT X1,Y1:NEXT T
2020 FOR I=0 TO 3:SOUND I,0,0,0:NEXT I:MN=MN-1:IF MN>0 THEN 4000
2025 FOR T=0 TO 255 STEP 5:SOUND 0,T,10,T/25:SOUND 1,T+1,10,T/25
2030 FOR I=708 TO 711:POKE I,T:NEXT I:NEXT T
2035 COLOR 91:FOR T=0 TO 250 STEP 10:SOUND 1,T,2,4:SOUND 0,T,0,4
2040 PLOT 0,T/25:DRAWTO 19,T/25:NEXT T:SOUND 0,0,0,0:SOUND 1,0,0,0:GOTO 10000
2100 FOR T=0 TO 15:SOUND 0,T,8,2:FOR I=708 TO 711:POKE I,T:NEXT I:NEXT T
2105 RESTORE 2150+20*(RND(0)*2>1)
2110 READ P1,P2,DR:SOUND 1,P1,10,10:SOUND 2,P2,10,10
2115 FOR T=0 TO DR*5:NEXT T:IF P2<>193 THEN 2110
2125 FOR T=15 TO 0 STEP -1:SOUND 0,T,8,T:FOR I=708 TO 711:POKE I,T:NEXT I
2130 NEXT T:SC=SC+10*SCR:SCR=SCR+1:IF (SCR=4 AND LVL=0) OR SCR=8 THEN 3000
2135 SOUND 1,0,0,0:SOUND 2,0,0,0:GOTO 4000
2150 DATA 64,162,4,96,162,4,64,162,4,96,162,4
2155 DATA 81,162,4,108,162,4,81,162,4,108,162,4
2160 DATA 136,182,16,144,182,32,144,193,32
2170 DATA 47,64,4,0,0,2,64,81,4,0,0,2,81,96,4,96,153,16,108,144,4
2175 DATA 0,0,2,108,144,4,144,193,16
3000 POSITION 0,11:? #6;"{inv}  MISSION COMPLETE {/inv}";:POKE 708,114:POKE 710,52
3005 SOUND 2,0,0,0:FOR T=10 TO 2 STEP -1:COLOR 219:PLOT 0,T:DRAWTO 19,T
3010 SOUND 0,200,2,10-T:SOUND 1,100,8,10-T:NEXT T
3015 FOR T=0 TO 10:COLOR 32:PLOT 19,T:DRAWTO 16-3*(T<2),T:PLOT 13,T
3020 DRAWTO 11*(T>5),T:PLOT 8,T:DRAWTO 0,T:SOUND 0,200,2,10-T
3025 SOUND 1,PEEK(53770),8,10-T:NEXT T:COLOR 64:PLOT 0,10:DRAWTO 19,10
3030 SOUND 0,0,0,0:SOUND 1,0,0,0:POKE 711,6:A=PEEK(560):B=0
3035 FOR T=5 TO 8:FOR I=0 TO 20:SOUND 0,PEEK(53770),8,5:POKE 560,A+RND(0)*1
3040 B= NOT B:COLOR 252+2*B:PLOT 8,9:PLOT 11,9:COLOR 253+2*B
3045 PLOT 9,9:PLOT 10,9:NEXT I:COLOR 32:PLOT 9,T:PLOT 10,T:NEXT T
3050 IF LVL=0 THEN LVL=1:GOTO 3080
3055 FOR T=2 TO 8:FOR I=0 TO 20:SOUND 0,PEEK(53770),8,8:POKE 560,A+RND(0)*1
3060 B= NOT B:COLOR 252+2*B:PLOT 8,9:PLOT 11,9:PLOT 13,9:PLOT 16,9
3065 COLOR 253+2*B:PLOT 9,9:PLOT 10,9:PLOT 14,9:PLOT 15,9:NEXT I
3070 COLOR 32:PLOT 14,T:PLOT 15,T:NEXT T
3080 POKE 560,A:FOR T=8 TO 0 STEP -0.5:SOUND 0,PEEK(53770),8,T:NEXT T
3085 SC=SC+100:COLOR 32:PLOT 0,9:DRAWTO 19,9:IF SCR<8 THEN 4000
3100 TY=0:A$="{inv}))))){/inv}well{inv}){/inv}done{inv})))))){/inv}":GOSUB 100:POKE 709,14:POKE 710,50
3105 FOR T=100 TO 255:SOUND 0,T,10,T/25:SOUND 1,T,2,T/25:NEXT T
3110 SOUND 0,0,0,0:SOUND 1,0,0,0:LVL=0:SC=SC+100:SCR=1:MN=MN+1:GOTO 4000
4000 POKE 712,148:POSITION 0,0:? #6;"{CLEAR}":POSITION 5,5:? #6;"GET READY"
4005 POKE 708,14:FOR T=0 TO 200:NEXT T
4010 POKE 559,0:POKE 712,0:POKE 710,40:POKE 709,172:POKE 711,10:POKE 708,0
4015 POSITION 0,11:? #6;"score";SC:POSITION 10,11:? #6;"men ";MN
4020 POSITION 0,1:ON SCR GOSUB 4100,4160,4220,4280,4340,4400,4460
4025 POKE 559,34:FOR T=112 TO 112+(MAX*2) STEP 0.1:POKE 708,T:NEXT T
4030 FOR T=50 TO 100:SOUND 0,T,10,5:SOUND 1,T+2,10,5:NEXT T
4035 SOUND 0,0,0,0:SOUND 1,0,0,0:X=X1:GOTO 1000
4099 REM ( "{CTRL-TAB}" IS [ESC][CTRL][TAB] )
4100 ? #6;"        {CTRL-TAB} {CTRL-TAB}         ";
4105 ? #6;"@ @{inv}.{/inv}@@@/@ @/@@@@{inv}.{/inv}   ";
4110 ? #6;"                   {CTRL-TAB}";
4115 ? #6;"@{inv}.{/inv}@/   {inv}-{/inv}/      {inv}+{/inv}/@@@";
4120 ? #6;"              {CTRL-TAB}     ";
4125 ? #6;"      / @@@{inv}-{/inv}@/@     ";
4130 ? #6;"                    ";
4135 ? #6;"  @@@@@      {inv}-{/inv}@@@@/ ";
4140 ? #6;"{CTRL-TAB}   {CTRL-TAB} @{CTRL-TAB}            ";
4145 ? #6;"@/@@@@@@@@@@@@@@@@{inv}-{/inv}@";
4150 MAX=6:X1=9:Y1=9:FOR T=0 TO 2:D(T)=1:X(T)=3:Y(T)=7:NEXT T
4155 RETURN
4160 ? #6;"                  @ ";
4165 ? #6;"@{inv}.{/inv}@@@@@@@@@@@@/@@@@{inv}.{/inv}";
4170 ? #6;"{CTRL-TAB}                 {CTRL-TAB} ";
4175 ? #6;"@/{inv}.{/inv}/           {inv}+{/inv}/@@ ";
4180 ? #6;"   @@@@@            ";
4185 ? #6;"      /   /{inv},{/inv}   /{inv}-{/inv}@@ ";
4190 ? #6;"   /{inv},{/inv}        /{inv}-{/inv}   {CTRL-TAB} ";
4195 ? #6;"{inv}-{/inv}    /  {inv}+{/inv}/{inv}-{/inv}     {inv}.{/inv}/@ ";
4200 ? #6;"@{CTRL-TAB}                  ";
4205 ? #6;"@@/{inv}-{/inv}@@@@@{inv}-{/inv}@@@@@@/{inv}-{/inv}@/";
4210 MAX=3:X1=19:Y1=1:X(0)=17:Y(0)=1:X(1)=5:Y(1)=9:X(2)=7:Y(2)=4
4215 RETURN
4220 ? #6;"@@@@@@@@@@/{inv},{/inv}    /{inv}.{/inv}@@";
4225 ? #6;"   {CTRL-TAB}           @{CTRL-TAB}   ";
4230 ? #6;"@@@@/@@@@@{inv}-{/inv}@@@@@@/@@";
4235 ? #6;"@                {CTRL-TAB}  ";
4240 ? #6;"@@@@{inv}-{/inv}@@@@@@@@@@@/@@@";
4245 ? #6;"       {CTRL-TAB}           @";
4250 ? #6;"/@@@@@{inv}.{/inv}@/@@@@@{inv}.{/inv}@{inv}-{/inv}@/@";
4255 ? #6;" @       @          ";
4260 ? #6;" @   {CTRL-TAB}   @   {CTRL-TAB}      ";
4265 ? #6;"{inv}-{/inv}@@@@@/@{inv}-{/inv}@@@@@/@@@{inv}-{/inv}@";
4270 MAX=5:X1=0:Y1=9:X(0)=10:Y(0)=6:X(1)=4:Y(1)=4:X(2)=12:Y(2)=2
4275 RETURN
4280 ? #6;"@            @@@@@@@";
4285 ? #6;"@@@@@@/{inv},{/inv} /{inv}.{/inv}    {CTRL-TAB}    ";
4290 ? #6;"@              @/@{inv}.{/inv}@";
4295 ? #6;"@{inv}.{/inv}@/         {inv}+{/inv}/     ";
4300 ? #6;"{CTRL-TAB}   / {inv}-{/inv}/{inv}+{/inv}@{inv},{/inv}/{inv}.{/inv}      {CTRL-TAB}";
4305 ? #6;"@/@{inv}.{/inv}@            {inv}.{/inv}/@";
4310 ? #6;"    {CTRL-TAB}               ";
4315 ? #6;"@{inv}.{/inv}@/@            /@{inv}.{/inv}";
4320 ? #6;"{CTRL-TAB}         /{inv},{/inv}   /{inv}-{/inv}{CTRL-TAB}  ";
4325 ? #6;"@/@@@@@{inv}-{/inv}@@@ /@{inv}-{/inv}  @@/";
4330 MAX=5:X1=9:Y1=4:X(0)=3:Y(0)=1:X(1)=4:Y(1)=1:X(2)=7:Y(2)=9
4335 RETURN
4340 ? #6;"{inv}.{/inv}                   ";
4345 ? #6;" {inv}.{/inv}/               {inv}+{/inv}/";
4350 ? #6;"     {inv}.{/inv}@@@  @@@@  /  ";
4355 ? #6;"        @@@@  @@@   ";
4360 ? #6;"    {CTRL-TAB}           {CTRL-TAB}   ";
4365 ? #6;"  @@@/@@@@@@@@@@@   ";
4370 ? #6;"                    ";
4375 ? #6;" /{inv},{/inv}             /{inv}-{/inv}  ";
4380 ? #6;"                    ";
4385 ? #6;"/{inv},{/inv}                /{inv}-{/inv}";
4390 MAX=1:X1=0:Y1=0:X(0)=16:Y(0)=3:X(1)=3:Y(1)=5:X(2)=10:Y(2)=3
4395 RETURN
4400 ? #6;"    {CTRL-TAB} @    {CTRL-TAB}      {CTRL-TAB} ";
4405 ? #6;"{inv}.{/inv}@@/@@@@{inv}.{/inv}@/@@@{inv}.{/inv}@@/@@";
4410 ? #6;"         {CTRL-TAB}          ";
4415 ? #6;"/@@{inv}-{/inv}@@{inv}.{/inv}@/@{inv}-{/inv}@/ /@{inv}.-{/inv}@/";
4420 ? #6;"         {CTRL-TAB}          ";
4425 ? #6;"{inv}-{/inv}@@@@//@{inv}.{/inv}@/@{inv}-{/inv} {inv}.{/inv}@//@{inv}-{/inv}";
4430 ? #6;"             {CTRL-TAB}      ";
4435 ? #6;" @@/@{inv}-.{/inv}@/ {inv}-{/inv}@/@/@{inv}.-{/inv}@/";
4440 ? #6;" {CTRL-TAB}@    {CTRL-TAB}            ";
4445 ? #6;"/@@{inv}-{/inv}@@/@@@@@{inv}-{/inv}@@@/ @{inv}-{/inv}";
4450 MAX=7:X1=19:Y1=9:X(0)=14:Y(0)=1:X(1)=14:Y(1)=9:X(2)=3:Y(2)=3
4455 RETURN
4460 ? #6;"/@@@@@@@@@{inv}.{/inv}@@@@@@ {CTRL-TAB} ";
4465 ? #6;"                @@@/";
4470 ? #6;"{inv}-{/inv}/{inv},{/inv} /    {inv}.{/inv}/{inv},{/inv}  /{inv}.{/inv}    ";
4475 ? #6;"            /{inv},{/inv}    /{inv}-{/inv}";
4480 ? #6;"   {inv}.{/inv}/   {inv}+{/inv}/{inv}.{/inv}   {CTRL-TAB}     ";
4485 ? #6;"              @/  {inv}.{/inv}@";
4490 ? #6;"   /{inv}-{/inv}/     /{inv}-{/inv}@@@@@ @";
4495 ? #6;"                    ";
4500 ? #6;"@                  {CTRL-TAB}";
4505 ? #6;"@{inv}-{/inv}@@@@@@@{inv}-{/inv}@@{inv}-{/inv}@@@@@/@";
4510 MAX=2:X1=5:Y1=9:X(0)=17:Y(0)=9:X(1)=11:Y(1)=0:X(2)=16:Y(2)=6
4515 RETURN
10000 POSITION 0,0:? #6;"{CLEAR}":POKE 559,0:COLOR 8:PLOT 0,2:PLOT 0,4:PLOT 0,7
10005 PLOT 0,11:COLOR 10:PLOT 19,2:PLOT 19,4:PLOT 19,7:PLOT 19,11
10010 POKE 709,4:POKE 710,12:POKE 711,50:POKE 559,34
10020 A$="))){inv}ANTIC{/inv}){inv}PRESENTS{/inv})))":TY=2:GOSUB 100
10025 A$=")))))shut))down)))))":TY=4:GOSUB 100
10030 A$="))){inv}BY{/inv}){inv}TONY{/inv}){inv}BARNES{/inv})))":TY=7:GOSUB 100
10035 IF PEEK(644)=0 OR PEEK(53279)=5 THEN 10100
10040 TY=11:A$="){inv}PRESS{/inv}){inv}fire{/inv}){inv}TO{/inv}){inv}PLAY{/inv})":GOSUB 100:POKE 540,50
10045 POKE 708,PEEK(20):IF PEEK(644)=0 THEN 10100
10050 IF PEEK(540)>0 THEN 10045
10055 A$="{inv}{CTRL-I}FINAL{CTRL-I}SCORE{CTRL-I}{/inv}":A$(14)=STR$(SC):A$(LEN(A$)+1)="{inv}{CTRL-I}{CTRL-I}{CTRL-I}{CTRL-I}{CTRL-I}{CTRL-I}{/inv}":GOSUB 100:POKE 540,50
10060 POKE 708,PEEK(20):IF PEEK(644)=0 THEN 10100
10065 IF PEEK(540)>0 THEN 10060
10070 GOSUB 120:GOTO 10040
10100 TY=11:GOSUB 120:TY=7:GOSUB 120:TY=4:GOSUB 120:TY=2:GOSUB 120
10105 FOR T=8 TO 0 STEP -1:FOR I=708 TO 711:POKE I,T:NEXT I:NEXT T
10110 SC=0:SCR=1:MN=3:LVL=0:GOTO 4000
20000 POKE 559,0:RESTORE 21100:READ DNUM
20010 D=PEEK(560)+256*PEEK(561)+4
20020 FOR I=1 TO DNUM:READ B:POKE D+B,135:NEXT I
20030 B=INT(ADR(DLI$)/256):A=ADR(DLI$)-B*256:POKE 512,A:POKE 513,B
20040 POKE 54286,192:POKE 256,Z:POKE 559,34:RETURN
21000 DIM DLI$(67)
21010 DLI$="H{inv}-{/inv}{CTRL-,}{CTRL-A}{inv}n{/inv}{CTRL-,}{CTRL-A}{inv}{CTRL-M}{/inv}{CTRL-J}{inv}TI{/inv}{CTRL-,}{inv}P{/inv}{CTRL-J}{inv}){/inv}H{inv}{CTRL-M}{/inv}{CTRL-X}{inv}P{CTRL-M}{/inv}{CTRL-J}{inv}T{/inv}h@{inv}I{/inv}{CTRL-A}{inv}P{/inv}{CTRL-J}{inv}){/inv}l{inv}{CTRL-M}{/inv}{CTRL-X}{inv}P{CTRL-M}{/inv}{CTRL-J}{inv}T{/inv}h@{inv}I{/inv}{CTRL-B}"
21012 DLI$(41)="{inv}P{/inv}{CTRL-J}{inv}){CTRL-H}{CTRL-M}{/inv}{CTRL-X}{inv}P{CTRL-M}{/inv}{CTRL-J}{inv}T{/inv}h@{inv}){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{CTRL-,}{CTRL-A}{inv})({CTRL-M}{/inv}{CTRL-X}{inv}P{CTRL-M}{/inv}{CTRL-J}{inv}T{/inv}h@"
21095 RETURN
21100 DATA 4,4,6,8,10
23000 DIM RDC$(200),MOV$(46)
23005 POKE 559,0:CHR=38912:I=256*224
23010 DIM CH$(20):CH$="h{inv}"{/inv}{CTRL-D}{inv} {/inv}{CTRL-,}{inv}1M{CTRL-Q}KHPyfNfLJPr{/inv}{CTRL-.}":GOSUB 30100
23012 MOV$="hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}":MOVX=ADR(MOV$)
23015 POKE 204,152:POKE 206,224:I=USR(ADR(CH$)):POKE 559,34
23020 I=USR(MOVX,ADR(RDC$),CHR+8,120):I=USR(MOVX,ADR(RDC$)+120,CHR+208,16)
23030 I=USR(MOVX,ADR(RDC$)+136,CHR+240,24):I=USR(MOVX,ADR(RDC$)+160,CHR+472,40)
23040 RETURN
30100 RDC$(1,60)="{CTRL-L}{CTRL-L}{CTRL-X}8Z{CTRL-X}$B{CTRL-L}{CTRL-L}{CTRL-X}{UP}{CTRL-X}{CTRL-X}0{CTRL-P}{CTRL-L}{CTRL-L}{CTRL-X}{UP}Z{CTRL-X}$B00{CTRL-X}8Z{CTRL-X}$B00{CTRL-X}8{CTRL-X}{CTRL-X}{CTRL-L}{CTRL-H}00{CTRL-X}{UP}Z{CTRL-X}$B{CTRL-X}{CTRL-X}<Z<{CTRL-X}$B{CTRL-C}{CTRL-F}&{BACK S}"
30110 RDC$(61,120)="{inv}{CTRL-;}x{/inv}|{inv}*{/inv}{CTRL-,}{inv}{CTRL-H}]{/inv}w*{CTRL-,}{CTRL-,}{CTRL-,}{inv}@{/inv}{CTRL-.}d{BACK S}{inv}_{/inv}{RIGHT}>U{CTRL-,}{INS CHAR}{inv}aC{CTRL-G}{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}aC{CTRL-G}{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}aC{CTRL-G}{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}aC{CTRL-G}{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}"
30120 RDC$(69,69)=CHR$(34)
30130 RDC$(121,160)="{CTRL-,}{INS CHAR}{inv}aC{CTRL-G}{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-X}$B$<{BACK S}{INS CHAR}f<{CTRL-X}{CTRL-X}{BACK S}fBf{BACK S}{CTRL-,}{CTRL-,}<{BACK S}fBf{BACK S}{CTRL-,}{INS CHAR}{inv}{CTRL-A}{/inv}B${CTRL-X}{INS CHAR}{CTRL-,}"
30140 RDC$(161,200)="{INS CHAR}{inv}{CTRL-Y}{CTRL-Y}{/inv}{INS CHAR}{INS CHAR}{inv}{CTRL-Y}{CTRL-Y}{/inv}{INS CHAR}{CTRL-A}{CTRL-,}@{CTRL-J}{CTRL-,}{inv}\v85{/inv}O{inv}T{/inv}7{inv}WkJo{CTRL-,}{/inv}{CTRL-,}{CTRL-B}P{CTRL-,};o{DOWN}{inv}-r{/inv}+{inv}lkW{/inv}S{inv}w{/inv}":RETURN

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: SHUTDOWN.BAS.

Credits