Secret Agent

Type
Utility
Category
Keyword cipher (encode/decode secret messages)
Author
John T. Smith
Published in
Antic, April 1985 (Vol. 3, No. 12)
Year
1985
Language
Atari BASIC
Requirements
Any Atari 8-bit of any memory size, Atari BASIC; disk drive, cassette or printer optional
Green text screen headed ENCODED MESSAGE, showing MESSAGE: [N-,JIX4(NG$%3QG$V' &N-3MG)'], then MESSAGE COMPLETED and PRESS RETURN TO CONTINUE

About the program

"This BASIC listing turns your Atari into an impressive cryptographic machine," Antic promised in April 1985. Secret Agent is a menu-driven program for encoding and decoding messages with a secret keyword. The article pointed out a practical use too: keeping messages private when you leave them on bulletin boards or electronic mail services. It can also encipher text files already on disk or cassette. The author, John T. Smith, "claims to live in Plymouth, Michigan", the magazine noted, adding that it's a fitting name for a cryptographer.

The article's example is an order to a fleet commander. The two sides have agreed on the keyword HONDA, and the message ATTACK PEARL HARBOR AT DAWN! comes out as a string of letters, digits and symbols. We typed the message into the emulator with the same keyword, leaving off the "!", and the result matched the magazine's printed cipher character for character. You can see it in the screenshot.

Typing it in

The listing is plain Atari BASIC. The only special characters are the inverse-video headings ({inv}…{/inv}: type them with the Atari or inverse key). The magazine's version had TYPO II checksums, which aren't in the disk version shown here.

How to use it

The main menu offers: 1 choose a new keyword, 2 encode, 3 decode, 4 show the current keyword, 5 quit.

  1. Choose 1, give the keyword's length (1–25), then type it one character at a time, pressing RETURN after each.
  2. Choose 2 or 3. Pick the input device (keyboard, disk or cassette), then answer Y or N for each extra output device: disk, printer or cassette. The result always appears on the screen as well.
  3. From the keyboard, type the message (up to 2,000 characters) and press RETURN. The program puts square brackets round it on screen, and DELETE BACK SPACE corrects mistakes.

Messages and keywords can use capital letters, numbers and punctuation, but not lower case, inverse video or control characters. The program simply ignores keys outside that range.

How it works

It's a Vigenère-style cipher worked on ATASCII codes. The allowed characters run from 32 (space) to 90 (Z), 59 symbols in all (LO=31, HI=90 in line 2150). To encode, line 8910 adds the ATASCII value of the next keyword character to the message character. Lines 8950–8970 then subtract 59 until the result falls back inside the range. Decoding subtracts the key instead. For example, A (65) plus H (72) is 137, and 137 − 59 = 78, which is N, the first character of the cipher. The keyword repeats under the message (J cycles from 1 to KEYLIM), so the same letter is enciphered differently depending on where it falls.

Some neat details:

  • Output choices as a product. OUT starts at 1 and is multiplied by 2 for disk, 3 for printer and 4 for cassette. Every combination gives a different number (6 is disk plus printer, 24 is all three), so lines 9170–9540 can tell from a single variable which output routines to run.
  • Big strings. M$, T$ and MSCR$ are filled with blanks by the usual Atari BASIC trick: set the first and last characters, then copy the string onto itself one place along (M$(2)=M$). Long results are shown 500 characters at a time.
  • Disk and cassette input reads one record, up to the first RETURN character, and skips anything outside the allowed range.

Variations to try

Raise HI to 122 so that lower-case letters can be used, and the alphabet grows to 91 symbols. Remember that both sender and receiver need the same version. Or add a menu option that makes up a random keyword.

Listing

100 REM SECRET AGENT
110 REM BY JOHN T. SMITH
120 REM ANTIC MAGAZINE
1000 GOSUB 25000
2000 DIM A$(1),AKEY$(25),DASH$(25),M$(2000),T$(2000),MSCR$(500)
2050 DIM INFILE$(15),OUTFILE$(15),BL$(40),L$(12)
2100 BL$(1)=" ":BL$(40)=BL$:BL$(2)=BL$
2150 LO=31:HI=90
4000 REM ***MAIN MENU***
4050 ? CHR$(125):POKE 710,160:POKE 712,48
4120 ? :? :? "         {inv}  SECRET AGENT {/inv}":? :?
4140 ? "         {inv}    MAIN MENU  {/inv}":? :? :?
4170 ? "MAKE YOUR SELECTION":?
4200 ? "   1--TO SELECT A NEW KEYWORD"
4210 ? "   2--TO ENCODE A MESSAGE"
4220 ? "   3--TO DECODE A MESSAGE"
4230 ? "   4--TO DISPLAY CURRENT KEYWORD"
4240 ? "   5--TO END PROGRAM":?
4300 ? "  ";
4310 TRAP 4300:INPUT CHOICE:TRAP 40000
4320 CHOICE=INT(CHOICE):IF CHOICE<1 OR CHOICE>5 THEN 4300
4360 IF CHOICE=5 THEN END
4370 IF CHOICE=4 THEN GOSUB 12000:GOTO 4050
4390 IF CHOICE=2 OR CHOICE=3 THEN GOSUB 6000:GOTO 4050
4400 IF CHOICE=1 THEN GOSUB 5000:GOTO 4050
5000 REM ***KEYWORD SECTION***
5110 ? CHR$(125):POKE 710,210:POKE 712,130
5115 DASH$(1)="-":DASH$(25)=DASH$:DASH$(2)=DASH$
5120 AKEY$=BL$:A$(1,1)=BL$
5130 ? :? :? "              {inv} KEYWORD {/inv}":? :? :?
5140 ? "LENGTH OF KEYWORD (1 TO 25)";
5145 TRAP 5140:INPUT KEYLIM:TRAP 40000
5150 KEYLIM=INT(KEYLIM):IF KEYLIM<1 OR KEYLIM>25 THEN 5140
5160 DASH$=DASH$(1,KEYLIM)
5190 ? :? :? "ENTER YOUR ";KEYLIM;" CHARACTER KEYWORD"
5200 ? "ONE CHARACTER AT A TIME":? :? :?
5250 FOR J=1 TO KEYLIM
5260 ? "CHARACTER ";J;" :  ";
5270 TRAP 5270:INPUT A$:TRAP 40000
5280 M=ASC(A$)
5290 IF M>HI OR M<=LO THEN POP :GOTO 5400
5300 AKEY$(J,J)=A$
5310 NEXT J
5330 ? :? :? :? :? "YOUR KEYWORD IS: ":?
5335 ? "     ";AKEY$
5340 ? "     ";DASH$
5350 FOR N=1 TO 250:NEXT N:RETURN
5400 ? :? :? "       {inv} INVALID CHARACTER {/inv}":?
5430 ? "KEYWORD CHARACTER ";A$
5440 ? "IS NOT IN THE AUTHORIZED LIST."
5450 ? "PLEASE CHOOSE A NEW KEYWORD."
5460 FOR N=1 TO 300:NEXT N:GOTO 5110
6000 REM ***ENCODING/DECODING SECTION***
6020 ? CHR$(125)
6050 M$(1)="":M$(2000)=M$:M$(2)=M$:T$=M$
6075 L=LEN(AKEY$):IF L<>0 THEN 6190
6090 POKE 710,48:POKE 712,130:POSITION 10,6:PRINT "     {inv} NO KEYWORD FOUND {/inv}"
6100 POSITION 10,10:PRINT "{inv} PLEASE CHOOSE KEYWORD FIRST {/inv}"
6110 FOR N=1 TO 250:NEXT N:RETURN
6190 ? CHR$(125):POKE 710,0:POKE 712,4
6220 ? :? :? :? "           {inv} INPUT/OUTPUT CONTROL {/inv}":? :? :?
6240 ? "SELECT INPUT DEVICE":?
6250 ? "  1--KEYBOARD"
6255 ? "  2--DISK"
6260 ? "  3--CASSETTE":?
6270 ? "  ";
6275 TRAP 6270:INPUT IN:TRAP 40000
6280 IF IN<>1 AND IN<>2 AND IN<>3 THEN 6270
6300 IF IN=1 OR IN=3 THEN 6510
6330 ? CHR$(125):? :? :? "      {inv} DISK INPUT FILE {/inv}":? :?
6340 INFILE$=BL$:L$=BL$
6360 ? :? :? "INPUT FILE NAME:  ";
6370 TRAP 6370:INPUT L$:TRAP 40000
6380 IF L$="" THEN 6340
6390 L=LEN(L$)
6410 ? :? "DISK DRIVE NUMBER:  ";
6420 TRAP 6420:INPUT A$:TRAP 40000
6430 IF A$="" OR A$=" " THEN A$="1"
6440 IF A$<>"1" AND A$<>"2" AND A$<>"3" AND A$<>"4" THEN 6410
6450 INFILE$(1,1)="D":INFILE$(2,2)=A$:INFILE$(3,3)=":":INFILE$(4,L+3)=L$
6490 OPEN #1,4,0,INFILE$
6510 ? CHR$(125):? :? :?
6520 OUT=1
6530 ? "         {inv} INPUT/OUTPUT CONTROL {/inv}":? :?
6540 ? "OUTPUT WILL APPEAR ON THE SCREEN.":? :?
6545 ? "  SELECT ADDITIONAL OUTPUT DEVICES:":?
6550 ? "    DISK (Y/N): ";
6560 TRAP 6550:INPUT A$:TRAP 40000
6565 IF A$="Y" THEN OUT=OUT*2
6570 IF A$<>"Y" AND A$<>"N" THEN 6550
6575 ? :PRINT "    PRINTER (Y/N): ";
6580 TRAP 6575:INPUT A$:TRAP 40000
6585 IF A$="Y" THEN OUT=OUT*3
6590 IF A$<>"Y" AND A$<>"N" THEN 6575
6595 ? :? "    CASSETTE (Y/N): ";
6600 TRAP 6595:INPUT A$:TRAP 40000
6605 IF A$="Y" THEN OUT=OUT*4
6610 IF A$<>"Y" AND A$<>"N" THEN 6595
6620 IF OUT=1 OR OUT=3 OR OUT=4 OR OUT=12 THEN 8020
6660 OUTFILE$=BL$:L$=BL$
6680 ? CHR$(125):? :? :? "      {inv} DISK OUTPUT FILE {/inv}":? :?
6690 ? "OUTPUT FILE NAME:  ";
6700 TRAP 6700:INPUT L$:TRAP 40000
6710 IF L$="" THEN 6660
6720 L=LEN(L$)
6740 ? :? "DISK DRIVE NUMBER:  ";
6750 TRAP 6750:INPUT A$:TRAP 40000
6760 IF A$="" OR A$=" " THEN A$="1"
6770 IF A$<>"1" AND A$<>"2" AND A$<>"3" AND A$<>"4" THEN 6740
6780 OUTFILE$(1,1)="D":OUTFILE$(2,2)=A$:OUTFILE$(3,3)=":":OUTFILE$(4,L+3)=L$
6820 OPEN #2,8,0,OUTFILE$
8000 REM ***ENCIPHERING/DECIPHERING***
8020 ? CHR$(125):POKE 710,192:POKE 712,112:? :?
8050 IF CHOICE=2 THEN ? "            {inv} ENCODING MESSAGE {/inv}"
8060 IF CHOICE=3 THEN ? "            {inv} DECODING MESSAGE {/inv}"
8080 IF IN=2 THEN 8300
8090 IF IN=3 THEN 8400
8110 ? :? :? :? :? "ENTER YOUR MESSAGE."
8120 ? "PRESS {inv} RETURN {/inv}TO END YOUR MESSAGE."
8130 ? :? "     MESSAGE:  [";
8160 OPEN #3,4,0,"K:"
8180 M$=""
8190 GET #3,M
8195 IF M=155 THEN 8280
8200 ML=LEN(M$)
8210 IF M=126 THEN 8250
8215 IF M>HI OR M<=LO THEN 8190
8220 M$(ML+1,ML+1)=CHR$(M)
8230 ? CHR$(M);
8240 GOTO 8190
8250 IF ML>1 THEN M$=M$(1,ML-1)
8260 IF ML=1 THEN M$=""
8265 ? CHR$(M);
8270 GOTO 8190
8280 ? "]":CLOSE #3:GOTO 8700
8300 REM ***DISK INPUT***
8310 M$=""
8320 ? :? :? :? "        {inv} DISK INPUT {/inv}"
8330 GET #1,M
8340 IF M=155 THEN 8380
8345 IF M>HI OR M<=LO THEN 8330
8350 ML=LEN(M$)
8360 M$(ML+1,ML+1)=CHR$(M)
8370 GOTO 8330
8380 CLOSE #1:GOTO 8700
8400 REM ***CASSETTE INPUT***
8430 ? :? :? :? "    {inv} CASSETTE INPUT {/inv}":? :?
8440 ? "PREPARE CASSETTE PLAYER."
8450 ? :? "PRESS {inv} RETURN {/inv} WHEN READY."
8480 OPEN #4,4,0,"C:"
8490 M$=""
8500 GET #4,M
8510 IF M=155 THEN 8560
8520 IF M>HI OR M<=LO THEN 8500
8530 ML=LEN(M$)
8540 M$(ML+1,ML+1)=CHR$(M)
8550 GOTO 8500
8560 CLOSE #4
8690 REM ***TRANSLATION SECTION***
8700 ML=LEN(M$)
8710 IF ML<>0 THEN 8800
8730 ? :? :? :? "    NO MESSAGE"
8740 FOR N=1 TO 250:NEXT N:RETURN
8800 ? :? :POKE 752,1
8840 J=1
8850 FOR I=1 TO ML
8860 M=ASC(M$(I,I))
8880 IF M>HI OR M<=LO THEN INDEX=M:GOTO 8990
8910 IF CHOICE=2 THEN INDEX=M+ASC(AKEY$(J,J))
8930 IF CHOICE=3 THEN INDEX=M-ASC(AKEY$(J,J))+(HI-LO)
8950 IF INDEX>HI THEN INDEX=INDEX-(HI-LO)
8960 IF INDEX>HI THEN INDEX=INDEX-(HI-LO)
8970 IF INDEX<=LO THEN INDEX=INDEX+(HI-LO)
8990 T$(I,I)=CHR$(INDEX)
9000 POSITION 15,20
9020 IF CHOICE=2 THEN ? "{inv} ENCODING {/inv}"
9030 IF CHOICE=3 THEN ? "{inv} DECODING {/inv}"
9050 SOUND 0,0,1,12:FOR N=1 TO 2:NEXT N:SOUND 0,0,0,0
9080 POSITION 15,20:? "{inv}          {/inv}"
9090 IF J>=KEYLIM THEN J=0
9100 J=J+1
9120 NEXT I
9140 POKE 752,0:T$=T$(1,ML)
9170 IF OUT=1 THEN 9700
9180 IF OUT=2 OR OUT=6 THEN 9460
9190 IF OUT=3 THEN 9600
9200 REM ***CASSETTE OUTPUT***
9220 ? CHR$(125):? :? :? "     {inv} CASSETTE OUTPUT {/inv}":? :?
9230 ? "PREPARE CASSETE PLAYER."
9240 ? :? "PRESS {inv} RETURN {/inv} WHEN READY.":? :? :?
9265 POKE 53775,35:POKE 53768,40:POKE 53764,0:POKE 53766,0:POKE 53773,255
9270 OPEN #4,8,0,"C:"
9280 FOR I=1 TO ML
9290 M=ASC(T$(I,I))
9300 PUT #4,M
9310 NEXT I
9320 M=155
9330 PUT #4,M
9350 CLOSE #4
9370 IF OUT=4 THEN 9700
9380 IF OUT=12 THEN 9600
9440 REM ***OUTPUT TO DISK***
9460 ? CHR$(125):? :? :? :? "        {inv} DISK OUTPUT {/inv}"
9465 FOR I=1 TO ML
9470 M=ASC(T$(I,I))
9480 PUT #2,M
9490 NEXT I
9500 M=155
9510 PUT #2,M
9520 CLOSE #2
9540 IF OUT=2 OR OUT=8 THEN 9700
9600 REM ***PRINTER OUTPUT***
9610 LPRINT :LPRINT :LPRINT
9620 IF CHOICE=2 THEN LPRINT "            ENCODED MESSAGE"
9630 IF CHOICE=3 THEN LPRINT "            DECODED MESSAGE"
9650 LPRINT :LPRINT :LPRINT :LPRINT "     MESSAGE:  [";T$;"]"
9700 REM ***SCREEN OUTPUT***
9740 SN=INT(ML/500)+1
9760 FOR I=1 TO SN
9780 MSCR$(1)="":MSCR$(500)=MSCR$:MSCR$(2)=MSCR$
9790 ? CHR$(125):? :? :? :?
9820 IF CHOICE=2 THEN ? "            {inv} ENCODED MESSAGE {/inv}"
9830 IF CHOICE=3 THEN ? "            {inv} DECODED MESSAGE {/inv}":? :? :?
9860 SCREND=I*500
9870 IF ML<SCREND THEN SCREND=ML
9880 MSCR$=T$(1+(I-1)*500,SCREND)
9900 ? "     MESSAGE:  [";MSCR$;"]":? :? :?
9950 IF SCREND>=ML THEN POP :GOTO 10130
9960 ? "PRESS {inv} RETURN {/inv}TO CONTINUE"
9970 TRAP 9970:INPUT A$:TRAP 40000
9990 NEXT I
10130 ? :? :? "          {inv} MESSAGE COMPLETED {/inv}":? :?
10180 ? "PRESS {inv} RETURN {/inv} TO CONTINUE"
10190 TRAP 10190:INPUT A$:TRAP 40000:RETURN
12000 REM ***CURRENT KEYWORD DISPLAY***
12010 ? CHR$(125):DASH$(1)="-":DASH$(25)=DASH$:DASH$(2)=DASH$
12020 L=LEN(AKEY$):IF L<>0 THEN 12130
12040 POKE 710,48:POKE 712,130
12060 POSITION 14,6:? "{inv} NO KEYWORD EXISTS {/inv}"
12080 POSITION 10,10:? "{inv} PLEASE CHOOSE KEYWORD FIRST {/inv}"
12090 FOR N=1 TO 300:NEXT N:RETURN
12130 POKE 710,208:POKE 712,130:DASH$=DASH$(1,KEYLIM)
12160 ? :? :? :? "        {inv} CURRENT KEYWORD {/inv}":? :? :?
12190 ? "YOUR CURRENT KEYWORD IS: ":?
12200 ? "     ";AKEY$
12220 ? "     ";DASH$
12270 ? :? :? :? "PRESS {inv} RETURN {/inv}TO CONTINUE"
12300 TRAP 12300:INPUT A$:TRAP 40000:RETURN
25000 ? CHR$(125):GRAPHICS 2+16
25100 POSITION 5,4:PRINT #6;"SECRET AGENT"
25110 POSITION 7,7:PRINT #6;"{inv}BY{/inv}"
25120 POSITION 7,8:PRINT #6;"{inv}JOHN T. SMITH{/inv}"
25160 FOR N=0 TO 255:SOUND 0,N/2,10,6:NEXT N
25180 FOR N=1 TO 50:SOUND 0,(255-N)/2,10,4:NEXT N
25190 FOR N=0 TO 255:SOUND 0,255-N/2,10,4:NEXT N
25200 FOR N=1 TO 64:SOUND 0,N,10,6:NEXT N
25250 SOUND 0,0,0,0:GRAPHICS 0:RETURN

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: AGENT.BAS.

Credits