Vampire Rats!
- Type
- Game
- Category
- Two-player duel game
- Author
- Tom Zarbock
- Published in
- Antic, November 1985 (Vol. 4, No. 7)
- Year
- 1985
- Language
- Atari BASIC
- Requirements
- Any Atari 8-bit computer, Atari BASIC, two joysticks (ports 1 and 2); disk or cassette
- Tags
- antic, two-player, joystick, halloween, redefined-characters, graphics-2, duel, 1985
- Related
- Alien Asylum, Alpha Run, Bats, Black Box, Box-In, Courting Crickets
About the program
For Halloween 1985 Antic printed what it called "one of the strangest arcade games we have ever published". Tom Zarbock, a business administration student from San Juan Capistrano, California, wrote Vampire Rats!, a duel for two players. The barnyard isn't big enough for both Count Ratula and Vampirodent, and the survivor will be "Transylvania's King for a Day".
Both rats slowly lose blood as time passes. Red bars at each side of the screen show their levels, and a rat darkens as a warning when it's running low. Victims appear at random around the yard, and you top up your blood by draining them, or your rival. A rat whose blood runs out loses.
Typing it in
The only special characters are inverse-video titles in lines 9275, 27025 and 27056: {inv} … {/inv} means press the Atari (inverse) key before and after. The custom rat, victim and fence shapes are DATA from line 25160 onwards. Check those numbers carefully, since a wrong value only shows up as an odd-looking shape. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.
How to play
Plug in two joysticks, RUN, and press a trigger at the title screen. The controls work "like an early videogame tank":
- Forward moves your rat in the direction it is facing.
- Left/right turn it to the next of eight directions.
- Fire plus the stick turns and moves at the same time.
- Back doesn't reverse. It makes the rat jump forward, faster and over obstacles, at a cost in blood.
To drain a victim or the other rat, you must be right next to it and facing it. The bite is automatic, with no button press, and comes with "a sizzling zap sound". Rats can't move onto an occupied square.
How it works
The arena is GRAPHICS 2 (GRAPHICS 2+16) with a redefined character set. Each rat has a separate character for each of its eight facings, so turning is just a matter of printing a different character. The arrays set up in lines 22200–22260 turn a facing number into X and Y steps (S(0,n) and S(1,n)) and joystick values into turns (F()), which keeps the movement code short. The fence is drawn with PLOT/DRAWTO using colour values that are really character codes (lines 26010–26050), a GRAPHICS 1/2 trick for drawing with any character in any of the four colours.
Listing
1 REM VAMPIRE RATS!
2 REM BY TOM ZARBOCK
5 REM (c) 1985, ANTIC PUBLISHING
10 GOTO 22000
5000 REM ACTIONS
5010 S1=STICK(0):S2=STICK(1):F1=AF(F1+1+F(S1)):F2=AF(F2+1+F(S2))
5020 REM PLYR 1 NEW FACING?
5030 IF S1>12 THEN 5049
5040 COLOR 10+F1:PLOT X1,Y1
5045 IF STRIG(0)=0 THEN S1=14
5049 REM PLYR 1 MOVES OR JMPS?
5050 IF S1<>14 AND S1<>13 THEN 5074
5055 U=1:IF S1=13 THEN U=2
5060 TRAP 5074:LOCATE X1+S(0,F1)*U,Y1+S(1,F1)*U,K
5065 IF K<>32 THEN 5074
5070 COLOR 32:PLOT X1,Y1:X1=X1+S(0,F1)*U:Y1=Y1+S(1,F1)*U:COLOR 10+F1:PLOT X1,Y1:POKE 53761,10:POKE 53761,0
5072 B1=B1-2*(S1=13)
5074 REM PLYR 1 BITES? & WHO?
5080 LOCATE X1+S(0,F1),Y1+S(1,F1),K
5085 IF K>183 AND K<187 THEN V1=10:COLOR 32:PLOT X1+S(0,F1),Y1+S(1,F1):B1=B1+5
5090 IF K>41 AND K<50 THEN B2=B2-2:B1=B1+2:POKE 708,156:SOUND 2,18,4,15
5199 REM PLYR 2 NEW FACING?
5200 IF S2>12 THEN 5219
5210 COLOR 42+F2:PLOT X2,Y2
5215 IF STRIG(1)=0 THEN S2=14
5219 REM PLYR 2 MOVES OR JMPS?
5220 IF S2<>13 AND S2<>14 THEN 5259
5225 U=1:IF S2=13 THEN U=2
5230 TRAP 5259:LOCATE X2+S(0,F2)*U,Y2+S(1,F2)*U,K
5240 IF K<>32 THEN 5259
5250 COLOR 32:PLOT X2,Y2:X2=X2+S(0,F2)*U:Y2=Y2+S(1,F2)*U:COLOR 42+F2:PLOT X2,Y2:POKE 53761,10:POKE 53761,0
5252 B2=B2-2*(S2=13)
5259 REM PLYR 2 BITES? & WHO?
5270 LOCATE X2+S(0,F2),Y2+S(1,F2),K
5280 IF K>183 AND K<187 THEN V1=10:COLOR 32:PLOT X2+S(0,F2),Y2+S(1,F2):B2=B2+5
5290 IF K>9 AND K<18 THEN B1=B1-2:B2=B2+2:POKE 709,206:SOUND 3,16,4,15
5350 REM UPDATE BLOOD LEVEL
5390 REM PLAYER 1
5400 IF B1>8 THEN COLOR 168:PLOT 0,B1P:B1P=B1P-1:B1=B1-8
5405 IF B1<0 THEN COLOR 41:PLOT 0,B1P:B1P=B1P+1:B1=B1+8
5406 IF B1P<0 THEN B1P=0:B1=8
5407 IF B1P>10 THEN F=2:GOTO 9000
5410 COLOR 160+INT(B1+0.5):PLOT 0,B1P
5449 REM PLAYER 2
5470 IF B2>8 THEN COLOR 168:PLOT 19,B2P:B2P=B2P-1:B2=B2-8
5480 IF B2<0 THEN COLOR 41:PLOT 19,B2P:B2P=B2P+1:B2=B2+8
5482 IF B2P<0 THEN B2P=0:B2=8
5484 IF B2P>10 THEN F=1:GOTO 9000
5490 COLOR 160+B2:PLOT 19,B2P
5500 B1=B1-0.1:B2=B2-0.1
5899 REM RANDOM VICTIMS
5900 IF PEEK(53770)>9 THEN 5940
5910 I=INT(16*RND(0)+2):J=INT(10*RND(0)+1):LOCATE I,J,D:IF D<>32 THEN 5910
5920 COLOR INT(3*RND(0))+184:PLOT I,J:POKE 77,0
5940 REM SOUNDS
5950 SOUND 1,0,8,V1:V1=V1-2:IF V1<0 THEN V1=0
5960 SOUND 2,0,8,0:SOUND 3,0,8,0
5980 POKE 708,150-6*(B2P>8):POKE 709,200-8*(B1P>8):POKE 53768,197
6000 GOTO 5000
9000 REM GAME ENDS
9005 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0:POKE 708,150:POKE 709,200
9030 COLOR 32:PLOT X1,Y1:PLOT X2,Y2
9040 J=10:X=X1:Y=Y1:IF F=2 THEN J=42:X=X2:Y=Y2
9050 FOR I=1 TO 15:FOR K=0 TO 7
9060 COLOR J+K:PLOT X,Y:NEXT K:NEXT I:RESTORE 9100
9080 READ I,J:IF I=-1 THEN 9270
9090 SOUND 0,I,10,8:SOUND 1,I+1,10,8:FOR K=1 TO J/4:NEXT K:GOTO 9080
9100 DATA 237,100,177,100,140,100,117,200,140,100,117,200,140,100,117,200,140,100,177,300,177,500,-1,-1
9270 SOUND 0,0,0,0:SOUND 1,0,0,0
9275 POSITION 1,0:? #6;"{inv}press trig to play{/inv}":POKE 712,0:POKE 711,6:POKE 710,4
9280 IF STRIG(0) AND STRIG(1) THEN 9280
9285 B1P=0:B2P=0
9290 GOTO 25000
22000 REM INITIALIZE
22100 DIM F(15),S(1,7),AF(9)
22190 RESTORE 22205
22200 FOR I=0 TO 15:READ D:F(I)=D:NEXT I
22205 DATA 0,0,0,0,0,1,1,1,0,-1,-1,-1,0,0,0,0
22210 FOR I=0 TO 1:FOR J=0 TO 7
22220 READ D:S(I,J)=D:NEXT J:NEXT I
22230 DATA 0,1,1,1,0,-1,-1,-1
22240 DATA -1,-1,0,1,1,1,0,-1
22250 FOR I=0 TO 9:READ D:AF(I)=D:NEXT I
22260 DATA 7,0,1,2,3,4,5,6,7,0
23000 GOTO 27000
25000 REM CUSTOM CHARACTER SET
25005 IF PEEK(1536)=154 THEN CHBASE=PEEK(1536)*256:GOTO 25150
25010 CHBASE=(PEEK(742)-4)*256:POKE 742,PEEK(742)-5:POKE 1536,CHBASE/256:POKE 756,CHBASE/256
25080 FOR I=0 TO 511:POKE CHBASE+I,PEEK(57344+I):NEXT I:REM MOVE ROM SET
25120 FOR I=CHBASE+8 TO CHBASE+216:READ D:POKE I,D:NEXT I
25150 GRAPHICS 2+16:POKE 756,CHBASE/256
25160 REM CUSTOM CHARACTER DATA
25170 DATA 0,0,0,0,0,0,0,126
25171 DATA 0,0,0,0,0,0,126,126
25172 DATA 0,0,0,0,0,126,126,126
25173 DATA 0,0,0,0,126,126,126,126
25174 DATA 0,0,0,126,126,126,126,126
25175 DATA 0,0,126,126,126,126,126,126
25176 DATA 0,126,126,126,126,126,126,126
25177 DATA 126,126,126,126,126,126,126,126
25178 DATA 0,0,0,0,0,0,0,0
25180 DATA 40,56,40,146,124,56,124,130
25190 DATA 4,40,37,154,120,118,48,8
25200 DATA 136,80,119,122,119,80,136,0
25210 DATA 8,48,118,120,154,37,40,4
25220 DATA 65,62,28,62,73,20,28,20
25230 DATA 16,12,158,30,89,164,20,32
25240 DATA 0,17,10,238,94,238,10,17
25250 DATA 32,20,164,89,30,110,12,16
25280 DATA 0,127,68,68,79,124,75,74
25290 DATA 0,255,34,34,255,72,255,0
25300 DATA 0,254,34,34,250,30,234,74
25310 DATA 74,74,78,74,122,74,78,122
25320 DATA 74,202,46,26,250,18,254,0
25330 DATA 74,75,122,76,79,72,127,0
25340 DATA 108,84,254,68,124,126,219,215
25350 DATA 12,24,48,113,127,63,99,0
25360 DATA 12,138,207,252,254,124,40,108
25370 DATA 0,69,213,247,127,62,0,0
26000 REM DRAW ARENA
26005 POKE 708,150:POKE 709,200:POKE 710,240:POKE 711,208:POKE 712,2:B1=8:B2=8
26010 COLOR 146:PLOT 1,0:COLOR 147:DRAWTO 17,0:COLOR 148:PLOT 18,0:COLOR 149:DRAWTO 18,10
26020 COLOR 150:PLOT 18,11:COLOR 147:DRAWTO 2,11
26030 COLOR 151:PLOT 1,11:COLOR 149:DRAWTO 1,1
26040 COLOR 8:PLOT 0,11:COLOR 40:PLOT 19,11
26050 COLOR 168:PLOT 0,10:DRAWTO 0,0:PLOT 19,10:DRAWTO 19,0
26060 X1=5:Y1=5:X2=14:Y2=5:COLOR 10:PLOT X1,Y1:COLOR 42:PLOT X2,Y2:GOTO 5000
27000 REM TITLE SCREEN
27010 GRAPHICS 2+16:POKE 708,48:T=5
27011 SOUND 0,250,10,10:SOUND 1,251,10,10:SOUND 2,252,10,10:K=4
27020 FOR X=1 TO 18:COLOR 42:PLOT X,0:DRAWTO 19-X,11:POKE 710,PEEK(53770)
27025 POSITION 3,5:? #6;"{inv}VAMPIRE{/inv} {inv} RATS!{/inv}":IF NOT STRIG(0) OR NOT STRIG(1) THEN 27100
27030 COLOR 0:PLOT X,0:DRAWTO 19-X,11
27040 NEXT X
27050 FOR Y=1 TO 10:COLOR 42:PLOT 19,Y:DRAWTO 0,11-Y:POKE 710,PEEK(53770)
27052 POKE 53768,K:J=J+1:IF J=40 THEN J=0:K=4*(K<>4)+6*(K<>6)
27055 COLOR 0:PLOT 19,Y:DRAWTO 0,11-Y
27056 POSITION 3,5:? #6;"{inv}VAMPIRE RATS!{/inv}":IF NOT STRIG(0) OR NOT STRIG(1) THEN 27100
27060 NEXT Y:GOTO 27020
27100 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:POKE 710,50:GOTO 25000
27200 RETURN
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: VAMPRAT.BAS.
Credits
- Program listing: Vampire Rats! — program listing (Antic, November 1985 (Vol. 4, No. 7)) — Tom Zarbock
- Picture: The animated title screen, which Antic called worthy of a Grade-B horror movie. — Tom Zarbock (program); screenshot by the site
- Antic, November 1985 - Vol. 4 No. 7: scan of the printed magazine, PDF page 49 (article) — Internet Archive, 1985
- Antic disk, November 1985 - Vol. 4 No. 7: VAMPRAT.BAS (detokenized listing) — Tom Zarbock, 1985
