Math Wizard

Type
Education
Category
Arcade-style arithmetic drill
Author
Matthew Ratcliff
Published in
Antic, April 1984 (Vol. 3, No. 1), Education
Year
1984
Language
Atari BASIC
Requirements
16K RAM (24K with disk), joystick in port 1, Atari BASIC
A GRAPHICS 8 screen in grey artifact stripes with an ADDITION header, an answer box showing 18, six columns of addition problems with their answers, a REPEAT ROUND message, and round and score counters down the right edge

About the program

Matthew Ratcliff, an electrical engineer and microcomputer enthusiast who contributed several programs to Antic, called Math Wizard "an educational shoot-'em-up". It drills addition, subtraction and multiplication in an arcade format for children or adults. Each round, six problems scroll slowly down the screen toward your "number blaster" (a flashing cursor) at the bottom. An answer box at the top shows a number. Slide under the problem that gives that answer and fire. A correct hit blasts the problem back to the top with its answer shown beneath it, and a new answer appears. If several problems share the answer, pick the nearest one to save time and earn a bigger speed bonus. Problems that reach the bottom go back up with their answers shown.

What you need

A joystick in port 1, 16K (24K with disk) and Atari BASIC.

Typing it in

Lines 20–80 are two machine-language routines stored in strings, full of inverse video ({inv}…{/inv}, Atari key), control characters ({CTRL-letter}, hold CTRL) and a few {BELL} (ESC then CTRL-2) and {TAB} (ESC then TAB) characters. The article singled out the 17th character of line 40, also found in line 60: an inverse underline, made with the Atari key on, SHIFT held, and the minus key. Check your typing with TYPO before running, or the program may lock up.

How to play

The opening menu sets the game. Move the stick up and down to choose an option, and left or right to change it. Hold the stick and the values change faster and faster. The options are the minimum and maximum starting numbers (at least five apart), the % correct needed to advance, the difficulty increment (how much the maximum grows each round), rounds per game and problem type. Press fire to start. Reach the required percentage and the next round uses bigger numbers. Miss it and you repeat the round. Your score is the correct answers plus bonuses, minus the value of each wrong answer.

How it works

  • GRAFTEXT (GTX$, 333 bytes) prints text on a GRAPHICS 4, 6 or 8 screen: A=USR(GX,ADR(B$),LEN(B$),X,Y). You can leave out Y, or X and Y, to print at the current cursor, and it safely ignores extra parameters. Ratcliff documented it for use in your own programs.
  • CX$ (55 bytes) fills a GRAPHICS 8 screen (7680 bytes) with one byte value very quickly: A=USR(ADR(CX$),165). On a TV, the dot patterns of GRAPHICS 8 produce artifact colours, so different values give different multicoloured backgrounds. Leave out the value for random noise.
  • The scrolling problems and the cursor are then just BASIC loops that draw and redraw text with GRAFTEXT.

Listing

5 REM MATH WIZARD
6 REM BY MATHEW RATCLIFF
7 REM ANTIC MAGAZINE APRIL 1984
10 DIM GTX$(333),B$(40),CX$(55):CX=ADR(CX$):GX=ADR(GTX$)
20 GTX$(1,60)="{inv}){/inv}{CTRL-A}{inv}{CTRL-E}\%{/inv}T{inv}{CTRL-E}d%{/inv}U{inv}{CTRL-E}b%{/inv}V{inv}{CTRL-E}c&{/inv}W{inv}){/inv}{CTRL-J}{inv}{CTRL-.}{/inv}{CTRL-E}{inv}{CTRL-P}{/inv}{CTRL-H}{inv}){/inv}{CTRL-T}{inv}{CTRL-.}{/inv}{CTRL-G}{inv}{CTRL-P}{/inv}{CTRL-B}{inv}){/inv}({inv}{CTRL-E}]{/inv}h{inv}p{/inv}({inv}*{/inv}h{inv}{CTRL-E}Y{/inv}h{inv}{CTRL-E}XJp{/inv}#hh{inv}{CTRL-E}\Jp{/inv}{UP}h{inv}{CTRL-E}c{/inv}h{inv}{CTRL-E}b{/inv}"
30 GTX$(61,120)="{inv}Jp{/inv}{CTRL-S}hh{inv}{CTRL-E}dJp{/inv}{CTRL-L}hh{inv}JP{CTRL-;}p{/inv}{CTRL-E}{inv}){/inv}{BELL}L{inv}$v%]{CTRL-E}{CTRL-.}){/inv}{CTRL-,}{inv}{CTRL-E}U"{/inv}{CTRL-H}{CTRL-J}&{inv}U{/inv}{CTRL-F}{inv}{CTRL-.}{CTRL-P}{/inv}{CTRL-G}{CTRL-X}e{inv}d{CTRL-P}{/inv}{CTRL-B}{inv}fUJPo{CTRL-E}T"{/inv}{CTRL-H}{inv}{CTRL-F}^%b{CTRL-E}{CTRL-.}%{/inv}"
40 GTX$(121,180)="{inv}c{/inv}{CTRL-F}{inv}{CTRL-.}{/inv}*{inv}E^{CTRL-P}{/inv}{CTRL-D}{inv}e^f{CTRL-.}JPr{CTRL-E}_{/inv}{CTRL-X}{inv}%{/inv}Xe{inv}T{CTRL-E}T%{/inv}Ye{inv}U{CTRL-E}U{/inv}{CTRL-X}{inv}%{CTRL-.}{/inv}e{inv}T{CTRL-E}T{CTRL-P}{/inv}{CTRL-B}{inv}fU%T{CTRL-E}V%U{CTRL-E}W {/inv}{CTRL-,}{inv}1XfXP{/inv}{CTRL-B}{inv}fY"{/inv}"
50 GTX$(181,240)="{CTRL-,}{inv}{CTRL-F}hI{CTRL-,}{CTRL-P}{/inv}{CTRL-D}){TAB}{inv}Fh*{CTRL-E}{CTRL-.}{CTRL-.}{/inv}{CTRL-.}{inv}0{/inv}{CTRL-K}{inv}){/inv}@{inv}{CTRL-.}{/inv} {inv}{CTRL-P}{/inv}{CTRL-B}{inv}){CTRL-.}{/inv}{CTRL-X}e{inv}{CTRL-.}{CTRL-E}Z"{/inv}{CTRL-,}{inv}{CTRL-F}["{/inv}{CTRL-C}{CTRL-F}{inv}Z{/inv}&{inv}[JPy{/inv}{CTRL-X}{inv}-t{/inv}{CTRL-B}e{inv}[{CTRL-E}[){/inv}{CTRL-H}{inv}{CTRL-E}g {/inv}{CTRL-,}{inv}1T{/inv}"
60 GTX$(241,300)="{inv}{CTRL-E}{CTRL-.}H1T{CTRL-E}a {/inv}{CTRL-,}{inv}1Z{/inv}E{inv}hfZP{/inv}{CTRL-B}{inv}f[&_p{/inv}{CTRL-M}{inv}P{/inv}{CTRL-B}{inv}P{/inv}{CTRL-TAB}f{inv}{CTRL-.}{/inv}&{inv}{CTRL-.}{/inv}&{inv}aJPy{CTRL-E}{CTRL-.}&_p{/inv}{CTRL-H}{CTRL-X}f{inv}{CTRL-.}{/inv}f{inv}aJPy%{CTRL-.}{CTRL-Q}TH%a{CTRL-Q}T{/inv}{CTRL-X}"
70 GTX$(301,333)="{inv}%]{/inv}e{inv}T{CTRL-E}T{CTRL-P}{/inv}{CTRL-B}{inv}fUFgP2fVP{/inv}{CTRL-B}{inv}fW%V{CTRL-E}T%W{CTRL-E}UF\P={/inv}{CTRL-.}"
80 CX$="{inv}"{/inv}{CTRL-A}h{inv}p{/inv}{CTRL-M}{inv}*{/inv}hh{inv}{CTRL-E}VJp{/inv}{CTRL-E}hh{inv}JP{CTRL-;}%{/inv}X{inv}{CTRL-E}T%{/inv}Y{inv}{CTRL-E}U){/inv}{LEFT}{inv}{CTRL-E}W {/inv}{CTRL-,}{inv}-{/inv}{CTRL-J}{inv}R{CTRL-.}{/inv}{CTRL-A}{inv}p{/inv}{CTRL-B}{inv}%V{/inv}Q{inv}T{CTRL-Q}THPpfUFWPj{/inv}{CTRL-.}"
90 REM A=USR(ADR(GTX$),ADR(B$),LEN(B$),X,Y)
100 DIM PNT(6),ANS(6),MIX(6),A$(40),C$(40),W$(10)
110 MIN=5:MAX=10:TYPE=1:PCNT=6:ROUNDS=10:BPCT=0:DIF=1:TH=1:HSCR=0:SCORE=0
120 GOTO 810
130 FOR W=15 TO 0 STEP -3:SOUND 0,25*(X+1),10,W:NEXT W:RETURN
140 A$="ROUND # ":A$(9)=STR$(ROUND)
150 A=USR(GX,ADR(A$),LEN(A$),48,48)
160 A=USR(GX,ADR("COMPLETED"),9,48,56)
170 A$="BONUS = ":A$(9)=STR$(176-Y)
180 SCORE=SCORE+176-Y
190 A=USR(GX,ADR(A$),LEN(A$),48,72)
200 A$="SCORE = ":A$(9)=STR$(SCORE):A=USR(GX,ADR(A$),LEN(A$),48,84)
210 FOR I=1 TO 50
220 A=240*RND(0):FOR Q=0 TO 15 STEP 5
230 SOUND 0,A,10,Q:SOUND 1,A+5,10,Q:NEXT Q:NEXT I
240 SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
250 ON TYPE GOTO 260,270,280
260 B$="{inv} {/inv}  +  {inv} {/inv}  +  {inv} {/inv}  +  {inv} {/inv}  +  {inv} {/inv}  +  {inv} {/inv}  +  {inv} {/inv}":GOTO 290
270 B$="{inv} {/inv}  -  {inv} {/inv}  -  {inv} {/inv}  -  {inv} {/inv}  -  {inv} {/inv}  -  {inv} {/inv}  -  {inv} {/inv}":GOTO 290
280 B$="{inv} {/inv}  x  {inv} {/inv}  x  {inv} {/inv}  x  {inv} {/inv}  x  {inv} {/inv}  x  {inv} {/inv}  x  {inv} {/inv}"
290 FOR I=1 TO 6:MIX(I)=I
300 A=INT(MAX*RND(0))+MIN:IF A>MAX THEN 300
310 B=INT(MAX*RND(0))+MIN:IF B>MAX THEN 310
320 IF B>A THEN C=A:A=B:B=C
330 ON TYPE GOTO 340,350,360
340 ANS(I)=A+B:GOTO 370
350 ANS(I)=A-B:GOTO 370
360 ANS(I)=A*B
370 C=6*(I-1)+2:B$(C,C+1)=STR$(A):B$(C+3,C+4)=STR$(B)
380 NEXT I
390 FOR I=6 TO 1 STEP -1:PNT(I)=1
400 A=INT(I*RND(0))+1
410 B=MIX(A):MIX(A)=MIX(I):MIX(I)=B:NEXT I
420 RETURN
430 GRAPHICS 24:POKE 710,0:A=USR(CX,INT(255*RND(0)))
440 ON TYPE GOTO 450,460,470
450 A=USR(GX,ADR("{inv}+ ADDITION +{/inv}"),12,112,0):GOTO 480
460 A=USR(GX,ADR("{inv}- SUBTRACTION -{/inv}"),15,96,0):GOTO 480
470 A=USR(GX,ADR("{inv}x MULTIPLICATION x{/inv}"),18,88,0)
480 FOR J=0 TO 6:FOR I=16 TO 176 STEP 8
490 A=USR(GX,ADR("{inv} {/inv}"),1,J*48,I)
500 NEXT I:NEXT J
510 RETURN
520 SCORE=SCORE+ANSW:PNT(X+1)=0
530 W$=B$(6*X+1,6*X+7):FOR I=Y TO 16 STEP -1
540 SOUND 0,I,10,5:SOUND 0,I+5,10,5
550 A=USR(GX,ADR(W$),7,XX-24,I):COLOR 1:PLOT XX+4,I+8
560 NEXT I
570 W$="=":W$(2)=STR$(ANSW):IF ANSW<10 THEN W$(LEN(W$)+1)=" "
580 A=USR(GX,ADR(W$),LEN(W$),XX-16,24):B$(6*X+2,6*X+6)="     "
590 SOUND 0,0,0,0:SOUND 1,0,0,0
600 COLOR 0:PLOT XX+4,184
610 DRAWTO XX+4,32
620 A=240*RND(0):FOR Q=0 TO 15 STEP 5
630 SOUND 0,A,10,Q:SOUND 1,A+5,10,Q:NEXT Q
640 SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
650 X1=X:FOR I=15 TO 0 STEP -0.1:SOUND 0,256*RND(0),8,I:NEXT I
660 FOR W=1 TO 6:IF PNT(W)=0 THEN 690
670 X=W-1:XX=X*48+24:ANSW=ANS(W)
680 GOSUB 530:SCORE=SCORE-ANSW:TOK=TOK-1:GOSUB 770
690 NEXT W
700 XX=24+48*X1:X=X1:RETURN
710 A$="  ":A$(3)=STR$(PC):A$(LEN(A$)+1)="{inv}%{/inv}"
720 A=USR(GX,ADR(A$),LEN(A$),48,48)
730 A=USR(GX,ADR("*REPEAT ROUND*"),14,48,56)
740 FOR I=15 TO 0 STEP -0.05
750 SOUND 0,15*I,6,I:NEXT I
760 RETURN
770 PC=INT(100*(TOK/6))
780 A=USR(GX,ADR("{inv}%{/inv}"),1,301,128):A$=STR$(PC):A$(LEN(A$)+1)=" "
790 FOR I=0 TO LEN(A$)-1:A=USR(GX,ADR(A$)+I,1,301,136+8*I):NEXT I
800 RETURN
810 GRAPHICS 0:POKE 77,0:REM NEW GAME
820 POKE 710,0:POKE 752,1
830 POSITION 24,0:? "* MATH WIZARD *"
840 ? "{inv}SCORE{/inv} ";SCORE;" {inv}HIGH{/inv} ";HSCR;" {inv}TYPE{/inv} ";TH
850 POSITION 2,2:? CHR$(17);:FOR I=3 TO 37:? CHR$(18);:NEXT I:? CHR$(5);
860 POSITION 2,3:? CHR$(124);"USE STICK 0 ";CHR$(27);CHR$(31)
870 POSITION 28,3:? CHR$(124);"UP/DN";CHR$(124);"L/R";CHR$(124);
880 POSITION 2,4:? CHR$(1);:FOR I=3 TO 37:? CHR$(18);:NEXT I:? CHR$(4);
890 FOR I=5 TO 19:POSITION 2,I:? CHR$(124);
900 POSITION 28,I:? CHR$(124);:POSITION 34,I:? CHR$(124);
910 POSITION 38,I:? CHR$(124);:NEXT I
920 POSITION 2,20:? CHR$(26);:FOR I=3 TO 37:? CHR$(18);:NEXT I:? CHR$(3);
930 RESTORE
940 FOR I=1 TO 12:READ X,Y,B$:POSITION X,Y:? B$;:NEXT I
950 DATA 4,5,Minimum Starting #
960 DATA 4,7,Maximum Starting #
970 DATA 3,9,% Correct to Advance
980 DATA 3,11,Difficulty Increment
990 DATA 6,13,Rounds Per Game
1000 DATA 3,15,Problem Type
1010 DATA 4,17,(1) Addition
1020 DATA 4,18,(2) Subtraction
1030 DATA 4,19,(3) Multiplication
1040 DATA 2,21,Move STICK 0 UP/DOWN to Select Item
1050 DATA 2,22,Left-Decrease Right-Increase Value
1060 DATA 2,23,Press {inv}FIRE{/inv} to Begin Game
1070 X=35:Y=5:SEL=1:DELA=50
1080 FOR I=1 TO 6
1090 POSITION X,Y
1100 ON I GOTO 1110,1120,1130,1140,1150,1160
1110 ? MIN;:GOTO 1170
1120 ? MAX;:GOTO 1170
1130 ? INT(100*PCNT/6);:GOTO 1170
1140 ? DIF;:GOTO 1170
1150 ? ROUNDS;:GOTO 1170
1160 ? TYPE;
1170 Y=Y+2:NEXT I
1180 FOR I=1 TO 3:POSITION 4,16+I:? " ";:NEXT I
1190 POSITION 4,16+TYPE:? CHR$(27);CHR$(31);
1200 POSITION 30,2*SEL+3:? CHR$(148);
1210 A=STICK(0):IF  NOT (STRIG(0)) THEN 1530
1220 IF A=15 THEN POSITION 30,2*SEL+3:? CHR$(20);:DELA=50:FOR I=1 TO 15:NEXT I:GOTO 1200
1230 IF A=13 THEN B=SEL+1:GOTO 1270
1240 IF A=14 THEN B=SEL-1:GOTO 1270
1250 B=(A=7)-(A=11):IF B<>0 THEN GOTO 1310
1260 GOTO 1210
1270 POSITION 30,2*SEL+3:? " ";:SEL=B:IF SEL<1 THEN SEL=6
1280 IF SEL>6 THEN SEL=1
1290 FOR I=1 TO 15:NEXT I:DELA=50
1300 FOR W=15 TO 0 STEP -1:SOUND 0,80,10,W:NEXT W:GOTO 1200
1310 ON SEL GOTO 1320,1350,1380,1410,1440,1470
1320 MIN=MIN+B:IF MIN<=0 THEN MIN=1
1330 IF MIN>MAX-5 THEN MIN=MAX-5
1340 POSITION X,5:? "  ";:POSITION X,5:? MIN;:GOTO 1500
1350 MAX=MAX+B:IF MAX>99 THEN MAX=99
1360 IF MAX<MIN+5 THEN MAX=MIN+5
1370 POSITION X,7:? "  ";:POSITION X,7:? MAX;:GOTO 1500
1380 PCNT=PCNT+B:IF PCNT>6 THEN PCNT=6
1390 IF PCNT<1 THEN PCNT=1
1400 POSITION X,9:? "   ";:POSITION X,9:? INT(100*PCNT/6);:GOTO 1500
1410 DIF=DIF+B:IF DIF<1 THEN DIF=1
1420 IF DIF>20 THEN DIF=20
1430 POSITION X,11:? "  ";:POSITION X,11:? DIF;:GOTO 1500
1440 ROUNDS=ROUNDS+B:IF ROUNDS>99 THEN ROUNDS=99
1450 IF ROUNDS<1 THEN ROUNDS=1
1460 POSITION X,13:? "  ";:POSITION X,13:? ROUNDS;:GOTO 1500
1470 FOR I=1 TO 3:POSITION 4,16+I:? " ";:NEXT I:TYPE=TYPE+B:IF TYPE<1 THEN TYPE=1
1480 IF TYPE>3 THEN TYPE=3
1490 POSITION X,15:? TYPE;:POSITION 4,16+TYPE:? CHR$(27);CHR$(31);
1500 DELA=DELA-5:IF DELA<1 THEN DELA=1
1510 FOR I=15 TO 0 STEP -5:SOUND 0,60,10,I:NEXT I
1520 FOR I=1 TO DELA:NEXT I:GOTO 1200
1530 SCORE=0:X=2:XX=120:PCNT=INT(100*PCNT/6)
1540 ON TYPE GOTO 1550,1560,1570
1550 C$="{inv}  {/inv}+{inv}  {/inv}=":GOTO 1580
1560 C$="{inv}  {/inv}-{inv}  {/inv}=":GOTO 1580
1570 C$="{inv}  {/inv}x{inv}  {/inv}="
1580 FOR ROUND=1 TO ROUNDS
1590 GOSUB 430:GOSUB 250:A$="{inv}PROB{/inv} 1  {inv}ROUND{/inv}":Y=32
1600 FOR I=0 TO LEN(A$)-1:A=USR(GX,ADR(A$)+I,1,301,8*I):NEXT I
1610 A$=STR$(ROUND):FOR I=0 TO LEN(A$)-1:A=USR(GX,ADR(A$)+I,1,301,112+8*I):NEXT I
1620 TOK=6:GOSUB 770
1630 REM WORK 6 PROBLEMS FOR CURRENT ROUND
1640 FOR PROB=1 TO 6:A$=STR$(PROB):A=USR(GX,ADR(A$),1,301,40)
1650 ANSW=ANS(MIX(PROB)):C$(7)="    ":C$(7)=STR$(ANSW):C$(LEN(C$)+1)="    "
1660 A=USR(GX,ADR(C$),LEN(C$),112,8)
1670 REM UPDATE POSITION OF PROBLEMS
1680 A=USR(GX,ADR(B$),37,0,Y)
1690 A=USR(GX,ADR("{CTRL-;}"),1,XX,184)
1700 A=STICK(0):IF A=15 THEN 1740
1710 X1=XX:X=X+(A=6 OR A=5 OR A=7)-(A=10 OR A=11 OR A=9):IF X<0 THEN X=0
1720 IF X>5 THEN X=5
1730 XX=24+48*X:A=USR(GX,ADR(" "),1,X1,184):A=USR(GX,ADR("{CTRL-;}"),1,XX,184):GOSUB 130
1740 A=USR(GX,ADR("{inv}{CTRL-;}{/inv}"),1,XX,184):IF STRIG(0) THEN 1790
1750 COLOR 1:PLOT XX+4,184:DRAWTO XX+4,Y+8
1760 IF ANS(X+1)=ANSW AND PNT(X+1)=1 THEN GOSUB 520:GOTO 1810
1770 COLOR 0:PLOT XX+4,184:DRAWTO XX+4,Y+8:TOK=TOK-1:GOSUB 770
1780 FOR I=15 TO 0 STEP -0.2:SOUND 0,255*RND(0),8,I:NEXT I
1790 Y=Y+1:IF Y>176 THEN Y=176:GOSUB 650:GOTO 1820
1800 GOTO 1680
1810 POKE 77,0:NEXT PROB
1820 GOSUB 770:IF PC<PCNT THEN GOSUB 710:GOTO 1590
1830 GOSUB 140:MAX=MAX+DIF:MIN=MIN+INT(DIF*RND(0)+1)
1840 PC=100:NEXT ROUND
1850 IF SCORE>HSCR THEN HSCR=SCORE:TH=TYPE
1860 PCNT=6:GOTO 810

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: MATHWIZ.BAS.

Credits