The Gantlet
- Type
- Game
- Category
- Puzzle maze / logic game
- Author
- Stephen Groll
- Published in
- Antic, February 1984 (Vol. 2, No. 11), "In the Public Domain"
- Year
- 1984
- Language
- Atari BASIC
- Requirements
- 16K RAM (cassette) or 24K (disk), Atari BASIC
- Tags
- antic, public-domain, puzzle, maze, graphics-3, locate, keyboard, atari-basic
About the program
Stephen Groll, pastor of the First Baptist Church of Sonoma, California, bought an Atari 400 as an educational tool and for his own amusement, and taught himself to program. The Gantlet is a puzzle disguised as a maze game. You must pass through twelve rooms in order. Each room has only one way out, and your job is to find it. There are no enemies and no time limit, just a coloured square and some very strange rooms. Groll's advice was to watch the square closely as it hits walls and other objects, because the way it moves and reacts gives subtle clues.
The game was hard enough that Antic printed hints for every room except the first ("so easy that even the Antic staff figured it out"), to be read one at a time if all else failed. They make it clear that some rooms are traps of the mind. In room two, for example, you must hit the bottom wall twice, go to the top-left box and repeat a sequence before the way out appears.
What you need
Atari BASIC. No joystick is used. The game was published for 16K with cassette or 24K with disk.
Typing it in
Plain ASCII, apart from inverse-video titles ({inv}…{/inv}, Atari key). The REM in line 4 says "FEBUARY", as printed. Each room is a separate block of lines (300, 500, 900, 1000 and so on) with its own special cases, such as IF X=28 AND Y=7 THEN X=19:Y=9. If you mistype one of those coordinates the room won't work properly, and you will never know why, so be careful.
How to play
At the prompt WHICH DIRECTION SHOULD I MOVE? type U, D, L or R and press RETURN. Then type how many steps to take. The square moves one step at a time and stops when it hits something. A rising chirp usually means something has changed. A buzz usually means you hit something you shouldn't have, and the room starts again.
How it works
- Every room is drawn in GRAPHICS 3 (40×20 large pixels) with
PLOTandDRAWTO. The border comes from the subroutine at 19000. - The movement subroutine at 20000 asks for direction and steps, erases the square, moves it, and uses
LOCATEto read the colour of the new position. It returns as soon as the square hits anything (W<>0) or reaches the edge. - The puzzles are in the room code. After each move, each room tests the square's position and the colour it hit, and responds by teleporting it, opening a gap or redrawing walls. That is why the rooms seem to behave so strangely.
TRAP 20000means a mistyped answer just asks the question again.
Listing
1 REM ** THE GANTLET ***
2 REM * BY STEVE GROLL *
3 REM * ANTIC MAGAZINE *
4 REM * FEBUARY, 1984 *
5 REM ******************
10 GRAPHICS 18:POSITION 5,2:? #6;"{inv}THE GANTLET{/inv}":POSITION 10,5:? #6;"BY":POSITION 5,8:? #6;"{inv}steve groll{/inv}"
20 FOR T=1 TO 1000:NEXT T:DIM D$(1):TRAP 20000
50 POKE 20,0:POKE 19,0:POKE 18,0:LC=0:RR=0:UR=0
100 GRAPHICS 3:COLOR 1:GOSUB 19000:COLOR 4:PLOT 39,9:PLOT 39,10
140 FOR L=1 TO 100:XX=(37*RND(1))+1:YY=(17*RND(1))+1:COLOR 3:PLOT XX,YY:NEXT L
160 X=INT(20*RND(1))+1:Y=INT(18*RND(1))+1:COLOR 2:PLOT X,Y:C=2
200 GOSUB 20000:IF W<>0 THEN GOSUB 19200:GOTO 100
300 GRAPHICS 3:COLOR 1:SETCOLOR 0,5,2:GOSUB 19000:X=1:Y=9:G=0
310 COLOR 1:PLOT 1,6:DRAWTO 38,6:PLOT 1,13:DRAWTO 38,13:SETCOLOR 1,2,8
320 PLOT 12,1:DRAWTO 12,18:PLOT 27,1:DRAWTO 27,18:OPN=0
330 COLOR 3:PLOT X,Y:GOSUB 20000:IF W=2 THEN X=33:Y=9:GOTO 397
335 IF Y=13 AND OPN=0 THEN Y=14:GOTO 397
340 IF Y=19 AND W=1 THEN Y=9:OPN=1:GOTO 397
360 IF Y=6 AND OPN=1 THEN X=X+2:Y=4:GOSUB 19100:W=0:IF X=12 OR X=27 THEN X=X+1:GOTO 330
365 IF (X=40 OR X=39) AND Y=4 AND W=0 THEN X=38:Y=7:COLOR 2:PLOT 17,19:DRAWTO 12,19:DRAWTO 12,6:DRAWTO 39,6:G=1
367 IF G=1 THEN DRAWTO 39,19:DRAWTO 21,19:COLOR 0:DRAWTO 20,19:DRAWTO 18,19:G=0:COLOR 2:PLOT X,Y:RET=1
380 IF X=28 AND Y=7 THEN X=19:Y=9:GOTO 397
383 IF X=28 AND Y=12 THEN X=19:Y=17:GOTO 397
385 IF X=38 AND Y=12 THEN X=34:Y=17:GOTO 397
386 IF X=38 AND Y=7 THEN X=33:Y=9:GOTO 397
388 IF W=0 AND Y=19 THEN 500
390 IF W=1 THEN 398
396 GOTO 330
397 GOSUB 19100:GOTO 330
398 GOSUB 19200:GOTO 300
500 GRAPHICS 3:SETCOLOR 1,9,6:SETCOLOR 2,0,0:C=1:COLOR 3:PLOT 38,14:PLOT 38,17:PLOT 36,16:PLOT 36,18:RET=0
510 COLOR 2:GOSUB 19000:Y=1:PLOT 19,9
515 COLOR 1:PLOT X,Y:GOSUB 20000
520 IF X=19 AND Y=9 THEN PLOT 39,16:DRAWTO 39,18:GOSUB 19100:GOTO 515
530 IF W<>0 THEN X=19:GOSUB 19200:GOTO 510
900 GRAPHICS 3:COLOR 2:SETCOLOR 4,4,0:SETCOLOR 1,0,0:GOSUB 19000:X=1
920 COLOR 1:PLOT X,Y:GOSUB 20000:IF Y>0 AND Y<9 AND X=39 THEN 1000
930 GOSUB 19200:X=19:Y=9:GOTO 920
1000 GRAPHICS 3:COLOR 1:Y=2:A=0:B=0:C=39:D=0:RET=0
1010 FOR L=0 TO 19:PLOT A,B:DRAWTO C,D:B=B+1:D=D+1:NEXT L
1020 COLOR 4:PLOT 0,9:DRAWTO 39,9:PLOT 0,10:DRAWTO 39,10:PLOT 19,0:DRAWTO 19,18:PLOT 20,18:DRAWTO 20,0
1030 PLOT 17,7:DRAWTO 22,7:PLOT 17,8:DRAWTO 22,8:PLOT 17,11:DRAWTO 22,11:PLOT 17,12:DRAWTO 22,12
1040 COLOR 3:X=19:Y=9:PLOT X,Y
1045 IF LC=5 AND RR=4 AND UR=1 THEN COLOR 4:PLOT 19,19:PLOT 20,19
1046 IF LC=5 THEN COLOR 1:PLOT 0,9:PLOT 0,10
1047 IF RR=4 THEN COLOR 1:PLOT 39,9:PLOT 39,10
1048 IF UR=1 THEN COLOR 1:PLOT 19,0:PLOT 20,0
1050 GOSUB 20000:IF W=1 THEN COLOR 1:PLOT X,Y:GOSUB 19200:GOTO 1040
1060 IF X=0 THEN 2000
1070 IF X=39 THEN 3000
1080 IF Y=0 THEN 3100
1090 IF Y=19 THEN 3300
2000 GRAPHICS 3:COLOR 1:SETCOLOR 0,4,0:SETCOLOR 4,7,2:SETCOLOR 2,0,0:GOSUB 19000
2010 PLOT 0,13:DRAWTO 38,13:COLOR 0:PLOT 39,9:PLOT 39,10:COLOR 2:PLOT 19,16:X=38:COLOR 3:PLOT X,Y:LC=0
2020 COLOR 2:PLOT 9,7:PLOT 29,7
2030 GOSUB 20000:IF W=1 OR (W=3 AND LC<2) THEN GOSUB 19200:GOTO 1000
2035 IF X=39 THEN 1000
2040 IF (LC=0 OR LC=1) AND W=2 THEN LC=LC+1:COLOR 3:PLOT X,Y:Y=5:PLOT X,Y:GOTO 2090
2050 IF (LC=2 OR LC=3) AND W=3 THEN LC=LC+1
2055 IF LC=3 THEN 2090
2060 IF LC=4 AND W=3 THEN PLOT 19,13:PLOT 20,13:GOTO 2090
2070 COLOR 3:PLOT X,Y:LC=5
2090 GOSUB 19100:GOTO 2030
2586 IF RB=2 AND LB=3 THEN PLOT 18,19:DRAWTO 20,19
3000 GRAPHICS 3:COLOR 1:GOSUB 19000:COLOR 0:PLOT 0,9:PLOT 0,10
3010 COLOR 1:PLOT 0,7:DRAWTO 39,7:COLOR 2:SETCOLOR 1,4,2:PLOT 9,4:PLOT 29,4:PLOT 19,14
3020 X=1:DO=0:RR=0
3030 COLOR 3:PLOT X,Y:GOSUB 20000:IF DO=0 AND X=19 AND Y=14 THEN Y=16:COLOR 1:PLOT O,9:PLOT 0,10:DO=1:GOTO 3095
3040 IF DO=1 AND X=19 AND Y=14 THEN Y=16:PLOT 0,9:PLOT 0,10:DO=0:GOTO 3095
3050 IF DO=1 AND Y=19 THEN Y=1:GOTO 3095
3060 IF Y=0 THEN Y=18:GOTO 3095
3065 IF X=0 AND W=0 THEN 1000
3070 IF W=2 THEN COLOR 3:PLOT X,Y:X=19:RR=RR+1:GOTO 3095
3080 IF W=3 THEN COLOR 1:PLOT X,Y:X=19:RR=RR+1:GOTO 3095
3085 IF W=1 AND Y=4 THEN RR=0
3090 X=19:Y=16:GOSUB 19200:GOTO 3030
3095 GOSUB 19100:GOTO 3030
3100 GRAPHICS 3:COLOR 2:SETCOLOR 1,0,0:SETCOLOR 4,12,2:GOSUB 19000:COLOR 1:PLOT 15,18:DRAWTO 15,11
3110 PLOT 16,13:DRAWTO 23,13:DRAWTO 23,8:PLOT 20,4:DRAWTO 33,4:PLOT 30,5
3120 DRAWTO 30,15:PLOT 31,7:DRAWTO 36,7:PLOT 36,3:DRAWTO 36,9:PLOT 34,18:DRAWTO 34,13:PLOT 26,11:DRAWTO 26,18
3130 PLOT 22,18:DRAWTO 22,16:DRAWTO 18,16:PLOT 25,1:DRAWTO 25,3
3140 PLOT 17,1:DRAWTO 17,8:PLOT 14,16:DRAWTO 9,16:PLOT 11,15:DRAWTO 11,9:PLOT 6,18:DRAWTO 6,14:DRAWTO 3,14
3150 PLOT 1,5:DRAWTO 12,5:DRAWTO 12,2:PLOT 5,1:DRAWTO 5,3:PLOT 16,7:DRAWTO 14,7
3160 PLOT 1,17:PLOT 2,17:PLOT 3,6:DRAWTO 3,10:DRAWTO 7,10:PLOT 8,9:DRAWTO 8,13:PLOT 6,2:DRAWTO 7,2
3170 COLOR 0:PLOT 19,19:PLOT 20,19:COLOR 2:PLOT 2,2:Y=18:COLOR 3:PLOT X,Y:RET=1:SEE=3:UR=0
3172 IF SEE=3 THEN SETCOLOR 0,2,8:SEE=0:FOR T=1 TO 1000:NEXT T:SETCOLOR 0,12,2
3175 GOSUB 20000:IF X=2 AND Y=2 THEN COLOR 0:PLOT X,Y:X=34:Y=2:COLOR 3:PLOT X,Y:GOSUB 19100:SEE=2:W=0:UR=1
3200 SEE=SEE+1:IF W<>0 THEN UR=0:GOSUB 19200:GOTO 1000
3205 IF Y=19 THEN 1000
3210 GOTO 3172
3300 GRAPHICS 3:COLOR 3:SETCOLOR 2,15,4:SETCOLOR 0,0,14:SETCOLOR 1,4,2:GOSUB 19000:PLS=12:SQ=0
3310 Y=1:MM=0:RET=1:C=2
3312 FOR L=1 TO PLS
3315 X1=INT(38*RND(1))+1:Y1=INT(18*RND(1))+1
3320 LOCATE X1,Y1,WW
3330 IF WW<>0 THEN 3315
3340 COLOR 1:PLOT X1,Y1:GOSUB 19400:SQ=SQ+1:NEXT L
3345 IF SQ=0 THEN SQ=4:GOTO 3415
3350 COLOR 2:PLOT X,Y:GOSUB 20000:MM=MM+1
3360 IF W=0 AND SQ<>0 AND MM=2 THEN PLS=1:MM=0:GOTO 3312
3370 IF W=1 THEN GOSUB 19300:SQ=SQ-1:MM=0:GOTO 3345
3380 IF W=3 THEN COLOR 3:PLOT 0,5:PLOT 0,6:X=19:Y=9:PLS=4:GOTO 3312
3390 GOTO 3350
3415 COLOR 2:PLOT X,Y:IF SQ=0 THEN COLOR 0:PLOT 0,17:PLOT 0,18:GOTO 3460
3418 X1=INT(38*RND(1)):Y1=INT(18*RND(1)):MOV=0
3420 LOCATE X1,Y1,W
3430 IF W<>0 THEN 3415
3440 COLOR 1:SETCOLOR 0,4,0:PLOT X1,Y1
3450 FOR LL=1 TO 10:FOR T=1 TO 10:SETCOLOR 0,0,14:NEXT T:FOR T=1 TO 5:SETCOLOR 0,0,0:NEXT T:GOSUB 19500:NEXT LL
3460 GOSUB 20000:MOV=MOV+1:IF W=1 THEN SQ=SQ-1:FOR L=1 TO 6:SETCOLOR 0,0,14:GOSUB 19100
3465 IF W=1 THEN COLOR 1:PLOT X,Y:FOR T=1 TO 20:NEXT T:COLOR 2:PLOT X,Y:FOR T=1 TO 10:NEXT T:NEXT L:GOTO 3415
3470 IF W=3 THEN COLOR 2:X=19:Y=9:PLOT X,Y:GOSUB 19200:MOV=0:GOTO 3460
3475 IF MOV=4 THEN COLOR 0:PLOT X1,Y1:GOTO 3415
3480 IF X=0 THEN 3500
3490 GOTO 3460
3500 GRAPHICS 3:COLOR 2:SETCOLOR 1,6,0:SETCOLOR 4,0,2:SETCOLOR 2,2,6:GOSUB 19000:C=1:RET=0:X=38:OT=0
3510 COLOR 1:SETCOLOR 0,4,0:PLOT X,Y:COLOR 3:UP=1:UPP=1:RB=0:LB=0
3520 PLOT 9,8:DRAWTO 9,10:IF OT=1 THEN 3540
3530 PLOT 29,8:DRAWTO 29,10
3540 IF LB=3 AND RB=2 THEN COLOR 0:PLOT 18,19:DRAWTO 20,19
3542 IF LB>=4 THEN LB=0
3544 IF RB>=3 THEN RB=0
3545 GOSUB 20000:OT=1:IF Y=19 AND W=0 THEN 3700
3550 IF W=3 AND X=9 AND UP=1 THEN COLOR 0:PLOT X,8:DRAWTO X,10:LB=LB+1:COLOR 3:UP=0:GOSUB 3590:GOTO 3540
3560 IF W=3 AND X=29 AND UPP=1 THEN COLOR 0:PLOT X,8:DRAWTO X,10:RB=RB+1:UPP=0:COLOR 3:GOSUB 3600:GOTO 3540
3570 IF W=3 AND X<11 AND UP=0 THEN COLOR 0:GOSUB 3590:COLOR 3:UP=1:GOTO 3520
3580 IF W=3 AND X>27 AND UPP=0 THEN COLOR O:GOSUB 3600:COLOR 3:UPP=1:GOTO 3530
3585 Y=9:GOSUB 19200:GOTO 3500
3590 PLOT 8,9:DRAWTO 10,9:Y=7:COLOR 1:PLOT X,Y:GOSUB 19300:RETURN
3600 PLOT 28,9:DRAWTO 30,9:COLOR 1:Y=7:PLOT X,Y:GOSUB 19300:RETURN
3700 GRAPHICS 3:COLOR 2:SETCOLOR 1,12,0:SETCOLOR 4,15,4:SETCOLOR 2,9,4:SETCOLOR 0,3,0:GOSUB 19000:Y=1:KE=0:C=2
3710 PLOT 8,7:DRAWTO 14,7:DRAWTO 14,13:DRAWTO 8,13:DRAWTO 8,7
3720 PLOT 25,7:DRAWTO 31,7:DRAWTO 31,13:DRAWTO 25,13:DRAWTO 25,7
3730 COLOR 3:PLOT 11,10:PLOT 11,4:COLOR 1:PLOT 28,10:PLOT 28,4
3750 IF KE=4 THEN 3800
3755 COLOR C:PLOT X,Y:GOSUB 20000:IF W=3 THEN C=3:KE=KE+1:GOTO 3795
3760 IF C=3 AND W=2 AND Y=13 THEN Y=14:PLOT 31,10:GOTO 3795
3770 IF W=1 THEN C=1:KE=KE+1:GOTO 3795
3780 IF C=1 AND W=2 AND X=8 THEN X=7:PLOT 14,10:GOTO 3795
3785 IF Y=19 AND W=0 THEN 4000
3790 X=19:Y=10:GOSUB 19200:GOTO 3750
3795 GOSUB 19100:GOTO 3750
3800 PLOT 18,19:DRAWTO 20,19:GOTO 3755
4000 GRAPHICS 3:COLOR 2:SETCOLOR 1,6,4:SETCOLOR 4,0,8:SETCOLOR 2,0,0:GOSUB 19000:Y=1:C=3:HBR=1:XX=19:YY=9
4010 COLOR 3:PLOT 10,8:DRAWTO 10,10:PLOT 30,8:DRAWTO 30,10:COLOR 1:PLOT XX,YY:DRAWTO XX+2,YY
4020 COLOR C:PLOT X,Y:GOSUB 20000:IF W=1 THEN Y=YY-2:COLOR 1:PLOT X,Y:GOSUB 19400:C=1:GOTO 4020
4030 IF X=10 AND C=1 AND W=3 THEN Y=6:C=3:GOTO 4500
4040 IF X=30 AND C=1 AND W=3 THEN Y=6:C=3:GOTO 4600
4045 IF Y=19 AND W=0 THEN 9000
4050 GOSUB 19400:X=20:Y=3:C=3:GOTO 4020
4500 IF HBR=1 OR HBR=2 OR HBR=3 OR HBR=6 OR HBR=9 OR HBR=10 THEN CC=0:GOTO 4800
4510 CC=0:GOTO 4700
4600 IF HBR=4 OR HBR=5 OR HBR=7 OR HBR=8 THEN CC=0:GOTO 4800
4610 CC=0:GOTO 4700
4700 IF YY<=9 THEN YY=10
4705 COLOR CC:PLOT XX,YY:DRAWTO XX+2,YY:IF CC=0 THEN CC=1:YY=YY-1:GOTO 4705
4710 HBR=HBR-1:IF HBR=0 THEN HBR=1
4720 GOSUB 19100:GOTO 4020
4800 COLOR CC:PLOT XX,YY:DRAWTO XX+2,YY:IF CC=0 THEN CC=1:YY=YY+1:GOTO 4800
4810 HBR=HBR+1:GOSUB 19100:GOTO 4020
9000 SEC=((PEEK(18)*256+PEEK(19))*256+PEEK(20))/60
9010 MIN=INT(SEC/60):HR=INT(MIN/60)
10000 GRAPHICS 18:POSITION 1,1:? #6;"congratulations you":POSITION 1,3:? #6;"made it! it took"
10010 POSITION 1,5:? #6;"you:":POSITION 2,7:? #6;"{inv}hrs.{/inv} {inv}min.{/inv} {inv}sec.{/inv}":POSITION 2,8:? #6;HR
10020 POSITION 8,8:? #6;MIN-HR*60:POSITION 14,8:? #6;INT(SEC-MIN*60)
10030 POSITION 4,10:? #6;"PRESS START"
10040 IF PEEK(53279)<>6 THEN 10040
10050 GOTO 50
19000 PLOT 0,0:DRAWTO 39,0:DRAWTO 39,19:DRAWTO 0,19:DRAWTO 0,0:RETURN
19100 FOR T=10 TO 1 STEP -2:SOUND 1,T*5,10,8:NEXT T:SOUND 1,0,0,0:RETURN
19200 FOR T=1 TO 15:SOUND 1,100,12,8:NEXT T:SOUND 1,0,0,0:RETURN
19300 FOR T=200 TO 20 STEP -15:SOUND 1,T,8,8:NEXT T:SOUND 1,0,0,0:RETURN
19400 FOR T=1 TO 3:SOUND 1,20,10,8:NEXT T:SOUND 1,0,0,0:RETURN
19500 FOR T=1 TO 10:SOUND 1,25,12,8:NEXT T:SOUND 1,0,0,0:RETURN
20000 TRAP 20000:? :? "WHICH DIRECTION SHOULD I MOVE";:INPUT D$:? :? "HOW MANY STEPS SHOULD I TAKE";:INPUT S
20040 FOR L=1 TO S:COLOR 0:PLOT X,Y:SOUND 0,10,0,0
20050 IF D$="U" THEN Y=Y-1
20060 IF D$="D" THEN Y=Y+1
20070 IF D$="R" THEN X=X+1
20078 IF D$="L" THEN X=X-1
20090 LOCATE X,Y,W
20095 IF W<>0 THEN RETURN
20097 IF X=39 OR Y=19 OR Y=0 OR X=0 THEN RETURN
30000 COLOR C:PLOT X,Y:SOUND 0,10,0,6:FOR T=1 TO 10:SOUND 0,0,0,0:NEXT T:FOR T=1 TO 15:NEXT T:NEXT L
30010 IF RET=1 THEN RETURN
30020 GOTO 20000
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: GANTLET.BAS.
Credits
- Program listing: The Gantlet — program listing (Antic, February 1984 (Vol. 2, No. 11), "In the Public Domain") — Stephen Groll
- Picture: Room one: the player's square among randomly placed blocks. — Stephen Groll (program); screenshot by the site
- Antic Software Archive — disk files (February 1984 - Vol. 2 No. 11): GANTLET.BAS — Stephen Groll, 1984
- Antic magazine scan (OCR text layer): Antic_Vol_2-11_1984-02_Personal_Finance_text.pdf — Internet Archive
