Bomb Squad
- Type
- Game
- Category
- Jetpack arcade game
- Author
- Paul Tupaczewski
- Published in
- Antic, June 1986 (Vol. 5, No. 2)
- Year
- 1986
- Language
- Atari BASIC (with machine-language helpers)
- Requirements
- 32K RAM with cassette or 48K with disk, Atari BASIC, joystick in port 1
About the program
"It's not just a job—it's an adventure. That's what they said when you enlisted in the Interplanetary Bomb Squad." As the Detonator, you jetpack through an endless labyrinth of weapon stores buried under the frozen crust of planet Htrae. Red bombs sit on girders, and you defuse them by landing on the girders, gently. In your way are whirling robot guards, Evil Eye (a rotating green thing that keeps trying to run you down), Puff the smiling red helium balloon and Buggo, a white rabbit who wanders left and right. Touch any of them and you lose a life. Antic admitted it never got past level two of the ten.
This was Paul Tupaczewski's first program in Antic. The magazine pointed out that the jetpack handles like the lander in its March 1986 Game of the Month. You push the stick the way you want to go. There's no downward thrust, so you have to let Htrae's weak gravity bring you down onto a girder. The green spires round the border only slow you down.
Typing it in
Lines 25 and 1080 are the hard ones. Line 25 builds the logo from inverse characters. Line 1080 holds a short machine-language transfer routine (XFR$), written with inverse and control characters: {inv}…{/inv} means press the Atari key before and after, {CTRL-E} means hold CTRL and press E, and {CTRL-,}/{CTRL-.} are CTRL with comma and full stop. The magazine also printed a second listing that wrote just those two lines to a file, LINES.LST, for anyone who had trouble, to be merged with ENTER "D:LINES.LST". That helper isn't on the disk and isn't needed if you type the lines as shown here. Other lines have inverse words only. TYPO II codes were printed for checking.
How to play
RUN the program. It takes about 30 seconds to set up before the logo rolls onto the screen. Press START or the joystick button. Every so often a mysterious symbol appears, among them:
- Crystal: all enemies freeze for a few seconds, but they're still deadly to touch.
- Snowflake: the enemies freeze again, and touching one now earns 500 points and sends it to the top of the screen.
Lose three lives and the Detonator is blasted. An extra life comes every 10,000 points.
How it works
- A general player mover. Line 915 reads 100 bytes of machine code into
PMMOV$. Every sprite on screen (your jetpack man, the spinning guard, the enemies and the explosion frames) is drawn by one call:USR(MOVX,player,PMB,ADR(shape$),X,Y,height). The shapes are kept in strings such asMAN$,BALL$andBOOM$, and animation just means passing a different slice of the string. - Collisions come from the hardware register for player 0 against playfields (53252), which tells the program what kind of scenery you have touched (lines 270–280).
- Numbers as variables.
C0…C12hold the small constants used everywhere, which saves memory in a large program. - Each room is drawn with
PLOT/DRAWTOin GRAPHICS 17, with some display-list rows changed to mode 7 (line 65).
Changes from the published listing
One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds a command called MOVE, so it rejected the published lines that use that word as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.
| Published | Now | Lines |
|---|---|---|
MOVE |
MOVX |
14 lines (260–915) |
Listing
2 REM BOMB SQUAD
3 REM BY PAUL TUPACZEWSKI
4 REM (c) 1982, ANTIC PUBLISHING
10 POKE 106,PEEK(740)
20 DIM EX$(4):EX$="*+, "
25 DIM BSM$(40):BSM$="{inv}_{/inv}":BSM$(40)="{inv}_{/inv}":BSM$(2)=BSM$:BSM$(7,14)="{inv};<=>?[\]{/inv}"
30 DIM PS1$(30),PS2$(30),PS3$(30),PS4$(30),STOR$(12),LIN(15)
32 RESTORE 35:FOR R=1 TO 15:READ A:LIN(R)=A:NEXT R
35 DATA 0,0,0,0,345,345,345,0,360,360,360,0,385,380,385
40 GOSUB 1070
45 POKE 710,0:GOSUB 915:POKE 559,34
50 GOSUB 875
55 LV=C3:SC=C0:RD=C1:BOMBS=C0:BONUS=C1:EXLV=10000
60 BN=C0:FRZ=C0:SQU=C0
65 GRAPHICS 17:DL=PEEK(560)+PEEK(561)*256+C4:FOR R=DL+C3 TO DL+12:POKE R,7:NEXT R:GOSUB 755:POKE 77,C0:SA=C1
70 POKE 756,ST/256:POKE 710,150:POKE 709,196
75 POSITION C1,C0:? #6;" {inv}SCORE{/inv} (1&) {inv}BONUS{/inv}"
80 POSITION C1,12:? #6;" {inv}HIGH{/inv} {inv}ROUND{/inv} {inv}LIVES{/inv}"
85 POSITION C1,C1:? #6;SC:POSITION C1,13:? #6;HS:POSITION 11,13:? #6;RD:POSITION 16,13
90 FOR R=C1 TO LV:? #6;CHR$(C5);:NEXT R:POSITION 16,C1:? #6;"0":L=RD:LT=C1
95 IF L>C5 THEN L=L-C5:LT=LT+C1:GOTO 95
100 HARD=LT/C2:ENAD=C1+LT:ENAD1=C1+LT:ON L GOTO 105,135,155,195,220
105 COLOR 36:PLOT C8,6:DRAWTO 12,6:PLOT 13,C4:DRAWTO 17,C4:PLOT 13,C8:DRAWTO 17,C8
110 PLOT 7,C4:DRAWTO C3,C4:PLOT 7,C8:DRAWTO C3,C8:COLOR 7:PLOT C0,11:DRAWTO 19,11:PLOT C0,C10:PLOT 19,C10
115 PLOT C0,C3:PLOT C0,C2:PLOT C1,C2:PLOT 18,C2:PLOT 19,C2:PLOT 19,C3
120 RESTORE 485:GOSUB 465
125 BX=128:BY=30:EX1=60:EY1=90:EX2=190:EY2=80
130 GOTO 240
135 COLOR 36:PLOT C10,11:PLOT C10,C8:PLOT C10,5:PLOT 7,C4:PLOT 7,7:PLOT 7,C10:PLOT 13,C10:PLOT 13,7:PLOT 13,C4
140 COLOR 7:PLOT 9,11:DRAWTO C0,11:DRAWTO C0,C2:PLOT 19,C2:DRAWTO 19,11:DRAWTO 11,11:RESTORE 505:GOSUB 465
145 BX=50:BY=80:EX1=50:EX2=50:EY1=64:EY2=40
150 GOTO 240
155 COLOR 36:PLOT C5,C4:DRAWTO 9,C8:PLOT 11,C8:DRAWTO 15,C4:PLOT C10,C5:PLOT C4,7:PLOT 16,7
160 RESTORE 500:GOSUB 465
165 COLOR 7:PLOT 9,C2:DRAWTO 11,C2:DRAWTO 11,C3:PLOT 9,C3:DRAWTO 9,C2:PLOT 9,C3:DRAWTO 8,C2:PLOT 11,3:DRAWTO 12,2
170 PLOT C3,C5:PLOT C5,C5:PLOT C4,C4:PLOT 15,C5:PLOT 16,C4:PLOT 17,C5
175 COLOR 36:PLOT C0,11:DRAWTO 19,11:COLOR 7:PLOT 0,10:DRAWTO 2,10:PLOT 0,9:PLOT 0,8:PLOT 1,9:PLOT 19,8:PLOT 19,9
180 PLOT 19,10:DRAWTO 17,10:PLOT 18,9
185 BX=200:BY=30:EX1=70:EX2=60:EY2=64:EY1=40
190 GOTO 240
195 COLOR 36:PLOT C1,11:DRAWTO 18,11:PLOT C1,C4:DRAWTO 18,C4:PLOT C4,C8:PLOT 16,C8:PLOT 8,C8:PLOT 12,C8
200 COLOR 7:PLOT 10,C5:DRAWTO 10,9:PLOT C3,C5:DRAWTO C0,10:PLOT 17,C5:DRAWTO 19,10:PLOT C4,C5:PLOT C3,6:PLOT C5,6
205 PLOT 16,C5:PLOT 15,6:PLOT 17,6
210 RESTORE 510:GOSUB 465:BX=60:BY=60:EX1=128:EX2=115:EY1=64:EY2=20
215 GOTO 240
220 COLOR 7:FOR R=C1 TO 19 STEP C2:FOR T=C3 TO 9 STEP C3:PLOT R,T:NEXT T:NEXT R
225 COLOR 36:FOR R=C2 TO 18 STEP C2:FOR T=C5 TO 11 STEP C3:PLOT R,T:NEXT T:NEXT R
230 RESTORE 515:GOSUB 465
235 BX=128:BY=64:EX1=50:EX2=200:EY1=25:EY2=EY1
240 GOSUB 825
245 X=128:Y=83:POKE 704,72:POKE 706,156:POKE 707,82
250 LR=C0:UPDN=C0:STOR$=MAN$(C1,C12)
255 POKE 705,196:BAL=C1:LFTRGT=C0:BN=C0:FRZ=C0:WT1=C0:WT2=C0:WT3=C0:SQU=C0
260 A=USR(MOVX,C0,PMB,ADR(STOR$),X,Y,C12)
265 POKE 53278,C1:IF SC>=EXLV THEN EXLV=EXLV+10000:LV=LV+(LV<>3):POSITION 15+LV,13:? #6;CHR$(5)
270 IF PEEK(53252)=C8 THEN GOSUB 700
275 IF PEEK(53252)=C2 THEN LR=INT(RND(0)*C3)-C1:UPDN=-INT(RND(0)*C2)
280 IF PEEK(53252)=C1 THEN GOSUB 620
285 IF SQU=C3 THEN SOUND C1,WT3,10,C4:WT3=WT3-7.5:IF WT3<=C0 THEN SOUND C1,C0,C0,C0:SQU=C0
290 IF FRZ=C3 THEN SOUND C2,100-WT2+100*(WT2/C2=INT(WT2/C2)),10,C4:WT2=WT2+C1:IF WT2=30 THEN FRZ=C0:SOUND 2,0,0,0
295 IF PEEK(53279)=6 THEN GOSUB 760:GOTO 50
300 IF PEEK(764)<>33 THEN 320
305 POKE 764,255
310 IF PEEK(764)<>33 THEN 310
315 POKE 764,255
320 A=USR(MOVX,C1,PMB,ADR(BALL$(SA*C8-7,SA*C8)),BX,BY,C8):SA=SA+C1-7*(SA=C8)
325 A=USR(MOVX,C2,PMB,ADR(EN1$),EX1,EY1,C8)
330 A=USR(MOVX,C3,PMB,ADR(EN2$),EX2,EY2,C8)
335 S=STICK(C0):UPDN=UPDN-(S=14 OR S=10 OR S=6)-(UPDN>C3)+(UPDN<-C3):LFTRGT=(S>C4 AND S<C12)
340 LR=LR+(S=7 OR S=6 OR S=C5)-(S=11 OR S=10 OR S=9)-(LR>5)+(LR<-5):GOTO LIN(S)
345 STOR$=MAN$(25,36):SOUND C0,100,C8,C4:GOTO 405
360 STOR$=MAN$(37,48):SOUND C0,100,C8,C4:GOTO 405
375 SOUND C0,C0,C0,C0:GOTO 405
380 SOUND C0,100,C8,C4:GOSUB 395:GOTO 405
385 SOUND C0,C0,C0,C0:FOR R=C1 TO C2:IF STOR$=MAN$(R*C12+13,R*C12+24) THEN STOR$=MAN$(R*C12-11,R*C12)
390 NEXT R:GOTO 405
395 FOR R=C1 TO C2:IF STOR$=MAN$(R*C12-11,R*C12) THEN STOR$=MAN$(R*C12+13,R*C12+24)
400 NEXT R:RETURN
405 GOSUB 580:X=X+LR:Y=Y+UPDN:UPDN=UPDN+(S<>14 AND S<>C10 AND S<>6)-(UPDN>5):IF Y>91 THEN UPDN=C0:Y=91
410 IF LFTRGT=C0 THEN LR=LR-SGN(LR)
415 LFTRGT=C0:IF RND(C0)>0.99 AND BN<>C2 THEN GOSUB 670
420 WT1=WT1+(BN=C2):IF WT1=45 THEN COLOR 32:PLOT Z1,Z2:BN=C0
425 IF RND(C0)>0.99 AND FRZ=C0 AND SQU=C0 THEN GOSUB 680
430 WT2=WT2+(FRZ=C2):IF WT2=45 THEN COLOR 32:PLOT Z3,Z4:FRZ=C0
435 IF RND(C0)>0.99 AND FRZ=C0 AND SQU=C0 THEN GOSUB 690
440 WT3=WT3+(SQU=C2):IF WT3=40 THEN COLOR 32:PLOT Z5,Z6:SQU=C0
445 X=X-LR*(X<50)-LR*(X>200):Y=Y+6*(Y<9)
450 IF PEEK(53260) THEN 530
460 GOTO 260
465 COLOR 129:DA=C1
470 READ XX,YY:IF XX=-C1 THEN 480
475 PLOT XX,YY:PS1$(DA)=CHR$(XX):PS2$(DA)=CHR$(YY):DA=DA+C1:GOTO 470
480 PS1$(DA)=" ":PS2$(DA)=" ":DA=DA-C1:RETURN
485 DATA 3,3,8,5,13,7,13,3,3,7
490 DATA 7,3,17,3,17,7,7,7,12,5
495 DATA 5,3,5,7,10,5,15,3,15,7,-1,-1
500 DATA 5,3,6,4,7,5,8,6,9,7,11,7,12,6,13,5,14,4,15,3,4,6,16,6,10,4,-1,0
505 DATA 10,10,10,7,10,4,7,3,7,6,7,9,13,9,13,6,13,3,-1,0
510 DATA 2,10,5,10,15,10,18,10,3,3,8,3,12,3,17,3,4,7,16,7,8,7,12,7,-1,0
515 DATA 2,4,6,4,10,4,14,4,18,4
520 DATA 4,7,8,7,12,7,16,7
525 DATA 2,10,6,10,10,10,14,10,18,10,-1,0
530 IF SQU=C3 THEN 565
535 FOR R=C0 TO C3:SOUND R,C0,C0,C0:NEXT R:COLOR 32:PLOT Z1,Z2:PLOT Z3,Z4:PLOT Z5,Z6
540 FOR R=C1 TO C4:A=USR(MOVX,C0,PMB,ADR(BOOM$(R*C12-11,R*C12)),X,Y,C12):SOUND C0,100,C0,16-R*C4
545 POSITION 15+LV,13:? #6;EX$(R,R):A=C1^C1:NEXT R:LV=LV-C1:A=USR(MOVX,C0,PMB,ADR("{CTRL-,}"),C0,C0,C1)
547 GOSUB 1400
550 IF LV THEN FOR R=C1 TO 200:NEXT R:GOTO 240
555 GOSUB 575:POSITION 6,6:? #6;"{inv}game over{/inv}":FOR R=C1 TO 500:NEXT R:IF SC>HS THEN HS=SC
560 GOSUB 760:GOTO 50
565 BX=128:BY=20:EX1=110:EY2=20:EY1=20:EX2=145:SC=SC+500:POSITION C1,C1:? #6;SC
570 FOR R=30 TO 50:FOR T=100 TO C0 STEP -R:SOUND C0,T,C10,C4:NEXT T:NEXT R:GOSUB 575:GOTO 460
575 FOR R=C0 TO C3:A=USR(MOVX,R,PMB,ADR("{CTRL-,}"),C0,C0,C1):NEXT R:RETURN
580 REM MOVE ENEMIES
585 IF FRZ=C3 OR SQU=C3 THEN RETURN
590 BX=BX-HARD*SGN(BX-X):BY=BY-HARD*SGN(BY-Y)
595 EY2=EY2+ENAD:IF EY2>19 AND EY2<90 THEN 605
600 EX2=INT(RND(C0)*140)+50:EY2=EY2-ENAD:ENAD=-ENAD
605 EX1=EX1+ENAD1:IF EX1>50 AND EX1<200 THEN 615
610 EY1=INT(RND(C0)*70)+20:EX1=EX1-ENAD1:ENAD1=-ENAD1
615 RETURN
620 X1=INT((X-48)/C8):Y1=(INT(Y/C8))
625 LOCATE X1,Y1,ZZ:IF ZZ=46 THEN 645
630 IF ZZ=35 THEN SQU=C3:WT3=255:GOTO 660
635 IF ZZ=45 THEN FRZ=C3:WT2=0:GOTO 665
640 RETURN
645 BONUS=BONUS+C1:IF BONUS>9 THEN BONUS=9
650 POSITION C10,C0:? #6;BONUS:COLOR 32:PLOT Z1,Z2:BN=C0
651 FOR R=0 TO 15:SOUND 0,121,10,R:SOUND 1,96,10,15-R:NEXT R
655 RETURN
660 COLOR 32:PLOT Z5,Z6:RETURN
665 COLOR 32:PLOT Z3,Z4:RETURN
670 BN=C2:WT1=C0:Z1=INT(RND(C0)*17)+C2:Z2=INT(RND(C0)*C10)+C2:LOCATE Z1,Z2,ZZ:IF ZZ<>32 THEN 670
675 COLOR 46:PLOT Z1,Z2:RETURN
680 FRZ=C2:WT2=C0:Z3=INT(RND(C0)*17)+C2:Z4=INT(RND(C0)*C10)+C2:LOCATE Z3,Z4,ZZ:IF ZZ<>32 THEN 680
685 COLOR 45:PLOT Z3,Z4:RETURN
690 SQU=C2:WT3=C0:Z5=INT(RND(C0)*17)+C2:Z6=INT(RND(C0)*C10)+C2:LOCATE Z5,Z6,ZZ:IF ZZ<>32 THEN 690
695 COLOR 35:PLOT Z5,Z6:RETURN
700 REM GOT A BOMB!
705 X1=INT((X-48)/C8):Y1=(INT(Y/C8))
707 LOCATE X1,Y1,ZZ:IF ZZ=129 THEN 715
710 X1=X1+1:LOCATE X1,Y1,ZZ:IF ZZ<>129 THEN RETURN
715 FOR R=C1 TO C3:POSITION X1,Y1:? #6;EX$(R,R):SOUND C0,10,8,20-R*5:NEXT R:SOUND 0,0,0,0:POSITION X1,Y1:? #6;" "
720 BOMBS=BOMBS+C1:SC=SC+C10*RD:FOR R=C1 TO DA:IF ASC(PS1$(R,R))=X1 AND ASC(PS2$(R,R))=Y1 THEN 730
725 NEXT R
730 PS3$=PS1$(C1,R):PS3$(R)=PS1$(R+C1):PS4$=PS2$(C1,R):PS4$(R)=PS2$(R+C1):POSITION C1,C1:? #6;SC:POSITION 16,C1
735 ? #6;BOMBS:PS1$=PS3$:PS2$=PS4$:IF PS3$<>" " THEN RETURN
740 GOSUB 765
745 BOMBS=C0:RD=RD+C1:BONUS=C1:GOTO 65
755 PMBASE=INT((PEEK(145)+C3)/C4)*C4:POKE 54279,PMBASE
757 PMB=PMBASE*256:POKE 559,46:POKE 53277,C3:POKE 623,1:RETURN
760 FOR R=C0 TO C3:A=USR(MOVX,R,PMB,ADR("{CTRL-,}"),C0,C0,C1):POKE 704+R,C0:NEXT R:POKE 559,34:POKE 53277,C0:RETURN
765 REM BONUS POINTS
770 GOSUB 760:FOR R=C0 TO C3:SOUND R,C0,C0,C0:NEXT R
775 GRAPHICS C0:POKE 710,C0:POKE 752,C1:POKE 756,ST/256:?
780 COLOR 47:PLOT C8,7:DRAWTO 32,7:DRAWTO 32,17:DRAWTO C8,17:DRAWTO C8,7:POSITION C8,7:? #6;"/"
785 POSITION 15,9:? "YOU GOT ";BOMBS
790 POSITION 17,11:? "BOMBS":GOSUB 815:FOR R=C1 TO 300:NEXT R
795 REM
800 GOSUB 815
805 FOR R=15 TO C0 STEP -C3:SOUND C0,60,C10,R:NEXT R:SC=SC+BONUS*100:BOMBS=BOMBS-C1:IF BOMBS<>C0 THEN 795
810 GOSUB 815:FOR R=C1 TO 300:NEXT R:RETURN
815 POSITION C10,13:? BOMBS;" x ";BONUS*100;" BONUS POINTS "
820 POSITION 14,15:? "SCORE: ";SC:RETURN
825 REM "GO!" SCROLL MESSAGE
827 OL=L*C2
830 POKE 704,OL*16-6:POKE 705,OL*16-6:POKE 706,OL*16-6:POKE 707,OL*16-6:X=48:X1=200:ADD=3.9
835 A=USR(MOVX,C0,PMB,ADR(GO$),X,60,C8):A=USR(MOVX,1,PMB,ADR(GO$(17)),X+C8,60,C8)
840 A=USR(MOVX,C2,PMB,ADR(GO$(9)),X1,60,C8):A=USR(MOVX,C3,PMB,ADR(GO$(25)),X1+C8,60,C8)
845 X=X+ADD:X1=X1-ADD:ADD=ADD-0.1:IF X<124 THEN 835
850 A=USR(MOVX,C0,PMB,ADR(GO$),125,60,C8):A=USR(MOVX,C1,PMB,ADR(GO$(17)),133,60,C8)
855 A=USR(MOVX,C2,PMB,ADR(GO$(9)),125,60,C8):A=USR(MOVX,C3,PMB,ADR(GO$(25)),133,60,C8)
860 FOR R=C1 TO 200:NEXT R:FOR R=PEEK(704) TO PEEK(704)-C10 STEP -C1:POKE 704,R:POKE 705,R:POKE 706,R:POKE 707,R
865 NEXT R
870 FOR R=C0 TO C3:A=USR(MOVX,R,PMB,ADR("{CTRL-,}"),C0,C0,C1):NEXT R:RETURN
875 REM TITLE PAGE
880 GRAPHICS 17:DL=PEEK(560)+PEEK(561)*256+C4:POKE DL+C3,7:POKE 710,70:POKE 711,150:POKE 756,ST/256
885 FOR R=21 TO C1 STEP -C1:POSITION C0,C2:? #6;BSM$(R,R+18):A=COS(C1):NEXT R
890 POSITION 9,C10:? #6;"BY":POSITION C3,C12:? #6;"PAUL TUPACZEWSKI"
895 POSITION 5,17:? #6;"{inv}PRESS{/inv} start":POSITION 7,19:? #6;"{inv}TO PLAY{/inv}"
900 POSITION C1,18:? #6;"{inv}OR JOYSTICK BUTTON{/inv}"
905 IF PEEK(53279)<>6 AND STRIG(C0) THEN 905
910 RETURN
915 DIM PMMOV$(100):MOVX=ADR(PMMOV$):RESTORE 950:C1=1:C2=2:C5=5:C8=8:C10=10:C12=12:C4=4:C0=0:C3=3
920 FOR X=C1 TO C10*C10:READ N:PMMOV$(X)=CHR$(N):NEXT X
925 DIM MAN$(48),BALL$(64):FOR R=C1 TO 48:READ D:MAN$(R)=CHR$(D):NEXT R:FOR R=C1 TO 64:READ D:BALL$(R)=CHR$(D)
930 NEXT R:DIM EN1$(C8),EN2$(C8):FOR R=C1 TO C8:READ D
933 EN1$(R)=CHR$(D):NEXT R:FOR R=C1 TO 8:READ D:EN2$(R)=CHR$(D)
935 NEXT R:DIM GO$(32):FOR R=1 TO 32:READ D:GO$(R)=CHR$(D):NEXT R
940 DIM BOOM$(48):FOR R=1 TO 48:READ D:BOOM$(R)=CHR$(D):NEXT R
945 RETURN
950 DATA 216,104,104,104,133,213,104,24,105,2,133,206,104,133,205,104,133,204,104,133,203,104,104,133,208
955 DATA 104,104,133,209,104,104,24,101,209,133,207,166,213,240,16,165,205,24,105,128,133,205,165,206,105
960 DATA 0,133,206,202,208,240,160,0,162,0,196,209,144,19,196,207,176,15,132,212,138,168,177,203,164
965 DATA 212,145,205,232,169,0,240,4,169,0,145,205,200,192,128,208,224,166,213,165,208,157,0,208,96
970 DATA 24,36,36,24,212,246,219,254,220,28,28,30
975 DATA 24,36,36,24,43,111,219,127,59,56,56,120
980 DATA 24,36,36,24,212,246,219,254,220,188,172,86
985 DATA 24,36,36,24,43,111,219,127,59,61,58,117
990 DATA 60,126,255,63,63,255,126,60
995 DATA 60,126,255,159,159,255,126,60
1000 DATA 60,126,255,207,207,255,126,60
1005 DATA 60,126,255,231,231,255,126,60
1010 DATA 60,126,255,243,243,255,126,60
1015 DATA 60,126,255,249,249,255,126,60
1020 DATA 60,126,255,252,252,255,126,60
1025 DATA 60,126,255,126,126,255,126,60
1030 DATA 66,36,60,90,126,90,102,60
1035 DATA 126,219,255,189,219,102,60,24
1040 DATA 127,0,158,0,146,0,195,0
1045 DATA 0,195,0,158,0,146,0,127
1050 DATA 254,0,73,0,73,0,25,0
1055 DATA 0,25,0,73,0,79,0,254
1060 DATA 255,255,255,255,255,255,255,255,255,255,255,255,0,126,126,126,126,126,126,126,126,126,126,0
1065 DATA 0,0,60,60,60,60,60,60,60,60,0,0,0,0,0,24,24,24,24,24,24,0,0,0
1070 POKE 106,PEEK(106)-5:GRAPHICS 0:CHSET=(PEEK(106)+1)*256
1072 GRAPHICS 2+16:POKE 710,0:POSITION 7,4:? #6;"ANTIC":POSITION 5,5:? #6;"PRESENTS!"
1075 CHI=CHSET/256:ST=CHSET:CLO=0:POKE 203,CLO:POKE 204,CHI
1080 DIM XFR$(28):XFR$="h{inv}){/inv}{CTRL-,}{inv}{CTRL-E}M(){CTRL-.}{CTRL-E}N1M{CTRL-Q}KHPyfLfN%NIdPo{/inv}{CTRL-.}"
1095 XFR=USR(ADR(XFR$)):RESTORE 1110
1100 READ A:IF A=-1 THEN RETURN
1105 FOR Z=0 TO 7:READ J:POKE CHSET+A*8+Z,J:NEXT Z:GOTO 1100
1110 DATA 1,4,8,60,110,94,94,126,60
1115 DATA 3,24,36,90,165,165,90,36,24
1120 DATA 4,238,221,187,119,0,0,0,0
1125 DATA 5,24,36,36,24,126,24,36,102
1130 DATA 6,0,0,102,60,24,60,102,0
1135 DATA 7,16,56,56,124,124,254,16,16
1140 DATA 8,0,56,28,126,28,56,0,0
1145 DATA 9,0,28,56,126,56,28,0,0
1150 DATA 10,0,0,36,24,24,36,0,0
1155 DATA 11,0,74,36,88,26,36,82,0
1160 DATA 12,137,82,36,154,89,36,74,14
1165 DATA 13,0,24,60,102,102,60,24,0
1170 DATA 14,66,195,24,36,36,24,195,66
1175 DATA 15,255,195,195,219,219,195,195,255
1180 DATA 16,0,60,118,118,118,118,60,0
1185 DATA 17,0,28,60,28,28,28,127,0
1190 DATA 18,0,60,110,28,56,112,126,0
1195 DATA 19,0,126,14,28,14,110,60,0
1200 DATA 20,0,14,30,62,110,126,14,0
1205 DATA 21,0,126,112,124,14,110,60,0
1210 DATA 22,0,60,112,124,118,118,60,0
1215 DATA 23,0,126,14,28,56,112,112,0
1220 DATA 24,0,60,118,60,118,118,60,0
1225 DATA 25,0,60,118,62,14,28,120,0
1230 DATA 27,0,240,216,241,219,219,241,0
1235 DATA 28,0,0,0,206,109,109,205,0
1240 DATA 29,0,6,6,231,182,182,183,0
1245 DATA 30,0,7,12,134,195,195,142,0
1250 DATA 31,0,0,0,57,109,109,60,12
1255 DATA 33,0,60,118,118,126,118,118,0
1260 DATA 34,0,124,118,124,118,118,124,0
1265 DATA 35,0,60,118,112,112,118,60,0
1270 DATA 36,0,124,118,118,118,118,124,0
1275 DATA 37,0,126,112,124,112,112,126,0
1280 DATA 38,0,126,112,124,112,112,112,0
1285 DATA 39,0,62,112,112,118,118,62,0
1290 DATA 40,0,118,118,126,118,118,118,0
1295 DATA 41,0,127,28,28,28,28,127,0
1300 DATA 42,0,14,14,14,14,110,60,0
1305 DATA 43,0,118,118,124,124,118,118,0
1310 DATA 44,0,112,112,112,112,112,126,0
1315 DATA 46,0,115,123,127,127,119,115,0
1320 DATA 47,0,60,118,118,118,118,60,0
1325 DATA 48,0,124,118,118,124,112,112,0
1330 DATA 49,0,60,118,118,118,118,59,0
1335 DATA 50,0,124,118,118,124,118,118,0
1340 DATA 51,0,60,112,60,14,14,60,0
1345 DATA 52,0,127,28,28,28,28,28,0
1350 DATA 53,0,118,118,118,118,118,60,0
1355 DATA 54,0,118,118,118,118,60,24,0
1360 DATA 56,0,118,118,60,60,118,118,0
1365 DATA 57,0,118,118,60,24,24,24,0
1370 DATA 58,0,126,14,28,56,112,126,0
1375 DATA 59,0,0,0,179,182,182,227,0
1380 DATA 60,0,3,3,143,219,219,207,0
1385 DATA 61,24,56,48,112,96,0,111,0
1390 DATA -1
1400 IF BX>115 AND BX<140 AND BY>75 THEN BX=128:BY=20
1405 IF EX1>115 AND EX1<140 AND EY1>75 THEN EX1=110:EY1=20
1410 IF EX2>115 AND EX2<140 AND EY2>75 THEN EX2=145:EY2=20
1415 RETURN
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: BOMBSQU.BAS.
Credits
- Program listing: Bomb Squad — program listing (Antic, June 1986 (Vol. 5, No. 2)) — Paul Tupaczewski
- Picture: The title screen, after the Bomb Squad logo has rolled in. — Paul Tupaczewski (program); screenshot by the site
- Antic, June 1986 - Vol. 5 No. 2: scan of the printed magazine, Bomb Squad, by Paul Tupaczewski, pp. 43-44 (listing p. 115) — Paul Tupaczewski, 1986
- Antic disk, June 1986 - Vol. 5 No. 2: BOMBSQU.BAS (detokenized listing) — Paul Tupaczewski, 1986
