Saucerian Shootdown
- Type
- Game
- Category
- Missile-launcher shooting game
- Author
- James (Jim) Catalano
- Published in
- Antic, January 1989 (Vol. 7, No. 9), Bonus Game
- Year
- 1989
- Language
- Atari BASIC
- Requirements
- 32K RAM, Atari BASIC, joystick in port 1
About the program
You're on the security console of a military outpost on the planet Traken when the scanners pick up unidentified objects darting about in Quadrant 24. The Occuloid Trackship's camera shows strange saucers. They don't answer your hails, and they don't seem hostile, but they could be spy drones, so you send in an Automated Missile Launcher. Antic called the game "as straightforward as its title". It was James Catalano's second Antic game, after Sorcerer's Apprentice, and it appeared as the Bonus Game in January 1989. The listing and the title screen just say SAUCERIAN.
Typing it in
You need 32K. Lines 20060–20075 hold the machine-language player-movement routine as strings of inverse and control characters. The magazine printed a second listing that wrote them to LINES.LST for merging, and the disk version here includes them. In this notation, {inv}…{/inv} means type with the Atari key on and {CTRL-R} means hold CTRL and press R (the line-drawing characters on the title screen).
How to play
Press the button at the title screen. The landscape is drawn first, with jagged mountains and a chequered plain stretching to the horizon. Then two saucers start zig-zagging across the sky. Move the launcher left and right with the joystick and press the button to fire. Each hit is worth 100 points, and every five hits earns a 1,000-point bonus. You have 50 missiles, and when they're gone, the score sheet shows your hits, misses and bonus. Press START to play again.
The catch is depth. A saucer can only be hit when it's in the top band of the sky, where it's drawn quadruple-width, so it looks nearest, and turns white. That's Antic's "targeted accurately". Further away it's narrower and darker, and missiles pass straight through.
The REM in line 10 points to a hidden feature. Line 686 waits while the button on a joystick in port 2 is held down, so that button freezes the game.
How it works
- The landscape is GRAPHICS 7+16 (mode 23). Lines 130–175 draw two ranges of random-walk mountains, each column a vertical line from a wandering height down to the horizon. Lines 110–113 fill the plain and draw a perspective grid. Horizontal lines get closer together towards the horizon (DATA 61, 63, 66, 70, 75, 81, 88), and rays fan out from a vanishing point at (79,61).
- Players for everything that moves. The launcher, the missile and the two saucers are players 0–3, positioned by a machine-language routine (
PMMOVQ) that copies a shape into player memory at any X and Y. - Fake 3-D. Each saucer moves 10 pixels in one of eight directions, and changes direction on a random 2-in-15 chance. Lines 580–590 then set its width (the size registers 53258 and 53259: normal, double or quadruple) and its brightness according to its height on the screen, so it seems to come nearer and go further away.
- Hit test. Lines 770–775 read the missile-to-player collision register (53261) and accept a hit only if that saucer is currently at the largest size.
Variations to try
- Give yourself more missiles: change
MISL=50in line 55 (and the "MISSILES FIRED:50" message in line 880). - Make hits possible at medium distance too, by accepting
UFOSIZEA=1as well in line 770 (andUFOSIZEBin 775).
Changes from the published listing
One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds a command called PMMOVE, so it rejected the published lines that use that word as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.
| Published | Now | Lines |
|---|---|---|
PMMOVE |
PMMOVQ |
18 lines (595–20050) |
PMMOVE$ |
PMMOVQ$ |
20050, 20070, 20072, 20075 |
Listing
10 REM SAUCERIAN (SCREENFREEZE @ 686)
15 REM BY JIM CATALANO
20 REM (c)1988, ANTIC PUBLISHING
30 GRAPHICS 0:POKE 710,0:POKE 752,1:DLI=PEEK(560)+PEEK(561)*256+4:POKE DLI-1,66
31 POKE DLI+6,7:POKE DLI+7,7:POKE DLI+11,6:POKE DLI+12,6:POKE DLI+17,6:POKE DLI+18,6
32 POSITION 7,3:? "{CTRL-R}{CTRL-R} P R E S E N T I N G {CTRL-R}{CTRL-R}":POSITION 1,5:? "S A U C E R I A N"
33 POSITION 7,7:? "DESIGNED AND PROGRAMMED BY":POSITION 2,9:? "james catalano"
34 POSITION 14,12:? "(c)1988":POSITION 2,14:? "{inv}antic magazine{/inv}":? :? " Press Trigger to Begin"
35 IF STRIG(0) THEN 35
39 REM INITIALIZATION
40 PMMODE=1:GRMODE=23:GOSUB 20050
45 POKE 708,50:POKE 709,52:POKE 710,54:POKE 712,136:UFOAX=INT(RND(0)*248)+1:UFOAY=INT(RND(0)*140)+1
50 UFOBX=INT(RND(0)*248)+1:UFOBY=INT(RND(0)*140)+1:UFOAMOV=INT(RND(0)*8)+1:UFOBMOV=INT(RND(0)*8)+1
55 BASEX=122:BASEY=190:MISX=BASEX:MISY=173:MISL=50:HIT=0:MIS=0:BONUS=0:SCR=0
100 REM LANDSCAPE ROUTINE
105 REM
110 GOSUB 130:FOR Y=60 TO 95:COLOR 3:PLOT 0,Y:DRAWTO 156,Y:NEXT Y:COLOR 2:RESTORE 113
111 READ L:IF L=-1 THEN FOR X=0 TO 156 STEP 14:PLOT 79,61:DRAWTO X,95:NEXT X:GOTO 114
112 PLOT 0,L:DRAWTO 156,L:PLOT 0,L:DRAWTO 79,61:DRAWTO 156,L:GOTO 111
113 DATA 61,63,66,70,75,81,88,-1
114 GOSUB 10005
115 GOTO 505
125 REM MOUNTAIN ROUTINE
130 COLOR 1:Y=40:X=-1:GOSUB 150
135 COLOR 2:Y=55:X=-1:GOSUB 150
145 RETURN
150 FOR T=1 TO 157
155 M=INT(RND(0)*2)+1
160 IF M=1 THEN Y=Y-1
165 IF M=2 THEN Y=Y+1
166 IF Y<35 THEN Y=Y+1
167 IF Y>59 THEN Y=Y-1
170 X=X+1
175 PLOT X,Y:DRAWTO X,60:NEXT T:RETURN
500 REM UFO 'A' CONTROL
505 POKE 53278,0:UFOADIR=INT(RND(0)*15)+1:IF UFOADIR<3 THEN 515
510 GOTO 520
515 UFOAMOV=INT(RND(0)*8)+1
520 IF UFOAMOV=1 THEN UFOAY=UFOAY-10
525 IF UFOAMOV=2 THEN UFOAX=UFOAX+10:UFOAY=UFOAY-10
530 IF UFOAMOV=3 THEN UFOAX=UFOAX+10
535 IF UFOAMOV=4 THEN UFOAX=UFOAX+10:UFOAY=UFOAY+10
540 IF UFOAMOV=5 THEN UFOAY=UFOAY+10
545 IF UFOAMOV=6 THEN UFOAX=UFOAX-10:UFOAY=UFOAY+10
550 IF UFOAMOV=7 THEN UFOAX=UFOAX-10
555 IF UFOAMOV=8 THEN UFOAX=UFOAX-10:UFOAY=UFOAY-10
560 IF UFOAX<15 THEN UFOAX=15:UFOAMOV=3
565 IF UFOAX>208 THEN UFOAX=208:UFOAMOV=7
570 IF UFOAY<10 THEN UFOAY=10:UFOAMOV=5
575 IF UFOAY>140 THEN UFOAY=140:UFOAMOV=1
580 IF UFOAY<71 THEN UFOSIZEA=3:UFOCOLA=14
585 IF UFOAY>70 AND UFOAY<116 THEN UFOSIZEA=1:UFOCOLA=10
590 IF UFOAY>115 THEN UFOSIZEA=0:UFOCOLA=6
595 POKE 53258,UFOSIZEA:POKE 706,UFOCOLA:A=USR(PMMOVQ,3,SHAPE3,SIZE3,UFOAX,UFOAY)
600 REM UFO 'B' CONTROL
605 UFOBDIR=INT(RND(0)*15)+1:IF UFOBDIR<3 THEN 615
610 GOTO 620
615 UFOBMOV=INT(RND(0)*8)+1
620 IF UFOBMOV=1 THEN UFOBY=UFOBY-10
625 IF UFOBMOV=2 THEN UFOBX=UFOBX+10:UFOBY=UFOBY-10
630 IF UFOBMOV=3 THEN UFOBX=UFOBX+10
635 IF UFOBMOV=4 THEN UFOBX=UFOBX+10:UFOBY=UFOBY+10
640 IF UFOBMOV=5 THEN UFOBY=UFOBY+10
645 IF UFOBMOV=6 THEN UFOBX=UFOBX-10:UFOBY=UFOBY+10
650 IF UFOBMOV=7 THEN UFOBX=UFOBX-10
655 IF UFOBMOV=8 THEN UFOBX=UFOBX-10:UFOBY=UFOBY-10
660 IF UFOBX<15 THEN UFOBX=15:UFOBMOV=3
665 IF UFOBX>208 THEN UFOBX=208:UFOBMOV=7
670 IF UFOBY<10 THEN UFOBY=10:UFOBMOV=5
675 IF UFOBY>140 THEN UFOBY=140:UFOBMOV=1
680 IF UFOBY<71 THEN UFOSIZEB=3:UFOCOLB=14
685 IF UFOBY>70 AND UFOBY<116 THEN UFOSIZEB=1:UFOCOLB=10
686 IF STRIG(1)=0 THEN 686
690 IF UFOBY>115 THEN UFOSIZEB=0:UFOCOLB=6
695 POKE 53259,UFOSIZEB:POKE 707,UFOCOLB:A=USR(PMMOVQ,4,SHAPE4,SIZE4,UFOBX,UFOBY)
700 REM MOVE MISSILE BASE
705 IF FIRE=1 THEN 755
710 ST=STICK(0):T=STRIG(0):POKE 77,0
715 IF ST=11 THEN BASEX=BASEX-8:MISX=MISX-8
720 IF ST=7 THEN BASEX=BASEX+8:MISX=MISX+8
725 IF BASEX<50 THEN BASEX=50:MISX=50
730 IF BASEX>194 THEN BASEX=194:MISX=194
735 A=USR(PMMOVQ,1,SHAPE1,SIZE1,BASEX,BASEY):A=USR(PMMOVQ,2,SHAPE2,SIZE2,MISX,MISY)
740 IF T=0 THEN MISL=MISL-1:FIRE=1:GOTO 755
744 IF MISL=0 THEN 870
745 GOTO 505
750 REM FIRED MISSILE
755 MISY=MISY-20
760 IF MISY<0 THEN MIS=MIS+1:SOUND 0,0,0,0:A=USR(PMMOVQ,2,SHAPE2,SIZE2,0,0):MISY=173:FIRE=0:GOTO 505
765 SOUND 0,MISY/19+19,0,15:A=USR(PMMOVQ,2,SHAPE2,SIZE2,MISX,MISY)
770 IF PEEK(53261)=4 AND UFOSIZEA=3 THEN HIT=HIT+1:GOTO 800
775 IF PEEK(53261)=8 AND UFOSIZEB=3 THEN HIT=HIT+1:GOTO 835
780 GOTO 505
785 REM MISSILE HIT
790 REM
795 REM SAUCER 'A' HIT
800 A=USR(PMMOVQ,2,SHAPE2,SIZE2,0,0):SOUND 0,0,0,0
805 FOR A=0 TO 75:SOUND 0,A*2,0,15:POKE 706,A*3:NEXT A
810 A=USR(PMMOVQ,3,SHAPE3,SIZE3,0,0):FOR V=15 TO 0 STEP -0.5:SOUND 0,A*2,0,V:NEXT V:SCR=SCR+100
815 UFOAX=INT(RND(0)*208)+1:IF UFOAX<15 THEN UFOAX=15
820 POKE 706,6:UFOAY=140:POKE 53258,0:A=USR(PMMOVQ,3,SHAPE3,SIZE3,UFOAX,UFOAY):FIRE=0:MISY=173:SOUND 0,0,0,0
825 GOTO 505
830 REM SAUCER 'B' HIT
835 A=USR(PMMOVQ,2,SHAPE2,SIZE2,0,0):SOUND 0,0,0,0
840 FOR A=0 TO 75:SOUND 0,A*2,0,15:POKE 707,A*3:NEXT A
845 A=USR(PMMOVQ,4,SHAPE4,SIZE4,0,0):FOR V=15 TO 0 STEP -0.5:SOUND 0,A*2,0,V:NEXT V:SCR=SCR+100
850 UFOBX=INT(RND(0)*208)+1:IF UFOBX<15 THEN UFOBX=15
855 POKE 707,6:UFOBY=140:POKE 53259,0:A=USR(PMMOVQ,4,SHAPE4,SIZE4,UFOBX,UFOBY):FIRE=0:MISY=173:SOUND 0,0,0,0
860 GOTO 505
865 REM GAME OVER
870 A=USR(PMMOVQ,1,SHAPE1,SIZE1,0,0):A=USR(PMMOVQ,2,SHAPE2,SIZE2,0,0):A=USR(PMMOVQ,3,SHAPE3,SIZE3,0,0)
875 A=USR(PMMOVQ,4,SHAPE4,SIZE4,0,0):POKE 53277,0:GRAPHICS 17:POKE 708,15
880 POSITION 5,2:? #6;"GAME OVER":POSITION 1,5:? #6;"MISSILES FIRED:50"
885 POSITION 6,7:? #6;"HITS:";HIT:POSITION 5,9:? #6;"MISSES:";MIS
890 BONUS=INT(HIT/5)*1000:POSITION 4,11:? #6;"BONUS: ";BONUS:SCR=SCR+BONUS:POSITION 4,15:? #6;"SCORE: ";SCR
895 POSITION 0,18:? #6;"{inv}press start to play again{/inv}"
900 IF PEEK(53279)=6 THEN POKE 106,PEEK(740):GRAPHICS 0:RUN
905 GOTO 900
10000 REM P/M DATA
10005 POKE 623,1
10010 REM MISSILE BASE
10015 DIM SHAPE1$(14):SHAPE1$="$fBf{inv}[{/inv}{INS CHAR}Z$Z{inv}{CTRL-A}{/inv}{INS CHAR}<{BACK S}{inv}{CTRL-Y}{/inv}":SHAPE1=ADR(SHAPE1$):SIZE1=14
10020 A=USR(PMMOVQ,1,SHAPE1,SIZE1,BASEX,BASEY)
10030 REM MISSILE
10035 DIM SHAPE2$(23):SHAPE2$="{CTRL-X}{CTRL-X}<<<{CTRL-,}<<<<<<fffff{inv}ggg[[{/inv}Z":SHAPE2=ADR(SHAPE2$):SIZE2=23
10040 A=USR(PMMOVQ,2,SHAPE2,SIZE2,MISX,MISY)
10050 REM SAUCER 1
10055 DIM SHAPE3$(7):SHAPE3$="{CTRL-X}{BACK S}{INS CHAR}{CTRL-,}{INS CHAR}{BACK S}{CTRL-X}":SHAPE3=ADR(SHAPE3$):SIZE3=7
10060 A=USR(PMMOVQ,3,SHAPE3,SIZE3,UFOAX,UFOAY)
10065 REM SAUCER 2
10070 DIM SHAPE4$(7):SHAPE4$="{CTRL-X}{BACK S}{INS CHAR}{CTRL-,}{INS CHAR}{BACK S}{CTRL-X}":SHAPE4=ADR(SHAPE4$):SIZE4=7
10075 A=USR(PMMOVQ,4,SHAPE4,SIZE4,UFOBX,UFOBY)
19999 RETURN
20000 REM P/M SETUP
20010 REM (DEFINE PMMODE & GRMODE
20015 REM BEFORE CALLING ROUTINE)
20050 DIM PAGCLR$(48),PMMOVQ$(202):PAGCLR=ADR(PAGCLR$):PMMOVQ=ADR(PMMOVQ$)
20060 PAGCLR$="h{inv}I{/inv}{CTRL-B}{inv}p{/inv}{CTRL-P}{inv}{CTRL-E}N"{/inv}{CTRL-,}{inv}dNP{/inv}{CTRL-A}{CTRL-.}hh{inv}h){/inv}{CTRL-,}{inv}pt{/inv}h{inv}{CTRL-E}L{/inv}h{inv}{CTRL-E}K{/inv}hh{inv}{CTRL-E}M){/inv}{CTRL-,}{inv}(*{CTRL-Q}KHP{CTRL-;}fLhdMPt{/inv}{CTRL-.}"
20070 PMMOVQ$(1,67)="h{inv}I{/inv}{CTRL-E}{inv}p{/inv}{CTRL-R}{inv}{CTRL-M}{/inv}{CTRL-,}{CTRL-D}{inv}"{/inv}{CTRL-,}{inv}l{/inv}{CTRL-,}{CTRL-D}{inv}P{/inv}{CTRL-A}{CTRL-.}hh{inv}h){/inv}{CTRL-,}{inv}ps{/inv}hh{inv}I{/inv}{CTRL-I}{inv}{CTRL-P}{/inv}{CTRL-I}hhhhhhhh{CTRL-.}{CTRL-X}{inv}I{/inv}{CTRL-,}{inv}pr{CTRL-M}{/inv}{CTRL-D}{CTRL-D}h{inv}{CTRL-E}N{/inv}h{inv}{CTRL-E}M{/inv}hh{inv}{CTRL-M}{/inv}{CTRL-E}{CTRL-D}hh{inv}{CTRL-M}{/inv}{CTRL-B}{CTRL-D}hh{inv}{CTRL-M}{/inv}{CTRL-C}{CTRL-D}"
20072 PMMOVQ$(68,134)="{inv}.{/inv}{CTRL-D}{CTRL-D}{inv}-{/inv}{CTRL-B}{CTRL-D}{INS LINE}{INS CHAR}{inv}O{CTRL-.}{/inv}{CTRL-E}{inv}0{/inv}{CTRL-B}{inv}{CTRL-P}{/inv}{CTRL-E}{inv}){/inv}{CTRL-,}{inv}{CTRL-M}{/inv}{CTRL-D}{CTRL-D}{inv}%OI{/inv}{CTRL-B}{inv}p{/inv}{UP}{inv}%{/inv}j{CTRL-X}i{CTRL-C}m{CTRL-D}{CTRL-D}{inv}{CTRL-E}L){/inv}{CTRL-,}{inv}{CTRL-E}K({CTRL-Q}KHP{CTRL-;}-{/inv}{CTRL-C}{CTRL-D}{inv}{CTRL-E}K{/inv}{CTRL-X}{inv}{CTRL-P}{/inv}A{inv}%{/inv}j{CTRL-X}i{CTRL-A}{inv}{CTRL-E}L){CTRL-,}{CTRL-E}K-{/inv}{CTRL-D}"
20075 PMMOVQ$(135,202)="{CTRL-D}{inv}p{/inv}{CTRL-U}{inv}"{/inv}{CTRL-,}{inv}%K{/inv}{CTRL-X}i{inv}{CTRL-,}{CTRL-E}K%L{/inv}i{CTRL-,}{inv}{CTRL-E}Lhl{/inv}{CTRL-D}{CTRL-D}{inv}Pm {/inv}{CTRL-,}{inv}{CTRL-X}{CTRL-Q}KH@{/inv}{TAB}{inv}Py-{/inv}{CTRL-C}{CTRL-D}{inv}I{CTRL-,}{CTRL-P}{/inv}{CTRL-A}{CTRL-.}e{inv}K{CTRL-E}K%L{/inv}i{CTRL-,}{inv}{CTRL-E}L {/inv}{CTRL-,}{inv}L{/inv}{CTRL-E}{CTRL-D}{inv}p{/inv}{CTRL-H}{inv}1M{CTRL-Q}KH{/inv}{CTRL-X}{inv}{CTRL-P}s{/inv}{CTRL-.}"
20080 IF PMMODE=1 THEN PAGES=16:DMA=62:GOTO 20110
20090 IF PMMODE=2 THEN PAGES=4:DMA=46:GOTO 20110
20100 RETURN
20110 POKE 54279,PEEK(106)-PAGES:POKE 106,PEEK(106)-PAGES:POKE 207,PMMODE
20120 GRAPHICS GRMODE
20130 PMBASE=PEEK(106)*256:POKE 559,DMA:POKE 53277,3:X=USR(PAGCLR,PMBASE,PAGES)
20135 REM P/M COLORS
20140 POKE 704,0:POKE 705,28
20150 RETURN
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: SAUCER.BAS.
Credits
- Program listing: Saucerian Shootdown — program listing (Antic, January 1989 (Vol. 7, No. 9), Bonus Game) — James (Jim) Catalano
- Picture: Two saucers in the top band of sky, drawn wide and white, which means they can be hit. — James (Jim) Catalano (program); screenshot by the site
- Antic Software Archive — January 1989 - Vol. 7 No. 9 disk: SAUCER.BAS — James (Jim) Catalano, 1989
- Antic magazine scan (OCR text layer): Antic_Vol_7-09_1989-01_8-bit_Shoppers_Guide_text.pdf — Internet Archive
