Escape From Barnaby's Isle
- Type
- Game
- Category
- Text adventure and adventure-writing tutorial
- Author
- David Woolley
- Published in
- Antic, April 1989 (Vol. 7, No. 12), "Adventure Works"
- Year
- 1989
- Language
- Atari BASIC
- Requirements
- 32K RAM, Atari BASIC; disk or cassette
About the program
Escape From Barnaby's Isle came with "Adventure Works", David Woolley's article in the April 1989 Antic on how to write a text adventure in BASIC. Woolley, a student from New Zealand making his first appearance in the magazine, kept the game small on purpose. It has fifteen locations, ten nouns and five verbs, so that every part of the engine can be seen and reused. You're stranded on an island and have to get off it. Along the way there's a shack, three trees with letters carved into them, an open grave, a pirate's chest and a troll guarding the way to the boat.
Antic ended the article with a contest: it would publish the best short adventures built on this program structure as disk bonuses. A much longer adventure by David Woolley, The Discovery Incident, appeared in the October/November 1989 issue.
Typing it in
There are only a few special characters. Each location name in the DATA lines is inverse ({inv}…{/inv}, typed with the Atari key on). {CTRL-,} is the heart character (hold CTRL and press comma), which marks "no object here". {BELL} is ESC then CTRL-2, and {DEL LINE} is ESC then SHIFT-DELETE. The odd spacing inside the descriptions is deliberate: it makes words break neatly at the 38-column screen edge.
Keep the line numbers. Line 4 warns do not renumber, because lines 15–35 RESTORE the DATA lines by number (10000 to 10014). The disk version lacks the magazine's TYPO II codes.
How to play
RUN it. After the title, type two-word commands: GO NORTH (or SOUTH, EAST, WEST), GET object, USE object, EXAMIN object and INFO. Note the spelling: the program compares the verb to "EXAMIN", so typing EXAMINE gets "YOU CAN'T DO THAT!". INFO lists the verbs, what you carry and every clue found so far. EXAMIN AREA redisplays the location. The BREAK key is disabled to stop accidents; hold SELECT while you type RUN if you want it to work.
Woolley said you should solve it easily. Read everything, and look at the three carvings together. At the end you get two points for each clue flag and four for each object, as a percentage.
How it works
The article walked through the engine in detail, and it's a good model:
- The map is a grid. Each DATA line holds an X,Y position, a description, an object and a four-letter exit code in N-S-E-W order, with
Ofor "no exit" (soNOOOmeans north only).GO NORTHadds 1 to Y andGO EASTadds 1 to X (lines 115–130). Lines 15–35 then search the 15 DATA lines for the matching coordinates. - The parser (lines 95–112) splits the input at the first space into verb
V$and nounN$. One-word INFO is allowed. Anything else without a noun triggers theTRAPat line 97. - State is two arrays.
O(1)–O(5)record which objects you carry andF(1)–F(8)which clues or events have happened. GET (lines 170–200) checks the noun, your location and whether you already have it, and line 425 hides objects you've taken.
Two bugs, fixed here
The published listing had two classic BASIC slips, both corrected in the listing below. They're worth knowing about before you build your own island:
- Scoring. Lines 500 and 505 put
NEXT QQafterTHEN. When the test fails, Atari BASIC skips the rest of the line,NEXTincluded, so each loop stopped at the first clue or object you didn't get and the score usually came out low. TheNEXTs now have lines of their own (502 and 507). - Precedence. In line 194
ANDbinds tighter thanOR, so any GET the program didn't recognise at the apple tree or the oak tree was answered "IT'S FAR TOO BIG." Brackets round the wholeORfix it.
Changes from the published listing
| Line | As published | Now | Why |
|---|---|---|---|
| 194 | IF N$="TREE" AND (X=4 AND Y=1) OR (X=2 AND Y=2) OR (X=2 AND Y=3) THEN … |
IF N$="TREE" AND ((X=4 AND Y=1) OR (X=2 AND Y=2) OR (X=2 AND Y=3)) THEN … |
Without the outer brackets, any unrecognised GET at two of the tree locations got the tree message. |
| 500, 505 | …THEN SCORE=SCORE+2:NEXT QQ (and +4) |
…THEN SCORE=SCORE+2 (and +4) |
A NEXT after THEN is skipped when the test fails, so the scoring loops ended early. |
| 502, 507 | (none) | NEXT QQ |
The NEXTs moved to lines of their own. |
Listing
1 REM ESCAPE FROM BARNABY'S ISLE
2 REM BY DAVID WOOLLEY
3 REM (c)1988, ANTIC PUBLISHING INC.
4 REM (DO NOT RENUMBER THIS PROGRAM!)
5 POKE 1791,PEEK(53279):GRAPHICS 18:? #6:? #6:? #6;" {inv}ESCAPE FROM{/inv}"
6 ? #6:? #6;" barnabys isle"
7 FOR QQ=1 TO 4000:NEXT QQ
8 GRAPHICS 0:CLR :POKE 710,0:BRK=PEEK(1791)<>5:GOSUB 600
10 DIM A$(100),B$(101),D$(100),O$(50),C$(4),V$(50),N$(50),O(5),F(8):X=3:Y=1
12 FOR QQ=1 TO 5:O(QQ)=0:NEXT QQ:FOR QQ=1 TO 8:F(QQ)=0:NEXT QQ
15 FOR QQ=10000 TO 10014
20 RESTORE QQ
25 READ XX,YY,D$,O$,C$
30 IF XX=X AND YY=Y THEN 37
35 NEXT QQ
37 IF X=3 AND Y=5 THEN 415
40 ? "{CLEAR}":? :? D$
42 GOSUB 425
45 IF LEN(O$)=1 THEN O$="NOTHING"
50 ? :? "YOU CAN SEE:";O$;".":? :? "VISIBLE EXITS:";
51 IF C$(1,1)="N" THEN ? "NORTH ";
52 IF C$(2,2)="S" THEN ? "SOUTH ";
53 IF C$(3,3)="E" THEN ? "EAST ";
54 IF C$(4,4)="W" THEN ? "WEST ";
55 ? :? "{DEL LINE}WHAT NOW";:INPUT A$
60 GOSUB 95
65 IF V$="GO" THEN 115
70 IF V$="GET" THEN 170
75 IF V$="USE" THEN 205
80 IF V$="EXAMIN" THEN 235
85 IF V$="INFO" THEN 320
90 ? "{inv}YOU CAN'T DO THAT!{/inv}{BELL}":GOTO 55
95 FOR QQ=1 TO LEN(A$)
97 TRAP 90
100 IF A$(QQ,QQ)=" " THEN 110
105 NEXT QQ
110 V$=A$(1,QQ-1)
111 IF V$="INFO" THEN RETURN
112 N$=A$(QQ+1,LEN(A$)):RETURN
115 IF N$="NORTH" AND C$(1,1)="N" THEN Y=Y+1:GOTO 15
120 IF N$="SOUTH" AND C$(2,2)="S" THEN Y=Y-1:GOTO 15
125 IF N$="EAST" AND C$(3,3)="E" THEN X=X+1:GOTO 15
130 IF N$="WEST" AND C$(4,4)="W" THEN X=X-1:GOTO 15
140 ? "{BELL}{inv}YOU CAN'T GO THAT WAY!{/inv}":GOTO 55
170 IF N$="RAT" AND X=5 AND Y=2 AND O(1)=0 THEN O(1)=1:GOTO 200
175 IF N$="BOOK" AND X=3 AND Y=3 AND O(2)=0 THEN O(2)=1:GOTO 200
180 IF N$="CUTLASS" AND X=4 AND Y=4 AND O(3)=0 THEN O(3)=1:GOTO 200
185 IF N$="APPLE" AND X=2 AND Y=2 AND O(4)=0 THEN O(4)=1:GOTO 200
190 IF N$="TALISMAN" AND X=2 AND Y=3 AND O(5)=0 THEN O(5)=1:GOTO 200
191 IF N$="CHEST" AND X=4 AND Y=4 THEN ? "IT'S FAR TOO HEAVY.":GOTO 55
192 IF N$="BOAT" AND X=3 AND Y=5 THEN ? "IT'S FAR TOO HEAVY.":GOTO 55
193 IF N$="TROLL" AND X=3 AND Y=4 THEN ? "HE WON'T COOPERATE.":GOTO 55
194 IF N$="TREE" AND ((X=4 AND Y=1) OR (X=2 AND Y=2) OR (X=2 AND Y=3)) THEN ? "IT'S FAR TOO BIG.":GOTO 55
195 ? "{BELL}{inv}I DON'T KNOW THAT OBJECT!{/inv}":GOTO 55
200 ? "YOU HAVE NOW GOT THE ";N$;".":GOTO 55
205 IF N$="RAT" AND O(1)=1 AND F(1)=1 AND X=3 AND Y=4 THEN ? "THE TROLL RUNS OFF, SCREAMING.":F(2)=1:GOTO 55
210 IF N$="BOOK" AND O(2)=1 THEN RESTORE 1000:READ B$:? B$:F(1)=1:GOTO 55
215 IF N$="CUTLASS" AND O(3)=1 AND X=3 AND Y=4 THEN ? "IT HAS NO EFFECT!":GOTO 55
220 IF N$="APPLE" AND O(4)=1 THEN ? "IT TASTES QUITE NICE.":O(4)=0:GOTO 55
225 IF N$="TALISMAN" AND O(5)=1 THEN ? "A STRANGE VOICE SAYS:'ROLLIN THE MAGICIAN WAS RIGHT!'":GOTO 472
227 IF N$="BOAT" AND X=3 AND Y=5 THEN 475
230 ? "{inv}YOU CAN'T DO THAT!{/inv}{BELL}":GOTO 55
235 IF N$="BOAT" AND X=3 AND Y=5 THEN ? "IT LOOKS STURDY ENOUGH TO RETURN YOU HOME.":GOTO 55
237 IF N$="AREA" OR N$="LOCATION" THEN 40
240 IF N$="TROLL" AND X=3 AND Y=4 THEN ? "HE LOOKS REAL MEAN AND UGLY.":GOTO 55
245 IF N$="SHACK" AND X=3 AND Y=3 THEN ? "IT HAS 4 EXITS, AND LOOKS PRETTY RUN DOWN.":GOTO 55
250 IF N$="TREE" AND X=2 AND Y=3 THEN ? "THE OAK TREE LOOKS VERY OLD.CARVED INTO IT IS:'U-T-R'.":GOTO 450
255 IF N$="TREE" AND X=2 AND Y=2 THEN ? "THE APPLE TREE LOOKS VERY YOUNG.CARVED INTO IT IS:'S-H-A'.":GOTO 455
260 IF N$="TREE" AND X=4 AND Y=1 THEN ? "THE PALM TREE LOOKS VERY STRANGE.CARVED INTO IT IS:'E-E-T'.":GOTO 460
265 IF N$="RAT" AND O(1)=1 THEN ? "IT LOOKS QUITE DEAD.":GOTO 55
270 IF N$="RAT" AND X=5 AND Y=2 THEN ? "IT LOOKS QUITE DEAD.":GOTO 55
275 IF N$="BOOK" AND O(2)=1 THEN ? "THE COVER SAYS 'ISLE HISTORY'.MANY PAGES ARE MISSING.":GOTO 470
280 IF N$="BOOK" AND X=3 AND Y=3 THEN ? "THE COVER SAYS 'ISLE HISTORY'.MANY PAGES ARE MISSING.":GOTO 470
285 IF N$="CUTLASS" AND O(3)=1 THEN ? "IT LOOKS REAL SHARP.":GOTO 55
290 IF N$="CUTLASS" AND X=4 AND Y=4 THEN ? "IT LOOKS REAL SHARP.":GOTO 55
295 IF N$="APPLE" AND O(4)=1 THEN ? "IT LOOKS GOOD TO EAT.":GOTO 55
300 IF N$="APPLE" AND X=2 AND Y=2 THEN ? "IT LOOKS GOOD TO EAT.":GOTO 55
305 IF N$="TALISMAN" AND O(5)=1 THEN ? "ITS USE IS A TOTAL MYSTERY TO YOU.":GOTO 55
310 IF N$="TALISMAN" AND X=2 AND Y=3 THEN ? "ITS USE IS A TOTAL MYSTERY TO YOU.":GOTO 55
315 IF N$="CHEST" AND X=4 AND Y=4 THEN ? "INSCRIBED INSIDE IS 'G- TO T-E N-RT- BEA-H'.":GOTO 465
317 ? "{inv}I DON'T KNOW THAT OBJECT!{/inv}{BELL}":GOTO 55
320 ? :? "{inv}COMPLETE LIST OF VERBS{/inv}"
325 ? :? "GO GET USE EXAMIN INFO"
330 ? :? "{inv}LIST OF OBJECTS FOUND{/inv}":?
335 IF O(1)=1 THEN ? "DEAD RAT,";
340 IF O(2)=1 THEN ? "BOOK,";
345 IF O(3)=1 THEN ? "CUTLASS,";
350 IF O(4)=1 THEN ? "APPLE,";
355 IF O(5)=1 THEN ? "MAGIC TALISMAN";
365 ?
370 ? :? "{inv}LIST OF CLUES FOUND{/inv}":?
375 IF F(1)=1 THEN RESTORE 1000:READ B$:? "THE BOOK SAYS:";:? B$
380 IF F(2)=1 THEN ? "YOU HAVE SCARED OFF THE TROLL."
385 IF F(3)=1 THEN ? "CARVED ON THE OAK TREE IS: U-T-R"
390 IF F(4)=1 THEN ? "CARVED ON THE APPLE TREE IS:S-H-A"
395 IF F(5)=1 THEN ? "CARVED ON THE PALM TREE IS: E-E-T"
400 IF F(6)=1 THEN ? "INSCRIBED INSIDE THE CHEST IS 'G- TO T-E N-RT- BEA-H'."
405 IF F(7)=1 THEN ? "THE BOOK IS CALLED 'ISLE HISTORY'."
407 IF F(8)=1 THEN ? "ROLLIN THE MAGICIAN WAS RIGHT."
410 GOTO 55
415 IF F(2)=1 THEN 40
420 ? "A TROLL PUSHES YOU BACK!":X=3:Y=4:FOR QQ=1 TO 1000:NEXT QQ:GOTO 15
425 IF X=5 AND Y=2 AND O(1)=1 THEN O$="NOTHING":RETURN
430 IF X=3 AND Y=3 AND O(2)=1 THEN O$="NOTHING":RETURN
435 IF X=4 AND Y=4 AND O(3)=1 THEN O$="NOTHING":RETURN
440 IF X=2 AND Y=3 AND O(5)=1 THEN O$="NOTHING":RETURN
445 RETURN
450 F(3)=1:GOTO 55
455 F(4)=1:GOTO 55
460 F(5)=1:GOTO 55
465 F(6)=1:GOTO 55
470 F(7)=1:GOTO 55
472 F(8)=1:GOTO 55
475 ? :? "{inv}***CONGRATULATIONS!***{/inv}"
480 ? :? "YOU HAVE ESCAPED FROM BARNABY'S ISLE."
495 ? "WITH A POINTS SCORE OF:";
500 FOR QQ=1 TO 8:IF F(QQ)=1 THEN SCORE=SCORE+2
502 NEXT QQ
505 FOR QQ=1 TO 5:IF O(QQ)=1 THEN SCORE=SCORE+4
507 NEXT QQ
510 TIMES=100/(16+20):PERCENT=SCORE*TIMES:PERCENT=INT(PERCENT)
515 ? SCORE;" AND A PERCENTAGE OF ";PERCENT;"%"
520 END
600 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
610 RETURN
1000 DATA "SO ROLLIN THE MAGICIAN HID HIS TREASURE IN THE OLD OAK TREE & WENT TO PROVE TROLLS FEAR OF RATS."
10000 DATA 3,1,{inv}SOUTH BEACH.{/inv}A BEATEN TRACK LEADS NORTH.TALL CLIFFS LOOM UP ON EITHER SIDE.,{CTRL-,},NOOO
10001 DATA 4,1,{inv}PALM TREE.{/inv}A LITTLE PALM TREE SITS ALONE OVERLOOKING THE CLIFF.,{CTRL-,},NOOO
10002 DATA 1,2,{inv}SUNKING'S COVE.{/inv}VICIOUS ROCKS SURROUND THIS ROUGH COVE.,{CTRL-,},OOEO
10003 DATA 2,2,{inv}APPLE TREE.{/inv}A QUIET APPLE TREE RESTS IN A CLEARING IN THE SCRUB.,APPLE,OOEW
10004 DATA 3,2,{inv}CROSSROADS.{/inv}HERE THE PATH SPLITS INTO THREE OTHER DIRECTIONS.,{CTRL-,},NSEW
10005 DATA 4,2,{inv}ROLLIN'S HILL.{/inv}A SMALL PEACEFUL HILL RISES UP OUT OF THE GROUND.,{CTRL-,},NSEW
10006 DATA 5,2,{inv}OPEN GRAVE.{/inv}A GRAVE HAS BEEN DUG HERE BUT THE OWNER IS NOWHERE TO BE SEEN.,DEAD RAT,OOOW
10007 DATA 2,3,{inv}OLD OAK TREE.{/inv}AN ANCIENT OAK TREE RISES OUT OF THE GROUND AHEAD.,MAGIC TALISMAN,OOEO
10008 DATA 3,3,{inv}SHACK.{/inv}A FORLORN SHACK STANDS IN A CLEARING BEFORE YOU.,BOOK,NSEW
10009 DATA 4,3,{inv}ARNIE'S RIVER.{/inv}NEXT TO YOU LIES A LITTLE RIVER.,{CTRL-,},NSEW
10010 DATA 5,3,{inv}WATERFALL.{/inv}A WATERFALL FALLS DOWN FROM HERE TO THE SEA.,{CTRL-,},OOOW
10011 DATA 2,4,{inv}WHEAT FIELD.{/inv}WHEAT STALKS DANCE MERRILY IN THE SUNSHINE.,{CTRL-,},OOEO
10012 DATA 3,4,{inv}DEAD MAN'S SWAMP.{/inv}A TERRIBLE SWAMP LIES HERE.TO THE NORTH YOU CAN SEE SOMETHING ODD.,{CTRL-,},NSEW
10013 DATA 4,4,{inv}PIRATE'S TREASURE.{/inv}AN OPEN CHEST LIES ON THE GROUND.,CUTLASS,OSOW
10014 DATA 3,5,{inv}NORTH BEACH.{/inv}YOU ARE FINALLY HERE!A BOAT LIES NEAR THE SHORE.,{CTRL-,},OSOO
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: BARNABY.BAS.
Credits
- Program listing: Escape From Barnaby's Isle — program listing (Antic, April 1989 (Vol. 7, No. 12), "Adventure Works") — David Woolley
- Picture: One GO NORTH from the start: the Crossroads. — David Woolley (program); screenshot by the site
- ANTIC Vol. 7 No. 12 (April 1989) — Adventure Works: Easy Way to Program Text Adventures, by David Woolley — David Woolley, 1989
- Antic Software Archive — April 1989 - Vol. 7 No. 12 disk: BARNABY.BAS — AtariMagazines.com (Kevin Savetz), 1989
