Good King Zurp
- Type
- Game
- Category
- Dig-and-collect arcade game
- Author
- Frank Martone
- Published in
- Antic, August 1989 (Vol. 8, No. 4)
- Year
- 1989
- Language
- Atari BASIC
- Requirements
- 24K RAM, Atari BASIC, joystick in port 1; disk or cassette
About the program
Antic introduced its August 1989 Game of the Month with the subtitle "The great pasta sauce chase… Don't ask!", followed by a page of nonsense history. Good King Zurp came to the throne of Xjigqh after Better King Xorpfgh met an unfortunate end picking a flower from a hostile grootlebush. Zurp was eventually overthrown by toothpick craftsmen who flattened him under his own pool table, but not before he had built his famous Horror Pits. The rebel leader's will says that whoever develops a nationally accepted spaghetti recipe will rule Xjigqh. Conveniently, the pits are full of ingredients.
Behind the joke is a fast dig-and-collect game, written entirely in BASIC by Frank Martone, that runs on any 8-bit Atari with 24K.
Typing it in
Most of the special characters are inverse text ({inv}…{/inv}, with the Atari key on). In the game they double as coloured graphics, because in GRAPHICS 1 (here GRAPHICS 17, without a text window) inverse and lower-case letters select different colour registers. Lines 8 and 9 fill the pit with rows of inverse ( and " characters, which the custom character set turns into earth. Copy them exactly, along with the character DATA in lines 1100–1193 and the display-list-interrupt DATA in lines 11115–11116. The disk version has no TYPO II codes.
How to play
After the title screens and the point table, press START. Steer with the joystick; you dig a tunnel wherever you go. The top line shows your score, the time left on this screen and your lives (you start with nine).
| Item | Points |
|---|---|
| Packet of pasta | 100 |
| Seasonings (pepper, oregano and "for some reason, dried horseradish") | 250 |
| Garlic clove | 500 |
| Special pasta (tortellini, ravioli…), appears now and then | 5,000 |
| Pesto sauce | 0 ("there isn't any") |
| Maggots and colanders | you die |
When the time runs out you move to a fuller screen with more colanders. Every third screen is a bonus round: grab three special pastas as they flash up between the traps to win a random bonus of 1,000–10,000.
How it works
- Movement by POKE. The player is drawn by poking a character code straight into screen memory at
SCR+X+20*Y(lines 17 and 50), cycling codes 10 and 11 to animate. Moving erases the old square with a 0 (line 4100), which is what leaves the tunnel behind. - LOCATE for pickups. Line 32 checks the square you've just entered. Codes 247, 59 and 106 are pasta, seasoning and garlic, 45 is a colander and 35 the special pasta.
- Chasing maggots. Up to three maggots move towards you (subroutines 500, 550 and 580). The first is always there, the second joins after 15,000 points and the third after 29,000. Each simply closes the horizontal gap first, then the vertical one, and its picture flips to face the way it's going (
SV=58or7). - Rising difficulty. Each new screen adds seasonings, garlic and pasta packets and lowers
DIFF, so colanders appear more often (line 81). Past 60,000 points the background flickers, and past 39,000 extra special pastas pop up. - A blue score bar. Lines 11111–11130 poke a short display-list interrupt into page 6 (address 1536). For 15 scan lines it sets the background register to blue, then restores the normal colour, which gives the status line its own coloured band.
- The character set is copied from ROM with a BASIC
PEEK/POKEloop (line 1010), which is why the start takes a few seconds.
Variations to try
- Start with more or fewer lives:
TUM=9in line 5. - Change the scoring in lines 47–49, or the thresholds for extra maggots in lines 57–58.
Listing
0 REM GOOD KING ZURP
1 REM BY FRANK MARTONE
2 REM (C)1989, ANTIC PUBLISHING INC.
3 DIM F$(13):GRAPHICS 17:POKE 708,15:SN=0:POSITION 3,10
4 ? #6;"ANTIC PRESENTS":GOSUB 1000:GOSUB 3000:GOSUB 400
5 GRAPHICS 17:TUM=9:SC=0:BRS=30:DIFF=400:S1=19:S2=20:CTT=0:BI=5:S3=1:S4=23
6 POKE 756,CH/256:S5=0:S6=3:EG=10:GOB=7:SCR=PEEK(88)+256*PEEK(89)
7 GOSUB 11111:POKE 711,255:POKE 708,138
8 FOR G=2 TO 7:POSITION 0,G:? #6;"{inv}(((((((((((((((((((({/inv}":SOUND 0,G+6,10,7-G:NEXT G
9 FOR G=8 TO 22:POSITION 0,G:? #6;"{inv}""""""""""""""""""""{/inv}":SOUND 0,G,10,10:SOUND 0,0,0,0:NEXT G
11 FOR B=1 TO BRS:K1=INT(RND(0)*19):K2=INT(RND(0)*20)+3:POSITION K1,K2
12 ? #6;"{inv}w{/inv}":SOUND 0,20,10,10:FOR HJ=0 TO 1:NEXT HJ:SOUND 0,0,0,0:NEXT B
13 FOR T=1 TO EG:E1=INT(RND(0)*19):E2=INT(RND(0)*20)+3:POSITION E1,E2
14 ? #6;";":SOUND 0,120,10,10:FOR HJ=1 TO 3:NEXT HJ:SOUND 0,0,0,0:NEXT T
15 FOR C=1 TO GOB:POSITION RND(0)*18,RND(0)*18+3:? #6;"j":SOUND 0,C,10,10:SOUND 0,0,0,0:NEXT C
16 X=10:Y=12:V=10:TIME=0:FOR G=10 TO 13:POSITION 9,G:? #6;" ":NEXT G
17 POKE SCR+X+20*Y,10:FOR G=1 TO 80:SOUND 0,G*2,0,10:NEXT G:SOUND 0,0,0,0:POSITION 16,1:? #6;"+":TIME=30
18 POSITION 0,0:? #6;"{inv}score time lives{/inv}":COLOR 32:PLOT X,Y
20 POSITION 9,1:? #6;INT(TIME);" ";:GOSUB 4100
21 ST=PEEK(632):TR=PEEK(644):TP=SCR+X+20*Y:POKE 709,14:POKE 77,0
25 IF TIME<11 THEN SOUND 1,TIME+30,10,10
31 POSITION 1,1:? #6;SC:POSITION 17,1:? #6;TUM
32 LOCATE X,Y,BC
33 IF BC=35 THEN FOR G=1 TO 4:FOR R=-15 TO 15 STEP 3:SOUND 0,ABS(R)+35,10,10:NEXT R:NEXT G:SC=S
35 SOUND 1,0,0,0:TIME=TIME-0.5:V=V+1:IF TIME<1 THEN 7000
47 IF BC=247 THEN FOR W=15 TO 0 STEP -2:SOUND 0,30,10,W:NEXT W:SC=SC+100
48 IF BC=59 THEN FOR W=15 TO 0 STEP -2:SOUND 0,W*8,10,W:NEXT W:SC=SC+250
49 IF BC=106 THEN FOR W=70 TO 60 STEP -2:SOUND 0,RND(0)*5+3,10,8:NEXT W:SC=SC+500
50 POKE SCR+X+20*Y,V:IF BC=40 THEN GOSUB 300
51 POKE 709,0:IF X>18 THEN POKE SCR+X+20*Y,0:X=X-1
52 IF X<1 THEN POKE SCR+X+20*Y,0:X=X+1
53 IF Y<3 THEN POKE SCR+X+20*Y,0:Y=Y+1
54 IF Y>22 THEN POKE SCR+X+20*Y,0:Y=Y-1
55 IF RND(0)*6<4 THEN GOSUB 500
57 IF RND(0)*5<2 AND SC>15000 THEN GOSUB 550
58 IF RND(0)*4<2 AND SC>29000 THEN GOSUB 580
60 SOUND 0,0,0,0:IF BC=45 THEN GOSUB 90
61 IF X=S1 AND Y=S2 THEN GOSUB 300
62 IF X=S3 AND Y=S4 THEN GOSUB 300
63 IF X=S5 AND Y=S6 THEN GOSUB 300
64 IF SC>60000 THEN POKE 710,PEEK(53770)
65 IF SC>39000 AND PEEK(53770)=44 THEN GOSUB 100
66 IF SC>100000 THEN POKE 710,0:FOR D=1 TO 1:NEXT D
80 IF V>11 THEN V=10
81 POKE 709,0:POKE 709,14:IF RND(0)*DIFF<13 THEN POSITION RND(0)*19,RND(0)*18+3:? #6;"-":SOUND 0,255,10,5
82 GOTO 20
90 FOR R=1 TO 4:POSITION X,Y:? #6;"-":FOR D=1 TO 10:NEXT D:SOUND 0,255,10,10
91 POSITION X,Y:? #6;" ":FOR D=1 TO 10:NEXT D:SOUND 0,0,0,0:NEXT R:GOSUB 300
94 RETURN
100 POSITION RND(0)*19,RND(0)*18+4:? #6;"#"
101 FOR R=2 TO 20:SOUND 0,R*4,10,10:SOUND 1,R*8,10,10:POKE 712,R*5:SOUND 2,R,10,10:POKE 712,R:NEXT R
102 POKE 712,0:FOR T=0 TO 3:SOUND T,0,0,0:NEXT T:RETURN
300 POSITION X,Y:? #6;"+":FOR G=14 TO 1 STEP -1:FOR W=1 TO 25:NEXT W:POKE 708,64+G
301 SOUND 0,G,10,G:SOUND 1,G+2,10,G:NEXT G:POKE 708,206:SOUND 0,0,0,0:SOUND 1,0,0,0
302 FOR EX=4 TO 6:POKE SCR+X+20*Y,EX:FOR W=1 TO 30:NEXT W:SOUND 0,EX*4,10,10:NEXT EX:POKE SCR+X+20*Y,0:X=10:Y=12
303 FOR S=0 TO 2:SOUND S,0,0,0:NEXT S
304 TUM=TUM-1
305 IF TUM=0 THEN GOTO 5000
306 FOR L=15 TO 1 STEP -0.3:SOUND 1,L,6,L:SOUND 2,L,6,L:NEXT L
310 FOR R=0 TO 2:SOUND R,0,0,0:NEXT R
311 POSITION S1,S2:? #6;" ":POSITION S3,S4:? #6;" ":POSITION S5,S6:? #6;" "
312 S1=3:S2=19:S3=18:S4=19:S5=3:S6=3:POKE 708,138
320 RETURN
400 GRAPHICS 17:POKE 711,137:S1=19:S2=18:S3=2:S4=18:S5=0:S6=5:POKE 756,CH/256:POKE 709,14
405 DL=PEEK(560)+256*PEEK(561):POKE DL+13,7:POKE DL+15,7
409 POSITION 3,7:? #6;"j j j j j j j j"
410 POSITION 3,8:? #6;"{inv}entering{/inv} {inv}screen{/inv}":SN=SN+1
411 POSITION 10,10:? #6;SN
412 POSITION 3,11:? #6;"j j j j j j j j"
417 FOR G=1 TO 2
420 FOR D=15 TO 0 STEP -1:SOUND 0,34,10,D:POKE 708,D:NEXT D:NEXT G:RETURN
500 SNK=SCR+S1+20*S2:SV=58
510 POKE SNK,0:SOUND 0,20,6,5
521 IF Y<S2 AND X=S1 THEN S2=S2-1:GOTO 529
522 IF Y>S2 AND X=S1 THEN S2=S2+1:GOTO 529
525 IF X<S1 THEN S1=S1-1:SV=58
526 IF X>S1 THEN S1=S1+1:SV=7
529 POKE SCR+S1+20*S2,SV:RETURN
550 SNK1=SCR+S3+20*S4:SV=58
555 POKE SNK1,0:SOUND 0,10,6,5
557 IF X<S3 THEN S3=S3-1:SV=58
558 IF X>S3 THEN S3=S3+1:SV=7
559 IF Y<S4 AND X=S3 THEN S4=S4-1
560 IF Y>S4 AND X=S3 THEN S4=S4+1
561 POKE SCR+S3+20*S4,SV:RETURN
580 SNK2=SCR+S5+20*S6:SV=58
585 POKE SNK2,0:SOUND 0,3,6,5
587 IF X<S5 THEN S5=S5-1:SV=58
588 IF X>S5 THEN S5=S5+1:SV=7
589 IF Y<S6 AND X=S5 THEN S6=S6-1
590 IF Y>S6 AND X=S5 THEN S6=S6+1
591 POKE SCR+S5+20*S6,SV:RETURN
1000 REM --CHARACTER SET--
1010 CH=(PEEK(106)-8)*256:FOR I=0 TO 512:POKE CH+I,PEEK(57344+I):NEXT I
1020 RESTORE 1100
1030 READ A:IF A<0 THEN RETURN
1040 FOR J=0 TO 7:READ B:POKE CH+A*8+J,B:NEXT J:GOTO 1030
1100 DATA 10,0,189,126,235,255,255,126,36
1110 DATA 11,0,36,126,255,106,255,126,60
1115 DATA 12,0,60,126,126,255,106,126,189
1120 DATA 4,0,0,4,0,16,8,64,0
1125 DATA 5,1,66,0,34,8,64,20,128
1130 DATA 6,0,0,4,80,8,20,0,0
1140 DATA 2,255,253,239,247,255,191,251,191
1143 DATA 58,48,88,56,8,18,34,36,24
1146 DATA 55,0,15,31,62,124,120,112,0
1149 DATA 63,7,5,7,56,40,184,128,128
1150 DATA 42,56,84,146,254,170,84,40,16
1170 DATA 3,146,84,16,238,16,84,146,0
1175 DATA 26,0,0,0,0,0,0,1,3
1176 DATA 27,0,126,255,171,171,255,255,0
1177 DATA 28,0,0,0,0,0,0,128,192
1178 DATA 29,7,7,7,15,15,15,15,7
1179 DATA 30,255,156,8,8,207,8,156,255
1180 DATA 31,224,224,112,112,112,112,240,224
1181 DATA 32,7,3,7,24,48,24,4,0
1182 DATA 61,189,195,255,126,60,24,24,0
1183 DATA 62,224,192,224,24,12,24,32,0
1184 DATA 49,0,0,0,255,0,255,0,0
1190 DATA 8,170,77,170,77,170,77,170,77
1191 DATA 13,254,170,170,170,170,170,170,254
1192 DATA 7,6,13,14,8,68,66,34,28
1193 DATA 8,3,192,12,0,51,0,6,96,-1
3000 GRAPHICS 17:POKE 756,CH/256:POKE 708,75:POKE 711,15:POKE 709,11
3003 POKE 710,255:POSITION 4,7:? #6;"jjjj jjjj jjjj"
3026 POSITION 9,9:? #6;"{inv}:;<{/inv}":POSITION 9,10:? #6;"{inv}=>?{/inv}":POSITION 9,11:? #6;"@]^"
3040 COLOR 81:PLOT 0,22:DRAWTO 19,22:PLOT 0,3:DRAWTO 19,3
3041 L=0.2:POSITION 0,3:? #6;"QQQQQQQQQQQQQQQQQQQQ"
3099 RESTORE 3200:R=4
3100 READ F$:IF F$="X" THEN GOTO 3500
3101 POSITION R,7:? #6;"%":FOR D=15 TO 0 STEP -1.3:SOUND 0,D+10,8,D:NEXT D
3102 POSITION R,7:? #6;F$;
3105 R=R+1:GOTO 3100
3200 DATA G,O,O,D,j,K,I,N,G,j,Z,U,R,P,X
3500 POSITION 2,16:? #6;" {inv}BY FRANK MARTONE{/inv}":SOUND 0,0,0,0:SOUND 1,0,0,0
3503 FOR G=1 TO 100:FOR J=15 TO 0:SOUND 0,J*2,0,R:SOUND 1,J*3,0,J
3505 POKE 709,J+100:NEXT J:NEXT G:SOUND 0,0,0,0:SOUND 1,0,0,0
4000 GRAPHICS 17:POKE 756,CH/256:POKE 708,14:POKE 710,55:POKE 709,255
4001 P=5:CC=0:POSITION 4,2:? #6;" {inv}point scale{/inv}"
4002 COLOR 81:PLOT 0,3:DRAWTO 19,3:PLOT 0,22:DRAWTO 19,22
4004 POSITION 1,P:? #6;"PASTA PKT w 100":GOSUB 4900
4005 POSITION 1,P:? #6;"SEASONINGS {inv};{/inv} 250":GOSUB 4900
4006 POSITION 1,P:? #6;"GARLIC {inv}j{/inv} 500":GOSUB 4900
4007 POSITION 1,P:? #6;"SPEC. PASTA # 5000":GOSUB 4900
4008 POSITION 1,17:? #6;"AVOID COLLANDERS {inv}-{/inv}"
4009 POSITION 1,19:? #6;"AVOID MAGGOTS {inv}z{/inv}'"
4010 POSITION 5,21:? #6;"PRESS START":FOR D=1 TO 50:NEXT D
4011 POSITION 5,21:? #6;"press start":FOR D=1 TO 50:NEXT D:CC=CC+1:IF CC=30 THEN GOTO 3000
4015 IF PEEK(53279)=6 THEN GOTO 5
4020 GOTO 4010
4100 POKE TP,0:X=X+(ST<8)-(ST>8 AND ST<12):Y=Y+(ST=13)-(ST=14):RETURN
4900 FOR D=15 TO 0 STEP -1:SOUND 0,50,10,D:NEXT D:P=P+3:RETURN
5000 POSITION 17,1:? #6;"0":FOR E=14 TO 0 STEP -1:POKE 710,64+E
5001 FOR R=1 TO 10:NEXT R:SOUND 0,E,0,10:NEXT E:SC=0:SN=0
5005 FOR D=7 TO 12:POSITION 5,D:? #6;" ":NEXT D
5010 POSITION 6,8:? #6;"{inv}game over{/inv}"
5050 FOR L=20 TO 70:SOUND 0,L,10,10:SOUND 1,L,6,10:NEXT L
5061 SOUND 0,0,0,0:SOUND 1,0,0,0:C=0
5065 C=C+1:POSITION 5,10:? #6;"PRESS START":C=C+1
5076 IF C=28 THEN FOR I=19 TO 0 STEP -1:COLOR 0:PLOT I,0:DRAWTO I,23:FOR D=1 TO 5:NEXT D:NEXT I:GOTO 3000
5080 IF PEEK(53279)=6 THEN SN=0:GOTO 5
6000 GOTO 5065
7000 COLOR 176:PLOT 9,1:COLOR 42:PLOT X,Y
7001 SOUND 0,255,10,10:SOUND 1,254,10,10:FOR L=1 TO 50:POKE 710,PEEK(53770):NEXT L
7002 RESTORE 7100
7005 READ MUSIC:IF MUSIC=255 THEN 7120
7010 SOUND 0,MUSIC,10,10:FOR G=7 TO 1 STEP -1.5:SOUND 1,MUSIC,10,G+4
7025 NEXT G:POKE 712,MUSIC:POKE 710,PEEK(53770):GOTO 7005
7100 DATA 121,1,121,121,96,114,121,96,96,1,96,96,81,91,96,91,91,1,91,91,76,81,91,96,96,114,114,121,121,121,255
7120 SOUND 0,0,0,0:SOUND 1,0,0,0:POKE 712,0:FOR I=0 TO 19:COLOR 0
7122 PLOT I,0:DRAWTO I,23:FOR D=1 TO 5:NEXT D:NEXT I
7201 IF DIFF<110 THEN DIFF=120
7202 CTT=CTT+1
7204 IF CTT=3 THEN 9000
7207 EG=EG+7:WB=WB+0.5:DIFF=DIFF-27:GOSUB 400:BRS=BRS+1
7210 GRAPHICS 17:POKE 756,CH/256:POKE 710,PEEK(53770):POKE 708,138:GOB=GOB+7:GOTO 7
9000 GRAPHICS 17:POKE 710,14:POKE 756,CH/256:POSITION 5,6:? #6;"{inv}bonus round{/inv}":CTT=0
9001 POSITION 3,10:? #6;"{inv}YOU MUST GRAB{/inv} 3"
9002 POSITION 3,12:? #6;"{inv}SPECIAL PASTAS{/inv}"
9003 POSITION 4,14:? #6;"{inv}TO GET BONUS{/inv}"
9004 COLOR 33:PLOT 0,16:DRAWTO 19,16:PLOT 0,4:DRAWTO 19,4
9006 FOR D=1 TO 140:POKE 708,RND(0)*10+50:NEXT D
9010 GRAPHICS 17:GOSUB 11111:POKE 756,CH/256:POSITION 5,0:? #6;"{inv}bonus round{/inv}":X=10:Y=10:POKE 708,156
9011 POSITION 0,22:? #6;"{inv}qqqqqqqqqqqqqqqqqqqq{/inv}":TIME=0:T=10:IF SC>30000 THEN T=6:S1=4:S2=16
9012 POSITION 0,3:? #6;"{inv}qqqqqqqqqqqqqqqqqqqq{/inv}":IF SC>70000 THEN T=3
9013 POSITION 5,23:? #6;"AVOID TRAPS"
9014 FOR K=5 TO 21 STEP 3
9015 POSITION 3,K:? #6;" - - - -"
9017 NEXT K:SCR=PEEK(88)+256*PEEK(89):BS=0
9050 TP=SCR+X+20*Y:ST=PEEK(632):POKE 710,14
9051 IF X=S1 AND Y=S2 THEN 9700
9053 IF SC>50000 AND RND(0)*9<5 THEN GOSUB 500
9055 GOSUB 4100:IF X>18 THEN POKE SCR+X+20*Y,0:X=X-1
9060 IF X<1 THEN POKE SCR+X+20*Y,0:X=X+1
9061 IF Y<5 THEN POKE SCR+X+20*Y,0:Y=Y+1
9062 IF Y>20 THEN POKE SCR+X+20*Y,0:Y=Y-1
9063 SOUND 0,0,0,0:IF BS=3 THEN 9200
9070 POKE TP,11:FOR D=1 TO 8:NEXT D:LOCATE X,Y,BC:POSITION 7,2:? #6;"COUNT ";BS
9075 IF BC=45 THEN 9700
9080 POKE TP,0:POKE 710,PEEK(53770)
9100 IF TIME=0 THEN T1=INT(RND(0)*15)+3:T2=INT(RND(0)*15)+4:POSITION T1,T2:? #6;"{inv}#{/inv}"
9103 TIME=TIME+1:IF TIME>T THEN POSITION T1,T2:? #6;" ":FOR D=10 TO 0 STEP -1:SOUND 0,10,10,D:NEXT D:TIME=0
9107 IF BC=163 THEN FOR D=1 TO 10:SOUND 0,D+2,8,6:POKE 712,D*3:NEXT D:BS=BS+1:SOUND 0,0,0,0:POKE 712,0
9150 GOTO 9050
9200 REM
9240 POSITION 3,23:? #6;"CONGRATULATIONS"
9241 POSITION 5,2:? #6;"{inv}rA{/inv}N{inv}d{/inv}o{inv}M {/inv}B{inv}o{/inv}n{inv}U{/inv}S "
9245 FOR D=1 TO 10:SOUND 0,RND(0)*10,10,10:SOUND 1,RND(0)*20,10,10:NEXT D:A=INT(RND(0)*10)*1000+1000:SC=SC+A
9246 POSITION 5,2:? #6;"BONUS ";A;" ":SOUND 0,0,0,0:SOUND 1,0,0,0
9247 FOR D=1 TO 10:FOR F=15 TO 0 STEP -1:POKE 708,F:NEXT F:NEXT D
9248 SN=SN+1:GOSUB 400:GRAPHICS 17:POKE 756,CH/256:POKE 710,121:POKE 708,138:GOTO 7
9700 POKE TP,0:POSITION 3,23:? #6;"SORRY NO BONUS"
9704 FOR JJ=30 TO 50
9705 FOR D=-15 TO 15 STEP 3:SOUND 0,ABS(D)+JJ,10,10:POKE 708,D+50:NEXT D
9706 NEXT JJ
9707 SOUND 0,20,6,10:POKE 708,255:FOR D=1 TO 40:NEXT D:SOUND 0,0,0,0
9710 SN=SN+1:GOSUB 400:GRAPHICS 17:POKE 756,CH/256:POKE 710,137:POKE 708,138:GOTO 7
9999 GOTO 9050
10000 REM --DLI-BLUE--
11111 RESTORE 11115
11112 FOR ADD=1536 TO 1536+28:READ B:POKE ADD,B:NEXT ADD
11115 DATA 72,138,72,141,10,212,169,112,141,26,208,162
11116 DATA 15,141,10,212,202,208,250,173,200,2,141,26,208,104,170,104,64
11120 POKE 512,0:POKE 513,6:DL=PEEK(560)+256*PEEK(561)
11130 POKE DL+2,112+128:POKE 54286,192
11147 POSITION 6,0:? #6;"{inv}get ready{/inv}":RETURN
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: PASTA.BAS.
Credits
- Program listing: Good King Zurp — program listing (Antic, August 1989 (Vol. 8, No. 4)) — Frank Martone
- Picture: Digging through the Horror Pits: pasta packets, seasoning tins and an approaching maggot. — Frank Martone (program); screenshot by the site
- Antic magazine scan (OCR text layer), August 1989, pp. 17-18: Good King Zurp, program by Frank Martone — Frank Martone; Internet Archive, 1989
- Antic Software Archive — August 1989 - Vol. 8 No. 4 disk: PASTA.BAS — Frank Martone, 1989
