Bumblbee
- Type
- Game
- Category
- Flying game (lander-style physics)
- Author
- Eddie Carstens
- Published in
- Antic, August 1986 (Vol. 5, No. 4), Game of the Month
- Year
- 1986
- Language
- Atari BASIC
- Requirements
- Any Atari 8-bit computer, any memory size, Atari BASIC, joystick in port 1; disk or cassette
- Tags
- antic, game-of-the-month, physics, gravity, joystick, graphics-7, mixed-mode, display-list, 1986
About the program
"Part Lunar Lander and part Joust" was Antic's description of its August 1986 Game of the Month. Eddie Carstens came up with it by accident. He was trying to imitate Joust with a single GRAPHICS 7 dot as the rider, decided the dot looked more like a bee, and added food and obstacles.
You're a flower-eating mutant bumblebee, and your goal is simply to stay airborne. Weight is everything. Red flowers are nutritious, worth 10 points each, but every meal adds a gram. Green flowers are toxic. Touching one makes the bee giddy and reverses its direction both ways, which can bounce you into another one. The bee can only carry 10 grams, three to six is the comfortable range, and below three it starves and floats off like a balloon. The top and bottom of the screen bounce you "like a jai alai ball", and you only have three bounces. The sides are flypaper.
Typing it in
Almost everything is plain text. The title screen (lines 2010–2015) has inverse words: {inv} … {/inv} means press the Atari (inverse) key before and after. {DEL LINE} (line 2005) is ESC then SHIFT-DELETE, and {DEL CHAR} (line 340) is ESC then CTRL-DELETE. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.
How to play
OPTION chooses one of five speeds and SELECT one of ten levels of bee metabolism (how fast you lose weight). Press START to fly. The fire button flaps the wings, which holds the bee up like a lander's thrust, and the stick pushes it left and right. Every 50 points earns an extra bounce. The status line shows score, bounces left, the high score and your weight G. The high score is kept in page 6 memory, so it survives a re-RUN.
How it works
- Physics in two lines. Each frame, the weight
Gis added to the vertical velocity unless you're flapping (line 152:YV=YV+G-(NOT STRIG(0))), and the joystick nudges the horizontal velocity. Line 270 takes a little offGevery frame according to the metabolism level, and every red flower adds 0.1 (line 250). This is the same balance as thrust against gravity in a lunar lander. - Collisions with LOCATE. The bee is a single pixel. Line 230 reads the colour under it: colour 3 is a red flower, colour 1 a poisoned green one.
- Mixed-mode screen.
POKE ST+3,66(line 100) changes the first line of the GRAPHICS 7 display list into a GRAPHICS 0 text line with its own screen address. Setting location 87 (the OS's record of the current mode) to 0 before printing, and back to 7 afterwards, lets ordinaryPRINTstatements write the status line.
Listing
10 REM BUMBLBEE
20 REM BY EDDIE CARSTENS
30 REM (c) 1986, ANTIC PUBLISHING
40 HIGH=PEEK(1536)*256+PEEK(1537):SPD=3:GOSUB 2010:GOTO 80
50 RX=INT(RND(0)*15)*10+10:RY=INT(RND(0)*8)*10+10:RETURN
60 PLOT RX,RY:DRAWTO RX+4,RY+4:PLOT RX+4,RY:DRAWTO RX,RY+4:PLOT RX+1,RY:DRAWTO RX+4,RY+3:PLOT RX,RY+1
70 DRAWTO RX+3,RY+4:PLOT RX+3,RY:PLOT RX+4,RY+1:PLOT RX,RY+3:PLOT RX+1,RY+4:COLOR 0:PLOT 0,1:RETURN
80 GRAPHICS 7+16:COLOR 2:PLOT 159,3:DRAWTO 159,95:DRAWTO 0,95:DRAWTO 0,3:FP=0:M=-3:N=15
90 SETCOLOR 2,4,2:SETCOLOR 0,12,8:SETCOLOR 1,0,15
100 ST=PEEK(560)+PEEK(561)*256:POKE ST+3,66
110 POKE 752,1:POKE 87,0:POSITION 1,0:? "SCR BOUNCES 3 HIGH G 4.0";
120 POSITION 27,0:? HIGH*10;:POKE 87,7
130 COLOR 3:GOSUB 50:GOSUB 60
140 G=0.4:X=80:Y=40:XV=0:YV=0
150 S=STICK(0):XC=0:XC=(S>4 AND S<8)-(S>8 AND S<12)
152 IF NOT FP THEN XV=XV+XC:YV=YV+G-( NOT STRIG(0)):GOTO 160
155 IF -XC=FP THEN XV=XV+XC:FP=0
160 PK=PEEK(53279):IF PK=7 THEN 190
165 IF PK=6 THEN 80
170 IF PK=3 OR PK=5 THEN GOSUB 2010:GOTO 80
190 IF NOT STRIG(0) THEN SOUND 0,0,4,4
200 PX=X:PY=Y:X=X+XV:Y=Y+YV:IF Y<1 OR Y>94 THEN 370
210 IF X>158 OR X<1 THEN XV=0:YV=0:COLOR 0:PLOT PX,PY:PX=157*(X>158)+1:FP=SGN(X-2):GOTO 370
230 LOCATE X,Y,C:IF C=1 THEN PSN=8:GOTO 370
240 IF C<>3 THEN 270
250 COLOR 0:GOSUB 60:GOSUB 360:GOSUB 50:COLOR 3:GOSUB 60:G=G+0.1:N=N+1
260 POKE 87,0:POSITION 5,0:? N*10+M*50;:POSITION 19,0:? INT(N/5);" ";:POKE 87,7
270 COLOR 0:PLOT PX,PY:COLOR 2:PLOT X,Y:SOUND 0,0,0,0:G=G-1E-03-LEV*3E-04
280 T=T+1:IF T<50-4*LEV THEN 330
290 QX=RX:QY=RY:Q=0
300 GOSUB 50:LOCATE RX,RY,C:IF C OR ABS(RX-X)<10 OR ABS(RY-Y)<10 THEN 320
310 COLOR 1:GOSUB 60:T=1
320 T=T-1:RX=QX:RY=QY
330 FOR W=1 TO (5-SPD)*7+1:NEXT W
340 COLOR 0:PLOT 0,1:POKE 87,0:POSITION 35,0:? INT(G*100)/10;:IF G<1 THEN ? "{DEL CHAR}";
345 IF PSN THEN PSN=PSN-1:SETCOLOR 0,12,8-PSN
350 POKE 87,7:POKE 77,0:GOTO 150
360 FOR I=120 TO 60 STEP -5:SOUND 0,I,10,15:NEXT I:SOUND 0,0,0,0:RETURN
370 SOUND 0,60,12,10
380 IF N<5 THEN 410
390 N=N-5:M=M+1:X=PX:Y=PY:XV=-XV:YV=-YV
400 COLOR 0:PLOT 0,1:POKE 87,0:POSITION 19,0:? INT(N/5);" ";:POKE 87,7:GOTO 150
410 IF M*5+N>HIGH THEN HIGH=M*5+N:HH=INT(H/256):LL=HIGH-HH*256:POKE 1536,HH:POKE 1537,LL
420 COLOR 2:PLOT 43,40:DRAWTO 36,40:DRAWTO 36,50:DRAWTO 43,50:DRAWTO 43,45:DRAWTO 39,45
430 PLOT 50,40:DRAWTO 46,50:PLOT 50,40:DRAWTO 54,50:PLOT 48,45:DRAWTO 52,45
440 PLOT 56,50:DRAWTO 56,40:DRAWTO 59,45:DRAWTO 62,40:DRAWTO 62,50
450 PLOT 73,40:DRAWTO 66,40:DRAWTO 66,50:DRAWTO 73,50:PLOT 67,45:DRAWTO 70,45
1050 PLOT 86,42:DRAWTO 88,40:DRAWTO 91,40:DRAWTO 93,42:DRAWTO 93,48
1055 DRAWTO 91,50:DRAWTO 88,50:DRAWTO 86,48:DRAWTO 86,43
1060 PLOT 96,40:DRAWTO 100,50:DRAWTO 104,40
1070 PLOT 113,40:DRAWTO 106,40:DRAWTO 106,50:DRAWTO 113,50:PLOT 107,45:DRAWTO 111,45
1080 PLOT 116,40:DRAWTO 124,40:DRAWTO 124,45:DRAWTO 116,45
1085 PLOT 116,40:DRAWTO 116,50:PLOT 120,45:DRAWTO 124,50
1090 COLOR 0:PLOT 124,40:PLOT 124,45:PLOT 0,1
1200 SOUND 0,0,0,0:GOSUB 2000:GOTO 80
2000 POKE 87,0:POSITION 5,0:? N*10+M*50;
2001 POSITION 19,0:? INT(N/5);" ";:POSITION 27,0:? HIGH*10:POSITION 35,0:? INT(G*100)/10
2004 POSITION 0,1:Z=0
2005 Z=Z+1:? "{DEL LINE}";:IF PEEK(53279)=7 AND Z<300 THEN 2005
2006 IF PEEK(53279)=6 THEN RETURN
2010 GRAPHICS 0:SETCOLOR 2,2,8:SETCOLOR 1,0,0:SETCOLOR 4,0,15:POKE 752,1:POSITION 15,0:? "{inv} BUMBLBEE {/inv}"
2011 ? " for ANTIC magazine"
2012 ? " by Eddie Carstens"
2015 POSITION 7,7:? "PRESS {inv}OPTION{/inv} TO SET SPEED.":POSITION 11,8:? "PRESS {inv}START{/inv} TO START."
2020 POSITION 16,11:? "SPEED ";SPD
2025 POSITION 11,14:? "METABOLISM ";LEV+1;" ";
2030 P=PEEK(53279):IF P=7 THEN 2020
2040 SPD=SPD+(P=3):SPD=SPD-(SPD=6)*5:LEV=LEV+(P=5):LEV=LEV-10*(LEV=10)
2050 IF P=6 THEN RETURN
2090 IF PEEK(53279)<>7 THEN 2090
2100 GOTO 2020
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: BUMBLBEE.BAS.
Credits
- Program listing: Bumblbee — program listing (Antic, August 1986 (Vol. 5, No. 4), Game of the Month) — Eddie Carstens
- Picture: The bee is the single dot in the middle, heading for a red flower. — Eddie Carstens (program); screenshot by the site
- Antic, August 1986 - Vol. 5 No. 4: scan of the printed magazine, PDF pages 41-42 (article) — Internet Archive, 1986
- Antic disk, August 1986 - Vol. 5 No. 4: BUMBLBEE.BAS (detokenized listing) — Eddie Carstens, 1986
