Escape From Hell!

Type
Game
Category
Platform game
Author
Tony Barnes
Published in
Antic, June 1988 (Vol. 7, No. 2), Game of the Month
Year
1988
Language
Atari BASIC
Requirements
48K RAM, Atari BASIC, joystick in port 1
Title screen on a dark magenta background: ESCAPE FROM in black, then a giant word Hell built from flickering flame-coloured characters, with BY TONY BARNES and PRESS THE TRIGGER TO BEGIN

About the program

Tony Barnes, from San Francisco, sent Antic a well-made BASIC platform game called Dynamite Dan. A little man ran through a dungeon collecting dynamite and bouncing on trampolines, chased by a robot that wandered at random. The editors liked it but found it a bit familiar. Then Technical Editor Charles Jackson, idly trying POKEs, came up with a hellish red background. Editor Nat Friedland took one look and said "Escape From Hell!", and the whole staff got carried away. Gregg Pearlman wrote a new story, Carolyn Cushman worked on the sound and graphics, and ad coordinator Katie Murphy suggested the ending. Antic apologised in print to Barnes, who was making his first appearance in the magazine, for what had happened to his game.

The new story is a running joke at Antic's own expense. Myron is condemned to Hell for writing yet another Lode Runner rip-off and, worse, for never using TYPO II, the magazine's checksum program. To win absolution he has to run through six infernal levels, against the clock, grabbing every Antic back issue (an "A" logo), while a pitchfork-waving Devil chases him. Fail and you lose one of your four "deaths". Antic also launched a "Challenge From Hell" contest for readers to rebuild the game with new graphics and a new story.

Typing it in

You need 48K. Line 9022 and lines 10001–10009 contain machine code and character data as strings of inverse and control characters. The magazine's second listing wrote them to LINES.LST for you to ENTER over the main program, and the disk listing here has them merged in. In this notation, {inv}…{/inv} means type with the Atari (inverse) key on, {CTRL-Y} means hold CTRL and press Y, and ESC-prefixed keys like {BACK S} are typed by pressing ESC first. The tune for the ending is the DATA in lines 1280–1380. Line 10010 contains RESTORE 30000, although there is no line 30000. That's how it was published, and it's harmless: Atari BASIC just sets the DATA pointer past the end of the program. Don't add a line 30000.

How to play

When the flames on the title screen die down, press the button. Myron is the little green figure and Satan is the red one. Move with the joystick to collect the "A"s. Each one is worth 5 to 10 points. The Devil secretly picks a target between 2,500 and 5,000 points, and reaching it ends your sentence, even if that takes more than one trip through the six screens.

  • Fire pits blast you upwards. That's the only way to go up within a screen.
  • Shaky ground holds you once, then falls away the next time. The Devil walks wherever he likes.
  • On later levels, arrows push you one way. You can't walk against them, but the Devil can.
  • In Hell, you can steer sideways while you fall.
  • Stuck? Press the button to commit "suicide". It costs a death, but the level restarts. START restarts the game.

Reach the target and the Hallelujah Chorus plays as Myron rises to Heaven.

How it works

The playfield is GRAPHICS 2 with a redefined character set at page 152 (line 10). The walls, ledges, fire, arrows, logos, Myron and the Devil are all characters, plotted with COLOR and PLOT. Movement and hazards are all LOCATE checks on the cell below or beside a figure. A space means fall, code 26 is a fire pit (launch upwards), 175 is a logo, 11 and 12 are the two states of shaky ground, and 173 and 174 are the arrows. The figures are animated by swapping the shape bytes of their characters with a small machine-language move routine. The flickering flames work the same way (lines 815 and 635). The ending makes Myron float up the screen along a sine-wave path (line 765), in time with the chorus data.

Variations to try

  • Take up Antic's challenge: keep the program's structure but redraw the character set and change the messages, and make it your own game.
  • Change the starting number of deaths or the time limit to make Hell a little kinder.

Listing

1 REM ESCAPE FROM HELL!
2 REM BY TONY BARNES
3 REM (c)1988, ANTIC PUBLISHING
10 GRAPHICS 18:POKE 756,152:POKE 708,38:POKE 709,244:POKE 710,50:POKE 711,214
12 DIM SET$(120),DEV$(24)
15 SUI=1:GOSUB 10000
20 POKE 559,34:GOTO 9000
500 FOR T=200 TO 0 STEP -50:SOUND 1,T,12,T/25:SOUND 0,T,8,T/25:NEXT T
505 SC=SC+10:IF SC>HVN AND FLG THEN POP :GOTO 700
506 POSITION 6,11:? #6;SC:BMB=BMB+1:IF BMB>=MAX THEN POP :GOTO 550
510 RETURN
550 COLOR 138:PLOT 0,0:DRAWTO 19,0:FOR T=1 TO 10:SOUND 1,237,20,T:SOUND 0,238,20,T
555 COLOR 138:PLOT 0,T:COLOR 42:PLOT 1,T:DRAWTO 18,T:COLOR 138:PLOT 19,T:NEXT T
560 COLOR 138:PLOT 0,11:DRAWTO 19,11:POSITION 6,5:? #6;"penance"
561 POSITION 5,6:? #6;"continues":FOR T=15 TO 0 STEP -0.1
565 SOUND 0,237,20,T:SOUND 1,238,20,T:NEXT T:FOR T=INT(TMR/10) TO 0 STEP -10
570 FOR I=6 TO 0 STEP -1:SOUND 0,30,10,I:NEXT I:SC=SC+5:NEXT T:SCR=SCR+1:GOTO 8000
600 FOR ZQ=15 TO 0 STEP -1:SOUND 1,122-ZQ,8,ZQ:SOUND 0,0,0,3
610 COLOR 134:IF ZQ/2=INT(ZQ/2) THEN COLOR 26
620 PLOT X1,Y1:NEXT ZQ:COLOR 27:PLOT X1,Y1:SOUND 0,0,0,3
630 FOR ZQ=0 TO 15 STEP 3:SOUND 1,122-ZQ,8,ZQ:COLOR (27-(ZQ/2=INT(ZQ/2)))
635 ZQ1=USR(FLIPM,39128,39128,8)
640 PLOT X1,Y1:NEXT ZQ:SOUND 0,0,0,0:SOUND 1,0,0,0:COLOR 32:PLOT X1,Y1
650 SUI=0:RETURN
700 GRAPHICS 18:POKE 756,152:DEG :M=-11/430:OLDX=0:OLDY=0:POKE 712,114:POKE 708,14
705 POSITION 0,0:? #6;"&&&&&&&&&&&& &&&&&&"
710 SOUND 2,0,0,0:FOR X=200 TO 50 STEP -10:SOUND 0,X,10,14:NEXT X:RESTORE 1280:FOR A=0 TO 430 STEP 10
720 TRAP 1270:READ T,ZQ,B,C,D,VOL
730 IF VOL=0 THEN 760
740 SOUND 0,ZQ,14,10:SOUND 1,B,14,6:SOUND 2,C,14,6:SOUND 3,C,14,6:FOR X=1 TO T:NEXT X
760 JNK=USR(MOV,ADR("{inv}{CTRL-Y}{/inv}Z${CTRL-X}{CTRL-X}{inv}g{/inv}")+3*(A/30=INT(A/30)),38960,3)
765 OFFSET=SIN(A)*3+9:Y=M*A+11
770 COLOR 32:PLOT OLDX,OLDY:COLOR 38:PLOT OFFSET,Y:OLDX=OFFSET:OLDY=Y
775 IF VOL=0 THEN FOR X=0 TO 3:SOUND X,0,0,0:NEXT X:IF T>24 THEN FOR X=1 TO T:NEXT X
778 SET$="   / / /   PRESS TRIGGER TO DIE AGAIN"
780 NEXT A:GRAPHICS 34:POKE 756,152:POKE 712,114:POKE 710,114:POKE 708,14:POSITION 6,5:? #6;"{inv}{CTRL-O}bsolved{/inv}":X=1
781 POKE 752,1:POKE 656,2:POKE 657,2:? SET$(X,37);SET$(1,X);:IF X>36 THEN X=1
785 POKE 711,PEEK(20):IF STRIG(0)=0 THEN POKE 559,0:GRAPHICS 2:GOTO 15
790 POKE 77,0:X=X+1:GOTO 781
800 X=X2+0.3*(X2<X1)-0.3*(X2>X1):LOCATE X,Y2,Z:IF Z>128 AND Z<137 THEN 2000
801 IF INT(X2+0.5)>INT(X2P+0.5) THEN ZQ=USR(MOV,ADR(SET$)+48,38968,24)
802 IF INT(X2+0.5)<INT(X2P+0.5) THEN ZQ=USR(MOV,ADR(DEV$),38968,24)
803 X2P=X2
805 IF Z=32 OR (Z>166 AND Z<170) THEN 815
810 X=X2
815 F2=F2+1:IF F2=3 THEN F2=0:ZQ=USR(MOV,FIRE+(RND(0)>0.66)*9,39120,8)
820 COLOR 32:PLOT X2,Y2:X2=X:COLOR 167+F2:PLOT X2,Y2:LOCATE X2,Y2+1,Z
825 IF Z=32 THEN COLOR 32:PLOT X2,Y2:Y2=Y2+1:COLOR 167:PLOT X2,Y2
830 IF Z=26 THEN 850
835 RETURN
850 I=Y2+1:COLOR 27:PLOT X2,I:FOR T=15 TO 0 STEP -1:SOUND 1,162,10,T:NEXT T
855 SOUND 0,Y2,10,2:SOUND 1,Y2+50,10,2:LOCATE X2,Y2-1,Z:IF Z<>32 THEN 865
860 COLOR 32:PLOT X2,Y2:Y2=Y2-1:IF Y2=0 THEN 865
862 COLOR 168:PLOT X2,Y2:GOTO 855
865 COLOR 26:PLOT X2,I:SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
1000 POKE 77,0:TMR=TMR-1:POSITION 15,11:? #6;INT(TMR/10);" ";:IF TMR<=0 THEN 2000
1002 IF PEEK(53279)=6 THEN 20
1003 SUI=1:IF PEEK(644)=0 THEN GOSUB 600:GOTO 2000
1004 REM COLOR 25:PLOT X1,Y1
1005 GOSUB 800:ST=PEEK(632):IF ST>12 THEN 1040
1010 X=X1+(ST<8)-(ST>8):IF X<0 OR X>19 THEN 1050
1015 LOCATE X,Y1,Z:IF Z=32 THEN 1030
1017 IF Z=175 THEN GOSUB 500:GOTO 1030
1020 X=X1
1030 FRM=1-FRM:COLOR 32:PLOT X1,Y1:X1=X:COLOR (130+2*(ST>8))+FRM:PLOT X1,Y1
1035 SOUND 0,21,8,8:SOUND 0,0,0,0:GOTO 1050
1040 COLOR 134:PLOT X1,Y1
1050 LOCATE X1,Y1+1,Z:IF Z=32 THEN COLOR 32:PLOT X1,Y1:Y1=Y1+1:COLOR 129:PLOT X1,Y1
1055 IF Z=26 THEN 1100
1060 IF Z=175 THEN GOSUB 500:COLOR 32:PLOT X1,Y1+1
1065 IF Z>166 AND Z<170 THEN 2000
1070 IF Z=11 THEN COLOR 12:PLOT X1,Y1+1
1072 IF Z=12 THEN COLOR 32:PLOT X1,Y1+1
1075 IF Z=173 THEN ST=7:GOSUB 800:GOTO 1010
1077 IF Z=174 THEN ST=11:GOSUB 800:GOTO 1010
1090 GOTO 1000
1100 I=Y1+1:COLOR 27:PLOT X1,I:FOR T=15 TO 0 STEP -1:SOUND 1,122-T,8,T:ZQ=USR(FLIPM,39128,39128,8)
1101 SOUND 0,0,0,3:NEXT T:SOUND 0,0,0,0
1102 FOR T=0 TO 53 STEP 6:SOUND 0,T,10,14:NEXT T
1105 SOUND 1,62-Y1-INT(RND(0)*4),10,Y1
1106 SOUND 0,62,0,4
1107 LOCATE X1,Y1-1,Z:IF Z<>32 THEN 1120
1110 COLOR 32:PLOT X1,Y1:Y1=Y1-1:IF Y1=0 THEN 1120
1115 COLOR 134:PLOT X1,Y1:GOTO 1105
1120 COLOR 26:PLOT X1,I:SOUND 0,0,0,0:SOUND 1,0,0,0:GOTO 1000
1200 REM
1270 END
1280 DATA 319,53,72,42,217,1,23,0,0,0,0,0,106,72,72,53,173,1,23,0,0,0,0,0
1290 DATA 106,64,81,53,162,1,23,0,0,0,0,0,106,72,85,53,217,1,293,0,0,0,0,0
1300 DATA 319,53,72,42,217,1,23,0,0,0,0,0,106,72,72,53,173,1,23,0,0,0,0,0
1310 DATA 106,64,81,53,162,1,23,0,0,0,0,0,106,72,85,53,217,1,83,0,0,0,0,0
1320 DATA 2,53,72,53,173,1,1,0,0,0,0,0,2,53,72,53,173,1,23,0,0,0,0,0
1330 DATA 106,53,64,40,162,1,18,0,0,0,0,0,106,53,72,42,217,1,23,0,0,0,0,0
1340 DATA 83,0,0,0,0,0,2,53,72,53,173,1,1,0,0,0,0,0,2,53,72,53,173,1
1350 DATA 23,0,0,0,0,0,106,53,64,40,162,1,18,0,0,0,0,0,106,53,72,42,217,1
1360 DATA 23,0,0,0,0,0,23,0,0,0,0,0,106,53,72,52,173,1,23,0,0,0,0,0
1370 DATA 106,57,81,47,193,1,106,53,85,72,217,1,106,53,96,72,144,1,23,0,0,0,0,0
1380 DATA 212,57,96,72,144,1,23,0,0,0,0,0,638,53,85,72,217,1,23,0,0,0,0,99
2000 I=PEEK(560):FOR T=100 TO 200 STEP 10:SOUND 0,T,10,10:SOUND 0,T,8,10:Z=INT(RND(0)*2)
2002 POKE 560,I+3*(Z=2)-3*(Z=1):NEXT T:FOR T=15 TO 0 STEP -1
2005 SOUND 0,PEEK(53770),0,T:SOUND 1,208,12,T:NEXT T:MN=MN-1:IF MN<0 THEN 2020
2010 POKE 560,I:GOTO 8000
2020 POKE 560,I
2025 ? #6;"{CLEAR}":Y1=1:DY=1:GOTO 9000
8000 POKE 559,0:? #6;"{CLEAR}":BMB=0:IF SCR=7 THEN SCR=1:FLG=1
8002 IF MN>0 THEN FOR T=1 TO MN:POSITION 16+T,0:? #6;"{inv}{CTRL-A}{/inv}";:NEXT T
8005 POSITION 0,1:ON SCR GOSUB 8020,8080,8130,8180,8230,8280
8010 POKE 559,34:POSITION 0,11:? #6;"SCORE=";SC
8015 POSITION 10,11:? #6;"TIME=";INT(TMR/10):COLOR 134:PLOT X1,Y1:GOTO 1000
8020 ? #6;"     *****       ***";
8025 ? #6;"*    {inv}/{/inv} {inv}/{/inv} {inv}/{/inv}  {inv}/{/inv}      *";
8030 ? #6;"**   ***** ***   * *";
8035 ? #6;"***     {inv}/{/inv}   **   * *";
8040 ? #6;"***   ****      {CTRL-Z}*{inv}/{/inv}*";
8045 ? #6;" {inv}/{/inv}  {inv}/{/inv} ****      ** *";
8050 ? #6;"*** *{CTRL-Z}****     *** *";
8055 ? #6;"  * ******     *** *";
8060 ? #6;" {inv}/{/inv}          {inv}/{/inv}   {inv}/{/inv}   ";
8065 ? #6;"***{CTRL-Z}******{CTRL-Z}***{CTRL-Z}*****";
8067 MAX=11:X1=0:Y1=1:X2=9:Y2=8:IF SUI THEN TMR=1001
8068 RETURN
8080 ? #6;"************  ******";
8085 ? #6;" {inv}//{/inv}        ****    *";
8090 ? #6;"**** **  {inv}/{/inv}    * *{inv}/{/inv} *";
8095 ? #6;"* {inv}/{/inv}     **  {inv}/{/inv}   ** *";
8100 ? #6;"****  {inv}/{/inv}    **     {inv}/{/inv}*";
8105 ? #6;"*  {inv}/{/inv}  ** {inv}/{/inv}  *{CTRL-Z}  ****";
8110 ? #6;"* **     ** {inv}/{/inv}     {inv}/{/inv}*";
8115 ? #6;"*  *        **  ****";
8120 ? #6;"      {inv}/{/inv}  {inv}/{/inv}  {inv}/{/inv}    {inv}/{/inv} {inv}/{/inv}";
8125 ? #6;"*{CTRL-Z}**{CTRL-Z}***{CTRL-Z}**{CTRL-Z}**{CTRL-Z}{CTRL-Z}****";
8127 MAX=17:X1=0:Y1=9:X2=16:Y2=7:IF SUI THEN TMR=501
8128 RETURN
8130 ? #6;"                    ";
8135 ? #6;"  * {inv}/{/inv} {inv}/{/inv}  {inv}//{/inv}  {inv}/{/inv} {inv}/{/inv} *  ";
8140 ? #6;"* *{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}* *";
8145 ? #6;"*  {inv}/{/inv} {inv}/{/inv}  {inv}/{/inv}  {inv}/{/inv}  {inv}/{/inv} {inv}/{/inv}  *";
8150 ? #6;"* {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} *";
8155 ? #6;"*   {inv}/{/inv}    {inv}//{/inv}    {inv}/{/inv}   *";
8160 ? #6;"* {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} {CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K} *";
8165 ? #6;"*    {inv}/{/inv}             *";
8170 ? #6;"*  ***    {inv}/{/inv}   ***  *";
8175 ? #6;"*{CTRL-Z}** **{CTRL-Z}****{CTRL-Z}** **{CTRL-Z}*";
8177 MAX=18:X1=4:Y1=8:X2=15:Y2=8:IF SUI THEN TMR=1001
8178 RETURN
8180 ? #6;"        {inv}/{/inv} {inv}/{/inv}  *******";
8185 ? #6;"{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}         ";
8190 ? #6;"{CTRL-Z}***   {inv}/{/inv}     {CTRL-K}{inv}/{/inv}{CTRL-K}{CTRL-K}*{CTRL-K}*";
8195 ? #6;"* {inv}//{/inv}  {CTRL-K}{CTRL-K}{CTRL-K}   {CTRL-K}{inv}/{/inv}{CTRL-K}{CTRL-K}{CTRL-K}* *";
8200 ? #6;"* {CTRL-K}{CTRL-K}  {CTRL-K}{inv}/{/inv}{CTRL-K} {CTRL-Z}{CTRL-K}{inv}/{/inv}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}*{inv}/{/inv}*";
8205 ? #6;"*     {CTRL-K}{CTRL-K}{CTRL-K}   {CTRL-K}{CTRL-K} {inv}/{/inv}{CTRL-K}* *";
8210 ? #6;"*   {inv}/{/inv}  {inv}/{/inv}   {CTRL-K}{CTRL-K} {CTRL-K}{CTRL-K}{CTRL-K}*{CTRL-K}*";
8215 ? #6;"* ******* **  **{inv}/{/inv}* *";
8220 ? #6;"*                  *";
8225 ? #6;"*{CTRL-Z}*******{CTRL-Z}***{CTRL-Z}****{CTRL-Z}*";
8227 MAX=14:X1=0:Y1=0:X2=15:Y2=9:IF SUI THEN TMR=901
8228 RETURN
8230 ? #6;"*           {inv}/{/inv}  {inv}/{/inv}   *";
8235 ? #6;"*{inv}----------{/inv}******  *";
8240 ? #6;"*  {inv}/{/inv}  {inv}/{/inv}           **";
8245 ? #6;"*  ******{inv}.........{/inv}* ";
8250 ? #6;"*                {inv}/{/inv}**";
8255 ? #6;"*      {inv}/{/inv}    {inv}/{/inv}  *****";
8260 ? #6;"*{CTRL-Z}{CTRL-L}{inv}.{/inv}* *** ***     {inv}/{/inv}*";
8265 ? #6;"*              *{inv}--{/inv} *";
8270 ? #6;"*{inv}/{/inv} {inv}/{/inv}   {inv}/{/inv}    {inv}/{/inv}    {inv}//{/inv} ";
8275 ? #6;"*{inv}----{/inv}{CTRL-Z}***{CTRL-Z}{CTRL-Z}**{CTRL-Z}{CTRL-Z}*{inv}....{/inv}";
8277 MAX=14:X1=1:Y1=0:X2=16:Y2=9:IF SUI THEN TMR=901
8278 RETURN
8280 ? #6;"*                  *";
8285 ? #6;"*{CTRL-K}{inv}/{/inv}     {inv}/{/inv}*       * *";
8290 ? #6;"**{CTRL-K}{inv}/{/inv}    *       {inv}/{/inv}* *";
8295 ? #6;"** {CTRL-K}{inv}/{/inv} {CTRL-Z}   *{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}** *";
8300 ? #6;"* {inv}/{/inv} {CTRL-K} *   * {inv}/{/inv}    * *";
8305 ? #6;"****{CTRL-K}     *{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}{CTRL-K}** *";
8310 ? #6;"* {inv}/{/inv} {inv}/{/inv}     * {inv}/{/inv}  {inv}/{/inv} * *";
8315 ? #6;"* ***     ***{CTRL-Z}{CTRL-Z}*** *";
8320 ? #6;"*          {inv}/{/inv} {inv}/{/inv} {inv}/{/inv} {inv}/{/inv} *";
8325 ? #6;"*{inv}----{/inv}{CTRL-Z}{inv}..{/inv}**********{CTRL-Z}*";
8327 MAX=15:X1=14:Y1=9:X2=0:Y2=0:IF SUI THEN TMR=501
8328 RETURN
9000 GRAPHICS 2:POKE 756,152:POKE 710,66:POKE 752,1:POKE 712,66:POKE 711,0
9001 ? :? ,"BY TONY BARNES"
9002 ? ,"YOUR SCORE = ";SC
9004 ? "    PRESS THE TRIGGER TO BEGIN";
9006 ? #6;"       {inv}escape{/inv}":? #6
9008 ? #6;"        {inv}from{/inv}":? #6
9010 ? #6;" <  <      <<  <<"
9012 ? #6;" >  >  >>   >   >"
9014 ? #6;" <<<< <  <  <   <"
9016 ? #6;" >  > >>>>  >   >"
9018 ? #6;" <  < <     <   <"
9020 ? #6;" >  >  >>> >>> >>>"
9021 SOUND 0,63,12,14:SOUND 1,62,12,14:SOUND 2,62,8,6:SOUND 3,1,16,2
9022 ZQ=USR(ADR("hhh{inv}*-{/inv}{CTRL-K}{inv}T{/inv}{CTRL-X}e{CTRL-T}{CTRL-J}{inv}{CTRL-M}{/inv}{CTRL-J}{inv}T{/inv}{INS LINE}{CTRL-R}{inv}P-{CTRL-D}{/inv}{CTRL-B}{inv}I{/inv}{CTRL-,}{inv}Pl{/inv}{CTRL-.}"),708)
9030 GRAPHICS 18:POKE 756,152:POKE 708,18:POKE 709,244:POKE 710,50:POKE 711,214:DEG
9035 SOUND 2,106,8,2:SOUND 3,1,14,14:SC=0:SCR=1:HVN=INT(RND(0)*2500)+2450:MN=3:TIMR=1001
9037 MN=3:TIMR=1001:HVN=HVN*(PEEK(632)<>14)+50:IF HVN<255 THEN FLG=1
9040 FOR T=11 TO 0 STEP -1:SOUND 0,T,8,T:SOUND 1,T+50,2,T:COLOR 32:PLOT 0,T
9045 DRAWTO 19,T:NEXT T:GOTO 8000
10000 POKE 559,0:CHR=38912:I=256*224
10001 MOV=ADR("hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}"):REM FM,TO,KNT
10004 FLIPM=ADR("hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p"{/inv}{CTRL-H}{CTRL-X}{CTRL-J}f{inv}KJPy%K{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnP_Fo{/inv}{CTRL-P}{inv}[{/inv}{CTRL-.}")
10006 SET$(1,60)="{CTRL-X}{CTRL-X}B<{CTRL-X}{CTRL-X}$f{CTRL-X}{CTRL-X}{CTRL-,}<Z{CTRL-X}$6{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-P}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-,}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-H}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-,}<Z{CTRL-X}$l{CTRL-X}{CTRL-X}{CTRL-,}<Z{CTRL-X}$f{inv}{CTRL-T}{/inv}{INS LINE}{INS LINE}I_={CTRL-U}6{CTRL-U}{INS LINE}{INS LINE}{inv}{CTRL-K}{/inv}"
10007 SET$(61,120)="{INS LINE}{CLEAR}{CTRL-T}6{CTRL-T}=]{inv}{CTRL-I}{/inv}{SHIFT-TAB}{CLEAR}{CTRL-U}6{inv}{CTRL-;}{CTRL-;}{CTRL-;}{/inv}{CTRL-,}{inv}___{/inv}{CTRL-,}{INS CHAR}{inv}+U{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}{CTRL-A}{CTRL-A}{/inv}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{INS CHAR}{inv}w{CTRL-C}{CTRL-A}{CTRL-C}w{/inv}{INS CHAR}{CTRL-,}{INS CHAR}{inv}oA{CTRL-A}Ao{/inv}{INS CHAR}{CTRL-,}{CTRL-X}8:vf{INS CHAR}{inv}C{/inv}{CTRL-,}"
10008 FIRE=ADR("{CTRL-,}{CTRL-,}{CTRL-H}Y{inv}V{CTRL-;}/{/inv}z{CTRL-,}{CTRL-,}{CTRL-P}{inv}{CTRL-Z}{/inv}k{inv}_u{/inv}^")
10009 DEV$="){inv}99{CTRL-R}z<({/inv}l{inv}(99Q9>{/inv}(l({inv}<:{CTRL-Q}y>(l{/inv}"
10010 POKE 204,152:POKE 206,224:I=USR(MOV,I,CHR,512):RESTORE 30000:FLG=0
10018 ZQ=USR(MOV,ADR(SET$),38920,120)
10020 READ I:IF I=-1 THEN RETURN
10030 FOR Z=0 TO 7:READ T:POKE (CHR+I*8)+Z,T:NEXT Z
10040 GOTO 10020
30140 REM
30150 DATA 26,0,0,8,89,214,251,175,122
30160 DATA 27,82,218,219,127,182,171,239,90
30170 DATA 28,170,170,170,170,170,170,170,170
30175 DATA 30,85,85,85,85,85,85,85,85
30180 DATA -1

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: HELL.BAS.

Credits