Nightshade
- Type
- Game
- Category
- Text adventure with a split-screen display
- Author
- Clayton Walnum
- Published in
- ANALOG Computing issue 36 (1985); later on the BELLCOM public domain disks
- Year
- 1985
- Language
- Atari BASIC (with machine-language helper routines)
- Requirements
- Any 8-bit Atari with 32K+ and Atari BASIC; disk or cassette to save games
About the program
Clayton Walnum wrote some of ANALOG's best-loved BASIC adventures, and Nightshade is one of the friendliest. You guide Denny, a boy who starts in his own bedroom with a strange book on the floor. Its title is Nightshade, and its last page is missing. Before long he's out by a pond, in a swamp, a hut, a cave and up a tree, dealing with a troll, a giant, a dwarf and an old hag, collecting scrolls, coloured doors, a jug, a mirror and the ingredients for a glue. The REM in line 0 reads "REVISED 2/16/85 | ANALOG COMPUTING ISSUE #36 [IF STUCK, REFER TO HINTS IN MAGAZINE]".
What you need
Atari BASIC and about 32K. The game saves your position to disk as D:NIGHTSHA.DAT, or to cassette.
Typing it in
- The text is in code. Every message is stored with each character shifted up by one, so
Jo!Efooz(t!cfesppnis "In Denny's bedroom", and you can't read the answers while typing. Type these strings exactly. A single wrong letter becomes a wrong letter on screen, but a missing quote will stop the program. - The DATA in lines 6120–6155 lists the objects (also shifted) with their starting rooms. Lines 5821–5882 are four small machine-language routines, so check them twice.
N1…N20and similar are constants read in line 1 (an ANALOG memory saver).GOSUB N3,GOTO N950and the like are deliberate.- Lines 10020–10095 draw the screen frame with CTRL-Q, CTRL-R, CTRL-A and other line-drawing characters, plus a few inverse labels.
How to play
Type two-word commands such as TAKE BOOK, EXAMINE BED or GIVE JUG, or a direction (N, S, E, W, U, D). Only the first three letters of each word count. The verbs are EXAMINE, LOOK, TAKE/GET, DROP, GIVE, PUT, TALK, DRINK, MOVE, CLIMB, SING, GO, ENTER, SAY, HIT, SMASH, GLUE and HELP, plus SAVE and LOAD. The screen keeps a running summary: the place, the exits, what Denny sees and what Denny has. Doors are referred to by colour. "Which door? Refer to it by color," says the game.
How it works
- Machine code for speed.
CC$searches the three-letter verb listVB$and noun listNN$.D$decodes a message in place by subtracting 1 from each character. An=becomes!, because a shifted!would be a quotation mark, which can't go inside a BASIC string.E$blanks a rectangle of the screen so only the changed boxes are redrawn, andL$finds the space between the two words you typed. - One integer per object.
I(X)holds each object's room number. Negative values mark special states, and −1 means "Denny is carrying it". The save routine just writes the room, a few flags and the 39 values ofI(). - Rooms as subroutines. Each room is a short line (lines 50–280 and on) that sets the description and the exits N, S, E, W, U and D.
GOSUB R*10runs the right one.
Listing
0 REM REVISED 2/16/85 | ANALOG COMPUT- ING ISSUE #36 [IF STUCK, REFER TO HINTS IN MAGAZINE]
1 READ N1,N2,N3,N4,N5,N6,N7,N8,N9,N10,NV,NN,SZ,N950,N11,N12,N13,N14,N15,N16,N17,N18,N19,N20,N6760:GOTO 5000
2 DATA 1,2,3,4,5,6,7,8,9,10,19,39,13,950,11,12,13,14,15,16,17,18,19,20,6760
3 A=USR(ADR(D$),ADR(A$),LEN(A$)):? A$:A$="":RETURN
4 POSITION N6,N10:? "Okay":RETURN
5 POKE N16,112:POKE 53774,112:RETURN
45 N=N0:S=N0:E=N0:W=N0:U=N0:D=N0:GOSUB R*N10:POSITION N11,N5:GOSUB N3:? A$:A$="":RETURN
50 A$="Jo!Efooz(t!cfesppn":N=N6:RETURN
60 A$="Jo!Efooz(t!dmptfu":S=N5:RETURN
70 A$="Jo!Efooz(t!cfe":U=N5:RETURN
80 A$=FA$:N=N11:W=N9:I(N6)=-R:RETURN
90 A$=FA$:N=N10:E=N8:I(N6)=-R:RETURN
100 A$=FA$:E=N11:S=N9:I(N6)=-R:RETURN
110 A$=FA$:S=N8:W=N10:I(N6)=-R:I(36)=-R:RETURN
120 A$="Cz!b!qpoe":N=N15:RETURN
130 A$="Jo!b!tnbmm!sppn":S=N10:RETURN
140 A$="Jo!b!txbnq":E=N15:S=N11:RETURN
150 A$="Po!b!spbe":S=N12:I(36)=-R:RETURN
160 A$="Jo!b!ivu":S=N15:RETURN
170 A$="Cz!uif!npvoubjotjef":RETURN
180 A$="Jo!b!dbwf":W=N17:RETURN
190 A$=SA$:E=N20+N2:W=N18:RETURN
210 A$=SA$:W=N18:RETURN
220 A$="Cz!uif!npvoubjotjef":N=N20+N4:S=N20+N5:W=N19:D=N20+N3:RETURN
230 A$=VA$:N=N20+N6:S=N20+N7:U=N20+N2:RETURN
240 A$=TA$:S=N20+N2:D=N20+N6:RETURN
250 A$=TA$:N=N20+N2:S=N20+N10:D=N20+N7:RETURN
260 A$=VA$:S=N20+N3:U=N20+N4:RETURN
270 A$=VA$:N=N20+N3:U=N20+N5:RETURN
280 A$="Jo!b!usff":D=N11:RETURN
290 A$="Jo!b!cpbu":U=R1:RETURN
300 A$=TA$:N=N20+N5:RETURN
900 RESTORE 5821:FOR X=N1 TO 72:READ A:CC$(X)=CHR$(A):NEXT X
901 FOR X=N1 TO 35:READ A:D$(X)=CHR$(A):NEXT X
902 FOR X=N1 TO 77:READ A:E$(X)=CHR$(A):NEXT X
903 FOR X=N1 TO 35:READ A:L$(X)=CHR$(A):NEXT X
904 FOR X=N1 TO NV:READ A:V(X)=A:NEXT X
905 FOR X=N1 TO NN:READ A$,A:Q=SZ-LEN(A$):I$(X*SZ-SZ+N1,X*SZ-Q)=A$:I(X)=A:NEXT X:GOTO 9000
950 IF LEN(A$) THEN GOSUB N3
951 IF R=N20+N9 THEN U=R1
952 IF R=N14 AND I(N10)<>-N1 THEN 4819
953 IF NOT UL THEN 1100
955 A=USR(ADR(E$),N11,N5,N20+N3):GOSUB 45
960 A=USR(ADR(E$),N11,N7,N20+N3):POSITION N11,N7:IF NOT (N OR S OR E OR W OR U OR D) THEN ? "None":GOTO 970
962 IF N THEN ? "N ";
963 IF S THEN ? "S ";
964 IF E THEN ? "E ";
965 IF W THEN ? "W ";
966 IF U THEN ? "U ";
967 IF D THEN ? "D "
970 A=USR(ADR(E$),N6,N14,N13):A=USR(ADR(E$),N6,N15,N13):A=USR(ADR(E$),N6,N16,N13):A=USR(ADR(E$),N6,N17,N13)
972 ROW=N14:FOR X=N1 TO NN:IF ABS(I(X))<>R THEN NEXT X:GOTO 974
973 A$=I$(X*SZ-SZ+N1,X*SZ):POSITION N6,ROW:GOSUB N3:IT=N1:ROW=ROW+N1:NEXT X
974 IF NOT IT THEN POSITION N6,ROW:? "Nothing"
980 A=USR(ADR(E$),N20+N1,N14,N13):A=USR(ADR(E$),N20+N1,N15,N13)
981 A=USR(ADR(E$),N20+N1,N16,N13):A=USR(ADR(E$),N20+N1,N17,N13)
982 ROW=N14:FOR X=N1 TO NN:IF I(X)<>-N1 THEN NEXT X:GOTO 984
983 A$=I$(X*SZ-SZ+N1,X*SZ):POSITION 21,ROW:GOSUB N3:ROW=ROW+N1:INV=N1:NEXT X
984 IF NOT INV THEN POSITION N20+N1,N14:? "Nothing"
1100 IT=N0:INV=N0:UL=N0
1260 POSITION N5,N11:SOUND N0,N20,N10,N8:FOR X=N1 TO N10:NEXT X:SOUND N0,N0,N0,N0
1265 TRAP 1260:INPUT IN$
1280 A=USR(ADR(E$),N6,N10,N20+N8):A=USR(ADR(E$),N5,N11,N20+N9):POSITION N6,N9:? IN$:POSITION N6,N10
1480 A=USR(ADR(L$),LEN(IN$),ADR(IN$)):IF A=N0 THEN ? "What?":H=N0:GOTO N950
1485 IF H THEN H=N0:A$=IN$(N1,A):GOTO N950
1490 IF A=N1 THEN V$=IN$(N1,N1):GOTO 1820
1500 V$=IN$(N1,A):N$=IN$(A+N2)
1501 IF N$(N1,N3)="DOO" THEN A$="Xijdi!epps@":GOTO N950
1502 IF N$(N1,N3)="SCR" THEN A$="Sfgfs!up!ju!cz!dpmps/":GOTO N950
1510 IF R=N6 AND I(25)=-R AND N$(N1,N3)="TRO" THEN I(N20+N5)=-N19:A$="If!svot!cfijoe!uif!dmpuift=":UL=N1:GOTO N950
1520 IF V$="SAVE" THEN 7060
1540 IF V$="LOAD" THEN 6820
1550 IF V$="HELP" THEN 4921
1580 IF LEN(V$)=N2 THEN V$(N3)=" "
1620 Y=USR(ADR(CC$),ADR(N$),ADR(NN$),LEN(NN$))
1640 Z=USR(ADR(CC$),ADR(V$),ADR(VB$),LEN(VB$))
1641 IF Z=N15 THEN 1760
1642 IF Y=N16 AND I(N13) THEN Y=N13
1720 IF NOT Y THEN ? "No such noun.":GOTO N950
1730 IF NOT Z THEN ? "No such verb.":GOTO N950
1760 Z=V(Z)
1780 ON Z GOTO 2001,2540,2740,4201,4561,4601,4721,4761,4810,4832,4872,4892
1820 IF R<>N19 OR (IN$(N1,N1)<>"E" AND IN$(N1,N1)<>"W") OR I(25)<>-R THEN 1823
1822 A$="Uspmm!xpo(u!mfu!Efooz!mfbwf=":GOTO N950
1823 IF R=N7 AND IN$(N1,N1)="U" THEN A$="Uif!cppl(t!cffo!ejtuvscfe=":GOSUB N3:F=N1
1830 IF V$="N" AND N THEN R=N:GOTO 1960
1840 IF V$="S" AND S THEN R=S:GOTO 1960
1860 IF V$="E" AND E THEN R=E:GOTO 1960
1880 IF V$="W" AND W THEN R=W:GOTO 1960
1900 IF V$="U" AND U THEN R=U:GOTO 1960
1920 IF V$="D" AND D THEN R=D:GOTO 1960
1940 ? "No such direction!":GOTO N950
1960 IF NOT F THEN GOSUB N4
1970 F=N0:UL=N1:GOTO N950
2001 IF Y=N1 AND I(Y)=-N1 AND NOT SL THEN A$="Uif!ujumf!jt!OJHIUTIBEF/":GOTO N950
2003 IF I(Y)=-N1 AND Y=N1 THEN A$="Uif!mbtu!qbhf!jt!njttjoh/":GOTO N950
2005 IF Y=N6 AND R=N10 AND I(N7)=N0 THEN A$="Uifsf(t!b!epps!jo!ju=":UL=N1:I(N7)=-R:GOTO N950
2010 IF R=N11 AND Y=N6 THEN A$="Bo!bsspx!qpjout!vq/":GOTO N950
2015 IF R=23 AND Y=26 AND NOT I(35) THEN A$="Efooz!tfft!tpnfuijoh=":I(35)=R:UL=N1:GOTO N950
2017 IF R=21 AND Y=23 AND I(Y)=-R THEN A$="Ju(t!Efooz(t!sppn=":GOTO N950
2019 IF R=N19 AND Y=25 AND I(N14)=-R AND I(24)=N0 THEN A$="If!ibt!b!cppl!qbhf/":I(24)=R:UL=N1:GOTO N950
2021 IF I(Y)=-N1 AND Y=32 THEN A$="Ju!tbzt;!VTF!CMVF!TDSPMM":GOTO N950
2022 IF I(Y)=-N1 AND Y=N8 THEN A$="Ju!tbzt;!BTZ!SQTFPU":GOTO N950
2023 IF Y=37 AND I(Y)=-N1 THEN A$="Ju(t!b!wfsz!npwjoh!qjfdf/":GOTO N950
2024 IF Y=34 AND I(Y)=-N1 THEN A$="HMVF;!nve-!bmhbf-!dsztubm/":GOTO N950
2025 IF I(Y)=-N1 AND Y=N5 THEN A$="Ju!tbzt;!BTZ!NTFFTB":GOTO N950
2026 IF R=21 AND Y=N12 THEN A$="Ju!tbzt;!BMJ!CBCB!XBT!IFSF":GOTO N950
2027 IF R=N19 AND Y=25 AND I(Y)=-R THEN A$="If(t!gsjhiufojohmz!vhmz=":GOTO N950
2028 IF Y=24 AND I(Y)=-N1 THEN A$="Ju(t!gspn!uif!cppl/":GOTO N950
2030 IF Y=33 AND I(33)=-N1 THEN A$="Ju!tbzt;!GPS!TUSFOHUI":GOTO N950
2500 ? "Denny sees nothing of value.":GOTO N950
2540 IF R=26 AND Y=30 AND I(33)<>-N4 THEN A$="Upp!ifbwz/":GOTO N950
2560 IF I(Y)=-N1 THEN ? "Denny already has it!":GOTO N950
2580 IF I(Y)<N0 THEN ? "Denny can't get that!":GOTO N950
2600 IF ABS(I(Y))<>R THEN ? "It's not here.":GOTO N950
2620 LOCATE 21,N17,A:COLOR A:PLOT 21,N17
2630 IF A<>32 THEN POSITION N6,N10:? "Denny can't carry anymore!":GOTO N950
2660 GOSUB N4:I(Y)=-N1:UL=N1:GOTO N950
2740 IF I(Y)<>-N1 THEN ? "Denny doesn't have it!":?:?:GOTO N950
2745 IF I(N16)<>-N1 OR (Y<>27 AND Y<>28 AND Y<>35) THEN 2750
2747 A$="Jo!uif!kvh///":I(Y)=-N4:UL=N1:GL=GL+N1:IF GL=N3 THEN I(N13)=-N1:I(N16)=N0
2748 GOTO N950
2750 LOCATE N6,N16,A:COLOR A:PLOT N6,N16
2755 POSITION N6,N10:IF A<>32 THEN ? "There's no more room here!":GOTO N950
2761 IF R<>N19 OR I(Y)<>-N1 OR Y<>N15 OR FT THEN 2840
2762 A$="If!tbx!ijntfmg!boe!gbjoufe=":I(Y)=R:I(N14)=-R:I(25)=N0:UL=N1:FT=N1:GOTO N950
2840 GOSUB N4
2842 I(Y)=R:UL=N1:GOTO N950
4201 IF R=N13 AND Y=N9 AND NOT I(N10) THEN A$="Uifz!tipx!Efooz!tpnfuijoh/":I(N10)=R:UL=N1:GOTO N950
4202 IF R=N13 AND Y=N9 THEN A$="Uifz!uijol!if!tipvme!mfbwf/":GOTO N950
4203 IF R=26 AND Y=29 AND NOT I(30) THEN A$="If!pggfst!Efooz!tpnfuijoh/":I(30)=R:UL=N1:GOTO N950
4204 IF R=N17 AND Y=N18 AND NOT I(N19) THEN A$="If!qpjout!up!tpnfuijoh/":I(N19)=-R:UL=N1:GOTO N950
4205 IF (R=26 AND Y=29) OR (R=N17 AND Y=N18) THEN A$="If!ibt!opuijoh!npsf!up!tbz/":GOTO N950
4220 IF R=30 AND Y=39 THEN A$="Tif!qjodife!Efooz=":COL=N10:GOTO 15000
4500 GOTO N6760
4561 IF I(Y)=-N1 AND Y=33 THEN A$="Efooz!gffmt!tuspoh=":I(33)=-N4:UL=N1:GOTO N950
4580 GOTO N6760
4601 IF R=N6 AND Y=N3 AND I(25)=-N19 AND NOT I(N4) THEN A$="Uifsf(t!b!tusbohf!eppsxbz=":I(N4)=-R:UL=N1:GOTO N950
4602 IF R=N6 AND Y=N3 AND I(N4)<>-R THEN A$="Efooz!tfft!uif!dmptfu!xbmm/":GOTO N950
4620 GOTO N6760
4721 IF R=N11 AND Y=N6 THEN R=28:GOSUB N4:UL=N1:GOTO N950
4759 GOTO N6760
4761 IF R=29 AND I(37)=-N1 THEN R1=N12*(R1=N17)+N17*(R1=N12):A$="Zpv!dsptt!uif!qpoe=":I(N17)=-R1:GOTO N950
4800 GOTO N6760
4810 IF R=N5 AND Y=N2 AND NOT SL THEN R=N7:I(25)=-N6:A$="[{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}{CTRL-;}":SL=N1:UL=N1:GOTO N950
4811 IF R=N15 AND Y=N11 THEN GOSUB N4:R=N16:UL=N1:GOTO N950
4812 IF R=N6 AND Y=N4 AND I(N4)=-R THEN R=N8:UL=N1:I(N4)=N0:GOSUB N4:GOTO N950
4813 IF R=N17 AND Y=N19 AND I(Y)=-R THEN R=N18:UL=N1:GOSUB N4:GOTO N950
4814 IF Y=N17 AND I(Y)=-R THEN R=29:UL=N1:GOSUB N4:GOTO N950
4815 IF R=N5 AND Y=N2 THEN A$="Efooz(t!opu!tmffqz=":GOTO N950
4817 IF R=N10 AND Y=N7 AND I(N7)=-R THEN R=N13:GOSUB N4:UL=N1:GOTO N950
4818 IF (R<>N11 AND R<>N15) OR Y<>36 THEN 4824
4819 IF I(N10)<>-N1 THEN A$="Efooz(t!tjoljoh=":COL=N11:GOTO 15000
4821 GOSUB N4:R=N14:UL=N1:GOTO N950
4824 IF R<>N18 THEN 4827
4825 IF Y=21 THEN A$="Efooz(t!gbmmjoh=":COL=N11:GOTO 15000
4826 R=Y-N1:UL=N1:GOSUB N4:GOTO N950
4827 IF R<>21 OR Y<>23 OR I(23)<>-R THEN 4830
4828 IF (I(N1)=-N1 OR I(N1)=N5 OR I(N1)=N6) AND I(N13)=-N1 AND I(24)=-N1 THEN R=N5:UL=N1:GOSUB N4:GOTO N950
4829 A$="Efooz!ibt!gbjmfe!ijt!njttjpo==":COL=N4:GOTO 15000
4830 GOTO N6760
4832 IF I(32)=-N1 AND I(33)=N0 AND I(N8)=-N1 AND N$(N1,N4)="PRES" THEN A$="Uif!cpy!pqfot=":UL=N1:I(33)=R:GOTO N950
4834 IF R=21 AND I(N5)=-N1 AND I(23)=N0 AND N$(N1,N4)="SESA" THEN I(23)=-R:UL=N1:A$="B!epps!bqqfbst=":GOTO N950
4840 A=USR(ADR(L$),LEN(N$),ADR(N$)):N$=N$(N1,A):? CHR$(34);N$;CHR$(34):GOTO N950
4872 IF R<>24 OR Y<>31 OR I(27)<>N0 OR I(30)<>-N1 THEN 4890
4874 A$="Uif!cpvmefst!csfbl!pqfo=":I(27)=R:I(38)=R:I(31)=N0:UL=N1:GOTO N950
4890 GOTO N6760
4892 IF I(N13)<>-N1 OR I(N1)<>-N1 OR I(24)<>-N1 OR (Y<>24 AND Y<>N1) THEN GOTO N6760
4893 IF R<>N5 AND R<>N6 THEN A$="Dbo(u!ep!uibu!ifsf=":GOTO N950
4894 GOTO 16000
4921 A$="Uzqf!jo!uif!fodszqufe!ijou/":H=N1:GOTO N950
5000 GRAPHICS N17:GOSUB N5:POSITION N5,N5:? #N6;"{inv}nightshade{/inv}":POSITION N9,N10:? #N6;"{inv}BY{/inv}"
5010 POSITION N3,N12:? #N6;"{inv}CLAYTON WALNUM{/inv}"
5780 DIM VB$(NV*N3),I$(NN*SZ),A$(160),IN$(26),V$(N10),N$(N10),CC$(77),D$(37),Z$(N1)
5800 DIM NN$(NN*N3),I(NN),E$(79),V(NV),L$(35),FA$(N19),SA$(N15),VA$(N11),TA$(N10)
5821 DATA 104,104,133,204,104,133,203,104,133,206,104,133,205,104,104,133,207,162,0,142,255,6,134,213,232
5822 DATA 160,0,177,203,209,205,208,8,200,192,3,208,245,134,212,96,173,255,6,24,105,3,197,207,240
5823 DATA 16,141,255,6,165,205,24,105,3,133,205,144,217,230,206,176,213,169,0,133,212,96
5841 DATA 216,104,104,133,204,104,133,203,104,104,133,205,160,0,177,203,201,61,240,11,56,233,1,145,203
5842 DATA 200,196,205,208,240,96,169,33,208,244
5861 DATA 104,104,104,141,253,6,104,104,141,254,6,104,104,141,255,6,165,88,133,203,165,89,133,204,174
5862 DATA 254,6,240,14,165,203,24,105,40,133,203,144,2,230,204,202,208,242,165,203,24,109,253,6,133
5863 DATA 203,144,2,230,204,56,165,203,233,1,133,203,176,2,198,204,172,255,6,169,0,145,203,136,208
5864 DATA 251,96
5881 DATA 104,104,104,141,255,6,104,133,204,104,133,203,160,0,177,203,201,32,240,8,200,204,255,6,208
5882 DATA 244,160,0,132,212,169,0,133,213,96
5890 FA$="Jo!b!nbhjdbm!gpsftu":SA$="Jo!b!tupof!sppn":VA$="Jo!b!wbmmfz":TA$="Po!b!usbjm"
5960 VB$="EXALOOTAKGETDROGIVPUTTALDRIMOVCLISINGO ENTSAYHITSMAGLUHEL"
6000 NN$(N1,93)="BOOBEDCLOGLOREDTREWOOBLUFAMSHOHUTSIGGLUFAIMIRJUGBOADWATUNGOLSILBRAGLAPAGTROSTRCRYMUDGIAHAMBOU"
6010 NN$(94,117)="BOXPOTCARALGSWAMUSROCHAG"
6060 I$=" ":I$(NN*SZ)=" ":I$(N2)=I$
6080 GOSUB 32000:GOTO 900
6100 DATA 1,1,2,2,3,3,3,4,5,6,7,8,9,9,10,11,11,12,13
6120 DATA CPPL,5,CFE,-5,DMPUIFT,-6,HMPXJOH!EPPS,0,SFE!TDSPMM,25,USFFT,0,XPPEFO!EPPS,0,CMVF!TDSPMM,28
6125 DATA FMG!GBNJMZ,-13,TXBNQ!TIPFT,0,IVU,-15,TJHO,-21
6130 DATA KVH!XJUI!HMVF,0,GBJOUFE!USPMM,0,NJSSPS,16,KVH,16,CPBU,-12,EXBSG,-17,UVOOFM,0
6140 DATA HPME!EPPS,-18,TJMWFS!EPPS,-18,CSBTT!EPPS,-18,HMBTT!EPPS,0,CPPL!QBHF,0,USPMM,0,TUSFBN,-23
6150 DATA DSZTUBMT,0,NVE,14,HJBOU,-26,IVHF!IBNNFS,0,CPVMEFST,-24,GBODZ!CPY,27,QPUJPO,0,SFDJQF!DBSE,16,BMHBF,0
6155 DATA TXBNQ,0,TIFFU!NVTJD,29,CJUT!PG!SPDL,0,PME!IBH,-30
6760 ? "Denny can't do that!":GOTO 1100
6820 TRAP 7040
6840 POSITION N6,N10:? "LOAD FROM {inv}T{/inv}APE OR {inv}D{/inv}ISK";:INPUT Z$:IF Z$="D" THEN 6900
6860 IF Z$<>"T" THEN ?:GOTO 6820
6880 POSITION N6,N10:? "CUE, PRESS RETURN TWICE.":OPEN #N1,N4,N0,"K:":GET #N1,A:CLOSE #N1
6885 OPEN #N1,N4,N0,"C:":GOTO 6920
6900 OPEN #N1,N4,N0,"D:NIGHTSHA.DAT":A$=""
6920 INPUT #N1,R,R1,GL,FT,SL
6980 FOR X=N1 TO NN:INPUT #N1,A:I(X)=A:NEXT X
7020 CLOSE #N1:UL=N1:?:?:TRAP 1260:GOTO N950
7040 POSITION N6,N10:? "NO GAME DATA SAVED! ":CLOSE #N1:GOTO 1100
7060 POSITION N6,N10:? "SAVE TO {inv}T{/inv}APE OR {inv}D{/inv}ISK";:INPUT Z$:IF Z$="D" THEN Z$=",":GOTO 7120
7080 IF Z$<>"T" THEN 7060
7100 POSITION N6,N10:? "CUE, PRESS RETURN TWICE.":OPEN #N1,N4,N0,"K:":GET #N1,A:CLOSE #N1:Z$=","
7110 OPEN #N1,N8,N0,"C:":GOTO 7140
7120 OPEN #N1,N8,N0,"D:NIGHTSHA.DAT"
7140 PRINT #N1;R;Z$;R1;Z$;GL;Z$;FT;Z$;SL
7200 FOR X=N1 TO NN:PRINT #N1;I(X):NEXT X
7220 CLOSE #N1:?:?:A$="":GOTO 1100
9000 GRAPHICS N0:GOSUB N5:POKE 756,CHSET:POKE 559,N0:DL=PEEK(560)+256*PEEK(561)+N4:POKE DL-N1,71:POKE DL+N2,N6
10001 POKE DL+24,65:POKE DL+25,PEEK(560):POKE DL+26,PEEK(561)
10005 POKE 82,N0:POKE 708,136:POKE 709,N8:POKE 710,N0:POKE 712,N0:POKE 752,N1
10010 POSITION N5,N0:? "NIGHTSHADE"
10020 POSITION N1,N1:? "{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E} |+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+|"
10030 POSITION N1,N3:? "|*{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}*| |+|{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}|+|"
10040 POSITION N1,N5:? "|*||{inv}PLACE{/inv} ||*| |+|{CTRL-A}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-D}|+|"
10050 POSITION N1,N7:? "|*||{inv}EXITS{/inv} ||*| |+|{CTRL-A}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-D}|+|"
10060 POSITION N1,N9:? "|*|| ||*| |+|| ||+|"
10070 POSITION N1,N11:? "|*|| ||*| |+|{CTRL-A}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-W}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-D}|+|"
10080 POSITION N1,N13:? "|*||{inv}DENNY SEES{/inv} |{inv}DENNY HAS{/inv} ||*| |+|| | ||+|"
10090 POSITION N1,N15:? "|*|| | ||*| |+|| | ||+|"
10095 POSITION N1,N17:? "|*|| | ||*|"
10100 POSITION N1,N18:? "|+|{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-X}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}|+| |*{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}*|"
10110 POSITION N1,N20:? "|+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+| {CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}"
10111 POKE 559,34
10113 R=N5:GL=N0:R1=N12:UL=N1:FT=N0:SL=N0
10120 A$="":GOTO N950
15000 GRAPHICS N0:POKE 752,N1:POKE 710,N0:POSITION COL,N7:GOSUB N3:POSITION N8,N9:? "DENNY WAKES UP IN BED."
15010 POSITION N6,N15:? "Do you want to play again?"
15020 OPEN #N1,N4,N0,"K:":GET #N1,A:CLOSE #N1:IF A=ASC("Y") THEN POSITION N17,N20:? "OKAY":RESTORE 6100:GOTO 904
15030 IF A=ASC("N") THEN END
15040 GOTO 15020
16000 GRAPHICS N0:POKE 710,N0:POKE 752,N1:POSITION N9,N11:? "You saved Nightshade!"
16010 GOTO 16010
32000 DIM MV$(N20):RESTORE 32001:FOR X=N1 TO N20:READ A:MV$(X)=CHR$(A):NEXT X
32001 DATA 104,162,4,160,0,177,205,145,203,200,208,249,230,206,230,204,202,208,242,96
32010 CHSET=PEEK(106)-N8:CHBASE=CHSET*256
32015 IF PEEK(CHBASE+80)=255 THEN RETURN
32020 POKE 204,CHSET:POKE 206,224:D=USR(ADR(MV$))
32030 READ A:IF A=-N1 THEN RETURN
32040 FOR BYTE=N0 TO N7:READ B:POKE CHBASE+A*N8+BYTE,B:NEXT BYTE:GOTO 32030
32100 DATA 10,255,170,170,170,170,170,170,255
32110 DATA 11,255,85,85,85,85,85,85,255,-1
Credits
- Program listing: Nightshade — program listing (ANALOG Computing issue 36 (1985); later on the BELLCOM public domain disks) — Clayton Walnum
- Picture: The opening location. The framed display updates after every command. — Clayton Walnum (program); screenshot by the site
- Gury's Atari 8-bit Forever — Nightshade (listing) — Clayton Walnum
- AtariMania — ANALOG Computing publisher list (Nightshade, 1985) — AtariMania, 1985
- ANALOG magazine index, issue 36 (linked from the Gury entry) — lbaeza.neocities.org
