Maneuver
- Type
- Game
- Category
- Two-player simultaneous-orders strategy game
- Author
- Will Woodard
- Published in
- Antic, April 1985 (Vol. 3, No. 12)
- Year
- 1985
- Language
- Atari BASIC
- Requirements
- Any Atari 8-bit, Atari BASIC, keyboard (two players)
About the program
"No huge scrolling map, no tanks and no trees. Just pure strategy!" Will Woodard, a computer science graduate student at North Texas State University, wrote Maneuver to boil down the war games of the day (he named Chris Crawford's Eastern Front) into "an elegant two-player battle of symbols". Each side has a circle, a spade and a heart on an 8 × 8 grid. The first player to destroy the other side's spade wins.
The pieces differ in armour, missile range and missile strength:
| Piece | Armour | Range | Missile strength |
|---|---|---|---|
| Circle | 13 | 5 | 3 |
| Spade | 20 | 2 | 5 |
| Heart | 17 | 3 | 5 |
Damage is greater the closer you are to the target, with a random element added.
Typing it in
Many lines contain control characters, which the program uses for the board edges and the playing-card symbols. {CTRL-S} means hold CTRL and press S, {CTRL-;} is CTRL with semicolon, and so on. {inv}…{/inv} means inverse video (press the Atari key before and after). {BELL} in line 426 is ESC then CTRL-2. The magazine asked readers to check the listing with TYPO II. The lower-case letters in DATA line 82 are the title letters that slide into place, so keep them lower case.
How to play
When a piece blinks, its owner types five orders, without spaces and without RETURN:
N,S,E,W: move one square north, south, east or west.1,2,3,4: fire north, east, south or west.-: skip a move.
EESE3, for example, moves east, east, south, east and then fires south. A piece can move and then fire, but once it has fired (or skipped) it can't move again in that turn. When all six pieces have orders, the computer carries them out one step at a time, in the order circle, spade, heart. Red moves first on odd turns and green on even. The damage totals are printed after each turn.
How it works
- A string as the screen. Lines 20–72 change the address of
A$in BASIC's variable value table (found through locations 134–135) so that the string sits on top of the GRAPHICS 2 screen memory.A$(PPOS,PPOS)="…"then puts a character straight onto the board.POKE 756,226switches to the ROM's second half-font, which has the card suits and line-drawing shapes. - GOSUB by key code. Each order is stored as its ATASCII code, and line 633 runs
GOSUB code*100. SoN(78) goes to line 7800,E(69) to 6900,1(49) to 4900 and-(45) to the do-nothing routine at 4500. - Checking orders. Line 1000 rejects a set of orders that tries to move after firing, and the player must type them again.
Listing
5 REM MANEUVER
6 REM BY WILL WOODARD
7 REM ANTIC MAGAZINE
10 DIM A$(240),BYTE$(80),B$(1),C$(1),D$(1),PLARR(12,9),PP(12)
15 GRAPHICS 2
20 VTABLE=PEEK(134)+256*PEEK(135)
30 SCREENRAM=PEEK(88)+256*PEEK(89)
40 OFFSET=SCREENRAM-ADR(A$)
50 V3=INT(OFFSET/256)
60 V2=OFFSET-256*V3
70 POKE VTABLE+2,V2
72 POKE VTABLE+3,V3
74 POKE 756,226
76 SETCOLOR 0,7,2:SETCOLOR 1,3,2:SETCOLOR 2,0,6:SETCOLOR 3,12,4:SETCOLOR 4,0,0
77 FOR A=1 TO 240 STEP 3:A$(A)="{CTRL-U}":A$(A+1)="{CTRL-S}":A$(A+2)="{CTRL-Y}":NEXT A
78 READ A,B,C,B$:IF A<>-1 THEN D$=A$(A-C,A-C)
79 IF A<>-1 THEN FOR I=A TO B STEP C:C$=A$(I,I):A$(I,I)=B$:A$(I-C,I-C)=D$:SOUND 0,I,10,8:SOUND 1,I,8,2:D$=C$
80 IF A<>-1 THEN NEXT I:GOTO 78
81 SOUND 0,0,0,0:SOUND 1,0,0,0
82 DATA 210,30,-20,e,40,31,-1,u,29,29,1,n,212,32,-20,v,21,28,1,a,33,33,20,e,2,27,1,m,59,34,-1,r,-1,-1,-1,f
90 OPEN #1,4,0,"K:"
100 GOSUB 30000
350 TURN=1
355 FOR PLY=0 TO 1
400 ? :? :? :? :FOR PIECE=1 TO NOPLY:? "Enter orders for blinking player"
404 IF PLARR(PIECE+(NOPLY*PLY),8)=0 THEN 430
405 PPOS=PP(PIECE+(NOPLY*PLY)):B$=A$(PPOS,PPOS)
410 FOR I=1 TO 10:SOUND 0,47,10,8:A$(PPOS,PPOS)="{inv}{CTRL-S}{/inv}":FOR D=1 TO 25:NEXT D:A$(PPOS,PPOS)=B$:FOR D=1 TO 25:NEXT D
415 SOUND 0,0,0,0:NEXT I
420 FOR J=1 TO PLARR(PIECE+(NOPLY*PLY),6):GET #1,MOVE:PLARR(PIECE+(NOPLY*PLY),J)=MOVE:? CHR$(MOVE);:NEXT J
425 GOSUB 1000
426 IF OK=0 THEN ? :? :? :? :? "{BELL}ERROR IN ORDERS...":FOR D=1 TO 200:NEXT D:PIECE=PIECE-1
430 ? :? :? :? :? :NEXT PIECE
435 NEXT PLY
540 ? :? :? :? :? "GREEN DAMAGE: {CTRL-T}:";PLARR(1,8);" {CTRL-;}:";PLARR(2,8);" {CTRL-,}:";PLARR(3,8)
550 ? "RED DAMAGE: {CTRL-T}:";PLARR(4,8);" {CTRL-;}:";PLARR(5,8);" {CTRL-,}:";PLARR(6,8)
600 FOR I=1 TO 5
605 FOR J=1 TO NOPLY
607 IF TURN=1 THEN PLY=0:GOSUB 632:PLY=1:GOSUB 634
609 IF TURN=2 THEN PLY=1:GOSUB 634:PLY=0:GOSUB 632
630 NEXT J
631 NEXT I:GOTO 639
632 IF PLARR(J+(NOPLY*PLY),8)=0 THEN RETURN
633 GOSUB PLARR(J+(NOPLY*PLY),I)*100:SOUND 0,0,0,0:RETURN
634 IF PLARR(J+(NOPLY*PLY),8)=0 THEN RETURN
635 GOSUB PLARR(J+(NOPLY*PLY),I)*100:SOUND 0,0,0,0:RETURN
639 TURN=TURN+1:IF TURN=3 THEN TURN=1
640 ? :? :? :? :? "GREEN DAMAGE: {CTRL-T}:";PLARR(1,8);" {CTRL-;}:";PLARR(2,8);" {CTRL-,}:";PLARR(3,8)
650 ? "RED DAMAGE: {CTRL-T}:";PLARR(4,8);" {CTRL-;}:";PLARR(5,8);" {CTRL-,}:";PLARR(6,8)
660 ? "Press any key to continue..":GET #1,Z
700 GOTO 355
1000 OK=1:OK2=0
1005 FOR I=1 TO PLARR(PIECE+(NOPLY*PLY),6)
1010 B$=CHR$(PLARR(PIECE+(NOPLY*PLY),I))
1020 IF (B$<>"N" AND B$<>"S" AND B$<>"E" AND B$<>"W") THEN OK2=1
1025 IF (OK2 AND B$<>"1" AND B$<>"2" AND B$<>"3" AND B$<>"4" AND B$<>"-") THEN OK=0
1030 NEXT I
1999 RETURN
4500 FOR D=1 TO 100:NEXT D:RETURN
4550 FOR D=1 TO 100:NEXT D:RETURN
4900 DIS=0:GOSUB 26000:FOR K=PP(J+(3*PLY))-20 TO PP(J+(3*PLY))-20-(PLARR(J+(3*PLY),7)*20) STEP -20
4902 DIS=DIS+1
4904 IF K<=67 THEN POP :GOTO 4940
4910 B$=A$(K,K):IF B$="T" OR B$="{inv}T{/inv}" OR B$="{CTRL-;}" OR B$="{inv}{CTRL-;}{/inv}" OR B$="@" OR B$="{inv}@{/inv}" THEN POP :GOTO 4925
4915 A$(K,K)="{inv}|{/inv}":C$=A$(K+20,K+20)
4920 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K+20,K+20)="{inv}{CTRL-S}{/inv}"
4922 NEXT K
4923 GOTO 4940
4925 B$=A$(K+20,K+20)
4926 IF B$<>"{inv}T{/inv}" AND B$<>"{inv}{CTRL-;}{/inv}" AND B$<>"{inv}@{/inv}" AND B$<>"T" AND B$<>"@" AND B$<>"{CTRL-;}" THEN A$(K+20,K+20)="{inv}{CTRL-S}{/inv}"
4927 B$=A$(K,K):FOR L=64 TO 95:A$(K,K)=CHR$(L):SOUND 0,L,10,8:SOUND 0,0,0,0:NEXT L
4930 A$(K,K)=B$
4932 GOSUB 9000
4935 RETURN
4940 C$=A$(K+20,K+20)
4942 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K+20,K+20)="{inv}{CTRL-S}{/inv}"
4945 RETURN
5000 DIS=0:GOSUB 26000:FOR K=PP(J+(3*PLY))+1 TO PP(J+(3*PLY))+1+PLARR(J+(3*PLY),7)
5002 DIS=DIS+1
5004 IF (INT(K/10))/2<>INT(INT(K/10)/2) AND K-(INT(K/10)*10)>=4 THEN POP :GOTO 5040
5010 B$=A$(K,K):IF B$="T" OR B$="{inv}T{/inv}" OR B$="{CTRL-;}" OR B$="{inv}{CTRL-;}{/inv}" OR B$="@" OR B$="{inv}@{/inv}" THEN POP :GOTO 5025
5020 A$(K,K)="{inv}R{/inv}":C$=A$(K-1,K-1)
5021 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K-1,K-1)="{inv}{CTRL-S}{/inv}"
5022 NEXT K
5023 GOTO 5040
5025 B$=A$(K-1,K-1):IF B$<>"{inv}T{/inv}" AND B$<>"{inv}{CTRL-;}{/inv}" AND B$<>"{inv}@{/inv}" AND B$<>"T" AND B$<>"@" AND B$<>"{CTRL-;}" THEN A$(K-1,K-1)="{inv}{CTRL-S}{/inv}"
5027 B$=A$(K,K):FOR L=64 TO 95:A$(K,K)=CHR$(L):SOUND 0,L,10,8:SOUND 0,0,0,0:NEXT L
5030 A$(K,K)=B$
5032 GOSUB 9000
5035 RETURN
5040 C$=A$(K-1,K-1)
5041 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K-1,K-1)="{inv}{CTRL-S}{/inv}"
5045 RETURN
5100 DIS=0:GOSUB 26000:FOR K=PP(J+(3*PLY))+20 TO PP(J+(3*PLY))+20+(PLARR(J+(3*PLY),7)*20) STEP 20
5102 DIS=DIS+1
5104 IF K>=174 THEN POP :GOTO 5140
5110 B$=A$(K,K):IF B$="T" OR B$="{inv}T{/inv}" OR B$="{CTRL-;}" OR B$="{inv}{CTRL-;}{/inv}" OR B$="@" OR B$="{inv}@{/inv}" THEN POP :GOTO 5125
5120 A$(K,K)="{inv}|{/inv}":C$=A$(K-20,K-20)
5121 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K-20,K-20)="{inv}{CTRL-S}{/inv}"
5122 NEXT K
5123 GOTO 5140
5125 B$=A$(K-20,K-20)
5126 IF B$<>"{inv}T{/inv}" AND B$<>"{inv}{CTRL-;}{/inv}" AND B$<>"{inv}@{/inv}" AND B$<>"T" AND B$<>"@" AND B$<>"{CTRL-;}" THEN A$(K-20,K-20)="{inv}{CTRL-S}{/inv}"
5127 B$=A$(K,K):FOR L=64 TO 95:A$(K,K)=CHR$(L):SOUND 0,L,10,8:SOUND 0,0,0,0:NEXT L
5130 A$(K,K)=B$
5132 GOSUB 9000
5135 RETURN
5140 C$=A$(K-20,K-20)
5141 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K-20,K-20)="{inv}{CTRL-S}{/inv}"
5145 RETURN
5200 DIS=0:GOSUB 26000:FOR K=PP(J+(3*PLY))-1 TO PP(J+(3*PLY))-1-PLARR(J+(3*PLY),7) STEP -1
5202 DIS=DIS+1
5204 IF (INT(K/10))/2=INT(INT(K/10)/2) AND K-(INT(K/10)*10)<=7 THEN POP :GOTO 5240
5210 B$=A$(K,K):IF B$="T" OR B$="{inv}T{/inv}" OR B$="{CTRL-;}" OR B$="{inv}{CTRL-;}{/inv}" OR B$="@" OR B$="{inv}@{/inv}" THEN POP :GOTO 5225
5220 A$(K,K)="{inv}R{/inv}":C$=A$(K+1,K+1)
5221 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K+1,K+1)="{inv}{CTRL-S}{/inv}"
5222 NEXT K
5223 GOTO 5240
5225 B$=A$(K+1,K+1):IF B$<>"{inv}T{/inv}" AND B$<>"{inv}{CTRL-;}{/inv}" AND B$<>"{inv}@{/inv}" AND B$<>"T" AND B$<>"@" AND B$<>"{CTRL-;}" THEN A$(K+1,K+1)="{inv}{CTRL-S}{/inv}"
5227 B$=A$(K,K):FOR L=64 TO 95:A$(K,K)=CHR$(L):SOUND 0,L,10,8:SOUND 0,0,0,0:NEXT L
5230 A$(K,K)=B$
5232 GOSUB 9000
5235 RETURN
5240 C$=A$(K+1,K+1)
5241 IF (C$<>"{inv}T{/inv}" AND C$<>"{inv}{CTRL-;}{/inv}" AND C$<>"{inv}@{/inv}" AND C$<>"T" AND C$<>"@" AND C$<>"{CTRL-;}") THEN A$(K+1,K+1)="{inv}{CTRL-S}{/inv}"
5245 RETURN
6400 PLARR(6,8)=PLARR(6,8)-DAM
6403 IF PLARR(6,8)<=0 THEN FOR SO=1 TO 25:SOUND 0,RND(0)*80+50,10,8:A$(PP(6),PP(6))=CHR$(RND(0)*225):NEXT SO
6405 SOUND 0,0,0,0
6410 RETURN
6900 PPOS=PP(J+(NOPLY*PLY)):B$=A$(PPOS,PPOS)
6902 C$=A$(PPOS+1,PPOS+1):IF C$="T" OR C$="{inv}T{/inv}" OR C$="{CTRL-;}" OR C$="{inv}{CTRL-;}{/inv}" OR C$="@" OR C$="{inv}@{/inv}" THEN 6920
6903 IF C$="{CTRL-.}" OR C$="{inv}{CTRL-.}{/inv}" OR C$="Y" OR C$="{inv}Y{/inv}" THEN 6920
6904 IF C$="{inv}{CTRL-D}{/inv}" THEN 6920
6910 A$(PPOS,PPOS)="{inv}{CTRL-S}{/inv}":A$(PPOS+1,PPOS+1)=B$
6915 PP(J+(NOPLY*PLY))=PP(J+(NOPLY*PLY))+1
6920 RETURN
7800 PPOS=PP(J+(NOPLY*PLY)):B$=A$(PPOS,PPOS)
7801 C$=A$(PPOS-20,PPOS-20)
7802 IF C$="T" OR C$="{inv}T{/inv}" OR C$="{CTRL-;}" OR C$="{inv}{CTRL-;}{/inv}" OR C$="@" OR C$="{inv}@{/inv}" OR C$="Y" OR C$="{inv}Y{/inv}" THEN 7820
7803 IF C$="{CTRL-.}" OR C$="{inv}{CTRL-.}{/inv}" OR C$="Y" OR C$="{inv}Y{/inv}" THEN 7820
7804 C$=A$(PP(J+(NOPLY*PLY))-20):IF C$="{inv}{CTRL-W}{/inv}" THEN 7820
7810 A$(PPOS,PPOS)="{inv}{CTRL-S}{/inv}":A$(PPOS-20,PPOS-20)=B$
7815 PP(J+(NOPLY*PLY))=PP(J+(NOPLY*PLY))-20
7820 RETURN
8300 PPOS=PP(J+(NOPLY*PLY)):B$=A$(PPOS,PPOS)
8302 C$=A$(PPOS+20,PPOS+20):IF C$="T" OR C$="{inv}T{/inv}" OR C$="{CTRL-;}" OR C$="{inv}{CTRL-;}{/inv}" OR C$="@" OR C$="{inv}@{/inv}" THEN 8320
8303 IF C$="{CTRL-.}" OR C$="{inv}{CTRL-.}{/inv}" OR C$="Y" OR C$="{inv}Y{/inv}" THEN 8320
8304 IF C$="{inv}{CTRL-X}{/inv}" THEN 8320
8310 A$(PPOS,PPOS)="{inv}{CTRL-S}{/inv}":A$(PPOS+20,PPOS+20)=B$
8315 PP(J+(NOPLY*PLY))=PP(J+(NOPLY*PLY))+20
8320 RETURN
8400 PLARR(4,8)=PLARR(4,8)-DAM
8403 IF PLARR(4,8)<=0 THEN FOR SO=1 TO 25:SOUND 0,RND(0)*80+50,10,8:A$(PP(4),PP(4))=CHR$(RND(0)*225):NEXT SO
8405 SOUND 0,0,0,0
8410 RETURN
8700 PPOS=PP(J+(NOPLY*PLY)):B$=A$(PPOS,PPOS)
8702 C$=A$(PPOS-1,PPOS-1):IF C$="T" OR C$="{inv}T{/inv}" OR C$="{CTRL-;}" OR C$="{inv}{CTRL-;}{/inv}" OR C$="@" OR C$="{inv}@{/inv}" THEN 8720
8703 IF C$="{CTRL-.}" OR C$="{inv}{CTRL-.}{/inv}" OR C$="Y" OR C$="{inv}Y{/inv}" THEN 8720
8704 IF C$="{inv}{CTRL-A}{/inv}" THEN 8720
8710 A$(PPOS,PPOS)="{inv}{CTRL-S}{/inv}":A$(PPOS-1,PPOS-1)=B$
8715 PP(J+(NOPLY*PLY))=PP(J+(NOPLY*PLY))-1
8720 RETURN
9000 CH=RND(0)*10:IF CH>5 THEN CHANCE=RND(1):GOTO 9002
9001 CHANCE=-RND(1)
9002 DAM=PLARR(J+(3*PLY),9)*(1/DIS)+CHANCE
9003 DAM=INT(DAM*100):DAM=DAM/100
9005 GOSUB ASC(B$)*100
9006 FOR X=1 TO 3:IF PLARR(X+(3*PLY),8)<=0 THEN PLARR(X+(3*PLY),8)=0:A$(PP(X+(3*PLY)),PP(X+(PLY*3)))="{inv}{CTRL-S}{/inv}"
9008 NEXT X
9014 IF PLARR(2,8)<=0 THEN GOTO 10000
9015 IF PLARR(5,8)<=0 THEN GOTO 10050
9017 ? :? :? :? :? "GREEN DAMAGE: {CTRL-T}:";PLARR(1,8);" {CTRL-;}:";PLARR(2,8);" {CTRL-,}:";PLARR(3,8)
9020 ? "RED DAMAGE: {CTRL-T}:";PLARR(4,8);" {CTRL-;}:";PLARR(5,8);" {CTRL-,}:";PLARR(6,8)
9049 RETURN
10000 FOR I=100 TO 40 STEP -1:SOUND 0,I,10,8:SOUND 1,I+17,10,8
10031 SETCOLOR 0,I,4:SETCOLOR 4,I+17,4
10032 SOUND 2,140-I,10,8:SOUND 3,140-I-17,10,8:NEXT I
10035 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0
10037 SETCOLOR 0,3,2:SETCOLOR 4,3,2
10040 ? :? :? "RED VICTORY":? "Do you wish to play again? <Y/N>":GET #1,ANS:IF ANS=89 THEN RUN
10049 GRAPHICS 0:END
10050 FOR I=200 TO 140 STEP -1:SOUND 0,I,10,8:SOUND 1,I+17,10,8
10081 SETCOLOR 0,I,4:SETCOLOR 4,I+17,4
10082 SOUND 2,240-I,10,8:SOUND 3,240-I-17,10,8:NEXT I
10085 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0
10087 SETCOLOR 0,12,4:SETCOLOR 4,12,4
10090 ? :? :? "GREEN VICTORY":? "Do you wish to play again? <Y/N>":INPUT B$:IF B$="Y" THEN RUN
10099 GRAPHICS 0:END
12300 PLARR(5,8)=PLARR(5,8)-DAM:RETURN
19200 PLARR(3,8)=PLARR(3,8)-DAM
19203 IF PLARR(3,8)<=0 THEN FOR SO=1 TO 25:SOUND 0,RND(0)*80+50,10,8:A$(PP(3),PP(3))=CHR$(RND(0)*225):NEXT SO
19205 SOUND 0,0,0,0
19210 RETURN
21200 PLARR(1,8)=PLARR(1,8)-DAM
21203 IF PLARR(1,8)<=0 THEN FOR SO=1 TO 25:SOUND 0,RND(0)*80+50,10,8:A$(PP(1),PP(1))=CHR$(RND(0)*225):NEXT SO
21205 SOUND 0,0,0,0
21210 RETURN
25100 PLARR(2,8)=PLARR(2,8)-DAM:RETURN
26000 SOUND 0,100,8,8:RETURN
26010 SOUND 0,145,8,8:RETURN
26100 SOUND 0,0,0,0:SOUND 1,0,0,0
30000 A$(47,54)="{inv}{CTRL-Q}{CTRL-W}{CTRL-W}{CTRL-W}{CTRL-W}{CTRL-W}{CTRL-W}{CTRL-E}{/inv}"
30010 A$(67,74)="{inv}{CTRL-A}T{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-D}{/inv}"
30020 A$(87,94)="{inv}{CTRL-A}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{/inv}T{inv}{CTRL-D}{/inv}"
30030 A$(107,114)="{inv}{CTRL-A}{CTRL-;}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-D}{/inv}"
30040 A$(127,134)="{inv}{CTRL-A}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{/inv}{CTRL-;}{inv}{CTRL-D}{/inv}"
30050 A$(147,154)="{inv}{CTRL-A}@{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-D}{/inv}"
30060 A$(167,174)="{inv}{CTRL-A}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{CTRL-S}{/inv}@{inv}{CTRL-D}{/inv}"
30070 A$(187,194)="{inv}{CTRL-Z}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-X}{CTRL-C}{/inv}"
30075 NOPLY=3
30080 FOR I=1 TO 3:READ X:PP(I)=X:NEXT I
30090 FOR I=1 TO 3:READ X:PP(I+3)=X:NEXT I
30110 DATA 68,108,148,93,133,173
30120 FOR I=1 TO 3:READ W,X,Y,Z:PLARR(I,6)=W:PLARR(I,7)=X:PLARR(I,8)=Y:PLARR(I,9)=Z
30130 PLARR(I+3,6)=W:PLARR(I+3,7)=X:PLARR(I+3,8)=Y:PLARR(I+3,9)=Z:NEXT I
30140 DATA 5,5,13,3,5,2,20,5,5,3,17,5
30150 RETURN
32600 GRAPHICS 0:INPUT S,E
32615 GRAPHICS 0:? :?
32620 ? S:S=S+1
32625 ? "CONT":POSITION 0,0:POKE 842,13:STOP
32630 POKE 842,12:IF S<=E THEN 32615
32635 GRAPHICS 0:END
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: MANEUVER.BAS.
Credits
- Program listing: Maneuver — program listing (Antic, April 1985 (Vol. 3, No. 12)) — Will Woodard
- Picture: The board, waiting for the first set of orders: green pieces on the left, red on the right. — Will Woodard (program); screenshot by the site
- Antic, April 1985 - Vol. 3 No. 12: scan of the printed magazine, Maneuver, by Will Woodard, pp. 55, 58, 74 — Internet Archive, 1985
- Antic disk, April 1985 - Vol. 3 No. 12: MANEUVER.BAS (detokenized listing) — Will Woodard, 1985
