Lie Detector (LIAR.BAS)

Lie Detector by Michael Krueger, 12

Description

Lie Detector by Michael Krueger, 12

From the Antic disk of March 1986 (Vol. 4 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.4 KB

Dialect
Atari BASIC
Lines
28
Variables
MAG, S, X, P, G, Y, Y(, X1, L, CN, I, D
BASIC listing (28 lines)
2 REM LIE DETECTOR
3 REM BY MICHAEL KRUEGER
4 REM (c) 1985, ANTIC PUBLISHING
10 MAG=1:GOSUB 1000:S=MAG*(191/227)
20 FOR X=0 TO 319:POKE 77,0:P=228-PADDLE(0):IF G THEN 60
30 IF P<10 THEN ? "0";
40 IF P<100 THEN ? "0";
50 ? P;"←←←";
60 Y=(227-P)*S:IF Y>191 THEN Y=191
70 COLOR 1:PLOT X,ABS(Y(X))
72 IF X<319 THEN DRAWTO X+1,ABS(Y)
80 COLOR 0:X1=X+19-319*(X>299):PLOT X1,ABS(Y(X1))
82 DRAWTO X1+1,ABS(Y(X1+1)):COLOR 1
84 PLOT X1,L:IF PEEK(CN)<>7 THEN GOSUB 100
90 Y(X+1)=Y:NEXT X:Y(0)=Y:GOTO 20
100 P=PEEK(CN):IF P<>5 THEN 140
110 G= NOT (G):IF G THEN GRAPHICS 56:GOTO 130
120 GRAPHICS 8+32
130 GOSUB 500:GOTO 170
140 IF P<>3 THEN 170
150 COLOR 0:PLOT 0,L:DRAWTO 319,L:L=Y:COLOR 1:PLOT 0,L:DRAWTO 319,L
170 IF PEEK(CN)<>7 THEN 170
180 RETURN
500 SETCOLOR 4,12,4:SETCOLOR 1,0,0:SETCOLOR 2,10,8:POKE 752,1:POKE 82,0:POKE 16,112:POKE 53774,112:RETURN
1000 DIM Y(320):POKE 559,0:FOR I=0 TO 320:Y(I)=191:NEXT I:D=1:CN=53279:L=95
1020 GRAPHICS 8:GOSUB 500:COLOR 1:PLOT 0,L:DRAWTO 319,L:? "↰  GRAPH SHOWS APPROXIMATE STRESS LEVEL  ";
1030 ? "SUBJECT'S SKIN CONDUCTIVITY:"
1040 PRINT "HIGH READINGS SHOW STRESS OR ACTIVITY   LOW READINGS INDICATE RELAXATION↑↑←←←";:RETURN