Valiant
- Type
- Game
- Category
- Scrolling maze adventure
- Author
- J. Sutherland
- Published in
- Antic, August 1985 (Vol. 4, No. 4), Game of the Month
- Year
- 1985
- Language
- Atari BASIC (with machine-language helper)
- Requirements
- 48K RAM recommended (see notes), Atari BASIC, joystick in port 1
About the program
Valiant was Antic's Game of the Month for August 1985, "a big, fast-scrolling maze adventure from the author of Arena Racer". The two games share the same machine-language window routine. You play the adventurer Hardluck. You have ignored an old man's warning in a tavern, ridden into the cursed Dimlit Forest after the legendary Golden Sword, and found that the only way out runs through the Doorway of Doom into the Underground Fortress of the Invisible Ghouls.
Inside, you collect treasure, pick up keys to open locked doors, find the Golden Sword and then look for the Heroes' Exit. You start with 100 strength points. The ghouls can't be seen until you run into one, and then they drain your strength until you get away or die. Your final score depends on the treasures you have taken.
Typing it in
Line 1020 (a machine-language routine in a string) and line 1080 contain special characters. {inv} … {/inv} means press the Atari (inverse) key before and after. {CTRL-,} and {CTRL-.} are CTRL with the comma and full stop. {CTRL-X} and {CTRL-F} mean hold CTRL and press the letter. {INS LINE} is ESC then SHIFT-INSERT, and {CLEAR} is ESC then SHIFT-CLEAR. The maze itself is in the DATA lines from 5200, which are long but plain. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.
Memory: the magazine said 32K disk or 24K cassette. However, the program sets its character set at page 152 (CB=152, about 38K) and PEEKs screen memory at the fixed address 40405. Both are only correct on a machine with 48K or more, such as any XL/XE, and that is where it runs here.
How to play
Press the trigger at the opening screen. Push the joystick up, down, left or right to move. Diagonals aren't used. The view scrolls round you. Walk into a key to pick it up (your keys appear at the bottom of the screen). Walk into a door while carrying a key to open it, which uses up the key. Gold adds to your GP (gold pieces) count, and keys and gold both raise EX. ST is your strength. If you blunder into a ghoul it shows itself and your strength starts to fall, so move away fast. Once you have the Golden Sword, find the exit at the far left of the fortress to win.
How it works
- The whole fortress lives in one string,
S$, built from DATA in lines 1300–1350 and laid out as rows 70 characters wide. Every move callsUSR(1536,ADR(S$)+70*Y+X), which copies a window of the maze onto a full-screen GRAPHICS 1 (GRAPHICS 17) display with Hardluck in the middle. - Instead of LOCATE, the program PEEKs screen memory beside the hero (
PEEK(40405+XD+20*YD)). The character code found there decides what happens: 0 is empty, 138 a key, 11 a door, 131 treasure, 133 the sword and 64 a ghoul (lines 50–130). - The first 104 bytes of a custom character set (line 1050) draw walls, doors, keys and treasure.
Listing
1 REM VALIANT
2 REM BY J. SUTHERLAND
3 REM (c) 1985, ANTIC PUBLISHING
7 GOTO 1000
10 A=USR(1536,ADR(S$)+70*Y+X)
20 S=STICK(0):IF S=15 THEN 20
30 XD=(S=7)-(S=11)
40 YD=(S=13)-(S=14)
50 IF PEEK(40405+XD+20*YD)=0 THEN X=X+XD:Y=Y+YD:SOUND 0,100,10,10:SOUND 0,0,0,0:GOTO 10
60 P=PEEK(40405+XD+20*YD):IF P=33 THEN 10
70 IF P=138 THEN KEY=KEY+1:EX=EX+5:GOSUB 1110
80 IF P=11 AND X=0 AND Y=40 AND SW<1 THEN 10
90 IF P=11 AND X=0 AND Y=40 AND SW=1 AND KEY>0 THEN 1470
100 IF P=11 AND KEY THEN GOSUB 1190:GOSUB 1110:GOSUB 1150:IF F THEN F=0:GOTO 1350
110 IF P=131 THEN GOSUB 1110:GP=GP+25:EX=EX+10
120 IF P=64 THEN POSITION 5+XD,4+YD:? #6;"{inv}{CTRL-F}{/inv}":GOTO 1380
130 IF P=133 THEN SW=1:GOSUB 1110
140 GOSUB 1150:GOTO 10
1000 CLR :GRAPHICS 17
1010 CB=152:POKE 756,CB:ML=1536
1020 A=USR(ADR("h{inv}"{/inv}{CTRL-,}{inv}={/inv}{CTRL-,}{inv}{CTRL-.}{/inv}{INS LINE}{CTRL-,}{inv}{CTRL-X}={/inv}{CTRL-,}{inv}a{/inv}{INS LINE}{CTRL-,}{inv}{CTRL-Y}h{CTRL-.}{/inv}{CTRL-,}{inv}Po{/inv}{CTRL-.}"))
1030 DIM T$(71),S$(3710),K$(16),F$(150)
1040 READ A:IF A>-1 THEN POKE ML+K,A:K=K+1:GOTO 1040
1050 FOR J=0 TO 103:READ A:POKE CB*256+J,A:NEXT J
1060 REM
1070 GOSUB 1300
1080 GRAPHICS 17:K$="{inv}*{CTRL-,}*{CTRL-,}*{CTRL-,}*{CTRL-,}*{CTRL-,}*{CTRL-,}*{CTRL-,}*{/inv}":POKE 709,70:POKE 708,138:POKE 710,26:POKE 711,200
1090 POKE 756,CB:POSITION 12,2:? #6;"(:":POSITION 12,4:? #6;"):":POSITION 12,6:? #6;"':":GOSUB 1150
1100 GOTO 1210
1110 D=XD+20*YD:POKE 40405+D,0
1120 LOC=70*(Y+YD)+X+XD+285:S$(LOC,LOC)="{CTRL-,}"
1130 FOR J=100 TO 80 STEP -0.5:SOUND 0,J,10,12:NEXT J:SOUND 0,0,0,0
1140 RETURN
1150 IF KEY THEN POSITION 1,14:? #6;K$(1,KEY*2):GOTO 1160
1155 POSITION 1,14:? #6;" "
1160 IF SW THEN POSITION 3,16:? #6;"{inv}%{/inv}"
1170 POSITION 14,2:? #6;ST;" ":POSITION 14,4:? #6;EX:POSITION 14,6:? #6;GP;" "
1180 RETURN
1190 KEY=KEY-1:POKE 40405+XD+20*YD,0:FOR J=90 TO 100 STEP 0.5:SOUND 0,J,10,12:NEXT J:SOUND 0,0,0,0
1200 RETURN
1210 X=10:Y=30:ST=100:F=1:A=USR(1536,ADR(S$)+70*Y+X):EX=0:GP=0
1220 POSITION 7,20:? #6;"{inv}valiant{/inv}":POSITION 5,16:? #6;"{inv}HIT TRIGGER{/inv}":POSITION 2,22:? #6;"{inv}BY J. SUTHERLAND{/inv}"
1230 POSITION 0,10:? #6;"{inv}*{/inv} = KEY{CTRL-,}{CTRL-,}{CTRL-,}{inv}#{/inv} = GOLD":? #6:? #6;"{inv}{CTRL-F}{/inv} = GHOUL{CTRL-,}{inv}%{/inv} = SWORD"
1240 ? #6:? #6;"+ = LOCKED DOOR"
1250 IF STRIG(0) THEN 1250
1260 POSITION 5,16:? #6;" {inv}GOOD LUCK{/inv} "
1270 FOR J=-40 TO 40:SOUND 0,ABS(J)+120,10,12:NEXT J:SOUND 0,0,0,0:POSITION 0,10:FOR J=1 TO 4
1280 ? #6;" ":? #6:NEXT J:POSITION 6,16:? #6;" "
1290 GOTO 10
1300 RESTORE 5690:READ F$,T$:F$(LEN(F$)+1)=T$:READ T$:FOR J=1 TO 4:S$(LEN(S$)+1)=T$:NEXT J
1310 FOR J=1 TO 44:READ A:S$(LEN(S$)+1)="{inv}LLLL{/inv}":S$(LEN(S$)+1)=F$(A,A+62):S$(LEN(S$)+1)="{inv}LLLL{/inv}":NEXT J
1320 FOR J=1 TO 4:S$(LEN(S$)+1)=T$:NEXT J
1330 S$(440,440)="{inv}{CTRL-J}{/inv}":S$(2589,2589)="{CTRL-K}"
1340 RETURN
1350 RESTORE 5200:S$="":FOR J=1 TO 49:READ T$:S$(LEN(S$)+1)=T$:NEXT J
1360 X=3:Y=39
1370 GOTO 10
1380 S1=STICK(0):IF S1<>15 AND S1<>S THEN POSITION 5+XD,4+YD:? #6;" ":S=S1:GOTO 30
1390 SOUND 2,10,10,12:FOR T=1 TO 4:NEXT T:SOUND 2,0,0,0
1400 ST=ST-1:GOSUB 1170:IF ST>1 THEN 1380
1410 FOR T=1 TO 500:NEXT T:? #6;"{CLEAR}":POSITION 3,2:? #6;"YOU HAVE BEEN"
1420 FOR J=1 TO 4:FOR K2=-3 TO 3:K=K2
1430 IF J=4 AND K2=3 THEN K=1
1440 POSITION ABS(K),5:? #6;" D E F E A T E D "
1450 SOUND 0,100-(10*J+5*ABS(K)),10,10:FOR T=1 TO 7+3*J:NEXT T:NEXT K2:NEXT J
1460 SOUND 0,0,0,0:GOTO 1490
1470 ? #6;"{CLEAR}":POSITION 2,2:? #6;"CONGRATULATIONS"
1480 POSITION 6,4:? #6;"YOU WON"
1490 SCORE=EX+10*ST:POSITION 2,9:? #6;"FINAL SCORE: ";SCORE
1500 FOR J=10 TO 20:FOR K=1 TO 9:SOUND 0,J+K*3,10,12:FOR T=1 TO 4:NEXT T:SOUND 0,0,0,0:NEXT K:NEXT J
1510 FOR T=1 TO 1000:NEXT T:RUN
4999 REM MACHINE LANGUAGE DATA
5000 DATA 104,104,133,204,104,133,203
5010 DATA 162,0,160,0
5020 DATA 177,203,157,129,157,232
5030 DATA 200,192,9
5040 DATA 208,245,138,24,105,11,170
5050 DATA 224,180,240,20,234
5060 DATA 165,203,24,233,185,144,2
5070 DATA 230,204,165,203,24,105,70
5080 DATA 133,203,24,144,214,169,2
5090 DATA 141,213,157,169,0,133,77,96,-1
5100 DATA 0,0,0,0,0,0,0,0
5110 DATA 251,251,251,0,191,191,191,0,24,0,60,90,0,24,36,102
5120 DATA 0,15,17,35,69,250,140,248
5130 DATA 248,30,55,51,3,6,12
5140 DATA 0,1,2,4,136,208,96,112,152
5150 DATA 219,90,66,60,24,24,36,102
5160 DATA 224,128,160,174,234,14,8,8
5170 DATA 224,128,224,46,228,4,4,4
5180 DATA 224,128,192,138,234,4,10,10
5190 REM DATA 0,6,6,6,6,102,60,0
5191 DATA 224,160,224,16,8,12,22,4
5192 DATA 255,60,60,44,60,60,60,255
5193 DATA 8,28,42,28,42,73,8,0
5200 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5210 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5220 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5230 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5240 DATA AAAAAAAAAAAAAAAAAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AA{CTRL-,}{inv}{CTRL-J}{/inv}{CTRL-,}{CTRL-,}AAAAA{CTRL-,}{CTRL-,}{CTRL-,}@A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{inv}{CTRL-E}{/inv}AAAA
5250 DATA AAAA{CTRL-,}{inv}{CTRL-C}{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AA{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-K}{CTRL-,}AAAA
5260 DATA AAAAAAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAA{CTRL-,}AAAAAA{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A@@{CTRL-,}@{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}AAAAAAAA
5270 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{inv}{CTRL-J}{/inv}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5280 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAA{CTRL-,}AAAA{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}AAAAA{CTRL-,}AAAA
5290 DATA AAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AAAAAAAAAAAAAA{CTRL-,}AAAAAAAAA{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-C}{/inv}AAAA
5300 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AAAAAAAAAAAA
5310 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}@{CTRL-,}{CTRL-,}@{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA{CTRL-,}{CTRL-,}AAA{CTRL-,}AAAA{CTRL-,}AAAA{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5320 DATA AAAA{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAAAAAAAAAAAAAAAAAAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}AAAAAAAAA{CTRL-,}AAAA
5330 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AAAA
5340 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}AAAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAAAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}AAAA
5350 DATA AAAA{CTRL-,}@{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}AA{CTRL-,}AA{CTRL-,}AAA{CTRL-,}AA{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}AAAA
5360 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A@{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}@A{CTRL-,}AA{CTRL-,}AA{CTRL-,}AA{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}AAAA
5370 DATA AAAA@{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}AA{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}AA{CTRL-,}AA{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AA{CTRL-,}A{CTRL-,}A{CTRL-,}AAAA
5380 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}AA{CTRL-,}AA{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}AAAA
5390 DATA AAAA{CTRL-,}AAAAAAAAAAAAAA{CTRL-,}AA{CTRL-,}AA{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}AAA{CTRL-,}AA{CTRL-,}A{CTRL-,}{CTRL-,}AAAA{CTRL-,}A{CTRL-,}AAAA
5400 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AAAA
5410 DATA AAAA{CTRL-,}{CTRL-,}@{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AAAAAAAAA{CTRL-,}AAAA
5420 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}AAA{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}A{CTRL-,}A{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5430 DATA AAAAAAAAAAA{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAAAAAAAAAAAA{CTRL-K}AAAAAAAAAAAAA{CTRL-,}AAAAAAAAAAAAAAAAAAAAAA
5440 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}@A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5450 DATA AAAA{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}@A{CTRL-,}{CTRL-,}@{inv}{CTRL-J}{/inv}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5460 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5470 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5480 DATA AAAAAAAA{CTRL-,}AAAAAAA{CTRL-,}AA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5490 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAA{CTRL-,}AAAAAAAAAAA{CTRL-,}AAAAAAAAAAAAA{CTRL-,}AAAAAAAAAAAAAAA{CTRL-,}AAAAAA
5500 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5510 DATA AAAAAA{CTRL-,}AA{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A@{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5520 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A@{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}AAAA
5530 DATA AAAA{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}@{CTRL-,}{CTRL-,}@A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5540 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5550 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}@A{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5560 DATA AAAAAAAAAAAA{CTRL-,}AAAAAAAAAAAAAAAAAAAAAAAAAAA{CTRL-,}AAAAAAAAAAAAAAAAAAA{CTRL-,}AAAA{CTRL-,}AAAA
5570 DATA AAAA{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5580 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAA@{inv}{CTRL-C}{/inv}@{inv}{CTRL-J}{/inv}@{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5590 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAAAAAAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAAAAAAAAAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5600 DATA AAAA@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5610 DATA AAAAAAAAAAAAA{CTRL-,}AAA{CTRL-,}AAAAAAAAAAAAAAAAAAAAAAA{CTRL-,}AAAAAAAAAAAA{CTRL-,}AAAAAAAAAAAAAAA
5620 DATA AAAAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{inv}{CTRL-C}{/inv}@{inv}{CTRL-C}{/inv}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5630 DATA AAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAAAAAAAAAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5640 DATA AAAA{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}@{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAA{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{inv}{CTRL-C}{/inv}@{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-K}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAA
5650 DATA AAAA{CTRL-K}A{inv}%8)4{/inv}AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5660 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5670 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5680 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
5690 DATA {inv}LLLL{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}LL{/inv}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}LL{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}LL{/inv}{CTRL-,}{inv}L{/inv}
5700 DATA {CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}LL{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}LL{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}LL{/inv}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}LL{/inv}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}LL{/inv}{CTRL-,}{inv}L{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{inv}L{/inv}{CTRL-,}{inv}LLLL{/inv}
5710 DATA {inv}LLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLL{/inv}
5720 DATA 10,9,4,21,12,14,11,9,5,2,19,29,5,19,21,32,16,7,18,19,22,2,6,3,5,7,4,2,1,4,7,4,12,16,12,21,30,6,3
5730 DATA 9,3,1,4,8,12,16,12,7,2,15,20,22,25,28,34,19,8,4
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: VALIANT.BAS.
Credits
- Program listing: Valiant — program listing (Antic, August 1985 (Vol. 4, No. 4), Game of the Month) — J. Sutherland
- Picture: The opening screen, with its legend of the redefined characters. — J. Sutherland (program); screenshot by the site
- Antic, August 1985 - Vol. 4 No. 4: scan of the printed magazine, PDF page 33 (article) — Internet Archive, 1985
- Antic disk, August 1985 - Vol. 4 No. 4: VALIANT.BAS (detokenized listing) — J. Sutherland, 1985
