Secret Agent (AGENT.BAS)
Secret Agent, game by John T. Smith, 68
Description
Secret Agent, game by John T. Smith, 68
From the Antic disk of April 1985 (Vol. 3 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 8.2 KB
- Dialect
- Atari BASIC
- Lines
- 257
- Variables
A$,AKEY$,M$,T$,MSCR$,INFILE$,OUTFILE$,BL$,L$,LO,HI,OP1,OP2,OP3,OP4,CHOICE,J,M,N,L,IN,OUT,ML,I,INDEX,SN,SCREND,DASH$,Y,KEYLIM
BASIC listing (257 lines)
100 REM SECRET AGENT
110 REM BY JOHN T. SMITH
120 REM ANTIC MAGAZINE
1000 GOSUB 25000
2000 DIM A$(1),AKEY$(25),DASH$(25),M$(2000),T$(2000),MSCR$(500)
2050 DIM INFILE$(15),OUTFILE$(15),BL$(40),L$(12)
2100 BL$(1)=" ":BL$(40)=BL$:BL$(2)=BL$
2150 LO=31:HI=90
4000 REM ***MAIN MENU***
4050 ? CHR$(125):POKE 710,160:POKE 712,48
4120 ? :? :? " SECRET AGENT ":? :?
4140 ? " MAIN MENU ":? :? :?
4170 ? "MAKE YOUR SELECTION":?
4200 ? " 1--TO SELECT A NEW KEYWORD"
4210 ? " 2--TO ENCODE A MESSAGE"
4220 ? " 3--TO DECODE A MESSAGE"
4230 ? " 4--TO DISPLAY CURRENT KEYWORD"
4240 ? " 5--TO END PROGRAM":?
4300 ? " ";
4310 TRAP 4300:INPUT CHOICE:TRAP 40000
4320 CHOICE=INT(CHOICE):IF CHOICE<1 OR CHOICE>5 THEN 4300
4360 IF CHOICE=5 THEN END
4370 IF CHOICE=4 THEN GOSUB 12000:GOTO 4050
4390 IF CHOICE=2 OR CHOICE=3 THEN GOSUB 6000:GOTO 4050
4400 IF CHOICE=1 THEN GOSUB 5000:GOTO 4050
5000 REM ***KEYWORD SECTION***
5110 ? CHR$(125):POKE 710,210:POKE 712,130
5115 DASH$(1)="-":DASH$(25)=DASH$:DASH$(2)=DASH$
5120 AKEY$=BL$:A$(1,1)=BL$
5130 ? :? :? " KEYWORD ":? :? :?
5140 ? "LENGTH OF KEYWORD (1 TO 25)";
5145 TRAP 5140:INPUT KEYLIM:TRAP 40000
5150 KEYLIM=INT(KEYLIM):IF KEYLIM<1 OR KEYLIM>25 THEN 5140
5160 DASH$=DASH$(1,KEYLIM)
5190 ? :? :? "ENTER YOUR ";KEYLIM;" CHARACTER KEYWORD"
5200 ? "ONE CHARACTER AT A TIME":? :? :?
5250 FOR J=1 TO KEYLIM
5260 ? "CHARACTER ";J;" : ";
5270 TRAP 5270:INPUT A$:TRAP 40000
5280 M=ASC(A$)
5290 IF M>HI OR M<=LO THEN POP :GOTO 5400
5300 AKEY$(J,J)=A$
5310 NEXT J
5330 ? :? :? :? :? "YOUR KEYWORD IS: ":?
5335 ? " ";AKEY$
5340 ? " ";DASH$
5350 FOR N=1 TO 250:NEXT N:RETURN
5400 ? :? :? " INVALID CHARACTER ":?
5430 ? "KEYWORD CHARACTER ";A$
5440 ? "IS NOT IN THE AUTHORIZED LIST."
5450 ? "PLEASE CHOOSE A NEW KEYWORD."
5460 FOR N=1 TO 300:NEXT N:GOTO 5110
6000 REM ***ENCODING/DECODING SECTION***
6020 ? CHR$(125)
6050 M$(1)="":M$(2000)=M$:M$(2)=M$:T$=M$
6075 L=LEN(AKEY$):IF L<>0 THEN 6190
6090 POKE 710,48:POKE 712,130:POSITION 10,6:PRINT " NO KEYWORD FOUND "
6100 POSITION 10,10:PRINT " PLEASE CHOOSE KEYWORD FIRST "
6110 FOR N=1 TO 250:NEXT N:RETURN
6190 ? CHR$(125):POKE 710,0:POKE 712,4
6220 ? :? :? :? " INPUT/OUTPUT CONTROL ":? :? :?
6240 ? "SELECT INPUT DEVICE":?
6250 ? " 1--KEYBOARD"
6255 ? " 2--DISK"
6260 ? " 3--CASSETTE":?
6270 ? " ";
6275 TRAP 6270:INPUT IN:TRAP 40000
6280 IF IN<>1 AND IN<>2 AND IN<>3 THEN 6270
6300 IF IN=1 OR IN=3 THEN 6510
6330 ? CHR$(125):? :? :? " DISK INPUT FILE ":? :?
6340 INFILE$=BL$:L$=BL$
6360 ? :? :? "INPUT FILE NAME: ";
6370 TRAP 6370:INPUT L$:TRAP 40000
6380 IF L$="" THEN 6340
6390 L=LEN(L$)
6410 ? :? "DISK DRIVE NUMBER: ";
6420 TRAP 6420:INPUT A$:TRAP 40000
6430 IF A$="" OR A$=" " THEN A$="1"
6440 IF A$<>"1" AND A$<>"2" AND A$<>"3" AND A$<>"4" THEN 6410
6450 INFILE$(1,1)="D":INFILE$(2,2)=A$:INFILE$(3,3)=":":INFILE$(4,L+3)=L$
6490 OPEN #1,4,0,INFILE$
6510 ? CHR$(125):? :? :?
6520 OUT=1
6530 ? " INPUT/OUTPUT CONTROL ":? :?
6540 ? "OUTPUT WILL APPEAR ON THE SCREEN.":? :?
6545 ? " SELECT ADDITIONAL OUTPUT DEVICES:":?
6550 ? " DISK (Y/N): ";
6560 TRAP 6550:INPUT A$:TRAP 40000
6565 IF A$="Y" THEN OUT=OUT*2
6570 IF A$<>"Y" AND A$<>"N" THEN 6550
6575 ? :PRINT " PRINTER (Y/N): ";
6580 TRAP 6575:INPUT A$:TRAP 40000
6585 IF A$="Y" THEN OUT=OUT*3
6590 IF A$<>"Y" AND A$<>"N" THEN 6575
6595 ? :? " CASSETTE (Y/N): ";
6600 TRAP 6595:INPUT A$:TRAP 40000
6605 IF A$="Y" THEN OUT=OUT*4
6610 IF A$<>"Y" AND A$<>"N" THEN 6595
6620 IF OUT=1 OR OUT=3 OR OUT=4 OR OUT=12 THEN 8020
6660 OUTFILE$=BL$:L$=BL$
6680 ? CHR$(125):? :? :? " DISK OUTPUT FILE ":? :?
6690 ? "OUTPUT FILE NAME: ";
6700 TRAP 6700:INPUT L$:TRAP 40000
6710 IF L$="" THEN 6660
6720 L=LEN(L$)
6740 ? :? "DISK DRIVE NUMBER: ";
6750 TRAP 6750:INPUT A$:TRAP 40000
6760 IF A$="" OR A$=" " THEN A$="1"
6770 IF A$<>"1" AND A$<>"2" AND A$<>"3" AND A$<>"4" THEN 6740
6780 OUTFILE$(1,1)="D":OUTFILE$(2,2)=A$:OUTFILE$(3,3)=":":OUTFILE$(4,L+3)=L$
6820 OPEN #2,8,0,OUTFILE$
8000 REM ***ENCIPHERING/DECIPHERING***
8020 ? CHR$(125):POKE 710,192:POKE 712,112:? :?
8050 IF CHOICE=2 THEN ? " ENCODING MESSAGE "
8060 IF CHOICE=3 THEN ? " DECODING MESSAGE "
8080 IF IN=2 THEN 8300
8090 IF IN=3 THEN 8400
8110 ? :? :? :? :? "ENTER YOUR MESSAGE."
8120 ? "PRESS RETURN TO END YOUR MESSAGE."
8130 ? :? " MESSAGE: [";
8160 OPEN #3,4,0,"K:"
8180 M$=""
8190 GET #3,M
8195 IF M=155 THEN 8280
8200 ML=LEN(M$)
8210 IF M=126 THEN 8250
8215 IF M>HI OR M<=LO THEN 8190
8220 M$(ML+1,ML+1)=CHR$(M)
8230 ? CHR$(M);
8240 GOTO 8190
8250 IF ML>1 THEN M$=M$(1,ML-1)
8260 IF ML=1 THEN M$=""
8265 ? CHR$(M);
8270 GOTO 8190
8280 ? "]":CLOSE #3:GOTO 8700
8300 REM ***DISK INPUT***
8310 M$=""
8320 ? :? :? :? " DISK INPUT "
8330 GET #1,M
8340 IF M=155 THEN 8380
8345 IF M>HI OR M<=LO THEN 8330
8350 ML=LEN(M$)
8360 M$(ML+1,ML+1)=CHR$(M)
8370 GOTO 8330
8380 CLOSE #1:GOTO 8700
8400 REM ***CASSETTE INPUT***
8430 ? :? :? :? " CASSETTE INPUT ":? :?
8440 ? "PREPARE CASSETTE PLAYER."
8450 ? :? "PRESS RETURN WHEN READY."
8480 OPEN #4,4,0,"C:"
8490 M$=""
8500 GET #4,M
8510 IF M=155 THEN 8560
8520 IF M>HI OR M<=LO THEN 8500
8530 ML=LEN(M$)
8540 M$(ML+1,ML+1)=CHR$(M)
8550 GOTO 8500
8560 CLOSE #4
8690 REM ***TRANSLATION SECTION***
8700 ML=LEN(M$)
8710 IF ML<>0 THEN 8800
8730 ? :? :? :? " NO MESSAGE"
8740 FOR N=1 TO 250:NEXT N:RETURN
8800 ? :? :POKE 752,1
8840 J=1
8850 FOR I=1 TO ML
8860 M=ASC(M$(I,I))
8880 IF M>HI OR M<=LO THEN INDEX=M:GOTO 8990
8910 IF CHOICE=2 THEN INDEX=M+ASC(AKEY$(J,J))
8930 IF CHOICE=3 THEN INDEX=M-ASC(AKEY$(J,J))+(HI-LO)
8950 IF INDEX>HI THEN INDEX=INDEX-(HI-LO)
8960 IF INDEX>HI THEN INDEX=INDEX-(HI-LO)
8970 IF INDEX<=LO THEN INDEX=INDEX+(HI-LO)
8990 T$(I,I)=CHR$(INDEX)
9000 POSITION 15,20
9020 IF CHOICE=2 THEN ? " ENCODING "
9030 IF CHOICE=3 THEN ? " DECODING "
9050 SOUND 0,0,1,12:FOR N=1 TO 2:NEXT N:SOUND 0,0,0,0
9080 POSITION 15,20:? " "
9090 IF J>=KEYLIM THEN J=0
9100 J=J+1
9120 NEXT I
9140 POKE 752,0:T$=T$(1,ML)
9170 IF OUT=1 THEN 9700
9180 IF OUT=2 OR OUT=6 THEN 9460
9190 IF OUT=3 THEN 9600
9200 REM ***CASSETTE OUTPUT***
9220 ? CHR$(125):? :? :? " CASSETTE OUTPUT ":? :?
9230 ? "PREPARE CASSETE PLAYER."
9240 ? :? "PRESS RETURN WHEN READY.":? :? :?
9265 POKE 53775,35:POKE 53768,40:POKE 53764,0:POKE 53766,0:POKE 53773,255
9270 OPEN #4,8,0,"C:"
9280 FOR I=1 TO ML
9290 M=ASC(T$(I,I))
9300 PUT #4,M
9310 NEXT I
9320 M=155
9330 PUT #4,M
9350 CLOSE #4
9370 IF OUT=4 THEN 9700
9380 IF OUT=12 THEN 9600
9440 REM ***OUTPUT TO DISK***
9460 ? CHR$(125):? :? :? :? " DISK OUTPUT "
9465 FOR I=1 TO ML
9470 M=ASC(T$(I,I))
9480 PUT #2,M
9490 NEXT I
9500 M=155
9510 PUT #2,M
9520 CLOSE #2
9540 IF OUT=2 OR OUT=8 THEN 9700
9600 REM ***PRINTER OUTPUT***
9610 LPRINT :LPRINT :LPRINT
9620 IF CHOICE=2 THEN LPRINT " ENCODED MESSAGE"
9630 IF CHOICE=3 THEN LPRINT " DECODED MESSAGE"
9650 LPRINT :LPRINT :LPRINT :LPRINT " MESSAGE: [";T$;"]"
9700 REM ***SCREEN OUTPUT***
9740 SN=INT(ML/500)+1
9760 FOR I=1 TO SN
9780 MSCR$(1)="":MSCR$(500)=MSCR$:MSCR$(2)=MSCR$
9790 ? CHR$(125):? :? :? :?
9820 IF CHOICE=2 THEN ? " ENCODED MESSAGE "
9830 IF CHOICE=3 THEN ? " DECODED MESSAGE ":? :? :?
9860 SCREND=I*500
9870 IF ML<SCREND THEN SCREND=ML
9880 MSCR$=T$(1+(I-1)*500,SCREND)
9900 ? " MESSAGE: [";MSCR$;"]":? :? :?
9950 IF SCREND>=ML THEN POP :GOTO 10130
9960 ? "PRESS RETURN TO CONTINUE"
9970 TRAP 9970:INPUT A$:TRAP 40000
9990 NEXT I
10130 ? :? :? " MESSAGE COMPLETED ":? :?
10180 ? "PRESS RETURN TO CONTINUE"
10190 TRAP 10190:INPUT A$:TRAP 40000:RETURN
12000 REM ***CURRENT KEYWORD DISPLAY***
12010 ? CHR$(125):DASH$(1)="-":DASH$(25)=DASH$:DASH$(2)=DASH$
12020 L=LEN(AKEY$):IF L<>0 THEN 12130
12040 POKE 710,48:POKE 712,130
12060 POSITION 14,6:? " NO KEYWORD EXISTS "
12080 POSITION 10,10:? " PLEASE CHOOSE KEYWORD FIRST "
12090 FOR N=1 TO 300:NEXT N:RETURN
12130 POKE 710,208:POKE 712,130:DASH$=DASH$(1,KEYLIM)
12160 ? :? :? :? " CURRENT KEYWORD ":? :? :?
12190 ? "YOUR CURRENT KEYWORD IS: ":?
12200 ? " ";AKEY$
12220 ? " ";DASH$
12270 ? :? :? :? "PRESS RETURN TO CONTINUE"
12300 TRAP 12300:INPUT A$:TRAP 40000:RETURN
25000 ? CHR$(125):GRAPHICS 2+16
25100 POSITION 5,4:PRINT #6;"SECRET AGENT"
25110 POSITION 7,7:PRINT #6;"BY"
25120 POSITION 7,8:PRINT #6;"JOHN T. SMITH"
25160 FOR N=0 TO 255:SOUND 0,N/2,10,6:NEXT N
25180 FOR N=1 TO 50:SOUND 0,(255-N)/2,10,4:NEXT N
25190 FOR N=0 TO 255:SOUND 0,255-N/2,10,4:NEXT N
25200 FOR N=1 TO 64:SOUND 0,N,10,6:NEXT N
25250 SOUND 0,0,0,0:GRAPHICS 0:RETURN
