Lie Detector (Biofeedback Monitor)
- Type
- Other
- Category
- Hardware project: skin-conductivity graph
- Author
- Michael Krueger
- Published in
- Antic, March 1986 (Vol. 4, No. 11)
- Year
- 1986
- Language
- Atari BASIC
- Requirements
- Any Atari 8-bit computer, Atari BASIC, a pair of Atari paddle controllers (modified as described), foil, wire and four alligator clips
- Tags
- antic, hardware-project, paddle, biofeedback, graphing, graphics-8, pot-reading, diy, 1986
About the program
Antic's March 1986 issue framed this project as a hard-boiled detective story ("It was so sleazy, even the guns had guns"), but the hardware is genuinely simple. Michael Krueger showed how to turn an Atari paddle controller into a biofeedback monitor that measures skin conductivity, the principle behind the galvanic-skin-response part of a polygraph. No soldering is needed. The magazine stressed that this is a toy, "much more inaccurate and easier to fool than a polygraph", and that it took no responsibility for misuse.
Building the sensor
Krueger's instructions, briefly:
- Make two electrodes. Fold a 4×5-inch sheet of aluminium foil into a pad about 1¼ × 2 inches, and do the same with a second sheet. Clip a two-foot wire with alligator clips at both ends to each pad.
- Find paddle 0. With the paddles plugged into port 1, it's the cord on the left of the plug (on an XL, the cord nearest you). Remove its back cover with a Phillips screwdriver.
- Inside is the potentiometer, with wires soldered to two of its three terminals. Clip your two wires to those two terminals, making sure the clips touch neither each other nor the third terminal. Turn the knob fully anticlockwise.
- Wrap the pads round two of the subject's fingers, at least a finger apart, on the "sweaty side", held on with rubber bands (not tightly). Most people feel nothing. If your subject feels more than a mild tingle, disconnect at once and check your work.
Typing it in
{CLEAR} is ESC then SHIFT-CLEAR. {UP} and {LEFT} are ESC followed by CTRL with the arrow keys. {inv} … {/inv} means press the Atari (inverse) key before and after. Antic printed TYPO II checksums beside each line of the magazine listing. They are not part of the program.
How to use it
RUN it. You get a light green screen with a line across the middle. The text window shows the reading, which should be 000 with nothing connected (227 means the electrodes or clips are touching). With the electrodes on, the graph rises as conductivity rises with nervousness or exercise (jogging on the spot works well) and falls as the subject relaxes.
- SELECT hides or restores the text window, which covers the bottom 32 lines of the graph.
- OPTION moves the reference line to the current reading.
- Hold START to pause.
- For more sensitivity, raise
MAGin line 10 (2 doubles the magnification and halves the range).
As a lie detector, sit the subject facing away from the screen. Ask a few unimportant questions and press OPTION to mark their normal level. A reading far above the line may be a lie. It works best if the subject knows the questions in advance.
How it works
The paddle's potentiometer is a variable resistor, and the Atari's POKEY chip measures its resistance, which BASIC reads with PADDLE(0). With the knob turned fully one way, the resistance that matters is the subject's skin. Line 20 turns the reading round (228-PADDLE(0)) so that higher conductivity plots higher. Lines 60–90 draw a scrolling trace across 320 columns. A gap a few pixels ahead of the pen is erased using the previous values saved in the array Y(), so the trace wipes as it goes, like a hospital monitor.
Listing
2 REM LIE DETECTOR
3 REM BY MICHAEL KRUEGER
4 REM (c) 1985, ANTIC PUBLISHING
10 MAG=1:GOSUB 1000:S=MAG*(191/227)
20 FOR X=0 TO 319:POKE 77,0:P=228-PADDLE(0):IF G THEN 60
30 IF P<10 THEN ? "0";
40 IF P<100 THEN ? "0";
50 ? P;"{LEFT}{LEFT}{LEFT}";
60 Y=(227-P)*S:IF Y>191 THEN Y=191
70 COLOR 1:PLOT X,ABS(Y(X))
72 IF X<319 THEN DRAWTO X+1,ABS(Y)
80 COLOR 0:X1=X+19-319*(X>299):PLOT X1,ABS(Y(X1))
82 DRAWTO X1+1,ABS(Y(X1+1)):COLOR 1
84 PLOT X1,L:IF PEEK(CN)<>7 THEN GOSUB 100
90 Y(X+1)=Y:NEXT X:Y(0)=Y:GOTO 20
100 P=PEEK(CN):IF P<>5 THEN 140
110 G= NOT (G):IF G THEN GRAPHICS 56:GOTO 130
120 GRAPHICS 8+32
130 GOSUB 500:GOTO 170
140 IF P<>3 THEN 170
150 COLOR 0:PLOT 0,L:DRAWTO 319,L:L=Y:COLOR 1:PLOT 0,L:DRAWTO 319,L
170 IF PEEK(CN)<>7 THEN 170
180 RETURN
500 SETCOLOR 4,12,4:SETCOLOR 1,0,0:SETCOLOR 2,10,8:POKE 752,1:POKE 82,0:POKE 16,112:POKE 53774,112:RETURN
1000 DIM Y(320):POKE 559,0:FOR I=0 TO 320:Y(I)=191:NEXT I:D=1:CN=53279:L=95
1020 GRAPHICS 8:GOSUB 500:COLOR 1:PLOT 0,L:DRAWTO 319,L:? "{CLEAR}{inv} GRAPH SHOWS APPROXIMATE STRESS LEVEL {/inv}";
1030 ? "SUBJECT'S SKIN CONDUCTIVITY:"
1040 PRINT "HIGH READINGS SHOW STRESS OR ACTIVITY LOW READINGS INDICATE RELAXATION{UP}{UP}{LEFT}{LEFT}{LEFT}";:RETURN
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: LIAR.BAS.
Credits
- Program listing: Lie Detector (Biofeedback Monitor) — program listing (Antic, March 1986 (Vol. 4, No. 11)) — Michael Krueger
- Picture: Ready and waiting: the light green screen, centre line and 000 reading that the article says to expect with nothing connected. — Michael Krueger (program); screenshot by the site
- Antic, March 1986 - Vol. 4 No. 11: scan of the printed magazine, PDF pages 37-38 (article) — Internet Archive, 1986
- Antic disk, March 1986 - Vol. 4 No. 11: LIAR.BAS (detokenized listing) — Michael Krueger, 1986
