Kooky's Quest

Type
Game
Category
Maze adventure with monster combat
Author
Eric Anschuetz, Robert Anschuetz and John Weisgerber
Published in
Antic, February 1985 (Vol. 3, No. 10), Game of the Month
Year
1985
Language
Atari BASIC
Requirements
32K RAM with disk (24K with cassette), Atari BASIC, joystick in port 1 and the keyboard
Title screen reading KOOKY'S QUEST in blue, PRESS START TO BEGIN in purple and green, and the authors' names ANSCHUETZ/WEISGERBER/ANSCHUETZ in white

About the program

Kooky's Quest was Antic's Game of the Month for February 1985, a "windowed scrolling maze adventure" by Eric Anschuetz, Robert Anschuetz and John Weisgerber. The magazine noted that all three were 19-year-old computer science students at Eastern Michigan University. Kooky (a smiley face) is trapped in an evil dungeon. The only way out is to go down to the lowest level, fetch the magic key and carry it back up to the portal on the top level.

Typing it in

The magazine asked readers to check each line with TYPO II as they typed and to SAVE before the first RUN. Special characters appear in nine lines:

  • Cursor controls in strings. A$, B$, F$, G$ and H$ (lines 150–190) mix < characters with {DOWN} and {LEFT}, so that printing one draws a vertical wall. Inside quotes, press ESC and then CTRL with = for {DOWN}, ESC then CTRL-+ for {LEFT}, ESC then CTRL-- for {UP} and ESC then CTRL-* for {RIGHT}.
  • {CLEAR} is ESC then SHIFT-CLEAR. {inv}…{/inv} is inverse video (press the Atari key before and after).

Line 200 is a 6 × 6 table of numbers, one row per monster and one column per weapon. It decides how hard each fight is, so check it carefully.

How to play

Press START, then choose E (expert) or B (beginner). Beginners get a map of the dungeon at the right of the screen, with the stairs marked D and U. Experts have no map and must listen for the stairs. Walk the corridors with the joystick.

Every room holds a treasure (a ring or a chest) and a monster. As you enter a room, pick a weapon with keys 1–6: sword, axe, mace, knife, lightning bolt or fireball. The first three are swung and the last three thrown: hold the button and push left or right. You can only attack sideways, never up or down. Grab the treasure before the monster does, or before either of you dies, or it's lost. You need one treasure to go down to level 2 and five for the deepest levels. You have ten lives for the whole game. The article suggests adding more in line 610. Treasures score 5 points and monsters 10.

How it works

  • The view. A framed window in the middle of the screen shows the corridor round Kooky. When Kooky moves, the program prints the wall strings one step further along, so the walls appear to slide past.
  • The map for each level is a block of DATA (lines 2300 onward) POKEd straight into screen memory by lines 1870–1880. The program reads the map square under Kooky with PEEK to decide which ways are open, and marks his position by setting the inverse bit (POKE X1,N+128).
  • Graphics. Lines 550–570 copy the ROM font to RAM and redefine 31 characters: the weapons, monsters, treasures and walls.
  • Small tricks. POKE 16,64:POKE 53774,64 disables the BREAK key. FOR MIAD=0 TO 0 STEP 0:NEXT MIAD is a loop that never ends, used to freeze the screen on the final message.

Listing

10 REM KOOKY'S QUEST
20 REM BY
30 REM ANSCHUETZ/WEISGERBER/ANSCHUETZ
40 REM ANTIC MAGAZINE
100 GRAPHICS 18:POKE 16,64:POKE 53774,64:DL=PEEK(560)+256*PEEK(561):SETCOLOR 2,0,0
110 POKE DL+10,6:POKE DL+11,6:POKE DL+12,6:POKE DL+13,2:SETCOLOR 0,8,4:POSITION 4,4
120 ? #6;"KOOKY'S QUEST":POSITION 5,8:? #6;"ANSCHUETZ/WEISGERBER/ANSCHUETZ"
130 POSITION 0,6:? #6;"{inv}press{/inv} start {inv}to begin{/inv}":IF PEEK(53279)<>6 THEN 130
140 DIM A$(25),B$(25):GRAPHICS 0:POKE 16,64:POKE 53774,64:POKE 752,1:SETCOLOR 2,0,2:SETCOLOR 4,0,2
150 A$="<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<":B$=" {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} "
160 DIM OHP(6,6),MON$(6),CON$(6),T$(2),WEP$(12):MON$="^;(/:\":CON$="[     ":T$="]_":WEP$="ghefcdabijkl"
170 FOR R=1 TO 6:FOR C=1 TO 6:READ A:OHP(R,C)=A:NEXT C:NEXT R
180 DIM F$(16):F$="<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<"
190 DIM G$(25),H$(25):G$="<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<{DOWN}{LEFT}<":H$="<{DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT} {DOWN}{LEFT}<"
200 DATA 30,15,10,6,5,7.5,10,30,15,5,7.5,6,15,10,30,7.5,6,5,5,7.5,6,15,30,10,7.5,6,5,10,15,30,6,5,7.5,30,10,15
210 DATA 0,0,64,248,64,0,0,0
220 DATA 0,0,2,31,2,0,0,0
230 DATA 0,27,10,254,10,27,0,0
240 DATA 0,216,80,127,80,216,0,0
250 DATA 0,31,14,254,14,31,0,0
260 DATA 0,248,112,127,112,248,0,0
270 DATA 0,64,96,255,96,64,0,0
280 DATA 0,2,6,255,6,2,0,0
290 DATA 0,0,63,24,252,0,0,0
300 DATA 0,0,252,24,63,0,0,0
310 DATA 0,40,18,92,58,72,20,0
320 DATA 0,20,72,58,92,18,40,0
330 DATA 255,135,219,219,219,219,135,255
340 DATA 126,255,255,231,231,255,255,126
350 DATA 60,24,36,66,66,36,24,0
360 DATA 85,85,85,85,85,85,85,85
370 DATA 254,254,254,0,239,239,239,0
380 DATA 0,126,219,255,189,195,126,0
390 DATA 255,231,195,195,231,231,231,255
400 DATA 255,219,147,219,219,219,193,255
410 DATA 126,255,255,255,255,255,255,126
420 DATA 73,114,149,12,126,146,34,85
430 DATA 28,62,42,28,42,34,85,85
440 DATA 36,219,126,66,255,165,36,231
450 DATA 0,0,219,126,24,36,0,0
460 DATA 240,80,248,30,7,33,67,62
470 DATA 0,28,42,28,73,62,8,54
480 DATA 124,84,124,40,254,56,124,238
490 DATA 0,0,192,224,191,234,192,0
500 DATA 60,66,129,255,165,165,255,0
510 DATA 170,170,170,170,170,170,170,170
520 ? "{CLEAR}"
530 DIM CHA$(31):CHA$="abcdefghijkl*+_@<>%&#[^;:/\()]?":CHS=(PEEK(106)-8)*256
540 PM=(PEEK(106)-12)*256:IF PEEK(CHS+9)<>0 THEN 590
545 ? :? :? "    One moment please...":FOR X=1 TO 700:NEXT X:? "{CLEAR}":POKE 559,0
550 FOR I=0 TO 1023:POKE CHS+I,PEEK(57344+I):NEXT I:FOR I=1 TO 31:CHP=CHS+(ASC(CHA$(I))-32)*8
560 IF I<13 THEN CHP=CHP+256
570 FOR J=0 TO 7:READ A:POKE CHP+J,A:NEXT J:NEXT I
580 FOR X=PM+64 TO PM+128:POKE X,255:NEXT X
590 POKE 53277,3:POKE 54279,PM/256-4:POKE 623,1:POKE 53256,3:POSITION 2,12:POKE 559,62
600 OPEN #1,4,0,"K:":? "{RIGHT}{RIGHT}{RIGHT}{RIGHT}SKILL - {inv}E{/inv}XPERT OR {inv}B{/inv}EGINNER";:GET #1,K:IF K<>69 AND K<>66 THEN CLOSE #1:? "{UP}":GOTO 600
610 ? "{CLEAR}":POKE 559,0:POKE 704,2:P=188:SC=PEEK(88)+256*PEEK(89):L=1:X=30:X1=SC+472:LI=10:RL=7
620 MO1=4:MO2=12:Q=1:ST=23:TS=15:POKE 82,0
630 POKE 756,CHS/256:GOSUB 1870
640 POSITION 4,3:? "{inv}KOOKY'S{/inv}{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{inv}QUEST{/inv}":POSITION 1,6:? "SCORE=0{DOWN}{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}LIVES=10{DOWN}{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}LEVEL=1"
650 POSITION 1,12:? "TREASURES=0"
660 FOR Y=18 TO 21:POSITION 0,Y:? "<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<";:NEXT Y
670 POSITION 27,3:? "??????????":POSITION 27,12:? "??????????"
680 FOR R=4 TO 11:POSITION 27,R:? "?":POSITION 36,R:? "?":NEXT R
690 POSITION 5,19:? "1 SWORD   3 MACE    5 L.BOLT  ":POSITION 5,20:? "2 AXE     4 KNIFE   6 FIREBALL"
700 POSITION 14,3:? "@@@@@@@@@@@":POSITION 14,13:? "@@@@@@@@@@@":FOR R=4 TO 12:POSITION 14,R:? "@":POSITION 24,R
710 ? "@":NEXT R:FOR R=4 TO 6:POSITION 15,R:? "<<<   <<<":POSITION 15,R+6:? "<<<<<<<<<":NEXT R
720 N=PEEK(X1):POKE X1,N+128:POSITION 2,0:? " ":POKE 704,42*(K=69)+132*(K=66):POKE 559,62:POKE 53248,160
730 J=STICK(0)
740 IF  NOT (CR=RL AND ((DMT<5 AND L>1) OR (DMT<1 AND L=1))) THEN 760
750 POSITION 4,16:? "YOU WILL WANDER LEVEL ";L;" FOREVER":FOR MIAD=0 TO 0 STEP 0:NEXT MIAD
760 IF J=14 AND (N=65 OR N=67 OR N=68 OR N=88 OR N=90 OR N=83 OR N=124 OR N<11) THEN ST=1:A=7:A1=9:GOTO 820
770 IF J=13 AND (N=65 OR N=81 OR N=68 OR N=69 OR N=87 OR N=83 OR N=124 OR N<11) THEN ST=-1:A=9:A1=7:GOTO 820
780 IF J=7 AND (N=65 OR N=81 OR N=87 OR N=82 OR N=88 OR N=90 OR N=83) THEN ST=-1:A=20:A1=18:GOTO 1020
790 IF J=11 AND (N=67 OR N=68 OR N=69 OR N=87 OR N=82 OR N=88 OR N=83) THEN ST=1:A=18:A1=20:GOTO 1020
800 IF N=6 OR N=10 THEN 2060
810 GOTO 730
820 V=ST*3:POKE X1,N
830 IF N=124 OR N=6 OR N=10 THEN 850
840 GOSUB 950*(N=69 OR N=68 OR N=67)+980*(N=65 OR N=90 OR N=81)+1000*(N=83 OR N=87 OR N=88)
850 A=A-V:A1=A1-V:X1=X1-ST*40:N=PEEK(X1):POKE X1,N+128
860 IF N=65 THEN 1890
870 IF N=68 THEN 1910
880 IF N=67 OR N=69 THEN 1930
890 IF N=87 OR N=88 THEN 1950
900 IF N=81 OR N=90 THEN 1970
910 IF N=83 THEN 1990
920 IF N=3 OR N=11 THEN 2010
930 IF N=6 OR N=10 THEN 2060
940 POKE 77,0:GOTO 730
950 FOR W=A TO A1 STEP ST:POSITION 15,W:? "<<<":POSITION 15,W+V:? "      ":NEXT W
960 FOR W=A TO A1 STEP ST:POSITION 15,W+V:? "<<<":NEXT W:RETURN
970 GOTO 730
980 FOR W=A TO A1 STEP ST:POSITION 21,W:? "<<<":POSITION 18,W+V:? "      ":NEXT W
990 FOR W=A TO A1 STEP ST:POSITION 21,W+V:? "<<<":NEXT W:RETURN
1000 FOR W=A TO A1 STEP ST:POSITION 15,W:? "<<<   <<<":POSITION 15,W+V:? "         ":NEXT W
1010 FOR W=A TO A1 STEP ST:POSITION 15,W+V:? "<<<   <<<":NEXT W:RETURN
1020 V=ST*3:POKE X1,N
1030 DQ=2050*(N=65 OR N=68 OR N=83)+2100*(N=67 OR N=88 OR N=90)+2150*(N=69 OR N=87 OR N=81)
1040 IF N<>82 THEN GOSUB 1140*(N=65 OR N=68 OR N=83)+1160*(N=67 OR N=88 OR N=90)+1180*(N=69 OR N=87 OR N=81)
1050 A=A-V:A1=A1-V:X1=X1-ST:N=PEEK(X1):POKE X1,N+128
1060 IF N=88 THEN 2130
1070 IF N=83 THEN 2150
1080 IF N=90 OR N=67 THEN 2170
1090 IF N=65 OR N=68 THEN 2190
1100 IF N=69 OR N=81 THEN 2210
1110 IF N=87 THEN 2230
1120 IF N=3 OR N=11 THEN 2250
1130 POKE 77,0:GOTO 730
1140 FOR W=A TO A1 STEP ST:POSITION W+V,4:? B$:POSITION W,4:? A$:NEXT W
1150 FOR W=A TO A1 STEP ST:POSITION W+V,4:? A$:NEXT W:RETURN
1160 FOR W=A TO A1 STEP ST:POSITION W+V,4:? B$(10):POSITION W,4:? G$(19):NEXT W
1170 FOR W=A TO A1 STEP ST:POSITION W+V,4:? G$(19):NEXT W:RETURN
1180 FOR W=A TO A1 STEP ST:POSITION W+V,7:? B$(10):POSITION W,10:? G$(19):NEXT W
1190 FOR W=A TO A1 STEP ST:POSITION W+V,10:? G$(19):NEXT W:RETURN
1200 QP=0:DM=0:GOTO 1210
1210 Z=INT(RND(0)*2):M3=16+6*Z:MM3=8:DM=0:MON=INT(RND(1)*5)+2:KX=19:KY=8:THP=0:IF L=5 THEN MON=1
1220 TX=INT(RND(0)*7)+16:TY=INT(RND(0)*7)+5:TY=TY+(TY=8):POSITION TX,TY:? T$(Z+1,Z+1)
1230 IF L=1 AND X1=SC+428 THEN POSITION 19,5:? "%"
1240 IF L=5 AND X1=SC+195 THEN POSITION 19,5:? ")"
1250 POSITION M3,MM3:? MON$(MON,MON):POSITION KX,KY:? ">"
1260 POSITION 10,16:? "CHOOSE YOUR WEAPON!";:GET #1,OWEP:OWEP=OWEP-48:POSITION 10,16:? "                      "
1270 IF OWEP>6 OR OWEP<1 THEN 1260
1280 MIAD=1^1^1:HP=OHP(MON,OWEP):OWEP=OWEP*2-1
1290 POSITION M3,MM3:? CON$(MON,MON):BC=INT(2*RND(0)+1):CB=INT(2*RND(0)+1)
1300 POSITION M3,MM3:? CON$(MON,MON):BC=INT(2*RND(0)+1):CB=INT(2*RND(0)+1)
1310 M3=M3+(BC=1)*(M3<22)-(BC=2)*(M3>16)
1320 MM3=MM3+(CB=1)*(MM3<11)-(CB=2)*(MM3>5)
1330 POSITION WX,KY:? " ":WX=WX*JW
1340 POSITION M3,MM3:? MON$(MON,MON)
1350 J=STICK(0)
1360 IF STRIG(0)=0 OR JW=1 THEN 1480
1370 IF J=14 THEN POSITION KX,KY:? " ":KY=KY-1
1380 IF J=13 THEN POSITION KX,KY:? " ":KY=KY+1
1390 IF J=7 THEN POSITION KX,KY:? " ":KX=KX+1
1400 IF J=11 THEN POSITION KX,KY:? " ":KX=KX-1
1410 PE=PEEK(SC+KX+KY*40):IF PE=61 OR PE=63 THEN SOUND 0,18,10,10:DMT=DMT+1^1:SOUND 0,0,0,0:PT=PT+5:GOTO 1460
1420 IF PE=9 THEN SOUND 0,18,10,10:KEY=1^1:SOUND 0,0,0,0:GOTO 1460
1430 IF PE=5 AND KEY THEN POSITION 4,16:? "YOU HAVE ESCAPED THE DUNGEON!!!":FOR MIAD=0 TO 0 STEP 0:NEXT MIAD
1440 IF PE=5 THEN 1460
1450 IF PE>0 AND PE<>30 THEN SOUND 0,10,100,10:LI=LI-1:GOTO 1660
1460 POSITION KX,KY:? ">"
1470 GOTO 1290
1480 J=STICK(0)
1490 WEP=OWEP:PE=PEEK(SC+KX+KY*40):IF PE>0 AND PE<>30 THEN SOUND 0,10,100,10:LI=LI-1:GOTO 1660
1500 IF OWEP>6 THEN 1550
1510 JW=0
1520 IF J=7 AND KX<22 THEN WX=KX+1:GOTO 1620
1530 IF J=11 AND KX>16 THEN WEP=WEP+1:WX=KX-1:GOTO 1620
1540 GOTO 1290
1550 IF JW=1 THEN 1590
1560 IF J=7 AND KX<22 THEN RA=1:WX=KX:GOTO 1610
1570 IF J=11 AND KX>16 THEN RA=-1:WX=KX:GOTO 1610
1580 GOTO 1290
1590 PE1=PEEK(SC+WX+KY*40):IF PE1=61 OR PE1=63 OR PE1=59 THEN WX=0:JW=0:GOTO 1290
1600 IF PE1>0 THEN SOUND 0,16,14,10:JW=0:THP=THP+HP*1^1:SOUND 0,0,0,0:IF THP=30 THEN PT=PT+10:GOTO 1660
1610 WEP=WEP+(RA=-1):WX=WX+RA*(WX<23)*(WX>15):JW=(WX<22)*(WX>16)
1620 PE1=PEEK(SC+WX+KY*40):IF PE1=61 OR PE1=63 OR PE1=59 THEN WX=0:JW=0:GOTO 1290
1630 IF PE1>0 THEN SOUND 0,16,14,10:JW=0:THP=THP+HP*1^1:SOUND 0,0,0,0:IF THP=30 THEN PT=PT+10:GOTO 1660
1640 POSITION WX,KY:? WEP$(WEP,WEP)
1650 GOTO 1290
1660 FOR W=5 TO 11:POSITION 16,W:? "       ":NEXT W:POSITION 7,8:? LI;" ":SOUND 0,0,0,0:CR=CR+1:POSITION 7,6:? PT
1670 POSITION 11,12:? DMT
1680 IF LI<1 THEN POSITION 15,15:? "GAME OVER":POSITION 7,16:? "PRESS BUTTON TO PLAY AGAIN":GOTO 2400
1690 J=STICK(0):UP=PEEK(X1-40):DO=PEEK(X1+40):FO=PEEK(X1+1):BA=PEEK(X1-1)
1700 IF J=14 AND (UP=65 OR UP=81 OR UP=68 OR UP=69 OR UP=87 OR UP=83 OR UP=124) THEN OW=1:ST=1:GOTO 1750
1710 IF J=13 AND (DO=65 OR DO=67 OR DO=68 OR DO=88 OR DO=90 OR DO=83 OR DO=124) THEN OW=2:ST=-1:GOTO 1750
1720 IF J=11 AND (BA=65 OR BA=81 OR BA=87 OR BA=82 OR BA=88 OR BA=90 OR BA=83) THEN OW=3:ST=1:GOTO 1810
1730 IF J=7 AND (FO=67 OR FO=68 OR FO=69 OR FO=87 OR FO=82 OR FO=88 OR FO=83) THEN OW=4:ST=-1:GOTO 1810
1740 GOTO 1690
1750 IF OW=1 THEN A=4:A1=11
1760 IF OW=2 THEN A=12:A1=5
1770 POSITION 16,A1+ST:? "       ":FOR W=A TO A1 STEP ST:POSITION 15,W:? "<<<   <<<":POSITION 15,W+ST
1780 ? "<<<<<<<<<":NEXT W
1790 POSITION 15,A1+ST:? "<<<   <<<"
1800 V=3*ST:A=7*(OW=1)+9*(OW=2):A1=9*(OW=1)+7*(OW=2):POKE X1,11:GOTO 850
1810 IF OW=3 THEN A=15:A1=22
1820 IF OW=4 THEN A=23:A1=16
1830 POSITION A1+ST,4:? H$
1840 FOR W=A TO A1 STEP ST:POSITION W,4:? A$
1850 POSITION W+ST,4:? G$:NEXT W:POSITION A1+ST,7:? B$(19)
1860 V=3*ST:A=18*(OW=3)+20*(OW=4):A1=20*(OW=3)+18*(OW=4):POKE X1,11:GOTO 1050
1870 RESTORE 2300+(L-1)*20
1880 FOR P=SC+188 TO SC+468 STEP 40:FOR RT=P TO P+7:READ M:POKE RT,M:NEXT RT:NEXT P:RETURN
1890 FOR W=A TO A1 STEP ST:POSITION 21,W:? "   ":NEXT W
1900 FOR W=A TO A1 STEP ST:POSITION 21,W:? "<<<":POSITION 21,W+V:? "   ":NEXT W:GOTO 730
1910 FOR W=A TO A1 STEP ST:POSITION 15,W:? "   ":NEXT W
1920 FOR W=A TO A1 STEP ST:POSITION 15,W:? "<<<":POSITION 15,W+V:? "   ":NEXT W:GOTO 730
1930 FOR W=A TO A1 STEP ST:POSITION 15,W:? "   ":NEXT W
1940 FOR W=A TO A1 STEP ST:POSITION 15,W:? "<<<<<<":POSITION 15,W+V:? "   ":NEXT W:GOTO 730
1950 FOR W=A TO A1 STEP ST:POSITION 15,W:? "         ":NEXT W
1960 FOR W=A TO A1 STEP ST:POSITION 15,W:? "<<<<<<<<<":POSITION 15,W+V:? "         ":NEXT W:GOTO 730
1970 FOR W=A TO A1 STEP ST:POSITION 21,W:? "   ":NEXT W
1980 FOR W=A TO A1 STEP ST:POSITION 18,W:? "<<<<<<":POSITION 21,W+V:? "   ":NEXT W:GOTO 730
1990 FOR W=A TO A1 STEP ST:POSITION 15,W:? "         ":NEXT W
2000 FOR W=A TO A1 STEP ST:POSITION 15,W:? "<<<   <<<":POSITION 15,W+V:? "         ":NEXT W:GOTO 730
2010 POSITION 15,A:? "<<<<<<<<<"
2020 A1=11*(ST=1)+5*(ST=-1)
2030 FOR W=A TO A1 STEP ST:POSITION 15,W:? "<       <":POSITION 15,W+ST:? "<<<<<<<<<":NEXT W
2040 POSITION 15,A:? "<<<<<<<<<":IF N=3 THEN QP=0:DM=0:GOTO 1210
2050 GOTO 1690
2060 IF (L>1 AND DMT<5) OR (L=1 AND DMT<1) THEN 730
2070 CR=0:PT=PT+50:IF N=6 THEN L=L-1:DMT=0:N=10:GOTO 2100
2080 IF N=10 THEN L=L+1:DMT=0:N=6
2090 FOR S=16 TO 32 STEP 4:SOUND 0,S,14,10:DL=EA*EA*EA:SOUND 0,0,0,0:EA=1^0:NEXT S:GOTO 2110
2110 RL=7*(L=1)+9*(L=2)+15*(L=3)+15*(L=4)+12*(L=5):POSITION 7,10:? L:POSITION 11,12:? "0 "
2120 GOSUB 1870:GOTO 730
2130 FOR W=A TO A1 STEP ST:POSITION W,4:? B$(19):NEXT W
2140 FOR W=A TO A1 STEP ST:POSITION W+V,4:? B$(19):POSITION W,4:? G$(19):NEXT W:GOTO 730
2150 FOR W=A TO A1 STEP ST:POSITION W,4:? B$:NEXT W
2160 FOR W=A TO A1 STEP ST:POSITION W+V,4:? B$:POSITION W,4:? A$:NEXT W:GOTO 730
2170 FOR W=A TO A1 STEP ST:POSITION W,4:? B$(19):NEXT W
2180 FOR W=A TO A1 STEP ST:POSITION W+V,4:? B$(19):POSITION W,4:? F$:NEXT W:GOTO 730
2190 FOR W=A TO A1 STEP ST:POSITION W,4:? B$:NEXT W
2200 FOR W=A TO A1 STEP ST:POSITION W+V,4:? B$:POSITION W,4:? G$:NEXT W:GOTO 730
2210 FOR W=A TO A1 STEP ST:POSITION W,7:? B$(10):NEXT W
2220 FOR W=A TO A1 STEP ST:POSITION W+V,R:? B$(10):POSITION W,R:? F$:NEXT W:GOTO 730
2230 FOR W=A TO A1 STEP ST:POSITION W,10:? B$(19):NEXT W
2240 FOR W=A TO A1 STEP ST:POSITION W+V,10:? B$(19):POSITION W,10:? G$(19):NEXT W:GOTO 730
2250 POSITION A,4:? G$
2260 A1=22*(ST=1)+16*(ST=-1)
2270 FOR W=A TO A1 STEP ST:POSITION W,4:? H$
2280 POSITION W+ST,4:? G$:NEXT W:POSITION A,4:? G$:IF N=3 THEN QP=0:DM=0:GOTO 1210
2290 GOTO 1690
2300 DATA 0,3,87,82,87,82,82,69,81,68,65,69,90,3,69,124,124,10,124,124,81,82,88,3,90,88,67,3,68,81,82,69,81,87
2310 DATA 82,69,90,67,81,67,90,83,82,88,82,87,88,69,3,124,81,3,87,3,69,124,90,88,88,82,88,82,88,67
2320 DATA 81,87,3,81,3,87,87,69,65,68,124,124,65,68,3,124,124,6,124,65,3,90,83,67,3,67,65,68,65,87,67,3,90,82
2330 DATA 67,90,3,124,81,68,81,87,82,87,88,67,124,10,124,3,82,3,69,81,68,124,90,88,82,88,88,67,90,67,
2340 DATA 81,3,87,3,87,87,87,3,10,65,83,87,67,3,67,124,65,83,3,88,69,124,81,3,3,67,124,81,3,68,65,69,0,81,88,68
2350 DATA 90,83,83,68,3,83,87,3,69,3,67,6,0,124,90,83,88,67,81,68,3,88,3,88,3,82,67,3
2360 DATA 81,3,69,3,81,3,87,69,6,90,83,83,88,67,65,3,90,3,67,65,82,3,90,69,81,69,81,3,69,90,87,3,3,68,65,67,124
2370 DATA 81,88,68,65,67,3,87,3,88,87,3,10,81,67,124,65,69,65,68,90,3,82,3,67,90,3,67
2380 DATA 81,87,82,82,82,82,69,3,90,3,81,3,69,3,90,67,81,67,124,81,83,88,82,3,3,81,68,3,124,3,82,67,90,88,67,65
2390 DATA 67,124,81,3,81,69,0,90,69,65,88,68,6,65,3,81,3,65,3,124,90,67,90,88,82,88,82,67
2400 IF STRIG(0)<>0 THEN 2400
2410 POKE 704,PEEK(710):POKE 53277,0:RUN

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: KOOKY.BAS.

Credits