Q.T.

Type
Game
Category
Three-screen arcade game
Author
Brian McWilliams
Published in
Antic, January 1985 (Vol. 3, No. 9)
Year
1985
Language
Atari BASIC (with a short machine-language routine)
Requirements
32K RAM with disk (24K with cassette), Atari BASIC, joystick in port 1
Q.T. title screen in large blocky characters: a red-and-cream bordered frame with ANTIC MAGAZINE PRESENTS, the letters Q.T. made of red blocks, and PROGRAMMED BY BRIAN MCWILLIAMS

About the program

"Meet Q.T., a cute little bird who lives inside a dangerous arcade game." Brian McWilliams was 17 and a senior at Alpena High School in Michigan when Antic printed his game in January 1985. The magazine added that he was working on an action game called "Droids". Q.T. has three different screens, each played at six increasingly difficult levels.

Typing it in

There are no special characters. Everything is plain text, and the redefined characters are all in DATA lines 10080–10180. The magazine asked readers to check the listing with TYPO II and SAVE a backup before running it. When you RUN it, the screen goes blank for about 10 seconds while the character set is built, then the title appears. The article also says to press RESET before running it again. The REM in line 2 says "Antic Magazine June 1984", although the game was printed in January 1985.

How to play

Press the joystick button to start. Your score is at the upper left, lives at the upper right and the bonus objects you've collected at the lower right.

  1. Ice cubes. The screen is crowded with ice blocks. Before the timer runs out, push the four corner blocks into their marked positions. Eat cubes, or kick them against the walls with the button, for points.
  2. Falling objects. Q.T. runs left and right along the bottom, catching things that fall from the top. Every miss brings a snapping jaw closer from the left, and every catch brings the bonus object nearer from the right. Dodge the "birdie-crushing I-beams".
  3. Balloons. Q.T. flies. Press the button to flap, or glide down without it, and pop as many balloons as you can. Each carries an item worth points. Don't glide off the screen or get crushed.

Survive all six levels and you reach the "You Win!" screen.

How it works

  • Machine-code font copy. A 32-byte routine in MOVX$ (DATA 10070–10075) copies 1K of the ROM character set to RAM. Lines 10020–10030 then read redefinitions in groups of one character number plus eight bytes, until TRAP 10060 catches the end of the DATA.
  • Constants as variables. The program uses O (the letter) for 0 and C1 for 1 almost everywhere. Each number in an Atari BASIC line takes seven bytes, but a variable reference takes only one, so this saves a lot of memory in a long program.
  • A high score that survives RUN. Line 7270 stores the score digits in page 6 (from location 1699), which BASIC doesn't clear. Line 20 reads them back, so the "top" score stays until the computer is switched off.
  • Joystick decoding. Line 310 turns the stick value into 1–4 with logical expressions and one ON A GOSUB.

Changes from the published listing

One change, so the program also runs under Altirra BASIC, the free replacement BASIC built into many emulators. Altirra BASIC adds a command called MOVE, so it rejected the published lines that use that word as the start of a variable name. The variable is renamed everywhere in the program. The new name is the same length, so the memory layout is unchanged and the program behaves exactly as published on genuine Atari BASIC. If you type it in from the magazine, the original names work fine on a real Atari.

Published Now Lines
MOVE$ MOVX$ 10, 10010

Listing

1 REM Q.T. BY BRIAN MCWILLIAMS
2 REM ANTIC MAGAZINE JUNE 1984
10 DIM MOVX$(32),A$(5):LIVES=3:OFF=7290:C1=1:GOSUB 10000
20 FOR X=C1 TO PEEK(1699):A$(X,X)=STR$(PEEK(1699+X)):NEXT X:HI=VAL(A$)
50 COLOR 61:PLOT O,C1:DRAWTO 19,C1:PLOT O,21:DRAWTO 19,21
55 PLOT 2,5:DRAWTO 17,5:DRAWTO 17,9:DRAWTO 2,9:DRAWTO 2,5
60 COLOR 162:PLOT O,2:DRAWTO O,20:PLOT 19,2:DRAWTO 19,20:COLOR 34:PLOT 4,2:DRAWTO 4,4:PLOT 15,2:DRAWTO 15,4
70 COLOR 47:PLOT 4,11:DRAWTO 8,11:DRAWTO 8,15:DRAWTO 4,15:DRAWTO 4,11:PLOT 11,11:DRAWTO 15,11:PLOT 13,12
80 DRAWTO 13,15:PLOT 7,14:PLOT 9,16:COLOR 175
85 PLOT 11,15:PLOT 15,15:POSITION 3,6:? #6;"antic magazine":POSITION 6,8
90 ? #6;"PRESENTS":POSITION 3,18:? #6;"programmed  by":POSITION 2,20:? #6;"BRIAN MCWILLIAMS"
100 GOSUB 7000:BRD=BRD+(BRD<3)-2*(BRD=3):BIC=BIC+(BRD=C1):Z=50*BIC:POSITION C1,23:? #6;"top ";HI
105 IF BIC=7 THEN 1800
125 BI=72*(BIC=C1)+74*(BIC=2)+75*(BIC=3)+58*(BIC=4)+86*(BIC=5)+81*(BIC=6):GOSUB 7020:IF BRD=C1 THEN GOSUB 1640
130 GOSUB 7020:COLOR 61:PLOT O,C1:DRAWTO 19,C1:DRAWTO 19,22:DRAWTO O,22:DRAWTO O,C1
140 GOSUB 7100:GOSUB 7110:TIME=750-(BIC*50):NI=10+5*BIC:GOSUB 7130
150 ON BRD GOSUB 200,800,1050
160 GOTO 100
200 COLOR 47:FOR X=C1 TO 75+10*BIC
210 A=INT(18*RND(O))+C1:B=INT(20*RND(O))+2:LOCATE A,B,C:IF C<>32 THEN 210
220 PLOT A,B:NEXT X:FOR X=C1 TO 4
240 A=INT(16*RND(O))+2:B=INT(18*RND(O))+3:LOCATE A,B,C:IF C>36 AND C<41 OR A=9 AND B=9 THEN 240
250 COLOR 36+X:PLOT A,B:NEXT X:BC=42:XP=9:YP=10:GOSUB 7065
300 IF  NOT STRIG(O) THEN GOSUB 460
310 A=STICK(O):A=(A=14 OR A=10 OR A=6)+2*(A=7)+3*(A=13 OR A=9 OR A=5)+4*(A=11):ON A GOSUB 350,420,410,440
320 LOCATE C1,2,UL:LOCATE 18,2,UR:LOCATE 18,21,LR:LOCATE C1,21,LL:IF UL=37 AND UR=38 AND LR=39 AND LL=40 THEN 600
340 GOSUB 7300:POKE 77,O:GOTO 300
350 Y=-C1:X=O
360 LOCATE XP+X,YP+Y,C:IF C=32 THEN GOSUB 7030:RETURN
370 IF C=47 THEN GOSUB 7090:GOSUB 7030:RETURN
380 IF  NOT X THEN IF C>36 AND C<41 OR C=BI THEN 400
390 RETURN
400 LOCATE XP+X*2,YP+Y*2,CC:IF CC=32 THEN GOSUB 7040:GOSUB 7030
405 RETURN
410 Y=C1:X=O:GOTO 360
420 IF BC=43 THEN BC=42:Y=O:X=O:GOSUB 7030:RETURN
430 Y=O:X=C1:GOTO 360
440 IF BC=42 THEN BC=43:Y=O:X=O:GOSUB 7030:RETURN
450 Y=O:X=-C1:GOTO 360
460 C=44*(BC=42)+95*(BC=43):COLOR C:PLOT XP,YP
465 FOR X=85 TO 45 STEP -C1:SOUND O,X,10,10:NEXT X:GOSUB OFF
470 GOSUB 7065:LOCATE XP-(BC=43)+(BC=42),YP,C:IF C=32 OR C=61 THEN RETURN
490 IF BC=42 THEN 520
500 FOR X=XP-C1 TO C1 STEP -C1:LOCATE X-C1,YP,CC:IF CC<>32 THEN GOSUB OFF:RETURN
510 SOUND O,114-X,10,12:COLOR 32:PLOT X,YP:COLOR C:PLOT X-C1,YP:NEXT X:GOSUB OFF:RETURN
520 FOR X=XP+C1 TO 18:LOCATE X+C1,YP,CC:IF CC<>32 THEN GOSUB OFF:RETURN
530 SOUND O,114+X,10,12:COLOR 32:PLOT X,YP:COLOR C:PLOT X+C1,YP:NEXT X:GOSUB OFF:RETURN
600 GOSUB 7150:FOR X=2 TO 21:LOCATE C1,X,C:IF C=32 OR C=42 OR C=43 THEN 620
610 POSITION C1,X:GOSUB 640
620 LOCATE 18,X,C:IF C=32 OR C=42 OR C=43 THEN 650
630 POSITION 18,X:GOSUB 640:GOTO 650
640 ? #6;CHR$(BI+128):GOSUB 7180:RETURN
650 NEXT X:SCORE=SCORE+BONUS+TIME:GOSUB OFF:RETURN
800 COLOR 32:PLOT O,2:PLOT O,3:PLOT 19,2:PLOT 19,3:PLOT 4,22:DRAWTO 15,22:COLOR 61:PLOT O,4:DRAWTO 2,4:PLOT 19,4
810 DRAWTO 17,4:PLOT 3,21:PLOT 16,21:PLOT 3,20:DRAWTO 16,20:COLOR 34:PLOT C1,2:PLOT C1,3
820 PLOT 18,2:PLOT 18,3:PLOT O,5:DRAWTO O,21:PLOT 2,5:DRAWTO 2,21:PLOT 19,5:DRAWTO 19,21:PLOT 17,5:DRAWTO 17,21
830 COLOR 93:PLOT 2,3:COLOR BI+128:PLOT 17,3:NM=3:NH=NM
850 XP=9:YP=19:BC=42:GOSUB 7065
860 FOR XX=C1 TO 11-BIC:A=STICK(O):A=(A>4 AND A<8)+2*(A>8 AND A<12)
865 COLOR 62:PLOT 2,NM:ON A GOSUB 420,440:GOTO 875
870 FOR A=C1 TO 10:NEXT A
875 COLOR 93:PLOT 2,NM:NEXT XX
880 A=INT(4*RND(O))+C1:IC=64*(A=1)+47*(A=2)+35*(A=3)+BI*(A=4):IP=INT(14*RND(O))+3
885 IV=Z*(IC=BI)+50*(IC=64 OR IC=47)
890 FR=(IC=64 OR IC=58 OR IC=72 OR IC=74)+2*(IC=75 OR IC=47)+3*(IC=35 OR IC=86 OR IC=81)
895 A=INT(2*RND(O))+C1:IC=IC+128*(A=2)
900 FOR XX=2 TO 18 STEP FR:COLOR IC:PLOT IP,XX:A=STICK(O):A=(A>4 AND A<8)+2*(A>8 AND A<12)
905 IF  NOT A THEN FOR X=C1 TO 10:NEXT X
907 ON A GOSUB 420,440:COLOR 32:PLOT IP,XX
910 SOUND C1,57+XX,10,9:NEXT XX:SOUND C1,O,O,O:LOCATE IP,19,C:IF C<>32 THEN IF IC=163 OR IC=35 THEN 7190
920 COLOR IC:PLOT IP,18+(C=32):FOR X=C1 TO 5:NEXT X:X=IP-XP:Y=-(C<>32):GOSUB 7090:COLOR 32:PLOT XP+X,YP+Y
925 IF IC=163 OR IC=35 THEN 860
930 IF C=32 THEN 1000
940 COLOR 32:PLOT 17,NH:POSITION 17,NH+C1:? #6;CHR$(BI+128);CHR$(34);" ":COLOR 61:PLOT 17,NH+2:DRAWTO 19,NH+2
950 NH=NH+C1:GOSUB 7170:GOSUB OFF:SCORE=SCORE+IV
960 GOSUB 7100:IF NH<19 THEN 860
970 X=C1:Y=O:FOR XX=XP TO 17:GOSUB 420:NEXT XX:GOSUB 7150:FOR XX=NM TO 18:GOSUB 7160:GOSUB 7180:NEXT XX
980 SCORE=SCORE+BONUS:RETURN
990 GOTO 860
1000 GOSUB 7160:IF NM<19 THEN 860
1020 FOR X=2 TO XP:COLOR 62:PLOT X,19:FOR Y=C1 TO 5:SOUND O,157-X,10,10:NEXT Y:COLOR 93:PLOT X,19:GOSUB OFF
1030 FOR Y=C1 TO 5:NEXT Y:COLOR 32:PLOT X,YP:NEXT X:GOSUB OFF:GOTO 7190
1050 COLOR 32:PLOT C1,22:DRAWTO 18,22:COLOR 61:PLOT C1,4:DRAWTO 4,4:PLOT 15,4:DRAWTO 18,4
1070 XP=4:YP=3:BC=42:GOSUB 7065
1080 IF BLL THEN 1100
1090 FOR XX=C1 TO 11-BIC
1095 IF  NOT NI THEN RETURN
1100 POKE 77,O:GOSUB 7100:IF  NOT STRIG(O) THEN 1500
1105 FOR A=C1 TO 25:NEXT A
1110 B=STICK(O):A=(B>4 AND B<8 AND BC<>92)+2*(B>8 AND B<12 AND BC<>92)+3*(B>4 AND B<8 AND BC=92)
1120 A=A+4*(B>8 AND B<12 AND BC=92):ON A GOSUB 420,440,1550,1530:GOTO 1140
1130 FOR A=C1 TO 15:NEXT A
1140 LOCATE XP,YP+C1,C:IF C=32 AND BC<>92 THEN BC=92:GOSUB 7065
1150 IF C=61 AND BC=92 THEN BC=42*(XP<5)+43*(XP>14):GOSUB 7065
1160 IF C=33 OR C=161 THEN C=92:GOTO 1320
1170 IF BC=92 AND YP=22 THEN 1600
1180 IF STRIG(O) AND BC=92 THEN COLOR 32:PLOT XP,YP:YP=YP+C1:GOSUB 7065
1190 IF  NOT BLL AND XX THEN NEXT XX:XX=O
1200 IF BLL THEN 1240
1210 A=INT(3*RND(O))+C1:IC=35*(A=C1)+63*(A=2)+BI*(A=3):A=INT(2*RND(O))+C1
1220 BLL=33*(A=C1)+161*(A=2):IP=INT(18*RND(O))+C1:IV=10*(IC=35)+50*(IC=63)+Z*(IC=BI)
1230 FR=(IC=35)+2*(IC=63 OR IC=75 OR IC=74 OR IC=72)+3*(IC=58 OR IC=81 OR IC=86):BLLY=20
1235 A=INT(2*RND(O))+C1:IC=IC+128*(A=2)
1240 FOR A=BLLY-C1 TO BLLY-FR STEP -C1:LOCATE IP,A,C:IF C=32 THEN NEXT A
1300 COLOR 32:PLOT IP,BLLY:DRAWTO IP,BLLY+2:BLLY=A+C1:COLOR BLL:PLOT IP,BLLY:COLOR 41:PLOT IP,BLLY+C1:COLOR IC
1310 PLOT IP,BLLY+2:SOUND C1,150+BLLY,10,3:IF C=32 THEN 1080
1320 COLOR 59:PLOT IP,BLLY:FOR X=10 TO O STEP -C1:SOUND C1,56,8,X:NEXT X:SOUND C1,O,O,O:COLOR 32:PLOT IP,BLLY
1325 IF C=92 THEN SCORE=SCORE+IV
1327 BLL=O:NI=NI-C1
1330 COLOR 32:PLOT IP,BLLY+C1:FOR A=BLLY+3 TO 22:LOCATE IP,A,C:IF C=92 THEN COLOR 32:PLOT IP,A-C1:GOTO 1600
1340 COLOR 32:PLOT IP,A-C1:COLOR IC:PLOT IP,A:SOUND O,124+A,10,12:NEXT A:SOUND O,O,O,O
1350 COLOR 32:PLOT IP,A-C1:GOTO 1090
1500 BC=92:GOSUB 7065:FOR X=O TO 10 STEP 2:SOUND 2,150,8,X:NEXT X:COLOR 36:PLOT XP,YP:FOR X=10 TO O STEP -2
1510 SOUND 2,150,8,X:NEXT X:LOCATE XP,YP-C1,C:IF C=32 THEN COLOR C:PLOT XP,YP:YP=YP-C1:GOSUB 7065
1520 SOUND 2,O,O,O:GOTO 1110
1530 X=-C1
1535 LOCATE XP+X,YP,C:IF C<>32 THEN X=O
1540 COLOR 32:PLOT XP,YP:XP=XP+X:GOSUB 7065:X=O:RETURN
1550 X=C1:GOTO 1535
1600 FOR X=O TO 2:SOUND X,O,O,O:NEXT X:COLOR 32:PLOT XP,YP
1605 COLOR 61:PLOT 8,22:DRAWTO 10,22:COLOR 41:PLOT 8,21:PLOT 8,20:PLOT 10,21:PLOT 10,20:COLOR 161:PLOT 8,19
1610 PLOT 10,19:COLOR 45:PLOT 9,21:FOR X=21 TO 15 STEP -C1:COLOR 32:PLOT 8,X+C1:DRAWTO 10,X+C1
1620 COLOR 61:PLOT 8,X:DRAWTO 10,X:COLOR 45:PLOT 9,X-C1:COLOR 41:PLOT 8,X-2:PLOT 10,X-2:COLOR 161:PLOT 8,X-3
1630 PLOT 10,X-3:FOR Y=C1 TO 10:NEXT Y:NEXT X:XP=9:YP=X:GOTO 7190
1640 YP=13:BC=42
1645 GOSUB 7020:COLOR 32:PLOT C1,22:DRAWTO 18,22:COLOR BI
1647 PLOT 13+BIC,14:COLOR 42:YP=13:PLOT 5+BIC,YP:RESTORE 1700
1650 FOR XP=6+BIC TO 13+BIC:COLOR 32:PLOT XP-C1,13:GOSUB 7065:READ A,B:SOUND O,A,10,10:FOR X=C1 TO B:NEXT X
1660 FOR X=10 TO O STEP -C1:SOUND O,A,10,X:NEXT X:NEXT XP:XP=XP-C1:FOR XX=C1 TO 9:GOSUB 410:NEXT XX
1670 BC=92:FOR YP=21 TO 8 STEP -C1:COLOR 32:PLOT XP,YP+C1:GOSUB 7065:READ A:SOUND O,A,10,10:FOR X=C1 TO 2:NEXT X
1680 COLOR 36:PLOT XP,YP:FOR X=10 TO O STEP -C1:SOUND O,A,10,X:NEXT X:NEXT YP:RETURN
1700 DATA 68,50,102,50,76,50,114,100,114,50,76,50,68,50,85,100
1710 DATA 47,243,53,243,96,243,60,243,53,243,47,243,60,243
1800 GOSUB 7020:COLOR 34:PLOT 6,C1:DRAWTO 6,9:PLOT 13,C1:DRAWTO 13,9:COLOR 61:PLOT 5,10:DRAWTO 14,10
1810 DRAWTO 14,12:DRAWTO 5,12:DRAWTO 5,10:POSITION 6,11:? #6;"you win^":POSITION 2,15:? #6;"CONGRATULATIONS^"
1820 IF SCORE>HI THEN 7270
1830 GOTO 7280
1840 CLR :END
7000 POSITION 3,O:? #6;"PRESS  TRIGGER"
7005 POKE 77,O:IF STRIG(O) THEN 7005
7010 RETURN
7020 COLOR 32:FOR X=O TO 22:PLOT O,X:DRAWTO 19,X:NEXT X:RETURN
7030 COLOR 32:PLOT XP,YP:XP=XP+X:YP=YP+Y:GOSUB 7065:SOUND O,57,10,10:GOSUB OFF:RETURN
7040 COLOR 32:PLOT XP+X,YP+Y:COLOR C:PLOT XP+X*2,YP+Y*2:SOUND O,217,10,10:GOSUB OFF:RETURN
7065 COLOR BC:PLOT XP,YP:RETURN
7090 COLOR 59:PLOT XP+X,YP+Y:FOR A=C1 TO 2:SOUND O,68,10,4:NEXT A:FOR A=C1 TO 2:SOUND O,85,10,4:NEXT A
7095 GOSUB OFF:SCORE=SCORE+10*(BRD=C1):RETURN
7100 POSITION 2,C1:? #6;SCORE;"=":RETURN
7110 COLOR 170:IF LIVES THEN FOR X=C1 TO LIVES:PLOT 14+X,C1:NEXT X:COLOR 61:PLOT 14+LIVES+C1,C1:RETURN
7120 COLOR 61:PLOT 15,C1:DRAWTO 17,C1:RETURN
7130 IF BRD=C1 THEN POSITION 9,C1:? #6;TIME;"="
7140 RETURN
7150 BONUS=O:POSITION 5,11:? #6;"bonus x ";Z:RETURN
7160 COLOR 32:PLOT 2,NM:POSITION O,NM+C1:? #6;" ";CHR$(34);"]":COLOR 61:PLOT O,NM+2:DRAWTO 2,NM+2:NM=NM+C1
7170 FOR X=C1 TO 2:SOUND O,128,10,15:NEXT X:GOSUB OFF:RETURN
7180 SOUND O,X+124,10,10:BONUS=BONUS+Z:POSITION 8,13:? #6;BONUS:GOSUB OFF:FOR A=C1 TO 25:NEXT A:RETURN
7190 COLOR 45:PLOT XP,YP:RESTORE 7250:FOR X=C1 TO 5:READ A,B:SOUND O,A,12,10:FOR Y=C1 TO B:NEXT Y
7200 FOR Y=10 TO O STEP -C1:SOUND O,A,12,Y:NEXT Y:NEXT X:LIVES=LIVES-C1:IF  NOT LIVES THEN 7260
7210 COLOR 32:PLOT XP,YP:GOSUB 7110:ON BRD GOTO 7230,7220,7230
7220 IF NM<19 THEN 850
7230 GOSUB 7020:GOTO 130
7250 DATA 85,85,76,25,72,25,85,50,60,100
7260 GOSUB 7120:POSITION 4,10:? #6;"end of game":IF SCORE<=HI THEN 7280
7270 A$=STR$(SCORE):POKE 1699,LEN(A$):FOR X=C1 TO LEN(A$):POKE 1699+X,VAL(A$(X,X)):NEXT X
7280 GOSUB 7000:GOTO 1840
7290 SOUND O,O,O,O:RETURN
7300 TIME=TIME-C1:GOSUB 7130:GOSUB 7100:IF  NOT TIME THEN POP :GOTO 7190
7310 RETURN
10000 RESTORE 10061:C=PEEK(106)-5:BASE=(C+C1)*256:POKE 559,O:POKE 106,C:GRAPHICS 17
10010 FOR X=C1 TO 32:READ Y:MOVX$(X)=CHR$(Y):NEXT X:JUNK=USR(ADR(MOVX$),BASE,57344):POKE 756,BASE/256
10020 TRAP 10060:READ INSET:FOR X=BASE+INSET*8 TO BASE+INSET*8+7
10030 READ CHANGE:POKE X,CHANGE:NEXT X:GOTO 10020
10060 POKE 559,254:RETURN
10070 DATA 104,104,133,215,104,133,214,104,133,213,104,133,212,162,4,160,0,177,212,145,214,200,208,249
10075 DATA 230,213,230,215,202,208,240,96
10080 DATA 29,170,85,170,85,170,85,170,85,2,24,126,90,66,66,90,126,24,15,0,126,126,126,126,126,126,0
10090 DATA 10,8,20,24,56,56,112,96,152,5,0,126,70,94,94,126,126,0,6,0,126,98,122,122,126,126,0
10100 DATA 7,0,126,126,122,122,98,126,0,8,0,126,126,94,94,70,126,0,12,8,20,24,58,62,112,96,152
10110 DATA 13,160,0,12,68,190,127,0,0,11,16,40,24,28,28,14,6,25,63,16,40,24,92,124,14,6,25
10120 DATA 27,146,84,0,198,0,84,146,0,26,254,254,170,138,170,254,254,0,40,124,68,108,56,16,24,16,24
10130 DATA 61,0,0,48,94,116,106,62,0,30,0,12,56,80,96,74,62,0,32,24,60,60,126,126,126,126,60
10140 DATA 3,0,255,126,126,126,255,0,0
10150 DATA 1,124,246,250,254,254,124,56,16,9,16,16,16,16,16,16,16,16,31,104,88,104,92,116,56,0,0
10160 DATA 60,0,195,36,24,24,36,0,0,4,0,0,0,126,153,36,0,0,42,24,60,36,36,126,126,126,126
10170 DATA 43,16,56,124,124,124,124,254,8,49,112,64,110,72,126,2,14,0,54,60,126,90,126,126,126,84,0
10180 DATA 62,12,12,24,24,48,48,0,48

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: QT.BAS.

Credits