Salvage 2001

Type
Game
Category
First-person exploration game
Author
Jim Tesch
Published in
Antic, September 1989 (Vol. 8, No. 5), Game of the Month
Year
1989
Language
Atari BASIC
Requirements
48K RAM, Atari BASIC, disk drive, joystick in port 1
A long grey-shaded alien starship among white stars in the upper GRAPHICS 9 part of the screen, above grey and green text panels reading SALVAGE 2001, BY JIM TESCH, PRESS START

About the program

It's the 21st century, a great time for junk. You own a surplus shuttle and a surplus spacesuit, and on a test flight you meet a huge alien starship drifting into the solar system, apparently abandoned. Now you're marooned aboard it, and your only way home is to restart its engines. You need to reach the engineering section on each of five decks. Each deck has 30 rooms, with a slightly different layout every game, and some corridors are one-way and close behind you.

Jim Tesch, from Fort Smith, Arkansas, owned an Atari he called "Gypsy", and this was his first Antic program. It ran as the September 1989 Game of the Month.

Typing it in

You need 48K. Lines 1080–1100 hold the display-list interrupt routines as strings of inverse and control characters. The magazine's second listing wrote them to LINES.LST for merging, and the disk version printed here includes them. {inv}…{/inv} means type with the Atari key on, {CTRL-M} means hold CTRL and press M, and the compass lines (660 onwards) use editing characters such as {DEL LINE}, {INS LINE} and {SHIFT-TAB}, typed by pressing ESC and then the key. Several lines do nothing but waste time, for example I=2^2^2^2, so keep them for the pauses.

How to play

Press START at the title screen, which shows the alien ship. Your helmet shows a 3-D view of the room you're in, with doorways where there are exits. Push the joystick forward, left or right to go through a door, or pull back to return to the room behind you. Below the view, a compass shows which way you're facing (Bow, Port, Aft or Starboard), and two bars show your oxygen and battery. Both run down as you move.

Large tanks refill your oxygen and triangles mark battery rechargers. Stand in the room and press the button. But the suit is old. The longer the game goes on, the more likely a refill is to cause a blowout that costs you supplies. OPTION shows the room number, at the cost of some energy. When you reach engineering (2,500 points), find the trans-shaft, the bar on the wall, to beam up to the next deck. Activating the ship doubles your score and makes you famous.

How it works

This is the most technical game in this run of Antic. Lines 1700–1750 build a custom display list in page 6. Eighty lines of ANTIC mode F, shown as GRAPHICS 9 with 16 shades of one colour, make the 3-D view, followed by 14 lines of ANTIC mode 4 multicolour text for the compass and messages. The program draws into both parts of the same screen by changing the OS's idea of the current mode (location 87) and the screen-memory pointer (88/89). Subroutine 1760 swaps between the two. The display-list interrupt routines in DLI$ change the display settings partway down the screen, so the two kinds of line can share one screen.

The rooms are drawn on the fly in lines 470–650. The view is a perspective box of shaded lines, with a far door drawn as nested rectangles of decreasing brightness and side doors as shaded parallelograms. The deck map is just two arrays. D() holds four exits per room (the room-number offset for each direction, or 0 for a wall), and R() marks special rooms: 1 for oxygen, 2 for a recharger, 3 for engineering and 4 for the trans-shaft. F(1) to F(4) rotate the compass, so "forward" always means the way you're facing. The oxygen and energy bars are players 0 and 1. Their length is POKEd into player memory, and they change colour as they run down, ending in red when supplies are low (lines 370–460).

Variations to try

  • A gentler suit: lower OLOSS and ELOSS (oxygen and energy used per move) in line 40.
  • Fewer blowouts: raise the 7500 in lines 390 and 440.

Listing

1 REM SALVAGE 2001 BY JIM TESCH
2 REM (C) 1989 ANTIC PUBLISHING
10 GOSUB 1700:GOSUB 1490:GOSUB 1070:GOSUB 1140
20 GOSUB 1360:POKE 559,46:GOSUB 1340:TXT$="SALVAGE 2001":Y=9:GOSUB 1320:TXT$="BY JIM TESCH":Y=10:GOSUB 1320
30 TXT$="PRESS START":Y=11:GOSUB 1320
40 POKE 53277,2:T=0:LVL=1:O=21:E=21:OLOSS=0.4:ELOSS=0.3:SCORE=0:POKE 704,94:POKE 705,94
50 IF PEEK(53279)=6 THEN GOSUB 370:GOSUB 420:I=2^2^2^2:GOSUB 310:GOTO 70
60 C=15*(C<>15):COLOR C:PLOT 39,4:PLOT 39,34:PLOT 68,28:FOR I=1 TO 200:NEXT I:GOTO 50
70 IF LVL=6 THEN GOTO 340
80 GOSUB 900:GOSUB 470:POKE 53279,8
90 IF O<=0 OR E<=0 THEN GOTO 320
100 IF  NOT R(ROOM) THEN 190
110 IF R(ROOM)=1 AND STRIG(0)=0 THEN SOUND 0,25,8,6:O=21:GOSUB 370:SOUND 0,0,0,0
120 IF R(ROOM)=2 AND STRIG(0)=0 THEN SOUND 0,5,2,6:E=21:GOSUB 420:SOUND 0,0,0,0
130 IF R(ROOM)<>3 OR (R(ROOM)=3 AND ENG=1) THEN 160
140 ENG=1:Y=9:TXT$="ENGINEERING":GOSUB 1320:I=2^2:SOUND 0,250,2,8:GOSUB 775
150 SCORE=SCORE+2500:GOSUB 310:POKE 734,32+(LVL*16):SOUND 0,0,0,0
160 IF R(ROOM)<>4 OR (R(ROOM)=4 AND ENG=0) THEN 190
170 POKE 734,32:TXT$="TRANSHAFT ACTIVE":Y=9:GOSUB 1320:LVL=LVL+1:GOSUB 785
180 SCORE=SCORE+5000+1000*((T-LVL*240)<0):GOSUB 310:GOTO 70
190 STK=STICK(0):T=T+1
200 IF STK=6 OR STK=5 OR STK=9 OR STK=10 OR STK=15 THEN 260
210 IF STK=14 AND D(F(1)+F) THEN ROOM=ROOM+D(F(1)+F):NR=1
220 IF STK=7 AND D(F(2)+F) THEN ROOM=ROOM+D(F(2)+F):F(1)=F(2):NR=1
230 IF STK=13 AND D(F(3)+F) THEN ROOM=ROOM+D(F(3)+F):F(1)=F(3):NR=1
240 IF STK=11 AND D(F(4)+F) THEN ROOM=ROOM+D(F(4)+F):F(1)=F(4):NR=1
250 IF NR THEN NR=0:GOSUB 470
260 IF PEEK(53279)=6 THEN 20
270 IF PEEK(764)=48 THEN 270
280 IF PEEK(53279)=3 THEN TXT$="ROOM ":TXT$(6)=STR$(ROOM):Y=9:GOSUB 1320:GOSUB 420:GOSUB 420:POKE 53279,8
290 IF T/50=INT(T/50) THEN GOSUB 890
300 GOTO 90
310 TXT$="        ":Y=12:GOSUB 1320:TXT$=STR$(SCORE):GOSUB 1320:RETURN
320 COLOR 0:FOR I=1 TO 6:X=RND(0)*79:Y=RND(0)*79:PLOT 39,39:DRAWTO X,Y:X2=X:Y2=Y:NEXT I
330 TXT$="TERMINAL CONDITION":Y=9:GOSUB 1320:TXT$="ALL VITAL SIGNS CEASED":Y=10:GOSUB 1320:I=2^2^2^2:GOTO 20
340 GOSUB 1340:GOSUB 1360:COLOR 15:PLOT 50,25:PLOT 52,25:PLOT 54,25
350 POKE 559,46:TXT$="SHIP ACTIVATED!":Y=9:GOSUB 1320:TXT$="YOU ARE FAMOUS!":Y=10:GOSUB 1320
360 SCORE=SCORE*2:GOSUB 310:GOTO 40
370 P=PM+512+89:POKE 53248,167:O=O-OLOSS:IF O>20 THEN O=20:GOTO 390:REM OXYGEN
380 POKE P-O,0:POKE 704,50+166*(O>7)-(30*(O>14)):RETURN
390 IF LVL=1 OR RND(0)*7500>T THEN GOTO 410
400 C=PEEK(734):FOR I=14 TO 0 STEP -1:POKE 734,I:SOUND 0,250,0,I:O=O-RND(0)*O:NEXT I:POKE 734,C
410 FOR I=1 TO 20:POKE P-I,0:NEXT I:FOR I=1 TO O:POKE P-I,120:NEXT I:POKE 704,50+166*(O>7)-30*(O>14):RETURN
420 POKE 53249,187:P=PM+640+89:E=E-ELOSS:IF E>20 THEN E=20:GOTO 440:REM ENERGY
430 POKE P-E,0:POKE 705,50+166*(E>7)-(30*(E>14)):RETURN
440 IF LVL=1 OR RND(0)*7500>T THEN GOTO 460
450 C=PEEK(734):FOR I=14 TO 0 STEP -1:POKE 734,I:SOUND 0,250,0,I:E=E-RND(0)*E:NEXT I:POKE 734,C
460 FOR I=1 TO 20:POKE P-I,0:NEXT I:FOR I=1 TO E:POKE P-I,120:NEXT I:POKE 705,50+166*(E>7)-30*(E>14):RETURN
470 POKE 559,0:POKE 87,9:POKE 77,0:GOSUB 1760:GOSUB 1340:REM ROOM DRAW
480 IF F(1)=0 THEN F(2)=1:F(3)=2:F(4)=3
490 IF F(1)=1 THEN F(2)=2:F(3)=3:F(4)=0
500 IF F(1)=2 THEN F(2)=3:F(3)=0:F(4)=1
510 IF F(1)=3 THEN F(2)=0:F(3)=1:F(4)=2
520 COLOR 9:FOR I=0 TO 79:COLOR 9:PLOT 0,I:DRAWTO 79,I:NEXT I:GOSUB 890
530 COLOR 6:PLOT 18,10:DRAWTO 61,10:PLOT 18,10:DRAWTO 18,79:PLOT 61,10:DRAWTO 61,79
540 FOR I=-1 TO 1:COLOR 7-I:PLOT 9-I,0:DRAWTO 17,9:PLOT 62,9:DRAWTO 70-I,0:NEXT I
550 F=(ROOM-1)*4:IF  NOT D(F(1)+F) THEN 580
560 C=7:FOR I=10 TO 0 STEP -1:C=C-1*(C>0):COLOR C:REM C
570 X=40-I:X2=40+I:Y=35-I:PLOT X,Y:DRAWTO X2,Y:PLOT X,Y:DRAWTO X,79:PLOT X2,Y:DRAWTO X2,79:NEXT I
580 IF  NOT D(F(4)+F) THEN 620
590 FOR I=-1 TO 1:COLOR 5-I:PLOT 0,12+I:DRAWTO 10,21:NEXT I:REM LEFT DOOR
600 COLOR 4:FOR I=0 TO 10:PLOT 0,12+I:DRAWTO 10,22:NEXT I
610 FOR I=0 TO 10:COLOR 10-I*0.5:PLOT 10-I,23:DRAWTO 10-I,79:NEXT I
620 IF  NOT D(F(2)+F) THEN 660
630 FOR I=-1 TO 1:COLOR 5-I:PLOT 79,12:NEXT I:REM RIGHT DOOR
640 COLOR 4:FOR I=0 TO 10:PLOT 79,12+I:DRAWTO 69,22:NEXT I
650 FOR I=0 TO 10:COLOR 10-I*0.5:PLOT 69+I,23:DRAWTO 69+I,79:NEXT I
660 POSITION 4,4:POKE 87,0:GOSUB 1760:IF F(1)=0 THEN ? #6;"{DEL LINE}":POSITION 4,2:? #6;"{inv}B{/inv}"
670 IF F(2)=0 THEN ? #6;"{SHIFT-TAB}":POSITION 4,2:? #6;"{inv}P{/inv}"
680 IF F(3)=0 THEN ? #6;"{INS LINE}":POSITION 4,2:? #6;"{inv}A{/inv}"
690 IF F(4)=0 THEN ? #6;"{CTRL-TAB}":POSITION 4,2:? #6;"{inv}S{/inv}"
700 POKE 87,9:GOSUB 1760:ON R(ROOM)>0 GOSUB 700+20*(R(ROOM))
710 POKE 559,46:RETURN
720 REM OXYGEN DRAW
725 COLOR 2:PLOT 55,37:DRAWTO 55,39:PLOT 54,38:DRAWTO 56,38:FOR I=-3 TO 3:COLOR 11-I:PLOT 55,40:DRAWTO 55+I,45
730 NEXT I:X=52:FOR I=-3 TO 3:COLOR 12-I:PLOT X,45:DRAWTO X,79:X=X+1:NEXT I:RETURN
740 COLOR 4:PLOT 25,37:DRAWTO 21,47:DRAWTO 29,47:DRAWTO 25,37:COLOR 15:PLOT 23,42:DRAWTO 27,42
750 RETURN
760 FOR I=1 TO 6:COLOR 3:PLOT 20+I,15:DRAWTO 20+I,37:PLOT 53+I,15:DRAWTO 53+I,37:NEXT I:IF ENG THEN 775
770 RETURN
775 FOR I=1 TO 20:C=RND(0)*16:COLOR C:X=RND(0)*5+21:Y=RND(0)*21+15:PLOT X,Y:PLOT X+33,Y:NEXT I
776 COLOR 14:PLOT 26,15:DRAWTO 53,15:RETURN
780 COLOR 0:PLOT 20,14:DRAWTO 59,14:RETURN
785 COLOR 15:FOR I=0 TO 39:PLOT 20+I,14:SOUND 0,39-I,12,8:NEXT I
790 FOR I=200 TO 0 STEP -1:COLOR RND(0)*15:PLOT RND(0)*79,RND(0)*79:SOUND 0,I,12,8:NEXT I:SOUND 0,0,0,0:RETURN
890 FOR I=-8 TO 8 STEP 0.15:SOUND 0,80,8,ABS(I):NEXT I:SOUND 0,0,0,0:GOSUB 370:GOSUB 420:RETURN
900 POKE 559,0:POKE 734,112:ENG=0:FOR I=1 TO 30:R(I)=0:NEXT I:REM DECK
910 FOR I=1 TO 30:R=(I-1)*4:D(R)=-5*(I>5):D(R+1)=1*(I/5<>INT(I/5)):D(R+2)=5*(I<26)
920 D(R+3)=-1*((I+4)/5<>INT((I+4)/5)):NEXT I
930 FOR I=0 TO 99 STEP 12:R=INT(RND(0)*20)+I:D(R)=0:NEXT I
940 FOR I=1 TO 6-LVL:REM OXYGEN
950 R=INT(RND(0)*30)+1:R(R)=1:NEXT I
960 FOR I=1 TO 6-LVL:REM PLACE POWER
970 R=INT(RND(0)*30)+1:IF R(R)<>0 THEN 970
980 R(R)=2:NEXT I
990 R=INT(RND(0)*30)+1:IF R(R)<>0 THEN 990:REM PLACE ENGINEERING
1000 R(R)=3
1010 R=INT(RND(0)*30)+1:IF R(R)<>0 THEN 1010
1020 R(R)=4:ROOM=INT(RND(0)*30)+1
1030 ROOM=INT(RND(0)*30)+1:IF R(ROOM)<>0 THEN 1030
1040 F=(ROOM-1)*4
1050 IF  NOT D(F) THEN F=F+1:GOTO 1050
1060 F(1)=INT(F/ROOM)-1:RETURN
1070 POKE 559,0:DIM DLI$(96):REM DLI ROUTINES
1080 DLI$="H{inv}-{/inv}{CTRL-,}{CTRL-A}{inv}n{/inv}{CTRL-,}{CTRL-A}{inv}{CTRL-M}{/inv}{CTRL-J}{inv}TI{/inv}{CTRL-,}{inv}P{/inv}{CTRL-M}{inv}){/inv}@{inv}{CTRL-M}{/inv}{ESC}{inv}P-^{/inv}{CTRL-B}{inv}{CTRL-M}{/inv}{CTRL-Z}{inv}P{/inv}h@{inv}I{/inv}{CTRL-A}{inv}P{/inv} {inv}){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{ESC}{inv}P){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{CTRL-V}"
1090 DLI$(41)="{inv}P){/inv}B{inv}{CTRL-M}{/inv}{CTRL-W}{inv}P)X{CTRL-M}{/inv}{CTRL-X}{inv}P)H{CTRL-M}{/inv}{CTRL-Y}{inv}P){/inv}{CTRL-F}{inv}{CTRL-M}{/inv}{CTRL-Z}{inv}P{/inv}h@{inv}I{/inv}{CTRL-B}{inv}P{/inv}{CTRL-Q}{inv}){/inv}{CTRL-N}{inv}{CTRL-M}{/inv}{CTRL-X}{inv}P){/inv}{CTRL-F}{inv}{CTRL-M}{/inv}{CTRL-Y}{inv}P)H{CTRL-M}{/inv}"
1100 DLI$(81)="{CTRL-Z}{inv}P{/inv}h@{inv}){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{CTRL-,}{CTRL-A}{inv}){/inv}{CTRL-J}{inv}{CTRL-M}{/inv}{CTRL-Z}{inv}P{/inv}h@"
1110 POKE DL,240:POKE DL+84,143:POKE DL+93,132:POKE DL+97,132
1120 B=INT(ADR(DLI$)/256):A=ADR(DLI$)-B*256:POKE 512,A:POKE 513,B
1130 POKE 54286,192:POKE 256,Z:POKE 559,34:RETURN
1140 POKE 87,0:GOSUB 1760:POKE 82,0
1150 POKE 559,0:POKE 752,1:REM LOWER SCREEN
1160 ? #6;"c c c c c caaaaaaaaaaaaaaaaaac c c c c c";
1170 ? #6;"{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}f bbbbbbbbbbbbbbbbbb           ";
1180 ? #6;"{CTRL-V}{CTRL-G}  {CTRL-Y}  {CTRL-F}{CTRL-V}                     O    E {CTRL-E}  ";
1190 ? #6;"{CTRL-V}       {CTRL-V}e   {CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}ffffff{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}   ' {CTRL-N}{CTRL-N} ' {CTRL-Y}  ";
1200 ? #6;"{CTRL-V}{CTRL-R}  {DEL LINE}  {CTRL-R}{CTRL-V}    {CTRL-A}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-D}   '    ' {CTRL-Y} c";
1210 ? #6;"{CTRL-V}       {CTRL-V}{inv}e{/inv}   {CTRL-A}{CTRL-D}          {CTRL-A}{CTRL-D}   ' {CTRL-N}{CTRL-N} ' {CTRL-Y}  ";
1220 ? #6;"{CTRL-V}{CTRL-F}  {CTRL-Y}  {CTRL-G}{CTRL-V}    {CTRL-Z}{CTRL-D} {CTRL-U}{CTRL-U}{CTRL-U}{CTRL-U}{CTRL-U}{CTRL-U}{CTRL-U}{CTRL-U} {CTRL-A}{CTRL-C}   '    ' {CTRL-Y}  ";
1230 ? #6;"{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}     {inv}dddddddddddd{/inv}    ' {CTRL-N}{CTRL-N} ' {CTRL-Y}  ";
1240 ? #6;"{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}    {inv}dddddddddddddd{/inv}   '    ' {CTRL-C}  ";
1250 ? #6;"{inv}dddd{/inv}                                {inv}dddd{/inv}";
1260 ? #6;"{inv}ddd{/inv}                                  {inv}ddd{/inv}";
1270 ? #6;"{inv}ddd{/inv}                                  {inv}ddd{/inv}";
1280 ? #6;"{inv}dddddd{/inv}                            {inv}dddddd{/inv}";
1290 ? #6;"c  c  c  c  c  c  c  c  c  c  c  c  c  c";
1300 RETURN
1310 REM TEXT PRINTER
1320 G=PEEK(87):POKE 87,0:GOSUB 1760:X=20-LEN(TXT$)/2:X2=X:FOR I=1 TO LEN(TXT$):POSITION X,Y:? #6;TXT$(I,I)
1330 SOUND 0,4,10,8:SOUND 0,0,0,0:X=X+1:NEXT I:POKE 87,G:GOSUB 1760:RETURN
1340 G=PEEK(87):POKE 87,0:GOSUB 1760:FOR I=9 TO 11:POSITION 5,I:? #6;"                          ":NEXT I:POKE 87,G
1350 GOSUB 1760:RETURN
1360 POKE 87,9:POKE 734,0:POKE 559,0:GOSUB 1760:REM SETUP TITLE SCREEN
1370 COLOR 0:FOR Y=0 TO 79:PLOT 0,Y:DRAWTO 79,Y:NEXT Y
1380 COLOR 12:FOR I=1 TO 25:X=RND(0)*79:Y=RND(0)*79:PLOT X,Y:NEXT I
1390 X=60:Y=10:FOR I=-2 TO 2:COLOR 8-ABS(I):PLOT X,Y:DRAWTO X+5,Y:Y=Y+1:X=X+I:NEXT I
1400 X=25:Y=16:FOR I=-4 TO 4:COLOR 8-ABS(I):PLOT X,Y:DRAWTO X+14,Y:Y=Y+1:NEXT I:COLOR 15:PLOT 34,24:DRAWTO 36,24
1410 X=31:Y=13:FOR I=-7 TO 7:COLOR 10-ABS(I):PLOT X,Y:DRAWTO X+5,Y:X=X+I:Y=Y+1:NEXT I
1420 X=39:Y=12:FOR I=-8 TO 8:COLOR 11-ABS(I):PLOT X,Y:DRAWTO X+20,Y:Y=Y+1:NEXT I:REM BODY
1430 X=33:Y=12:FOR I=-8 TO 8:COLOR 13-ABS(I):PLOT X,Y:DRAWTO X+5*(I<0),Y:X=X-1*(I<0):Y=Y+1:NEXT I
1440 X=39:Y=5:FOR I=-14 TO 14:COLOR 15-ABS(I):PLOT X,Y:Y=Y+1:NEXT I:COLOR 5:PLOT 57,28:DRAWTO 67,28
1450 X=72:Y=35:FOR I=0 TO 1:COLOR 10-I*4:PLOT X,Y:DRAWTO 74,Y:X=X-1:Y=Y+1:NEXT I
1460 X=50:COLOR 0:PLOT X,25:PLOT X+2,25:PLOT X+4,25
1470 X=72:Y=35:FOR I=0 TO 1:COLOR 10-I*4:PLOT X,Y:DRAWTO 74,Y:X=X-1:Y=Y+1:NEXT I
1480 COLOR 12:PLOT 74,33:DRAWTO 74,34:RETURN
1490 POKE 559,0:CH=CHBAS*256:FOR I=0 TO 1023:POKE CH+I,PEEK(57344+I):NEXT I:RESTORE 1520:REM CHSET
1500 READ A:IF A=-1 THEN POKE 559,34:POKE 756,CHBAS:RETURN
1510 FOR I=0 TO 7:READ X:POKE CH+A*8+I,X:NEXT I:GOTO 1500
1520 DATA 1,0,60,60,60,60,0,60,0,16,0,252,204,204,204,204,252,0,17,0,240,48,48,48,48,48,0
1530 DATA 18,0,252,12,12,252,192,252,0,19,0,252,12,60,12,12,252,0,20,0,204,204,204,252,12,12,0
1540 DATA 21,0,252,192,192,252,12,252,0,22,0,252,192,252,204,204,252,0,23,0,252,12,12,60,48,48,0
1550 DATA 24,0,252,204,204,252,204,252,0,25,0,252,204,252,12,12,12,0,26,0,0,48,48,0,48,48,0
1560 DATA 33,0,252,204,204,252,204,204,0,34,0,252,204,240,204,204,252,0,35,0,252,204,192,192,204,252,0
1570 DATA 36,0,240,204,204,204,204,240,0,37,0,252,192,240,192,192,252,0,38,0,252,192,240,192,192,192,0
1580 DATA 39,0,252,192,192,204,204,252,0,40,0,204,204,252,204,204,204,0,41,0,252,48,48,48,48,252,0
1590 DATA 42,0,12,12,12,204,204,252,0,43,0,204,204,240,240,204,204,0,44,0,192,192,192,192,192,252,0
1600 DATA 45,0,204,204,252,252,204,204,0,46,0,252,204,204,204,204,204,0,47,0,48,204,204,204,204,48,0
1610 DATA 48,0,240,204,204,240,192,192,0,49,0,48,204,204,204,204,60,15,50,0,252,204,204,240,204,204,0
1620 DATA 51,0,252,192,252,12,12,252,0,52,0,252,48,48,48,48,48,0,53,0,204,204,204,204,204,252,0
1630 DATA 54,0,204,204,204,204,252,48,0,55,0,204,204,204,252,252,204,0,56,0,204,204,48,48,204,204,0
1640 DATA 57,0,204,204,48,48,48,48,0,58,0,252,12,60,240,192,252,0,86,16,16,16,16,16,16,16,16
1650 DATA 92,0,48,252,204,48,48,48,0,93,0,48,48,48,204,252,48,0,94,0,12,48,255,48,12,0,0
1660 DATA 95,0,48,12,255,12,48,0,0,97,20,85,105,105,105,105,105,105,98,105,105,105,105,85,20,0,0
1670 DATA 99,0,20,65,85,65,20,0,0,100,255,255,255,255,255,255,255,255,101,0,0,0,255,255,255,255,255
1680 DATA 102,0,0,0,170,170,170,170,170, 103,170,170,170,170,170,170,170,170,124,192,192,192,192,192,192,192,192
1690 DATA -1
1700 A=PEEK(106):PMBAS=A-8:CHBAS=A-16:POKE 106,CHBAS:POKE 54279,PMBAS:DL=1536:REM DISPLAY LIST
1710 DIM TXT$(30),R(30),D(119),F(4):PM=PMBAS*256:GRAPHICS 8:POKE 559,0
1720 FOR I=0 TO 2:POKE DL+I,112:NEXT I:POKE DL+3,79:POKE DL+4,PEEK(88):POKE DL+5,PEEK(89)
1730 FOR I=6 TO 84:POKE DL+I,15:NEXT I:FOR I=85 TO 98:POKE DL+I,4:NEXT I:POKE DL+99,65
1740 S1=PEEK(88):S2=PEEK(89):S4=S1+S2*256+3200:S3=S4-256*INT(S4/256):S4=INT(S4/256)
1750 POKE 560,0:POKE 561,DL/256:POKE 559,34:RETURN
1760 IF PEEK(87)=9 THEN POKE 88,S1:POKE 89,S2:RETURN :REM SCREEN MEMORY
1770 POKE 88,S3:POKE 89,S4:RETURN

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: SALVAGE.BAS.

Credits