3-D Fuji

Type
Graphics
Category
3-D wireframe rotation tutorial
Author
Jerry O'Neill
Published in
Antic, August 1983 (Vol. 2, No. 5), "3-D Fuji: Spin the symbol"
Year
1983
Language
Atari BASIC
Requirements
16K RAM (Listing 1) or more for Listing 2, Atari BASIC
A GRAPHICS 8 wireframe: a square with a letter A on it and three arrows for the X, Y and Z axes, the Z arrow drawn diagonally

About the program

Arcade games such as Zaxxon made 3-D graphics fashionable. In Antic's August 1983 graphics issue, Jerry O'Neill explained the principles behind them with two programs that build a wireframe object from X, Y and Z coordinates and turn it to any angle you like. The first rotates a simple test object: a square with a letter A on it and three arrows for the axes. The second does the same for the Atari "Fuji" symbol, named, as the article noted, for its resemblance to Mount Fuji. It also includes an alternative object, a barn with a silo.

What you need

Atari BASIC. O'Neill wrote that Listing 1 runs on a 16K cassette machine. Listing 2 holds about 280 points, so give it more memory, 32K or above.

Typing it in

Both listings are plain ASCII except for the inverse-video START and SELECT prompts ({inv}…{/inv}, Atari key). The coordinates are in DATA. A point of -999,-999,-999 means "lift the pen" and start a new line. In Listing 1 the first DATA item is the object's name and the number of points. In Listing 2 the logo's curves are typed in only once and mirrored by the program, and the many REMs explain each step. They can be left out.

How to use it

RUN, wait while the data is read, then press START for the automatic demonstration. It shows the object at five angles of yaw, then five of pitch, then five of roll. Or press SELECT to type your own angles in degrees as yaw,pitch,roll, for example 30,20,10. Listing 2 first asks whether you want the logo (1) or the barn (2). In manual mode, press any key after a picture is drawn to enter new angles.

How it works

  • Faking the Z axis. A flat screen has only X and Y, so O'Neill draws Z as a line at 45°: the screen position is X + Z*0.707 across and Y + Z*0.707 down (C=0.707 in line 240). HC and VC move the origin to the centre of the screen.
  • Rotation. Lines 100–120 apply the three standard rotations, each a pair of sines and cosines: yaw about the vertical axis, pitch about the horizontal axis and roll about the axis pointing out of the screen. DEG (line 250) lets you give angles in degrees, and the sines and cosines are worked out once per picture (lines 660 and 830), not once per point.
  • Staying on screen. TRAP 190 catches the ERROR 141 or ERROR 3 caused by a point off the edge of the GRAPHICS 24 screen. It lifts the pen, so no stray line is drawn to the next point.
  • XRATIO, YRATIO and ZRATIO (line 330 of Listing 1) stretch the object, for example to correct the aspect ratio of your TV.

Listings

Listing 1: the 3-D letter A

1 REM ANTIC 8/83
10 GOTO 200
49 REM SUBROUTINE PLOTS SHAPE
50 GRAPHICS 24:SETCOLOR 2,0,0:COLOR 1
60 FLAG=0:TRAP 190
70 FOR I=1 TO LAST
80 X=X(I):Y=Y(I):Z=Z(I)
90 IF Y=-999 THEN FLAG=0:GOTO 150
100 TX=X*CSYW+Z*SNYW:TY=Y:TZ=X*-SNYW+Z*CSYW:X=TX:Y=TY:Z=TZ
110 IF PITCH<>0 THEN TY=Y*CSPT+Z*-SNPT:TZ=Y*SNPT+Z*CSPT:X=TX:Y=TY:Z=TZ
120 IF ROLL<>0 THEN TX=X*CSRL+Y*SNRL:TY=X*-SNRL+Y*CSRL:TZ=Z
130 IF FLAG=0 THEN PLOT TX+C*TZ+HC,TY+C*TZ+VC:FLAG=1:GOTO 150
140 DRAWTO TX+C*TZ+HC,TY+C*TZ+VC
150 NEXT I
160 FOR DEL=1 TO 100:SOUND 0,121,10,6:NEXT DEL:SOUND 0,0,0,0
170 IF PEEK(764)=255 AND MODE=2 THEN 170
180 POKE 764,255:RETURN
190 FLAG=0:TRAP 190:GOTO 150
199 REM INITIALIZING SECTION
200 GRAPHICS 2:POKE 752,1
210 POSITION 3,2:? #6;"atari graphics":POSITION 7,5:? #6;"IN 3-D"
230 DIM ALT$(15):READ ALT$:READ LAST:DIM X(LAST),Y(LAST),Z(LAST)
240 C=0.707:HC=160:VC=90:MODE=1:CH=1
250 DEG
299 REM READ SHAPE DATA
300 POKE 752,1:? :? "One moment please.":? "Reading data for ";ALT$
320 FOR I=0 TO LAST:X(I)=0:Y(I)=0:Z(I)=0:NEXT I
329 REM 'RATIOS' ALLOW SCALING SHAPE. ADJUST XRATIO TO COMPENSATE SHAPE SHOWN ON YOUR TV SCREEN
330 XRATIO=1:YRATIO=1:ZRATIO=1
340 FOR I=1 TO LAST
350 READ X,Y,Z
360 X(I)=X*XRATIO:Y(I)=Y*YRATIO:Z(I)=Z*ZRATIO
370 IF X=-999 THEN X(I)=X:Y(I)=Y:Z(I)=Z
380 NEXT I
390 YAW=0:PITCH=0:ROLL=0:MODE=1
400 ? :? "For auto-rotate routine, press {inv} START {/inv}":? "For manual settings, press {inv} SELECT {/inv}"
410 IF PEEK(53279)=5 THEN MODE=2:GOTO 720
420 IF PEEK(53279)=6 THEN 600
430 GOTO 410
599 REM AUTO-ROTATE ROUTINE: YAW, PITCH, ROLL--5 POSITIONS FOR EACH
600 FOR DIRECTION=1 TO 3
610 FOR TURN=0 TO 4
620 YAW=0:PITCH=0:ROLL=0
630 IF DIRECTION=1 THEN YAW=TURN*75
640 IF DIRECTION=2 THEN PITCH=TURN*60
650 IF DIRECTION=3 THEN ROLL=TURN*60
660 CSYW=COS(YAW):SNYW=SIN(YAW):CSPT=COS(PITCH):SNPT=SIN(PITCH):CSRL=COS(ROLL):SNRL=SIN(ROLL)
670 GOSUB 50
680 FOR DEL=1 TO 1000:NEXT DEL
690 NEXT TURN
700 NEXT DIRECTION
709 REM END OF AUTO-ROTATE; NOW MANUAL MODE
710 MODE=2
720 TRAP 810
790 GRAPHICS 0
800 ? :? :? "The last display used values of":? :? "YAW=";YAW:? "PITCH=";PITCH:? "ROLL=";ROLL
810 TRAP 810:? :? :? "Enter desired new angles":? :? "of yaw, pitch, and roll.":?
820 INPUT YAW,PITCH,ROLL
830 CSYW=COS(YAW):SNYW=SIN(YAW):CSPT=COS(PITCH):SNPT=SIN(PITCH):CSRL=COS(ROLL):SNRL=SIN(ROLL)
840 GRAPHICS 0:POKE 752,1
850 SETCOLOR 2,3,4:? :? :? :? "After the image is drawn,":? :? "press any key to draw another."
860 FOR DEL=1 TO 1000:NEXT DEL
870 POKE 764,255:GOSUB 50
880 GOTO 790
1999 REM LETTER A WITH 3D ARROWS
2000 DATA 3-D LETTER A,30
2010 DATA -12,15,0,0,-15,0,12,15,0,8,6,0,-8,6,0,-999,-999,-999
2020 DATA -20,20,0,20,20,0,20,-20,0,-20,-20,0,-20,20,0,-999,-999,-999
2030 DATA -50,0,0,50,0,0,40,10,0,50,0,0,40,-10,0,-999,-999,-999
2040 DATA 0,50,0,0,-50,0,-10,-40,0,0,-50,0,10,-40,0,-999,-999,-999
2050 DATA 0,0,-50,0,0,50,-10,0,40,0,0,50,10,0,40,-999,-999,-999

Listing 2: the Atari logo and a barn

1 REM ANTIC 8/83
2 REM SHOWS ROTATION IN ALL 3 AXES FOR ATARI LOGO AND BARN WITH SILO
10 GOTO 200
49 REM SUBROUTINE PLOTS SHAPE
50 GRAPHICS 24:SETCOLOR 2,0,0:COLOR 1
59 REM FLAG=0 MEANS PLOT; FLAG=1 MEANS DRAWTO. TRAP 190 FOR LINES PAST EDGE OF SCREEN
60 FLAG=0:TRAP 190
69 REM VARIABLE 'LAST' ALLOWS DATA BASES WITH VARYING NUMBERS OF POINTS
70 FOR I=1 TO LAST
80 X=X(I):Y=Y(I):Z=Z(I)
89 REM -999 INDICATES NEXT VALUE WILL BEGIN A NEW LINE, SO FLAG=0 FOR PLOT INSTEAD OF DRAWTO
90 IF Y=-999 THEN FLAG=0:GOTO 150
99 REM CALCULATE YAW; ROTATION ON Y (VERTICAL) AXIS
100 TX=X*CSYW+Z*SNYW:TY=Y:TZ=X*-SNYW+Z*CSYW:X=TX:Y=TY:Z=TZ
109 REM CALCULATE PITCH; ROTATION ON X (HORIZONTAL) AXIS
110 IF PITCH<>0 THEN TY=Y*CSPT+Z*-SNPT:TZ=Y*SNPT+Z*CSPT:X=TX:Y=TY:Z=TZ
119 REM CALCULATE ROLL; ROTATION ON Z AXIS (AXIS THAT COMES OUT FROM PLANE OF SCREEN)
120 IF ROLL<>0 THEN TX=X*CSRL+Y*SNRL:TY=X*-SNRL+Y*CSRL:TZ=Z
129 REM IF FLAG=0 THEN NEW LINE, SO PLOT FIRST POINT
130 IF FLAG=0 THEN PLOT TX+C*TZ+HC,TY+C*TZ+VC:FLAG=1:GOTO 150
139 REM IF FLAG=1 THEN CONTINUE EXISTING LINE; DRAWTO NEXT POINT
140 DRAWTO TX+C*TZ+HC,TY+C*TZ+VC
150 NEXT I
159 REM SOUND INDICATES PICTURE IS DONE
160 FOR DEL=1 TO 100:SOUND 0,121,10,6:NEXT DEL:SOUND 0,0,0,0
169 REM IF IN MANUAL MODE, WAIT FOR ANY KEY TO BE PRESSED
170 IF PEEK(764)=255 AND MODE=2 THEN 170
179 REM GET RID OF KEY PRESSED AND RETURN FROM SUBROUTINE
180 POKE 764,255:RETURN
189 REM TRAP ERRORS FOR LINES PAST EDGE OF SCREEN (ERROR 141) AND SET FLAG TO PLOT NEXT POINT
190 FLAG=0:TRAP 190:GOTO 150
199 REM INITIALIZING SECTION
200 GRAPHICS 2:POKE 752,1
210 POSITION 3,2:? #6;"atari graphics":POSITION 7,5:? #6;"IN 3-D"
220 ? "One moment, please..."
229 REM FIRST DATA STATEMENT INDICATES NUMBER OF POINTS, STORED IN VARIABLE 'LAST'
230 READ LAST:DIM X(LAST),Y(LAST),Z(LAST),ALT$(15)
238 REM C=SIN & COS OF 45 DEGREES; HC=HORIZONTAL CENTER OF IMAGE; VC=VERTICAL CENTER
239 REM MODE=1 FOR AUTOMATIC DEMO, 2 FOR MANUAL CONTROL; CH=1 TO CHOOSE ATARI LOGO, CH=2 FOR BARN OR OTHER SHAPE
240 C=0.707:HC=160:VC=90:MODE=1:CH=1
250 DEG
260 SOUND 0,121,10,4:SOUND 1,96,10,4:SOUND 2,81,10,4
269 REM INITIALIZE ARRAYS; X AND Y=0,Z=-8
270 FOR I=0 TO 243:X(I)=0:Y(I)=0:Z(I)=-8:NEXT I
280 SOUND 0,243,10,4:SOUND 1,193,10,4:SOUND 2,162,10,4
289 REM READ DATA 4 TIMES FOR 4 CURVED PARTS OF LOGO
290 FOR SHAPE=1 TO 4
300 RESTORE 1010
310 FOR I=1 TO 49
320 READ X,Y
329 REM CHANGE COORDINATES FOR 4 CURVES
330 IF SHAPE=1 THEN X(I)=X:Y(I)=Y
340 IF SHAPE=2 THEN X(I+49)=X:Y(I+49)=Y:Z(I+49)=8
350 IF SHAPE=3 THEN X(I+98)=-X:Y(I+98)=Y
360 IF SHAPE=4 THEN X(I+147)=-X:Y(I+147)=Y:Z(I+147)=8
370 NEXT I
380 NEXT SHAPE
389 REM READ DATA FOR 2 STRAIGHT PARTS OF LOGO
390 FOR SHAPE=0 TO 1
400 RESTORE 1050
410 FOR I=1 TO 6
420 READ X,Y
430 X(196+I+SHAPE*6)=X:Y(196+I+SHAPE*6)=Y:IF SHAPE=1 THEN Z(202+I)=8
440 NEXT I
450 NEXT SHAPE
459 REM READ DATA FOR CONNECTING LINES BETWEEN FRONT AND BACK PARTS OF LOGO
460 FOR I=209 TO 242 STEP 3
470 READ X,Y
480 X(I)=X:X(I+1)=X:X(I+2)=-999:Y(I)=Y:Y(I+1)=Y:Y(I+2)=-999:Z(I+1)=8
490 NEXT I
499 REM READ DATA FOR WORD 'ATARI'
500 FOR I=245 TO 278
510 READ X,Y
520 X(I)=X:Y(I)=Y:Z(I)=8
530 NEXT I
539 REM FADE OUT SOUND
540 FOR VOL=4 TO 0 STEP -0.02:SOUND 0,243,10,VOL:SOUND 1,193,10,VOL:SOUND 2,162,10,VOL:NEXT VOL
549 REM GIVE USER A CHOICE OF DISPLAY ROUTINES
550 SETCOLOR 2,12,4:? :? :? "For auto-rotate routine, press {inv} START {/inv}"
560 ? "For manual settings, press {inv} SELECT {/inv}"
569 REM PRESSING START SETS MODE=1
570 IF PEEK(53279)=6 THEN MODE=1:GOTO 600
579 REM PRESSING SELECT SETS MODE=2, SKIPS AUTO-ROTATE ROUTINE
580 IF PEEK(53279)=5 THEN MODE=2:GOTO 710
590 GOTO 570
599 REM AUTO-ROTATE ROUTINE: YAW, PITCH, ROLL--5 POSITIONS FOR EACH
600 FOR DIRECTION=1 TO 3
610 FOR TURN=0 TO 4
620 YAW=0:PITCH=0:ROLL=0
630 IF DIRECTION=1 THEN YAW=TURN*75
640 IF DIRECTION=2 THEN PITCH=TURN*60
650 IF DIRECTION=3 THEN ROLL=TURN*60
659 REM LINE 660 CALCULATES SIN & COS FOR YAW, PITCH, AND ROLL VALUES
660 CSYW=COS(YAW):SNYW=SIN(YAW):CSPT=COS(PITCH):SNPT=SIN(PITCH):CSRL=COS(ROLL):SNRL=SIN(ROLL)
669 REM GO TO PLOTTING SUBROUTINE
670 GOSUB 50
679 REM GIVE THE USER SOME TIME TO LOOK AT DISPLAY
680 FOR DEL=1 TO 1000:NEXT DEL
690 NEXT TURN
700 NEXT DIRECTION
709 REM ALL DONE WITH AUTO-ROTATE DEMO, SO SET MODE=2
710 MODE=2:IF CH=2 THEN 790
719 REM TRAP 810 TRAPS DATA ENTRY ERRORS FOR YAW, PITCH, ROLL
720 TRAP 810
729 REM READ NAME OF ALTERNATE SHAPE
730 READ ALT$
739 REM CH=2 MEANS SHOW ALTERNATE SHAPE INSTEAD OF LOGO, SO SKIP LINES 750-780
740 IF CH=2 THEN 790
750 GRAPHICS 0
760 ? :? :? "To see an ATARI logo, enter 1":? :? "To see a(n) ";ALT$;", enter 2"
770 INPUT CH
779 REM IF CH=2, THIS IS THE FIRST TIME FOR THE NEW SHAPE, SO READ DATA
780 IF CH=2 THEN 900
790 GRAPHICS 0
800 ? :? :? "The last display used values of":? :? "YAW=";YAW:? "PITCH=";PITCH:? "ROLL=";ROLL
809 REM TRAP IF BAD ENTRIES FOR YAW, PITCH, ROLL
810 TRAP 810:? :? :? "Enter desired new angles":? :? "of yaw, pitch, and roll.":?
820 INPUT YAW,PITCH,ROLL
829 REM CALCULATE SIN & COS FOR YAW, PITCH, AND ROLL
830 CSYW=COS(YAW):SNYW=SIN(YAW):CSPT=COS(PITCH):SNPT=SIN(PITCH):CSRL=COS(ROLL):SNRL=SIN(ROLL)
840 GRAPHICS 0:POKE 752,1
849 REM REMIND USER THAT IN MANUAL MODE YOU MUST PRESS A KEY FOR NEW IMAGE
850 SETCOLOR 2,3,4:? :? :? :? "After the image is drawn,":? :? "press any key to draw another."
860 FOR DEL=1 TO 1000:NEXT DEL
869 REM GET RID OF LAST KEY PRESSED; GO TO PLOTTING SUBROUTINE
870 POKE 764,255:GOSUB 50
879 REM AFTER PLOTTING, ASK USER FOR CHOICES FOR NEXT IMAGE
880 GOTO 740
899 REM READ DATA FOR ALTERNATE SHAPE
900 POKE 752,1:? :? :? "One moment, please..."
909 REM READ NUMBER OF DATA POINTS
910 READ LAST
919 REM SET ARRAYS EQUAL TO ZERO
920 FOR I=0 TO LAST:X(I)=0:Y(I)=0:Z(I)=0:NEXT I
928 REM 'RATIOS' ALLOW SCALING SHAPE. ADJUST XRATIO TO COMPENSATE SHAPE SHOWN ON YOUR TV SCREEN
929 REM LARGER VALUES (RATIO=4) STRETCH OUT IMAGE ALONG X,Y,Z AXIS; SMALLER VALUES (RATIO=1 OR 0.5) SQUEEZE IMAGE
930 XRATIO=2:YRATIO=1:ZRATIO=1
939 REM READ BARN DATA, OR YOUR OWN DATA BY CHANGING DATA LINES FROM 2000 ON
940 FOR I=1 TO LAST
950 READ X,Y,Z
960 X(I)=X*XRATIO:Y(I)=Y*YRATIO:Z(I)=Z*ZRATIO
969 REM IF X=-999 THEN DON'T MULTIPLY BY RATIO
970 IF X=-999 THEN X(I)=X:Y(I)=Y:Z(I)=Z
980 NEXT I
989 REM NOW BACK TO MAIN PROGRAM
990 YAW=0:PITCH=0:ROLL=0:MODE=1:GOTO 550
999 REM ATARI LOGO DATA; LAST=278
1000 DATA 278
1009 REM CURVED PARTS OF LOGO (USED 4 TIMES)
1010 DATA -20,-56,-20,-10,-21,-8,-22,2,-24,4,-24,8,-26,10,-26,12,-28,14,-28,16,-30,18,-32,20,-34,22
1020 DATA -36,24,-38,26,-40,28,-42,30,-42,31,-50,34,-54,36,-60,38,-70,40,-70,56,-62,56,-54,54
1030 DATA -48,52,-44,50,-40,48,-38,46,-34,44,-32,42,-30,40,-28,38,-26,36,-24,34,-24,32,-22,30
1040 DATA -20,28,-20,26,-18,24,-18,22,-16,20,-16,18,-14,16,-13,12,-12,10,-12,-56,-20,-56,-999,-999
1049 REM STRAIGHT PARTS OF LOGO (USED 2 TIMES)
1050 DATA -8,-56,-8,56,8,56,8,-56,-8,-56,-999,-999
1059 REM CONNECTING LINES FROM FRONT TO BACK OF LOGO
1060 DATA -20,-56,-70,40,-70,56,-12,-56,-8,-56,-8,56,8,56,8,-56,12,-56,70,56,70,40,20,-56
1069 REM DATA FOR WORD "ATARI"
1070 DATA 21,75,25,65,29,75,28,72,22,72,-999,-999
1080 DATA 31,65,39,65,35,65,35,75,-999,-999
1090 DATA 41,75,45,65,49,75,48,72,42,72,-999,-999
1100 DATA 53,75,53,65,58,65,60,67,60,70,58,72,60,75,58,72,53,72,-999,-999
1110 DATA 64,65,70,65,67,65,67,75,64,75,70,75,-999,-999
1999 REM NAME OF ALTERNATE SHAPE AND NUMBER OF DATA POINTS
2000 DATA BARN,154
2010 DATA -25,21,-15,-25,21,15,-25,-9,15,-25,-9,-15,-25,-17,-9,-25,-21,0,-25,-17,9,-25,-9,15,-999,-999,0,-25,5,-9
2020 DATA -25,5,-5,-25,-1,-5,-25,-1,-9,-25,5,-9,-999,-999,-999,-25,2,-9,-25,2,-5,-999,-999,-999,-25,-1,-7,-25,5,-7
2030 DATA -999,-999,-999,-25,5,5,-25,5,9,-25,-1,9,-25,-1,5,-25,5,5,-999,-999,-999,-25,2,5,-25,2,9,-999,-999,-999
2040 DATA -25,5,7,-25,-1,7,-999,-999,-999,15,-9,-15,15,21,-15,15,21,15,15,-9,15,15,-9,-15,15,-17,-9,15,-21,0
2050 DATA 15,-17,9,15,-9,15,-999,-999,-999,15,5,-9,15,5,-5,15,-1,-5,15,-1,-9,15,5,-9,-999,-999,-999,15,2,-9
2060 DATA 15,2,-5,-999,-999,-999,15,-1,-7,15,5,-7,-999,-999,-999,15,5,5,15,5,9,15,-1,9,15,-1,5,15,5,5
2070 DATA -999,-999,-999,15,2,5,15,2,9,-999,-999,-999,15,5,7,15,-1,7,-999,-999,-999,-25,21,15,15,21,15,15,-9,15
2080 DATA -25,-9,15,-25,21,15,-999,-999,-999,-25,21,-15,15,21,-15,15,-9,-15,-25,-9,-15,-25,21,-15,-999,-999,0,-11
2090 DATA 21,15,1,21,15,1,13,15,-11,13,15,-11,21,15,-5,21,15,-5,13,15,-11,21,15,-11,13,15,-5,21,15,1,13,15
2100 DATA 1,21,15,-5,13,15,-999,-999,-999,-25,-9,-15,15,-9,-15,15,-17,-9,-25,-17,-9,-25,-21,0,15,-21,0,15,-17,9
2110 DATA -25,-17,9,-25,-9,15,15,-9,15,15,-17,9,15,-21,0,15,-17,-9,15,-9,-15,-999,-999,-999,-25,-9,-15,-25,-17,-9
2120 DATA -25,-21,0,-25,-17,9,-25,-9,15,-999,-999,-999,15,21,-12,15,-15,-12,20,-21,-10,15,-15,-8,15,21,-8,18,21,-5
2130 DATA 18,-15,-5,20,-21,-10,22,-15,-5,22,21,-5,25,21,-8,25,-15,-8,20,-21,-10,25,-15,-12,25,21,-12,22,21,-15
2140 DATA 22,-15,-15,20,-21,-10,18,-15,-15,18,21,-15,15,21,-12,15,21,-8,18,21,-5,22,21,-5,25,21,-8,25,21,-12
2150 DATA 22,21,-15,18,21,-15,15,21,-12,-999,-999,0,15,-15,-12,15,-15,-8,18,-15,-5,22,-15,-5,25,-15,-8,25,-15,-12
2160 DATA 22,-15,-15,18,-15,-15,15,-15,-12,-999,-999,-999

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: FUJI1.BAS, FUJI2.BAS.

Credits