Dragonlord

Type
Game
Category
Joystick-driven dungeon role-playing game
Author
Clayton Walnum
Published in
ANALOG Computing (1985); later on the BELLCOM public domain disks
Year
1985
Language
Atari BASIC
Requirements
Any 8-bit Atari with 32K+ and Atari BASIC; joystick in port 1
Green screen with the prompt WHAT WILL BE THY NAME FOR THIS QUEST? and a dashed entry line

About the program

Dragonlord is a small but complete role-playing game in Atari BASIC by Clayton Walnum, who wrote many of ANALOG Computing's adventures. It's played almost entirely with the joystick. A dungeon of 77 rooms (11 across and 7 down) hides gold, spells, serums, orcs and thieves, and somewhere in it is the dragon. Kill it and "THE TOWN REJOICES!". Your character has hit points, strength, a weapon, a stock of pies, spells and serums, and a purse. The game was published by ANALOG Computing and later included on the BELLCOM public domain disks.

What you need

Any Atari with Atari BASIC and about 32K, and a joystick. Allow a little time after RUN: "ONE MOMENT PLEASE" stays up while the screens and tables are built.

Typing it in

  • Like other ANALOG listings, numbers are mostly constant variables (N0…N20, N77 and so on) set up early in the program. Type them exactly. Labels such as GOSUB ROOMPOS, GOSUB CHOOSE and GOTO DEAD are variables holding line numbers, which Atari BASIC allows.
  • The status panels and the shop are drawn from PRINT strings made of |, ), #, ', %, $, (, *, & and ,. After the character set is changed these become box corners and edges, so copy every character and every space.
  • Lower-case words in quotes are lower case in the original. The "CL$" and "MV$" DATA at lines 3360–3390 is read into strings, so check the counts.

How to play

Type your name. Then the joystick does everything: move the "magical stick" cursor to a command and press the button. The commands are MOVE (pick N, S, E or W where there's an exit), MAP (a map of your progress so far), CAST (spend a spell to teleport: choose the room number with the stick) and STORE (going to the shop costs some strength). Each step costs strength, and more if you've run out of pies. You eat a pie every third move. Rooms may hold gold, a spell, a serum (drink it to restore strength), an orc to fight, or a thief who steals half your gold. In combat both sides lose hit points and strength each round, and a better weapon makes the difference.

Ye olde shoppe sells spells, gypsy brew, pies, lodging ("A GOOD NIGHT'S SLEEP!" restores strength), a doctor ("THE DOCTOR HAS HEALED THEE") and weapons: daggers, a sword and a long sword. If your purse is too meagre, the shopkeeper says so. When you die, the game shows your score and offers another go.

How it works

The dungeon is a 7×11 grid numbered 1–77, so moving north or south is ±11 and east or west ±1 (lines 900–930). The dragon's room DR is chosen at random when the dungeon is stocked (lines 110–130). The map is a separate screen in memory. Line 950 points the OS screen pointer (88/89) at it, prints the current room's square, and points it back, so the map builds up without being redrawn. CHOOSE is a general joystick menu routine used for every choice in the game.

Changes from the published listing

One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds a command called DIR, so it rejected the published lines that use that word as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.

Published Now Lines
DIR DRN 690, 980, 2350
DIR$ DRN$ 1920, 2300, 2390

Listing

1 REM {inv}   DRAGONLORD    {/inv}
2 REM by Clayton Walnum
3 REM 
10 N1=1:N2=2:N3=3:N4=4:N5=5:N6=6:N7=7:N8=8:N9=9:N10=10
20 N11=11:N12=12:N13=13:N14=14:N15=15:N16=16:N17=17:N18=18:N19=19:N20=20:N21=21:N77=77:GOTO 2260
30 RESTORE:FOR X=N0 TO 27:READ A:POKE ADR(R$)+N1+X,A:NEXT X
40 FOR X=CHBASE+264 TO CHBASE+479:READ A:POKE X,A:NEXT X
50 FOR X=CHBASE+128 TO CHBASE+207:READ A:POKE X,A:NEXT X
60 FOR X=CHBASE+24 TO CHBASE+103:READ A:POKE X,A:NEXT X
70 FOR X=CHBASE+216 TO CHBASE+223:READ A:POKE X,A:NEXT X
80 FOR X=N1 TO N77:READ A:RM(X)=A:I(X)=N0:NEXT X:I(39)=N7
90 READ A:IF A=-N1 THEN 3030
100 X=INT(RND(N0)*N77)+N1:IF I(X) THEN 100
110 IF A=N1 THEN DR=X
120 I(X)=A:GOTO 90
130 ROOM=INT(RND(N0)*N77)+N1:IF NOT B THEN X=INT(RND(N0)*N8)+N1:IF X=N1 THEN ROOM=DR
140 FOR X=N1 TO N5:FOR Y=N0 TO N16:SOUND N0,Y*N2,Y,N4:POKE 708,Y*N10:FOR A=N1 TO N5:NEXT A:NEXT Y:NEXT X
150 POKE 559,N0:SOUND N0,N0,N0,N0:GOTO 950
160 SOUND N0,N10,N12,N8:FOR X=N1 TO N20:NEXT X:SOUND N0,N0,N0,N0:RETURN 
170 SOUND N0,100,N12,N8:FOR X=N1 TO 100:NEXT X:SOUND N0,N0,N0,N0:RETURN 
180 RT=RM(R):COL=(R-INT(R/N11)*N11)*N3:IF INT(R/N11)=R/N11 THEN COL=33
190 ROW=INT(R/N11)*N3:IF INT(R/N11)=R/N11 THEN ROW=ROW-N3
200 RETURN 
210 R=ROOM:GOSUB ROOMPOS:C=COL:RW=ROW:R=DR:GOSUB ROOMPOS:POSITION 34,N14:Q=N0:D=N0
220 Q=N1*(COL<C AND ROW<RW)+N2*(COL>C AND ROW<RW)+N3*(COL>C AND ROW>RW)+N4*(COL<C AND ROW>RW)
230 D=N1*(COL=C AND ROW<RW)+N2*(COL>C AND ROW=RW)+N3*(COL=C AND ROW>RW)+N4*(COL<C AND ROW=RW)
240 IF Q=N1 THEN D=N1:IF RND(N0)<0.5 THEN D=N4
250 IF Q=N2 THEN D=N2:IF RND(N0)<0.5 THEN D=N1
260 IF Q=N3 THEN D=N3:IF RND(N0)<0.5 THEN D=N2
270 IF Q=N4 THEN D=N3:IF RND(N0)<0.5 THEN D=N4
280 RETURN 
290 ROW=R:POSITION COL,ROW:? ">"
300 IF STRIG(N0)=N0 THEN 300
310 IF STRIG(N0)=N0 THEN GOSUB SND1:CH=ROW-R+N1:RETURN 
320 ST=STICK(N0):IF ST<>N14 AND ST<>N13 THEN 310
330 RO=ROW:ROW=ROW+(ST=N14)*-N1+(ST=N13)*N1:IF ROW<R THEN ROW=R+N3
340 IF ROW>R+N3 THEN ROW=R
350 POSITION COL,RO:? " ":POSITION COL,ROW:? ">":FOR X=N1 TO 25:NEXT X:GOTO 310
360 FOR X=N1 TO 300:NEXT X:RETURN 
370 N=N0:S=N0:E=N0:W=N0:RT=RM(ROOM)
380 ON RT GOTO 390,400,410,420,430,440,450,460,470,480,490,500,510,520,530
390 N=N1:E=N1:E$="  ,,":RETURN 
400 N=N1:S=N1:E$=" , ,":RETURN 
410 N=N1:W=N1:E$=" ,, ":RETURN 
420 S=N1:E=N1:E$=",  ,":RETURN 
430 S=N1:W=N1:E$=",,  ":RETURN 
440 E=N1:W=N1:E$=", , ":RETURN 
450 N=N1:E=N1:S=N1:E$="   ,":RETURN 
460 N=N1:E=N1:W=N1:E$="  , ":RETURN 
470 S=N1:E=N1:W=N1:E$=",   ":RETURN 
480 N=N1:S=N1:E=N1:W=N1:E$="    ":RETURN 
490 N=N1:E$=" ,,,":RETURN 
500 S=N1:E$=",, ,":RETURN 
510 E=N1:E$=", ,,":RETURN 
520 W=N1:E$=",,, ":RETURN 
530 N=N1:S=N1:W=N1:E$=" ,  ":RETURN 
540 REM *** STATUS SCREEN ***
550 IF STR>N20 OR SM<N1 THEN 580
560 GRAPHICS N17:POKE 756,CHSET:POSITION N1,N6:? #N6;"{inv}you drink a serum{/inv}"
570 STR=STR+INT(RND(N0)*N15)+N15:SM=SM-N1:GOSUB DELAY2
580 GRAPHICS N0:POKE 559,N0:POKE N77,N0:POKE 756,CHSET:POKE 752,N1:POKE 709,N8:POKE 710,N0
590 DL=PEEK(560)+256*PEEK(561)+N4
600 POKE DL-N1,70:POKE DL+N2,N6:POKE DL+N21,N6:POKE DL+22,N6:POKE DL+23,N6:POKE DL+24,N6
610 POKE DL,N0:POKE DL+N1,STTUS:POKE 88,N0:POKE 89,STTUS
620 POSITION N9,N3:? N$:POSITION N9,N5:? HP;" ":POSITION N9,N7:? STR;" ":POSITION N9,N9:? PIE;" "
630 POSITION 30,N3:? W$(WN*N7-N6,WN*N7);:IF W=N2 THEN ? " "
640 POSITION 30,N5:? SPL;" ":POSITION 30,N7:? SM;" "
650 POSITION 30,N9:? G;" ":POSITION N1,N20:? "                  "
660 POSITION N10,N14:? ROOM;" ":POSITION N10,N15:? "        {LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}";
670 POSITION N21,N13:? "{inv} COMMAND {/inv}":POSITION 22,N14:? " MOVE":POSITION 22,N15:? " MAP  "
680 POSITION 23,N16:? "CAST":POSITION 22,N17:? " STORE"
690 GOSUB DRN:POSITION N10,N15
700 IF N THEN ? "N ";
710 IF S THEN ? "S ";
720 IF E THEN ? "E ";
730 IF W THEN ? "W ";
740 IF B THEN POSITION 33,N14:? "[[[["
750 POSITION N21,N19:? "THE MAGICAL STICK ":POSITION N21,N20:? "PICKS THY COMMAND":POKE 559,34
760 IF PIE=N0 THEN FOR X=N1 TO N4:FOR Y=240 TO N0 STEP -N20:SOUND N0,Y,N10,N4:NEXT Y:NEXT X:SOUND N0,N0,N0,N0
770 COL=22:R=N14:GOSUB CHOOSE:ON CH GOTO 790,1450,1540,1660
780 REM *** MOVE ***
790 POSITION N21,N13:? "    N    {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}      {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}W   E{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}     {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}   S  "
800 POSITION 22,ROW:? " ":POKE 766,N1:POSITION 25,N15:? "{UP}"
810 POSITION N21,N19:? "                 ":POSITION N21,N20:? "                   "
820 POSITION N1,N20:? "PICK THY DIRECTION":TURN=TURN+N1:CH=N1
830 IF STRIG(N0)=N0 THEN 830
840 IF STRIG(N0)=N0 THEN GOSUB SND1:POKE 766,N0:GOTO 900
850 ST=STICK(N0):POSITION 25,N15:IF ST=N14 THEN ? "{UP}":CH=N1
860 IF ST=N13 THEN ? "{DOWN}":CH=N2
870 IF ST=N7 THEN ? "{RIGHT}":CH=N3
880 IF ST=N11 THEN ? "{LEFT}":CH=N4
890 GOTO 840
900 IF CH=N1 AND N THEN ROOM=ROOM-N11:GOTO 950
910 IF CH=N2 AND S THEN ROOM=ROOM+N11:GOTO 950
920 IF CH=N3 AND E THEN ROOM=ROOM+N1:GOTO 950
930 IF CH=N4 AND W THEN ROOM=ROOM-N1:GOTO 950
940 SOUND N0,150,N12,N8:FOR X=N1 TO N20:NEXT X:SOUND N0,N0,N0,N0:POKE 766,N1:GOTO 840
950 POKE 88,N0:POKE 89,MAP:R=ROOM:GOSUB ROOMPOS:POSITION COL,ROW:? RM$(RT*N17-N16,RT*N17)
960 STR=STR-N1-N1*(PIE=N0):IF STR<N1 THEN GOTO DEAD
970 CNT=CNT+N1:IF CNT=N3 THEN CNT=N0:PIE=PIE-N1:IF PIE<N0 THEN PIE=N0
980 GOSUB DRN
990 GRAPHICS N0:POKE 559,N0:POKE 756,CHSET:POKE 710,N0:POKE 709,N12:POKE 752,N1:DL=PEEK(560)+256*PEEK(561)+N4
1000 POKE DL-N1,71:POKE DL+N2,N7:POKE DL+N3,N7:POKE DL+N4,N7:POKE DL+N5,N7:POKE DL+N6,N7:POKE DL+N7,N7
1010 POKE DL+N8,N6:POKE DL+N9,N6:POKE DL+N10,N6:POKE DL+N18,65:POKE DL+N19,PEEK(560):POKE DL+N20,PEEK(561)
1020 POKE 82,N0:POSITION N1,N0:? ",,,,,,,,,,,,,,,,,   ,               ,"
1030 ? " ,               ,   ,               ,   ,               ,   ,               ,"
1040 ? " ,,,,,,,,,,,,,,,,,"
1050 POSITION N9,N0:? E$(N1,N1):POSITION 37,N1:? E$(N2,N2):POSITION N9,N3:? E$(N3,N3):POSITION N21,N1:? E$(N4,N4)
1060 IF I(ROOM)=N7 THEN X=INT(RND(N0)*N3)+N1:IF X=N1 THEN I(ROOM)=N2
1070 IF I(ROOM)>N2 THEN POKE 559,34:GOTO 1350
1080 IF I(ROOM)=N2 THEN POKE 710,N8:POKE 709,N0:POKE 559,34:POSITION 28,N1:? "{inv}orc{/inv}":FOR X=N1 TO 50:NEXT X:GOTO 1130
1090 POKE 559,34:POSITION 26,N1:? "{inv}DRAGON!{/inv}":FOR Y=N1 TO N8:FOR Z=N1 TO 30:POKE 710,Z*N8:POKE 712,Z*N8-N6
1100 SOUND N0,Z,N6,N8:NEXT Z:NEXT Y:SOUND N0,N0,N0,N0
1110 GRAPHICS N18:POKE 756,CHSET:IF B THEN POSITION N1,N1:? #N6;"{inv}THE TOWN REJOICES!{/inv}":I(DR)=N0:SC=SC+100:GOTO 2180
1120 GOTO DEAD
1130 CHP=N5:CSTR=N10:POSITION N1,N4:? "{inv}thee:{/inv}     {inv}orc:{/inv}"
1140 POSITION N1,N5:? "{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}  |                                    |"
1150 ? " |                                    |  |    THY HP:          ORC HP:        |"
1160 ? " |                                    |  |       STR:             STR:        |"
1170 ? " {CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}";
1180 PL=WN-N1:B$="{inv}PLUS {/inv} ":C$=STR$(PL):C$=CHR$(ASC(C$)+128):B$(N6,N6)=C$
1190 POSITION N8,N6:? "{inv}THY WEAPON IS {/inv}";B$:POSITION 28,N1:? "   "
1200 POSITION N14,N8:? HP;" ":POSITION 31,N8:? CHP;" ":POSITION N14,N10:? STR;" ":POSITION 31,N10:? CSTR;" "
1210 D1=INT(RND(N0)*N9)+N1:POSITION N5,N1:? D$(D1*N9-N8,D1*N9-N6):POSITION 25,N1:? D$(D1*N9-N5,D1*N9-N3)
1220 POSITION N5,N2:? D$(D1*N9-N2,D1*N9):SOUND N0,150,N2,N8:SOUND N0,N0,N0,N0
1230 IF STRIG(N0) THEN 1210
1240 D1=D1-INT(N4-STR/N20)+PL:POSITION N6,N4:? D1;" ":STR=STR-N1-N1*(PIE=N0):IF STR<N1 THEN GOTO DEAD
1250 FOR X=N1 TO N20:D2=INT(RND(N0)*N9)+N1:POSITION N11,N1:? D$(D2*N9-N8,D2*N9-N6)
1260 POSITION 31,N1:? D$(D2*N9-N5,D2*N9-N3):POSITION N11,N2:? D$(D2*N9-N2,D2*N9):SOUND N0,150,N2,N8
1270 SOUND N0,N0,N0,N0:NEXT X:POSITION N15,N4:? D2;" ":CSTR=CSTR-N1:IF CSTR<N1 THEN 1330
1280 H=INT(RND(N0)*N5)+N1:IF D1>=D2 THEN SC=SC+N1:GOTO 1310
1290 FOR X=N0 TO 255 STEP N5:SOUND N0,X,N10,N4:NEXT X:SOUND N0,N0,N0,N0:HP=HP-H:IF HP<N1 THEN GOTO DEAD
1300 GOTO 1200
1310 FOR X=250 TO N0 STEP -N10:SOUND N0,X,N10,N4:NEXT X:SOUND N0,N0,N0,N0:CHP=CHP-H:IF CHP<N1 THEN 1330
1320 GOTO 1200
1330 X=INT(RND(N0)*N5)+N4:GRAPHICS N0:POKE 756,CHSET:POKE 710,N0:POKE 752,N1:POSITION N14,N8:? "HE IS DEAD!"
1340 POSITION N11,N12:? "YOU FOUND ";X;" GOLD!":G=G+X:I(ROOM)=N7:SC=SC+N11:GOSUB DELAY2:GOTO 550
1350 IF I(ROOM)=N3 THEN POSITION 25,N1:? "{inv}teleport{/inv}":SC=SC+N1:GOTO TEL
1360 COL=N10:IF I(ROOM)=N7 THEN POSITION 27,N1:? "{inv}empty{/inv}":GOTO 1420
1370 POSITION N5,N1:? "{inv}you found{/inv}":SC=SC+N1
1380 IF I(ROOM)=N4 THEN POSITION N6,N2:? "{inv}a spell{/inv}":SPL=SPL+N1
1390 IF I(ROOM)=N5 THEN X=INT(RND(N0)*N5)+N4:POSITION N3,N2:? X;" {inv}gold pieces{/inv}":G=G+X
1400 IF I(ROOM)=N6 THEN POSITION N6,N2:? "{inv}a serum{/inv}":SM=SM+N1
1410 IF I(ROOM)=N8 THEN POSITION N5,N2:? "{inv}the theif{/inv}":G=INT(G/N2):FOR Z=N1 TO N8:GOSUB SND2:NEXT Z
1420 SC=SC+N1:POSITION COL,N7:? #N6;"PRESS THY TRIGGER"
1430 IF STRIG(N0) THEN 1430
1440 GOSUB SND1:I(ROOM)=N7:GOTO 550
1450 GRAPHICS N0:POKE 756,CHSET:POKE 752,N1:POKE 710,N0:POKE 711,54:POKE 712,112
1460 DL=PEEK(560)+256*PEEK(561)+N4:POKE DL+22,N6:POKE DL+23,N6:POKE DL+24,N6:POKE DL,N0:POKE DL+N1,MAP
1470 POKE 88,N0:POKE 89,MAP:POKE 559,34
1480 R=ROOM:GOSUB ROOMPOS
1490 POSITION COL+N1,ROW+N1:? "{CTRL-T}":FOR X=N1 TO N10:NEXT X
1500 POSITION COL+N1,ROW+N1:? " ":FOR X=N1 TO N10:NEXT X
1510 IF STRIG(N0)=N0 THEN GOSUB SND1:GOTO 550
1520 GOTO 1490
1530 REM *** CAST SPELLS ***
1540 IF SPL>N0 THEN SPL=SPL-N1:ROOM=N1:GOTO 1560
1550 GOSUB SND2:POSITION COL,ROW:? " ":GOTO 770
1560 POSITION N21,N13:? "         {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}    {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}>  {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}     {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}     "
1570 POSITION N21,N19:? "                 ":POSITION N21,N20:? "                 ":POSITION N5,N20:? "WHAT ROOM?"
1580 IF STRIG(N0)=N0 THEN 1580
1590 IF STRIG(N0)=N0 THEN 1630
1600 ST=STICK(N0):ROOM=ROOM+(ST=N14)*N1+(ST=N13)*-N1:IF ROOM>N77 THEN ROOM=N1
1610 IF ROOM<N1 THEN ROOM=N77
1620 POSITION 25,N15:? ROOM;" ":FOR X=N1 TO N10:NEXT X:GOTO 1590
1630 SOUND N0,248,N10,N4:SOUND N1,255,N14,N4:SOUND N2,246,N14,N4:SOUND N3,243,N10,N4
1640 POKE ADR(R$)+24,26:D=USR(ADR(R$)+N1,N2):FOR X=N0 TO N3:SOUND X,N0,N0,N0:NEXT X:GOTO 950
1650 REM *** STORE ***
1660 STR=STR-N2-N2*(PIE=N0):IF STR<N1 THEN GOTO DEAD
1670 S=INT(RND(N0)*N10)+N1:IF STR>90 THEN S=N1
1680 IF S<N6 THEN SL=N0:S$(36,75)="------- WELCOME ALL ADVENTURERS! -------":GOTO 1730
1690 S$(36,75)="---- SPECIAL TODAY:    PERCENT OFF! ----"
1700 IF S<N9 THEN S$(56,57)="10":SL=0.1
1710 IF S=N9 THEN S$(56,57)="20":SL=0.2
1720 IF S=N10 THEN S$(56,57)="30":SL=0.3
1730 GRAPHICS N0:POKE 559,N0:POKE 710,N0:POKE 756,CHSET:DL=PEEK(560)+256*PEEK(561)+N4
1740 POKE DL-N1,70:FOR X=N2 TO N6:POKE DL+X,N6:NEXT X:FOR X=N9 TO N20:POKE DL+X,N6:NEXT X:COL=N6:R=N7
1750 POKE 752,N1:POKE 82,N0:TURN=TURN+N1:POKE DL,N0:POKE DL+N1,STORE:POKE 88,N0:POKE 89,STORE:POKE 559,34
1760 FOR X=N1 TO 80:B$=S$(X,37+X):POSITION N1,N3:? B$;:FOR Y=N1 TO N8:NEXT Y
1770 IF STRIG(N0)=N0 THEN POP:GOSUB SND1:GOTO 1790
1780 NEXT X:GOTO 1760
1790 COL=N6:R=N6:ROW=N6:POSITION N1,N3:? "                                      "
1800 POSITION N7,N6:? "        {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}        {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}        {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}        "
1810 POSITION N10,N3:? "YOU HAVE ";G;" GOLD.":GOSUB DELAY2
1820 POSITION N10,N3:? "CHOOSE THE DEPARTMENT"
1830 POSITION COL,ROW:? " ":POSITION N7,N6:? "magic {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}health {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT} weapons{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}exit   "
1840 GOSUB CHOOSE:POSITION COL,ROW:? " ":POSITION N9,N3:IF ROW<N9 THEN ? "  MAKE THY PURCHASE   "
1850 ON CH GOTO 1860,1930,2020,2110
1860 POSITION N7,N6:? "spells{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}gypsy {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}brew   "
1870 GOSUB CHOOSE:ON CH GOTO 1880,1900,1890,1820
1880 COST=N10:GOSUB 2070:SPL=SPL+N1:GOTO 2090
1890 COST=60:GOSUB 2070:B=N1:GOTO 2090
1900 COST=N20:GOSUB 2070
1910 GOSUB CLUE:POSITION N7,N6:? "      {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}     {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}     {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}    "
1920 POSITION 27,N7:? DRN$(D*N5-N4,D*N5):GOSUB DELAY2:POSITION 27,N7:? "     ":GOTO 2090
1930 POSITION N7,N6:? "pie  {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}lodging{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}doctor "
1940 GOSUB CHOOSE:ON CH GOTO 1950,1990,1960,1820
1950 COST=N10:GOSUB 2070:PIE=PIE+N5:GOTO 2090
1960 COST=N15:GOSUB 2070
1970 X=INT(RND(N0)*N10)+N15:HP=HP+X:IF HP>50 THEN HP=50
1980 POSITION N1,N3:? "THE DOCTOR HAS HEALED THEE -- ";X;" HP --":GOSUB DELAY2:GOTO 2090
1990 COST=N15:GOSUB 2070
2000 X=INT(RND(N0)*N15)+N20:STR=STR+X:IF STR>100 THEN STR=100
2010 POSITION N1,N3:? "   A GOOD NIGHTS SLEEP! -- ";X;" STR --  ":GOSUB DELAY2:GOTO 2090
2020 POSITION N7,N6:? "dagger{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}s sword{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}l sword"
2030 GOSUB CHOOSE:ON CH GOTO 2040,2050,2060,1820
2040 COST=N10:GOSUB 2070:WN=N2:GOTO 2090
2050 COST=30:GOSUB 2070:WN=N3:GOTO 2090
2060 COST=50:GOSUB 2070:WN=N4:GOTO 2090
2070 POSITION COL,ROW:? " ":GD=G:G=INT(G-(COST-(SL*COST))):IF G<N0 THEN 2140
2080 P=N1:RETURN 
2090 FOR X=N1 TO N2:SOUND N0,N3,N0,N8:FOR Y=N1 TO N8:NEXT Y:SOUND N0,N0,N0,N0
2100 FOR Y=N1 TO N3:NEXT Y:NEXT X:FOR X=N14 TO N0 STEP -0.3:SOUND N0,N5,N10,X:SOUND N1,N20,N10,X:NEXT X:GOTO 1790
2110 IF NOT P THEN 2150
2120 POSITION N1,N3:? "    I THANK THEE FOR THY PURCHASE!"
2130 FOR X=N14 TO N0 STEP -0.3:SOUND N0,30,N10,X:NEXT X:GOSUB DELAY2:P=N0:GOTO 2150
2140 POSITION N1,N3:? "      {inv} THY PURSE IS TOO MEAGER! {/inv}":GOSUB SND2:GOSUB DELAY2:G=GD:POP:GOTO 1790
2150 POKE 559,N0:POSITION N3,N3:? "                                "
2160 POSITION N7,N6:? "press{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT} thy  {DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}joystick{DOWN}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}button":GOTO 550
2170 GRAPHICS N18:POKE 756,CHSET:POSITION N2,N1:? #N6;"{inv}YOU ARE DEAD!{/inv}"
2180 POSITION N2,N3:? #N6;"DO YOU WANT":? #N6;"  TO PLAY AGAIN?"
2190 IF I(DR)=N0 THEN SC=SC+(200-TURN)
2200 POSITION N4,N7:? #N6;"SCORE: ";SC
2210 OPEN #N1,N4,N0,"K:":GET #N1,A:CLOSE #N1:IF A=ASC("N") THEN POKE 82,N2:END 
2220 IF A<>ASC("Y") THEN 2210
2230 POSITION N4,N10:? #N6;"{inv}one moment{/inv}"
2240 RESTORE 2940:HP=50:STR=100:SPL=N0:PIE=N1:CNT=N0:B=N0:WN=N1:G=60:ROOM=39:SC=N0:SM=N0:TURN=N0:GOTO 80
2250 REM *** INITIALIZE ***
2260 RTOP=PEEK(106)-N21:POKE 106,RTOP:GRAPHICS N0:DL=PEEK(560)+256*PEEK(561)+N4:POKE DL+N4,N7:POKE DL+N5,N6
2270 POKE DL+N8,N6:POKE DL+N9,N6:POKE 710,N0:POKE 752,N1:MAP=RTOP+N1:STTUS=RTOP+N6:STORE=RTOP+N11
2280 POSITION N4,N3:? "dragonlord":POSITION N8,N6:? "{inv}by{/inv}":POSITION 22,N6:? "{inv}clayton walnum{/inv}"
2290 POSITION N10,N20:? "ONE MOMENT PLEASE"
2300 DIM RM(N77),I(N77),RM$(255),MV$(N20),N$(N9),W$(28),DRN$(N20),S$(120),B$(40),CL$(40)
2310 DIM R$(N1),R(N5),C$(N1),E$(N4),D$(81)
2320 S$(N1)=" ":S$(120)=" ":S$(N2)=S$
2330 S$(N1)=" ":S$(120)=" ":S$(N2)=S$:RESTORE 3370:FOR X=N1 TO 40:READ A:CL$(X)=CHR$(A):NEXT X
2340 WN=N1:PIE=N1:CNT=N0:G=60:SPL=N0:HP=50:STR=100:B=N0:ROOM=39:SM=N0:SC=N0:TURN=N0
2350 ROOMPOS=180:CHOOSE=290:DRN=370:CLUE=210:DEAD=2170:DELAY2=360:SND1=160:SND2=170:TEL=130
2360 RM$="{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}| {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-R}{CTRL-C}{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}| |{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} |{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-R}{CTRL-C}{CTRL-Q}{CTRL-R}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}| {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}{CTRL-Q}{CTRL-R}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} |{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}"
2370 RM$(86)="{CTRL-Q}{CTRL-R}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-R}{CTRL-C}{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}| {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-R}{CTRL-C}{CTRL-Q}{CTRL-R}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}"
2380 RM$(171)="{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}| |{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-R}{CTRL-C}{CTRL-Q}{CTRL-R}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}| |{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}{CTRL-Q}{CTRL-R}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}| {CTRL-A}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-R}{CTRL-C}{CTRL-Q}{CTRL-R}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} |{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-R}{CTRL-C}{CTRL-Q}{CTRL-X}{CTRL-E}{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-D} |{DOWN}{LEFT}{LEFT}{LEFT}{CTRL-Z}{CTRL-W}{CTRL-C}"
2390 W$="NONE   DAGGER S SWORDL SWORD":DRN$="northeast southwest "
2400 D$="{inv}++++;++++;+++++++;;+++;+++;;+;+++;+;;+;+;+;+;;+;;+;;+;;+;;;;;+;;;;;+;;;;;;;;;;;;;{/inv}"
2410 CHSET=RTOP+N17:CHBASE=CHSET*256:POKE 203,N0:POKE 204,CHSET:POKE 205,N0:POKE 206,224
2420 FOR X=N1 TO N20:READ A:MV$(X)=CHR$(A):NEXT X:D=USR(ADR(MV$)):POKE 756,CHSET:GOTO 30
2430 DATA 104,104,104,162,255,160,58,202,208,9,136,208,6,170,202
2440 DATA 138,208,241,96,142,10,212,142,22,208,24,144,235
2450 DATA 0,248,60,102,102,126,231,0
2460 DATA 0,252,102,252,102,102,124,0
2470 DATA 0,254,102,112,240,102,62,0
2480 DATA 0,248,108,102,230,108,124,0
2490 DATA 0,254,96,124,224,102,126,0
2500 DATA 0,254,99,252,108,96,96,0
2510 DATA 0,254,102,96,238,102,62,0
2520 DATA 0,118,54,126,54,54,118,0
2530 DATA 0,126,24,60,24,24,126,0
2540 DATA 0,14,6,6,246,102,60,0
2550 DATA 0,230,110,248,120,110,102,0
2560 DATA 0,240,96,224,96,118,126,0
2570 DATA 0,227,119,255,107,99,119,0
2580 DATA 0,230,118,126,126,110,246,0
2590 DATA 0,254,102,230,102,102,126,0
2600 DATA 0,252,102,238,124,96,112,0
2610 DATA 0,254,102,230,102,108,118,0
2620 DATA 0,252,102,230,124,108,118,0
2630 DATA 0,254,96,126,6,102,126,0
2640 DATA 0,126,216,24,24,24,28,0
2650 DATA 0,230,102,230,102,126,124,0
2660 DATA 0,230,102,230,102,126,24,0
2670 DATA 0,227,99,235,127,119,99,0
2680 DATA 0,230,102,60,60,102,118,0
2690 DATA 0,230,102,60,24,56,56,0
2700 DATA 0,254,108,24,48,102,126,0
2710 DATA 170,170,170,170,170,170,170,170
2720 DATA 0,254,102,238,118,102,126,0
2730 DATA 0,24,120,120,24,24,126,0
2740 DATA 0,124,102,76,24,54,126,0
2750 DATA 0,126,206,24,12,102,62,0
2760 DATA 0,12,28,60,108,254,12,0
2770 DATA 0,254,96,252,6,102,124,0
2780 DATA 0,124,224,124,230,102,126,0
2790 DATA 0,254,102,12,24,48,48,0
2800 DATA 0,60,102,60,230,102,254,0
2810 DATA 0,254,102,254,6,12,56,0
2820 DATA 0,60,102,219,195,0,0,0
2830 DATA 24,28,6,54,54,6,28,24
2840 DATA 24,56,96,108,108,96,56,24
2850 DATA 24,24,12,198,230,62,0,0
2860 DATA 0,0,62,230,198,12,24,24
2870 DATA 24,24,48,99,103,124,0,0
2880 DATA 0,0,124,103,99,48,24,24
2890 DATA 0,0,0,195,219,102,60,0
2900 DATA 255,255,255,255,255,255,255,255
2910 DATA 247,247,0,189,189,0,247,247
2920 DATA 255,255,195,129,129,129,195,255
2930 REM *** ROOM DATA ***
2940 DATA 4,6,6,9,6,9,6,9,6,6,5
2950 DATA 1,9,9,8,5,2,4,8,9,9,3
2960 DATA 12,11,2,4,3,2,1,5,2,11,12
2970 DATA 7,6,10,10,6,10,6,10,10,6,15
2980 DATA 11,12,2,1,5,2,4,3,2,12,11
2990 DATA 4,8,8,9,3,2,1,9,8,8,5
3000 DATA 1,6,6,8,6,8,6,8,6,6,3
3010 DATA 1,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,3,3,3,3,4,4,4,4,4,5,5,5,5,5,6,6,6,6,6,6,6,7,7,7,7,7
3020 DATA 7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,8,-1
3030 POKE 87,N0:POKE 88,N0:POKE 89,MAP:A=USR(ADR(CL$),N15)
3040 POSITION N18,N9:? RM$(154,170)
3050 POSITION 26,N21:? "{inv}a map of{/inv}":POSITION N4,22:? "{inv}thy progress{/inv}";
3060 POKE 89,STTUS:POSITION N5,N0:? "{inv}dragonlord{/inv}"
3070 POSITION N0,N1:? "{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-W}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}"
3080 POSITION N0,N2:? "|)################'|)################'|"
3090 POSITION N0,N3:? "|% NAME:          $|% WEAPON:        $|"
3100 POSITION N0,N4:? "|%                $|%                $|"
3110 POSITION N0,N5:? "|%   HP:          $|% SPELLS:        $|"
3120 POSITION N0,N6:? "|%                $|%                $|"
3130 POSITION N0,N7:? "|%  STR:          $|%  SERUM:        $|"
3140 POSITION N0,N8:? "|%                $|%                $|"
3150 POSITION N0,N9:? "|%  PIE:          $|%   GOLD:        $|"
3160 POSITION N0,N10:? "|(****************&|(****************&|"
3170 POSITION N0,N11:? "{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-X}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}"
3180 POSITION N0,N12:? "{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}{CTRL-Q}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-E}"
3190 POSITION N0,N13:? "|)################'||{inv} COMMAND {/inv}||)####'|"
3200 POSITION N0,N14:? "|%  ROOM:         $||  MOVE   ||%    $|"
3210 POSITION N0,N15:? "|% EXITS:         $||  MAP    ||(****&|"
3220 POSITION N0,N16:? "|(****************&||  CAST   |{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}"
3230 POSITION N0,N17:? "{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}|  STORE  |":POSITION N20,N18:? "{CTRL-Z}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-R}{CTRL-C}"
3240 POKE 89,STORE:POKE 82,N0:POSITION N1,N0:? ",,,,,,,,,,,,,,,,,,  ,                ,  , {inv}ye olde shoppe{/inv} ,"
3250 POSITION N21,N1:? ",                ,  ,,,,,,,,,,,,,,,,,,"
3260 POSITION N4,N5:? ",,,,,,,,,,,,        ,          ,        ,  press   ,        ,          ,"
3270 ? "    ,   thy    ,        ,          ,        , joystick ,        ,          ,"
3280 ? "    ,  button  ,        ,          ,        ,,,,,,,,,,,,"
3290 POSITION N2,N11:? "{inv}MAGIC{/inv}        {inv}HEALTH{/inv}       {inv}WEAPONS{/inv}       SPELLS: 10   5 PIE  : 10  DAGGER : 10"
3300 ? "  GYPSY : 20   LODGING: 15  S SWORD: 30   BREW  : 60   DOCTOR : 15  L SWORD: 50"
3310 GRAPHICS N0:POKE 756,CHSET:POKE 752,N1:POKE 710,160
3320 POSITION N2,N10:? "WHAT WILL BE THY NAME FOR THIS QUEST?"
3330 POSITION N14,N13:? "---------{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}{LEFT}";:INPUT N$
3340 FOR X=N1 TO N9:IF N$(X,X)<>"-" THEN NEXT X:GOTO 550
3350 TRAP 3030:N$=N$(N1,X-N1):POP:GOTO 550:TRAP 40000
3360 REM *** CL$ DATA ***
3370 DATA 104,104,104,133,205,165,88,133,203,165,89,133,204,162,0,169,0,168,145,203,200,208,251,232,228,205
3380 DATA 240,11,24,165,204,105,1,133,204,240,234,208,232,96
3390 REM *** MV$ DATA ***
3400 DATA 104,162,4,160,0,177,205,145,203,200,208,249,230,206,230,204,202,208,242,96

Credits