Thief
- Type
- Game
- Category
- Cave flying / treasure hunt
- Author
- Max Langert
- Published in
- Antic, March 1985 (Vol. 3, No. 11)
- Year
- 1985
- Language
- Atari BASIC
- Requirements
- Any Atari 8-bit, joystick in port 1, Atari BASIC
- Related
- Air Raid 2000, Bats, Biffdrop, Diamond Dave, Diver, Drop
About the program
Antic introduced Max Langert, 13, of Oakland, California, as possibly the youngest game programmer it had ever published. Thief is a cave-flying game with no enemies at all. You are a pilot who has flown into caves where treasures stolen from your planet were hidden centuries ago. On each screen you must touch the treasure before you can leave, and you can only leave by the right-hand edge. Brushing a cave wall costs 50 energy units and sucks you back to the left side of the screen. Hitting one of the large jagged rocks, or running out of energy, blows up your ship. The fuel tank holds 1000 units, and energy cubes give a 500-unit recharge.
Gravity pulls the ship down, and it gets stronger after every five screens. Picking up the treasure turns gravity off for the rest of the screen. You score 1000 points per treasure, plus points for energy cubes, energy left at the end of a screen and simply staying alive.
What you need
A joystick in port 1 and Atari BASIC. It runs on any Atari.
Typing it in
The caves are strings of redefined characters in DATA. Each screen's layout is 19 lines of text that are READ and PRINTed to the screen, so every character matters. Inverse letters ({inv}…{/inv}, Atari key) mark the treasure and energy cube. The D characters in the status-line strings are not typos: in the redefined font, D is the solid border block. Antic asked readers to check the program with TYPO II and SAVE it before running.
How to play
Press START on the title screen. The joystick moves the ship in eight directions, and pushing up fights the gravity. After the ship is destroyed for the last time, press START to play again.
How it works
- Your ship is player 0. Its shape (nine bytes in line 1280) is POKEd into player memory at a new vertical offset each step (
Q), and its horizontal position is POKEd into 53248. - Each step adds the current gravity
GRtoQ. Pushing up subtracts a little more than gravity. While you carry a treasure (TR=1), lines 13–14 cancel the pull. - What you touched comes from
PEEK(53252), the player-to-playfield collision register. Each kind of cave object is drawn in its own colour, so the value tells the program what was hit: 1 is a wall, 2 a jagged rock, 4 the treasure and 8 an energy cube (lines 15–25). RESTORE LIandGOSUB LIuse a variable line number to choose the current screen's layout and the subroutine that places its treasure and cube. After the last screen the caves repeat withGRincreased by 0.5.
Listing
1 REM THIEF
2 REM BY MAX LANGERT
3 REM ANTIC MAGAZINE
8 GOSUB 7000
10 S=STICK(0):POKE 53278,255:SOUND 2,199,10,2:SOUND 3,200,10,2:EN=EN-3:SC=SC+1
11 POKE 77,0
12 POKE 53248,A
13 IF TR=1 THEN FA=GR:GOTO 15
14 Q=Q+GR+1:FA=0
15 IF PEEK(53252)=1 THEN SOUND 0,255,8,12:FOR Z=1 TO 9:NEXT Z:FOR Z=1 TO 9:EN=EN-5:NEXT Z:GOSUB 200
16 IF PEEK(53252)=2 THEN 3000
17 IF PEEK(53252)=4 THEN TR=1:TRE=TRE+1:GOSUB 5000
18 IF TR=0 THEN 20
19 IF S=13 THEN Q=Q+2
20 IF S=14 THEN Q=Q-2-GR+FA
21 IF S=10 THEN Q=Q-2-GR+FA:A=A-3
22 IF S=6 THEN Q=Q-2-GR+FA:A=A+3
23 IF S=5 THEN A=A+3
24 IF S=9 THEN A=A-3
25 IF PEEK(53252)=8 THEN E=1:GOSUB 2500
26 IF S=7 THEN A=A+3
27 IF S=11 THEN A=A-3
34 RESTORE 1280
35 FOR I=START+580+Q TO START+588+Q:READ X:POKE I,X:NEXT I:POKE 53278,255:POKE 53248,A
36 POSITION 11,1:? #6;EN;"D":POSITION 13,21:? #6;SC:POSITION 18,1:? #6;TRE
37 IF EN<1 THEN POSITION 11,1:? #6;"0DD":GOTO 3000
50 IF A>201 AND TR=1 THEN RO=RO+1:E=0:TR=0:A=46:LI=490+10*RO:GOSUB 6000:GOSUB 700
55 IF A<46 THEN A=46
56 IF A>202 THEN A=202
90 GOTO 10
200 RESTORE 1280
205 FOR Z=A TO 46 STEP -0.5:POKE 53248,Z:SOUND 0,Z*2,12,8:NEXT Z
210 IF Q>23 THEN Q=21
211 IF Q<-45 THEN Q=-42
220 A=46:SOUND 0,0,0,0:GOTO 34
369 EN=1000:SH=3
500 DATA )DD&')(')&(')()&DD'), *. -., +/ +;, *. q u v *<, -< =!#$%#$!%#$D/
502 DATA "+. >&')(')&(')(@, -/, +;, *D!#$%? quw=?, >(DD&(@ =!#D;, -< u *D&)@, +D!$? -<, >&()@ +;
504 DATA """"""""""+; v =!@,""""""""""*D#$%!D;, =?quvwu -D&')('@, +D!#$%/ *;, -DDDDD< +/
506 DATA !DDDDDDD#$DD!#%$#%!#
507 IF TR=0 THEN POSITION 15,5:? #6;"{inv}J{/inv}":N=15:M=5
508 IF E=0 THEN POSITION 12,15:? #6;"{inv}k{/inv}":NN=12:MM=15
509 RETURN
510 DATA &'(DDDDD&(')(')&('&), *DDD;, +DD)@, =DD/ =?, -DD@ -. v, +D< =!DD!#?
512 DATA "">)@ -D&'(D< vu, -. */ =?, >@ -; *., +/ */, quvw +. -;
514 DATA ""=!#$%#$!? -/ +<, >)DD&'()@ +D!#D;, +< *DD&'@, -. *D/, +; =? -D.
516 DATA """"+D!#D/quw+D; q, vw*DDDDD!#$DDD%$?,%$#%DDDDDDDDDDDDDDD%
517 IF TR=0 THEN POSITION 6,17:? #6;"{inv}J{/inv}":N=6:M=17
518 IF E=0 THEN POSITION 16,13:? #6;"{inv}k{/inv}":NN=16:MM=13
519 RETURN
520 DATA &'DD&'(')(&)'(&)'DD), *. -/, +< +;, +D!#$%? qw v +., >&'(')@ =!#$#%D;
522 DATA """"""""""">)DDD&'@, *D<, =? =? v +D/, -. *D!#$%DD;, =D. >&'()DD&@, *D; *.
524 DATA "">D;u -/ =?, -D!#$%? -/ =D<, >'DDDD; *; >D/, +DDD. *; */ +<
526 DATA """""-DD(@ >@ +., =%$DD/ +;, -DDDD; w +.,!#DDDDDD!#$%$%#$!DD!
527 IF TR=0 THEN POSITION 16,19:? #6;"{inv}J{/inv}":N=16:M=19
528 IF E=0 THEN POSITION 16,5:? #6;"{inv}k{/inv}":NN=16:MM=5
529 RETURN
530 DATA &DDD'()'(&'&)('(&)'(, +D., *D<, -D; quvwq=?v q u, >)(!#$%#%!DD%$#%?, >'DDD)('(&DDD@
532 DATA """""">D@ >D@, =?, +. =D? q, -/ =%$#!DDD%$#$!?, *; +D&'()')(&'DD<, -< +. *D;
534 DATA "+/ -. *D;, +. -D!#$%#$? +D/, -< >&')('(&@ +D., *< -D;, *. +D/
536 DATA "-<qv -D/,!DD!#$%#%$!$#%!$DDD%
537 IF TR=0 THEN POSITION 7,14:? #6;"{inv}J{/inv}":N=7:M=14
538 IF E=0 THEN POSITION 4,5:? #6;"{inv}k{/inv}":NN=4:MM=5
539 RETURN
540 DATA &'(DDD)(DDDDD&'()&'), +D/ >)(D/, >)@ *; q, u +; =#?, =? >@ >(@
542 DATA ""=$? *<, -D; -. w v q, >'@ +/ =#!? =?, +; >)D< -<, *;u */ >@
544 DATA ""=? =DD? +;w, +/ *DD/ =DD$?, >@ >)(@ >'&D<, >@, q u v w, =? =!#$%!$?q v
546 DATA ""+< *DDDDDDD!%$?, +D#$DDDDDDDDDDD/,$%DDDDDDDDDDDDDDDD%#
547 IF TR=0 THEN POSITION 17,17:? #6;"{inv}J{/inv}":N=17:M=17
548 IF E=0 THEN POSITION 12,12:? #6;"{inv}k{/inv}":NN=12:MM=12
549 RETURN
700 RESTORE LI
701 FOR A=2 TO 20:READ A$:POSITION 0,A:? #6;A$:NEXT A:GOSUB LI
709 IF T=0 THEN GOSUB 2000:SOUND 0,0,0,0:SOUND 1,0,0,0
710 POSITION 0,0:? #6;"DDDDDDDDDDDDDDDDDDDD":POSITION 0,1:? #6;"DDDDENERGY:DDDDDT:DD"
715 POSITION 0,21:? #6;"DDPPDDDSCORE:DDDDDDD":POSITION 0,22:? #6;"DDDDDDDDDDDDDDDDDDDD"
717 POSITION 1+SH,21:? #6;"DD"
750 RETURN
1100 DIM MM$(49)
1105 MM$(1)="hh{inv}{CTRL-E}O{/inv}h{inv}{CTRL-E}N{/inv}h{inv}{CTRL-E}M{/inv}h{inv}{CTRL-E}L{/inv}h{inv}*{CTRL-.}{/inv}{CTRL-,}{inv}p{/inv}{CTRL-R}{inv} {/inv}{INS CHAR}{inv}1N{/inv}"
1110 MM$(24)="{inv}{CTRL-Q}L{CTRL-H}@{/inv}{INS CHAR}{inv}PwfOfMJPn{/inv}h{inv}(1N{CTRL-Q}L{CTRL-H}@{/inv}"
1115 MM$(46)="{INS CHAR}{inv}Pw{/inv}{CTRL-.}"
1120 DIM KF$(465)
1125 KF$(1)="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}a{inv}s{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}"
1130 KF$(24)="{CTRL-,}Fo{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}<{CLEAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}0y{/inv}{INS CHAR}{INS CHAR}{INS CHAR}"
1135 KF$(46)="{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}s{/inv}a{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}y0{/inv}{INS CHAR}{INS CHAR}{INS CHAR}"
1140 KF$(68)="{INS CHAR}{INS CHAR}{INS CHAR}{CLEAR}<{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}oF{INS CHAR}{TAB}{INS CHAR}{TAB}??{TAB}{TAB}?"
1145 KF$(90)="{TAB}{INS CHAR}{TAB}{TAB}??{TAB}{TAB}?{TAB}{INS CHAR}{TAB}??{INS CHAR}{TAB}{TAB}?{TAB}?{TAB}{INS CHAR}"
1150 KF$(112)="{TAB}{inv}|{/inv}{DEL CHAR}{DEL CHAR}{inv}||{/inv}{DEL CHAR}{INS CHAR}{DEL CHAR}{DEL CHAR}{INS CHAR}{inv}|||{/inv}{DEL CHAR}{INS CHAR}{DEL CHAR}{inv}C{CTRL-A}{CTRL-M}{CTRL-M}{/inv}"
1155 KF$(133)="{inv}{CTRL-A}{CTRL-A}C{/inv}{INS CHAR}{inv}gGgg{CTRL-A}{CTRL-A}{CTRL-A}{/inv}{INS CHAR}{inv}C{CTRL-Y}sgO{CTRL-A}{CTRL-A}{/inv}{INS CHAR}{inv}C{/inv}"
1160 KF$(154)="{inv}{CTRL-A}ys9{CTRL-A}C{/inv}{INS CHAR}{inv}cC{CTRL-S}{CTRL-A}{CTRL-A}ss{/inv}{INS CHAR}{inv}{CTRL-A}{/inv}{SHIFT-TAB}{inv}{CTRL-C}qq{CTRL-A}{/inv}"
1165 KF$(175)="{inv}{CTRL-C}{/inv}{INS CHAR}{inv}A{/inv}{SHIFT-TAB}{inv}{CTRL-C}{CTRL-A}{CTRL-I}{CTRL-A}A{/inv}{INS CHAR}{inv}{CTRL-A}yqcG{CTRL-O}{CTRL-O}{/inv}{INS CHAR}{inv}C{CTRL-Y}{CTRL-A}{/inv}"
1170 KF$(196)="{inv}C{CTRL-Y}{CTRL-Y}C{/inv}{INS CHAR}{inv}C{CTRL-Y}{CTRL-Y}Aq{CTRL-C}{CTRL-G}{/inv}{INS CHAR}{INS CHAR}{inv}GG{/inv}{INS CHAR}{inv}GG{/inv}{INS CHAR}{INS CHAR}"
1175 KF$(217)="{DEL CHAR}{DEL CHAR}{DEL CHAR}{inv}|{/inv}{DEL CHAR}{DEL CHAR}{INS CHAR}{DEL CHAR}{DEL CHAR}{DEL CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{DEL CHAR}{inv}|{/inv}{DEL CHAR}{CTRL-L}{BACK S}{INS CHAR}{TAB}{TAB}"
1180 KF$(238)="?{TAB}{TAB}{INS CHAR}?{TAB}{INS CHAR}{INS CHAR}{INS CHAR}{TAB}s |{DEL CHAR}{INS CHAR}{INS CHAR}{DEL CHAR}{inv}|{/inv}{DEL CHAR}{DEL CHAR}{inv}|{/inv}"
1185 KF$(259)="{DEL CHAR}{INS CHAR}{INS CHAR}{DEL CHAR}{BACK S}4{inv}gC[C{CTRL-A}{CTRL-Y}{CTRL-Y}{/inv}{INS CHAR}{inv}{CTRL-C}{CTRL-Y}{CTRL-Y}{CTRL-C}{CTRL-Y}{CTRL-Y}{CTRL-C}{/inv}"
1190 KF$(280)="{INS CHAR}{inv}C{CTRL-A}{CTRL-O}{/inv}{SHIFT-TAB}{inv}{CTRL-O}{CTRL-A}C{/inv}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{INS CHAR}{inv}{CTRL-A}?{CTRL-O}?{/inv}"
1195 KF$(301)="{inv}{CTRL-A}{CTRL-A}{CTRL-A}{/inv}{INS CHAR}{inv}{CTRL-A}{CTRL-A}{CTRL-O}{CTRL-C}{CTRL-C}{CTRL-O}{CTRL-O}{/inv}{INS CHAR}{inv}C{CTRL-A}{/inv}{SHIFT-TAB}{inv}{CTRL-A}{CTRL-I}{CTRL-A}C{/inv}{INS CHAR}{inv}{CTRL-I}{/inv}"
1200 KF$(322)="{inv}{CTRL-I}{CTRL-A}{CTRL-A}{CTRL-A}{CTRL-I}{CTRL-I}{/inv}{INS CHAR}{inv}{CTRL-A}{CTRL-A}gg{CTRL-A}{CTRL-A}{CTRL-A}{/inv}{INS CHAR}{CTRL-,}{CTRL-X}<{BACK S}BZ"
1205 KF$(343)="B{BACK S}{CTRL-,}{BACK S}B^B^B{BACK S}{SHIFT-TAB}{SHIFT-TAB}{SHIFT-TAB}{SHIFT-TAB}{inv}{CTRL-A}{CTRL-A}{CTRL-A}{/inv}{INS CHAR}{INS LINE}{inv}{CTRL-I}{CTRL-A}{/inv}"
1210 KF$(364)="{inv}{CTRL-U}{/inv}{INS LINE}{INS LINE}{INS LINE}{INS CHAR}{INS LINE}{inv}{CTRL-M}{CTRL-E}{CTRL-Q}{CTRL-Y}{/inv}{INS LINE}{INS LINE}{INS CHAR}{inv}C{CTRL-A}{CTRL-M}{CTRL-M}{CTRL-A}{CTRL-A}C{/inv}{INS CHAR}"
1215 KF$(385)="{CTRL-,}{CTRL-,}{CTRL-X}<f{INS CHAR}{CTRL-,}{CTRL-,}{CTRL-H}{UP}{UP}<>>{BACK S}{TAB}{inv}{CTRL-C}{CTRL-I}{CTRL-I}{CTRL-A}{CTRL-G}{/inv}"
1220 KF$(406)="{inv}{CTRL-S}{CTRL-Q}{/inv}{INS CHAR}{inv}C{CTRL-A}{/inv}{SHIFT-TAB}{inv}Cy{CTRL-A}{CTRL-C}{/inv}{INS CHAR}{inv}{CTRL-A}{CTRL-A}{CTRL-A}gggg{/inv}{INS CHAR}{CTRL-,}{CTRL-P}"
1225 KF$(427)="{CTRL-X}<>{BACK S}{DEL CHAR}{INS CHAR}{CTRL-H}{CTRL-X}{UP}<<{BACK S}{TAB}{TAB}{CTRL-,}{CTRL-H}{UP}{UP}>{TAB}{INS CHAR}"
1230 KF$(448)="{INS CHAR}{inv}{CTRL-Y}{CTRL-Y}CCC{CTRL-Y}{CTRL-Y}{/inv}{INS CHAR}{inv}{CTRL-I}{CTRL-I}{CTRL-I}{CTRL-I}Cgg{/inv}{INS CHAR}"
1265 TM=PEEK(106):CB=TM-4:CA=CB*256:POKE 106,CB-1:GRAPHICS 17
1270 X=USR(ADR(MM$),ADR(KF$),CA,1024)
1275 POKE 756,CB
1277 T=0:E=0:GOSUB 700
1279 POKE 106,PEEK(740)
1280 DATA 0,0,0,28,54,127,0,0,0
1285 A=PEEK(106)-24:POKE 54279,A:START=256*A:POKE 559,46:POKE 53277,3
1290 FOR T=START+512 TO START+1024:POKE T,0:NEXT T
1293 RESTORE 1280
1295 FOR I=START+580+Q TO START+588+Q:READ X:POKE I,X:NEXT I
1300 POKE 623,4:POKE 704,44:A=46:POKE 53278,255:GOTO 34
2000 POSITION 0,0:? #6;"DDDDDDDDDDDDDDDDDDDD":POSITION 0,1:? #6;"DDDDDDDTHIEFDDDDDDDD"
2010 POSITION 0,21:? #6;"DDDBYDMAXDLANGERTDDD":POSITION 0,22:? #6;"DDDDDDDDDDDDDDDDDDDD"
2020 DATA 121,243,90,217,108,30,102,204,60,121,243,60,193,173,90,193,173,60
2030 RESTORE 2020
2040 FOR S=1 TO 6:READ A,B,C:SOUND 0,A,10,12:SOUND 1,B,10,12:FOR Z=1 TO C:NEXT Z:NEXT S
2050 FOR Z=12 TO 0 STEP -0.08:SOUND 0,193,10,Z:SOUND 1,173,10,Z:IF PEEK(53279)=6 THEN RETURN
2055 NEXT Z
2056 POSITION 0,21:? #6;"DDDDDHITDSTARTDDDDDD"
2060 IF PEEK(53279)=6 THEN RETURN
2065 POKE 77,0
2070 GOTO 2060
2500 POSITION NN,MM:? #6;" ":EN=EN+500:SC=SC+500:FOR Z=1 TO 8:SOUND 0,RND(0)*200+10,10,10:FOR W=1 TO 25:NEXT W
2510 NEXT Z:SOUND 0,0,0,0:GOTO 10
3000 DATA 0,0,66,36,0,36,66,0,0,0
3005 EN=1000
3015 RESTORE 3000
3020 FOR I=START+580+Q TO START+588+Q:READ X:POKE I,X:NEXT I:SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0
3030 FOR Z=1 TO 25:SOUND 0,100,10,10:NEXT Z:SOUND 0,0,0,0:FOR Z=1 TO 100:NEXT Z
3040 SH=SH-1:IF SH=0 THEN 3060
3050 POKE 53278,255:POSITION 1+SH,21:? #6;"DD":SOUND 0,200,12,15:FOR Z=1 TO 10:NEXT Z:SOUND 0,0,0,0:GOSUB LI
3055 GOTO 1279
3060 POSITION 1,8:? #6;"=!#$%#%!$#!#$#%!#?":POSITION 1,9:? #6;"*GAMEDTERMINATION."
3065 POSITION 1,10:? #6;">&'()')&)('))&'('@":POSITION 0,7:? #6;" "
3066 POSITION 0,11:? #6;" "
3070 FOR Z=50 TO 250 STEP 2:SOUND 0,Z,10,5:SOUND 1,Z-1,10,10:IF PEEK(53279)=6 THEN POKE 53248,10:RUN
3080 NEXT Z:GOTO 3070
5000 FOR Z=200 TO 30 STEP -1:SOUND 0,Z,10,10:SOUND 1,Z,10,10:NEXT Z:SC=SC+1000:POSITION N,M:? #6;" "
5010 SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
6000 IF LI>540 THEN LI=500:RO=1:GR=GR+0.5
6002 FOR R=0 TO EN STEP 5:SOUND 0,100,10,10:SC=SC+5:POSITION 13,21:? #6;SC:SOUND 0,0,0,0:NEXT R
6010 FOR Z=0 TO 22:POSITION 0,Z:? #6;" ":NEXT Z:RETURN
7000 RO=1:LI=500:DIM A$(20):SH=3:EN=1000
7010 GOTO 1100
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: THIEF.BAS.
Credits
- Program listing: Thief — program listing (Antic, March 1985 (Vol. 3, No. 11)) — Max Langert
- Picture: The title screen is drawn with the same cave characters as the game. — Max Langert (program); screenshot by the site
- Antic Software Archive — disk files (March 1985 - Vol. 3 No. 11): THIEF.BAS — Max Langert, 1985
- Antic magazine scan (OCR text layer): Antic_Vol_3-11_1985-03_Ultimate_Printer_Guide_text.pdf — Internet Archive
