Arena Racer

Type
Game
Category
Scrolling maze action game
Author
J. Sutherland
Published in
Antic, May 1985 (Vol. 4, No. 1), Game of the Month
Year
1985
Language
Atari BASIC (with machine-language helper)
Requirements
Any Atari 8-bit computer, any memory size, Atari BASIC, joystick in port 1
Arena Racer in play: a small viewscreen showing green cavern walls and the Huntercraft, with score, spare craft and LEVEL: 1 below

About the program

Arena Racer was Antic's Game of the Month for May 1985, and the magazine called it "unusually fast" for BASIC. The set-up is gloriously grim. You're a fighter ace shot down over a hostile planet, and the local warlord drops you, unarmed, into a Huntercraft in the Arena, a maze of caverns 15 levels deep. On every level you must find four glowing orbs while laser cannons fire across the passages, and you have a strict time limit. Fail and your craft disintegrates ("HAHAHAHA!!", as the article puts it). Finish level 15 and you start again, faster. The author admitted he'd never got past level 12.

Typing it in

Line 1030 holds a machine-language routine as a string full of special characters. {inv} … {/inv} means press the Atari (inverse) key before and after. {CTRL-,} and {CTRL-.} are CTRL with the comma and full stop keys, {CTRL-X} means hold CTRL and press X, and {INS LINE} is ESC then SHIFT-INSERT. Lines 140 and 230 use {CTRL-,} to erase a collected orb from the maze. The level DATA in lines 6000–6290 is long but plain text. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.

How to play

You start with four Huntercraft and earn a bonus craft every five levels. Fly in any of eight directions with the joystick, and fly over an orb to collect it. The rising whine is your timer. The fire button is the Panic Button: while you hold it, your craft stays still and lasers can't hurt it, but the timer runs out faster. Collect all four orbs to go to the next level, with bonus points for the time left.

How it works

  • The whole Arena is one 4,900-character string, S$, holding 70 rows of 70 characters, built from the level DATA. Each odd DATA line describes one row with letters (A = solid wall, B = open space, C/D/F = wall patterns, E/G = patterns with laser cannons). The line after it gives the four orb positions as row × 70 + column.
  • Every frame, USR(1536,ADR(S$)+70*Y+X) calls the machine-language routine in page 6. It copies the part of the maze around your craft onto a small GRAPHICS 1 viewscreen, so the maze appears to scroll smoothly in any direction.
  • The routine also leaves the code of whatever your craft touched in location 207. Lines 80–120 check it: 65 is a wall (you bounce back), 131/132 is a laser (you're destroyed) and 200 is an orb.
  • The joystick is decoded with Boolean arithmetic in line 30, and line 50 checks the maze ahead before allowing a move.

Designing levels

The magazine explained how to make your own Arena. Every level is a 70-character pattern line followed by an orb line. The first and last five characters of each pattern line must be "A" (solid wall), and orbs must not sit in any laser's line of fire, or they get destroyed.

Listing

1 REM ARENA RACER
2 REM BY J. SUTHERLAND
3 REM ANTIC MAGAZINE
5 GOTO 1000
10 SOUND 3,TM,10,12:TM=TM-0.6+0.02*(15-L):IF TM<30 THEN X=1:Y=60:SOUND 3,0,0,0:GOTO 190
15 A=USR(1536,ADR(S$)+70*Y+X):IF  NOT STRIG(0) THEN FOR T=1 TO 3:NEXT T:GOTO 10
20 SOUND 3,0,0,0:S=STICK(0):IF S=15 OR S=OS THEN 40
30 OS=S:NYD=(S=13)+(S=9)+(S=5)-(S=14)-(S=10)-(S=6):NXD=(S=7)+(S=6)+(S=5)-(S=10)-(S=9)-(S=11)
40 IF PEEK(207)<>0 THEN P=PEEK(207):POKE 207,0:GOTO 80
50 IF PEEK(SL+NXD+20*NYD)<>65 THEN XD=NXD:YD=NYD
60 X=X+XD:Y=Y+YD
70 GOTO 10
80 OS=15:IF P=65 THEN NXD=-XD:NYD=-YD:X=X-XD:Y=Y-YD:GOTO 10
90 IF P=133 THEN NXD=-XD:NYD=-YD:X=X-XD:Y=Y-YD:GOTO 10
100 IF P=134 THEN NXD=-XD:NYD=-YD:X=X-XD:Y=Y-YD:GOTO 10
110 IF P=131 OR P=132 THEN 190
120 IF P<>200 THEN 10
130 FOR J=100 TO 130:SOUND 1,J,10,12:NEXT J:SOUND 1,0,0,0
140 S$(70*(Y+4)+X+9)="{CTRL-,}":G=G+1:SC=SC+25+2*L:POSITION 2*G-1,16:? #6;"{inv}{CTRL-H}{/inv}":POSITION 8,14:? #6;SC:IF G<4 THEN 10
150 FOR J=240 TO 125 STEP -0.5:SOUND 1,J,10,14:SOUND 2,J+1,10,14:NEXT J:SOUND 1,0,0,0:SOUND 2,0,0,0
160 SC=SC+2*INT(TM):L=L+1:MEN=MEN+(BN>3)-(MEN>10):BN=BN+1:IF BN=5 THEN BN=0
170 IF L>14 THEN L=0:IF PEEK(1684)>4 THEN POKE 1684,PEEK(1684)-2
180 GOSUB 1080:GOTO 10
190 FOR J=9 TO 20:FOR C=9 TO 13:POKE 1671,C:SOUND 0,200,8,20-J:A=USR(1536,ADR(S$)+70*Y+X):NEXT C
200 NEXT J:POKE 1671,2:POSITION MEN*2-3*(MEN>1),18:? #6;" "
210 MEN=MEN-1:IF MEN<1 THEN 250
220 SOUND 0,0,0,0:FOR T=1 TO 400:NEXT T:TM=254
230 S$(70*(Y+4)+X+9)="{CTRL-,}":GOTO 10
240 GOTO 50
250 POSITION 5,17:? #6;"{inv}GAME OVER{/inv}":POSITION 3,19:? #6;"press trigger":POKE 40410,0:FOR J=0 TO 3
260 SOUND J,0,0,0:NEXT J
270 IF STRIG(0) THEN 270
280 CLR :RUN
1000 CLR :GRAPHICS 17:POSITION 4,3:? #6;"ARENA  {inv}racer{/inv}":POSITION 9,5:? #6;"by":POSITION 4,7:? #6;"{inv}J.SUTHERLAND{/inv}"
1010 CB=PEEK(106)-6:POKE 756,CB:ML=1536:POSITION 5,9:? #6;"one moment":SETCOLOR 2,9,4
1020 DIM T$(70),T2$(70),S$(4900)
1030 T$="h{inv}"{/inv}{CTRL-,}{inv}={/inv}{CTRL-,}{inv}{CTRL-.}{/inv}{INS LINE}{CTRL-,}{inv}{CTRL-X}={/inv}{CTRL-,}{inv}a{/inv}{INS LINE}{CTRL-,}{inv}{CTRL-Y}h{CTRL-.}{/inv}{CTRL-,}{inv}Po{/inv}{CTRL-.}":T$(9)=CHR$(CB):T$(15)=CHR$(CB+1):A=USR(ADR(T$)):RESTORE 5000
1040 READ A:IF A>-1 THEN POKE ML+K,A:K=K+1:CM=CM+A:GOTO 1040
1050 ML=PEEK(89)*256+PEEK(88)+3:SL=ML+87:HB=INT(SL/256):LB=SL-HB*256:POKE 1551,HB:POKE 1550,ML-HB*256
1055 POKE 1667,HB:POKE 1666,LB:POKE 1674,HB:POKE 1673,LB
1060 FOR J=0 TO 111:READ A:POKE CB*256+J,A:NEXT J
1070 MEN=4:L=0:BN=0
1080 RESTORE 6000+L*20:READ T2$:POSITION 2,9:? #6;"ENTERING LEVEL ";L+1:G=0:TM=254
1090 S$="":FOR J=1 TO 70:A=ASC(T2$(J,J))-65:RESTORE 2000+A*10
1100 READ T$:S$(LEN(S$)+1)=T$:SOUND 0,120,10,12:POSITION 1,11:? #6;70-J;"  ":SOUND 0,0,0,0:NEXT J
1110 X=1:Y=60:XD=0:YD=0:NXD=0:NYD=0:? #6;"{CLEAR}"
1120 RESTORE 6000+L*20+10:FOR J=1 TO 4:READ A:S$(A,A)=CHR$(200):NEXT J:POSITION 1,14:? #6;"SCORE: ";SC
1130 POSITION 1,18:IF MEN>1 THEN FOR J=1 TO MEN-1:? #6;"{inv}"{/inv} ";:NEXT J
1140 POSITION 4,22:? #6;"LEVEL: ";L+1:GOTO 10
2000 DATA AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
2010 DATA AAAAA{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}AAAAA
2020 DATA AAAAA{CTRL-,}AAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA{CTRL-,}AAAAA
2030 DATA AAAAA{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}AAAAA
2040 DATA AAAAA{CTRL-,}{CTRL-,}{CTRL-,}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}A{CTRL-,}A{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{CTRL-,}{CTRL-,}{CTRL-,}AAAAA
2050 DATA AAAAAAAAAAA{CTRL-,}AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA{CTRL-,}AAAAAAAAAAA
2060 DATA AAAAA{CTRL-,}{CTRL-,}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{inv}{CTRL-E}{/inv}{CTRL-,}{CTRL-,}A{CTRL-,}{CTRL-,}{inv}{CTRL-F}{/inv}AA{CTRL-,}{CTRL-,}AAAAA
5000 DATA 104,104,133,204,104,133,203
5010 DATA 162,0,160,1
5020 DATA 177,203,157,131,157
5030 DATA 201,131,208,16,169,0,145,203,136,177,203,201,65,240,4
5040 DATA 169,131,145,203,200
5050 DATA 201,132,208,20,169,0,145,203,232,200,192,15,240
5060 DATA 51,177,203,201,65,240,4,169,132,145,203
5080 DATA 201,133,208,12,165,206,201,0,208,6,200,169,132,145,203,136
5090 DATA 201,134,208,12,165,206,201,0,208,6,136,169,131,145,203,200
5100 DATA 232,200,192,15,240
5110 DATA 3,76,11,6,138,24
5120 DATA 105,6,170,224,180,240,19
5130 DATA 165,203,24,233,185,144,2
5140 DATA 230,204,165,203,24,105,70
5150 DATA 133,203,76,9,6,173,218,157,133,207,169,2,141
5160 DATA 218,157,169,0,133,77,230,206,165,206,201,12,208,4,169,0,133,206,238,199,2,96,-1
5170 DATA 0,0,0,0,0,0,0,0,255,255
5180 DATA 255,255,255,255,255,255
5190 DATA 60,24,189,231,231,189,24,60
5200 DATA 0,0,0,85,42,0,0,0
5210 DATA 0,0,0,85,42,0,0,0
5220 DATA 192,96,248,159,184,240,96,192
5230 DATA 3,6,31,249,29,15,6,3
5240 DATA 32,1,18,8,20,74,128,2
5250 DATA 28,42,93,127,93,42,28,0
5260 DATA 16,32,133,18,160,8,68,1
5270 DATA 22,1,20,136,17,2,40,129
5280 DATA 129,32,0,2,80,0,9,0
5290 DATA 1,64,8,0,0,32,2,0
5300 DATA 32,1,18,8,20,74,128,2
6000 DATA AAAAABBBBBBEBBBBBBBEBBBBBBBEBBBBBEBBBBBBBEBBBBBBBEBBBBBBBEBBBBBBBAAAAA
6010 DATA 672,1338,2075,3043
6020 DATA AAAAABEBEBBEBBBEEBBCBBBEBBEBBBEBECEBBEBBBBCBBBEBBCBBBEBEBBBBEBBEBAAAAA
6030 DATA 652,1290,2222,3113
6040 DATA AAAAABBCBEBGBCBFBECDCCEGCCEFBCECDEBEFBCBECBBEDECBBBDBEBBCEBCDEBFBAAAAA
6050 DATA 721,1025,3034,3169
6060 DATA AAAAABBCBEBBBCBFBECBCCBGCCBFBCBBBEBEFBCBEBBBEDBCBBBDBEBBCBBCDBBFBAAAAA
6070 DATA 924,2042,3536,2129
6080 DATA AAAAABBBBEEEBBBEEEBBBEEEBBBEEEBBBEEEBBBEEEBBFBBEEEBBBEEEBBBEEEBBBAAAAA
6090 DATA 764,1290,2222,3113
6100 DATA AAAAABFFFFGBGFFFEBGFFFFBFFFFFBFFFFFBFFBFEBEFFFFBFFBGBFBCEDDEFFFFBAAAAA
6110 DATA 811,1324,4108,2914
6120 DATA AAAAABFGGGGFFFGGDGGCCCECEGEEGBBBBBEGBBBBBFEFGBGGEEBBBBBEFEFGFGFBBAAAAA
6130 DATA 987,1115,3479,3194
6140 DATA AAAAABGEGCBGBBCBDBEGBBDBBCBGEBBBBGBBDBCBBGBBDDBBGEGBBCBBBGBDBBBGBAAAAA
6150 DATA 512,1213,3314,501
6160 DATA AAAAABBBGBFFEBBFFGFFBBBBEGEBBBGEGBBGGGGDEEEEBBFBBFFBEBBCCECBBBFBBAAAAA
6170 DATA 512,1131,3104,851
6180 DATA AAAAABBDDDDDBEBBGBGEGBDDDBBFBEGBGEBBBEEEBDDEDDBBCBBCBBDBBCBBEEGEBAAAAA
6190 DATA 513,1214,3104,851
6200 DATA AAAAABBEEBFBGGBDBEEBBBGGBEBBEEGEEBBBBBBGGEGGBBBFFDDGGBBBFEFBBGEBBAAAAA
6210 DATA 717,1115,3479,3104
6220 DATA AAAAABBBBBEGEGEBFDFCDFBEGCGEBBBBFFFBEEGEEBBDDDBBCCCBBEGBBGEBBEGBBAAAAA
6230 DATA 987,1115,3759,3166
6240 DATA AAAAABBBFFFFBEEEEBDDDBGGGBCCCBEGGEBEGEGBBBFFFBCDCCECFFBBDBCCBEGEBAAAAA
6250 DATA 582,1283,3314,521
6260 DATA AAAAABBBEEEEBEEEGEEEEBEEEBEEGBBBBDDDCCGEEDEEEEEFFBCEGEDBBCCEBBBBBAAAAA
6270 DATA 539,1502,2345,3199
6280 DATA AAAAABBBBBEBBBBBEGBFBGEBFFBCCBDDBGEBDBEGBBFBEEBGGBEGGBBBCCBBDDBBBAAAAA
6290 DATA 498,2639,2905,597

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: ARENA.BAS.

Credits