Taxman

Type
Game
Category
Maze chase game
Author
Robert Patton ("Rassilon")
Published in
Antic, April 1987 (Vol. 5, No. 12), Game of the Month
Year
1987
Language
Atari BASIC (with machine-language helper routines)
Requirements
48K RAM, Atari BASIC, joystick in port 1; disk or cassette
Taxman: a vault filled with rows of small purple rectangles (the money stacks) inside a red border, (C) 1987 ANTIC across the middle, and L=1, SELECT LEVEL, TAXMAN BY RASSILON, START A GAME below

About the program

Antic's April 1987 issue was about taxes, so its Game of the Month was a little stress relief. In Robert Patton's Taxman, you have quietly opened five accounts at a very unusual Swiss bank, and you must grab the interest before a crack team of IRS field auditors catches up with you. Get caught once and you have to declare the interest. Get caught ten times and you're audited, and the game is over. Patton signed his programs "Rassilon", as the REM shows.

The bank's rules are peculiar. Interest is collected by running over the green stacks of dollars in the vault. In Account n (screen n) each stack needs n passes to collect and pays $n. Account 1 has 255 stacks at $1 each, and later accounts have fewer stacks but need more passes. Clearing an account earns a bonus of $100 × account number × your remaining chances, and the auditors move faster in each account.

Typing it in

Lines 540 and 580–630 hold machine-language routines and character data as strings full of special characters. {inv} … {/inv} means press the Atari (inverse) key before and after, and {CTRL-x} means hold CTRL and press the key. In the magazine, Listing 2 wrote these lines to a LINES.LST file for you to ENTER, but it isn't on the disk, so type them carefully and SAVE before you RUN. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.

How to play

SELECT chooses the starting level (account) and START begins. Move with the joystick, diagonals included. Sometimes a diagonal is your only escape. The auditors' patterns never change, only their speed, so learn the timing. Press the fire button as you reach the edge of the screen to wrap round to the other side. Patton called it "a very helpful evasion technique".

How it works

Patton said he wrote Taxman mainly to show off some useful BASIC and USR techniques while keeping the program short: player-missile graphics, an altered character set, a Boolean-logic joystick routine, P/M shape data stored in strings, and four small public-domain machine-language routines, which he named:

  • Z ("zero") fills a page of memory with zeros, for example to clear player memory (line 660).
  • M ("move memory") copies any number of bytes. Line 650 uses it to copy the 1,024-byte ROM character set into RAM at MYCS for redefining.
  • R ("rotate") rotates a run of bytes through a mask, which moves the missiles vertically (lines 120–130).
  • E holds the data for the explosion display, during which the player size also changes.

Listing

10 REM TAXMAN
14 REM BY "RASSILON" (ROBERT PATTON)
16 REM (c) 1987 ANTIC PUBLISHING INC.
18 BRK=1:IF PEEK(53279)=5 THEN BRK=0
20 GOSUB 520:GOSUB 340:GOTO 200
30 S=PEEK(632):T=PEEK(644)
40 C=C+((S=6)+(S=7)+(S=5))-((S=10)+(S=11)+(S=9)):R=R+((S=9)+(S=13)+(S=5))-((S=10)+(S=14)+(S=6))
50 IF C<2 THEN C=2:IF T=0 THEN C=17
60 IF R<2 THEN R=2:IF T=0 THEN R=17
70 IF C>17 THEN C=17:IF T=0 THEN C=2
80 IF R>17 THEN R=17:IF T=0 THEN R=2
90 IF BRK THEN POKE 16,112:POKE 53774,112
95 POKE 77,0:POKE HCLR,0:RETURN
100 LOCATE C,R,POM:CO=C:RO=R
110 GOSUB 30
120 X=USR(ADR(R$),PMM+20,MSL(1),71)
130 X=USR(ADR(R$),PMM+20,MSL(2),71)
140 POKE HM(3),HM3:HM3=HM3+2+L:IF HM3>198 THEN HM3=56:HM1=HM1+8:IF HM1>199-8*L THEN HM1=103
150 POKE HM(0),HM0:HM0=HM0-2-L:IF HM0<56 THEN HM0=198:HM2=HM2-8:IF HM2<55+8*L THEN HM2=151
160 POKE HM(1),HM1:POKE HM(2),HM2
170 IF C=9 AND R=8 THEN 190
180 IF PEEK(53256) OR PEEK(53257) OR PEEK(53258) OR PEEK(53259) THEN GOSUB 260:GOTO 200
190 POKE HCLR,0:IF CO=C AND RO=R THEN 110
200 P0=48+8*C:POKE HP0,P0:X=USR(Z,PMP0+6):X=USR(M,PMP0,PMP0+16+4*R,4)
210 IF POM=32 THEN 100
220 POM=POM-1:IF POM=38-L THEN SC=SC+1*L:POSITION 3,0:? #6;SC;:CNT=CNT+1
230 IF CNT=MCNT THEN GOSUB 480:GOTO 200
240 IF POM<=38-L THEN POM=32
250 COLOR POM:PLOT CO,RO:GOTO 100
260 E=ADR(E$):FOR V=14 TO 0 STEP -1:POKE 704,14+16*V:SOUND 0,114,0,V:SOUND 1,136,4,V
270 X=USR(Z,PMP0+6):X=USR(M,E,PMP0+14+4*R,8):E=E+8:SDL=PEEK(560)
280 IF E>ADR(E$)+56 THEN E=ADR(E$):POKE 53256,1:P0=P0-4:POKE HP0,P0
290 FOR W=0 TO 24+2*V:POKE 709,W:NEXT W:NEXT V
291 C=9:R=8:POKE HCLR,0:POKE 53256,0:MEN=MEN-1:POSITION 16,0:? #6;MEN;"{CTRL-J}";:POKE 704,28:POKE 709,150
300 IF MEN=0 THEN GOSUB 320:GOSUB 340:POP :GOTO 200
310 RETURN
320 POKE HP2,0:POSITION 6,8:? #6;"{inv}GAME OVER{/inv}";:POSITION 0,21:? #6;"  {inv}PRESS FIREBUTTON{/inv}  ":IF STRIG(0)=1 THEN 320
330 RETURN
340 GOSUB 490:GOSUB 510:MEN=10:L=1:GOSUB 440
350 CSL=PEEK(53279)
355 POSITION 3,5:? #6;"{inv}(C) 1987 ANTIC{/inv}"
360 POSITION 3,20:? #6;"&SELECT LEVEL&";
370 POSITION 0,21:? #6;"{inv}&{/inv}taxman {inv}BY RASSILON&{/inv}";
380 POSITION 3,22:? #6;"&START A GAME&";
390 POSITION 8,19:? #6;"L=";L;:FOR W=0 TO 15:NEXT W
400 IF (PEEK(632)=14 AND PEEK(644)=0) OR CSL=5 THEN L=L+1:IF L=6 THEN L=1
410 IF (PEEK(632)=15 AND PEEK(644)=0) OR CSL=6 THEN 430
420 GOTO 350
430 SC=0:GOSUB 490:GOSUB 450:GOSUB 470:RETURN
440 COLOR 38:FOR CC=1+L TO 18-L:FOR RR=1+L TO 18-L:PLOT CC,RR:NEXT RR:NEXT CC:COLOR 32:PLOT 9,8:RETURN
450 C=9:R=8:CO=C:RO=R:CNT=0:HM0=198:HM1=103:HM2=151:HM3=56:MCNT=18-2*L:MCNT=MCNT*MCNT-1
460 GOSUB 440:POKE HP2,120:RETURN
470 POSITION 3,0:? #6;SC:POSITION 13,0:? #6;"&%$";MEN;"{CTRL-J}";:POSITION 8,19:? #6;"L=";L:RETURN
480 SC=SC+100*L*MEN:MEN=MEN+2*L:L=L+1:GOSUB 490:GOSUB 450:GOSUB 470:RETURN
490 POKE HP2,0:FOR I=2 TO 18:POSITION 2,I:? #6;"                ":NEXT I
500 FOR I=20 TO 22 STEP 2:POSITION 3,I:? #6;"              ":NEXT I:RETURN
510 COLOR 10:PLOT 0,0:DRAWTO 19,0:DRAWTO 19,19:DRAWTO 0,19:DRAWTO 0,0:RETURN
520 DIM R$(54),HM(3),MSL(3),E$(56)
540 E$="{CTRL-,}{CTRL-H}*\{CTRL-T}*{CTRL-H}{CTRL-,}{CTRL-H}A{CTRL-D}{inv}({/inv}{CTRL-T}{CTRL-A}@{CTRL-H}{inv}{CTRL-T}{/inv}{CTRL-A}{CTRL-T}{inv} {/inv}{CTRL-A}{CTRL-T}{CTRL-A}{inv}{CTRL-H}{CTRL-Q}{/inv}J {inv}{CTRL-B}{/inv}A{CTRL-B}T{inv}{CTRL-I}{/inv}H{CTRL-A}@{CTRL-,}{inv}{CTRL-B}{/inv}{CTRL-A}{CTRL-H}B{inv}{CTRL-A}{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-,}{/inv}{CTRL-A}B{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}":E$(3,3)=CHR$(34):E$(6,6)=CHR$(34)
570 FOR I=0 TO 3:HM(I)=53252+I:NEXT I:MSL(0)=252:MSL(1)=243:MSL(2)=207:MSL(3)=67
580 R$="hh{inv}{CTRL-E}L{/inv}h{inv}{CTRL-E}K{/inv}hh{inv}{CTRL-E}M{/inv}hh{inv}(%M{/inv}I{INS CHAR}1{inv}K{/inv}H{inv}1K{/inv}%{inv}M{CTRL-Q}K{CTRL-H}%M{/inv}I{INS CHAR}1{inv}KH{/inv}{CTRL-Q}{inv}K{CTRL-Q}K{CTRL-H}Pk%M{/inv}1{inv}K{CTRL-Q}K{/inv}h{CTRL-Q}{inv}K{CTRL-Q}K{/inv}{CTRL-.}"
620 Z=ADR("hh{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T){/inv}{CTRL-,}{inv}({CTRL-Q}THP{CTRL-;}{/inv}{CTRL-.}")
630 M=ADR("hh{inv}{CTRL-E}q{/inv}h{inv}{CTRL-E}p{/inv}h{inv}{CTRL-E}U{/inv}h{inv}{CTRL-E}T{/inv}h{inv}{CTRL-E}o{/inv}h{inv}{CTRL-E}n {/inv}{CTRL-,}{inv}1p{CTRL-Q}TfTP{/inv}{CTRL-B}{inv}fUfpP{/inv}{CTRL-B}{inv}fqFnPjFo{/inv}{CTRL-P}{inv}f{/inv}{CTRL-.}")
640 CS=PEEK(756)*256:PMB=PEEK(740)-8:POKE 54279,PMB:HP0=53248:MYCS=PMB-4:POKE 106,MYCS-4
650 GRAPHICS 17:POKE 708,196:POKE 709,150:POKE 710,68:POKE 756,MYCS:MYCS=MYCS*256:X=USR(M,CS,MYCS,1024)
660 PMB=PMB*256:POKE 559,46:POKE 53277,3:POKE 623,1:PMP0=PMB+512:PMM=PMB+384:X=USR(Z,PMM):HCLR=53278
670 PMP2=PMB+768:X=USR(Z,PMP2):HP2=53250:P2=120:FOR I=0 TO 3:READ D:POKE PMP2+48+I,D:NEXT I:DATA 60,36,36,60
680 FOR I=704 TO 707:POKE I,28:NEXT I
690 FOR I=25 TO 85 STEP 12:POKE PMM+I,60:POKE PMM+I+1,60:NEXT I
700 FOR I=35 TO 80 STEP 20:POKE PMM+I,3:POKE PMM+I+1,3:NEXT I
710 POKE PMM+27,192:POKE PMM+28,192
720 POKE PMM+43,192:POKE PMM+44,192
730 POKE PMM+67,192:POKE PMM+68,192
740 POKE PMM+83,192:POKE PMM+84,192
750 FOR I=0 TO 39:READ D:POKE MYCS+16+I,D:NEXT I:FOR I=0 TO 7:POKE MYCS+80+I,255:NEXT I
760 DATA 0,102,102,0,0,102,102,0,231,231,231,0,0,231,231,231,0,0,0,24,24,0,0,0,0,0,60,60,60,60,0,0
770 DATA 0,126,126,126,126,126,126,0
780 X=USR(Z,PMP0):FOR X=PMP0 TO PMP0+3:POKE X,255:NEXT X:RETURN

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: TAXMAN.BAS.

Credits