Tank Battle (Use BASIC to Animate)
- Type
- Game
- Category
- Four-player tank game / player-missile tutorial
- Author
- Fred Pinho
- Published in
- Antic, June 1984 (Vol. 3, No. 2), "Use BASIC to Animate" (part 1 of 2)
- Year
- 1984
- Language
- Atari BASIC
- Requirements
- 32K RAM, Atari BASIC, up to four joysticks (400/800); two players on XL machines (see below)
About the program
A reader wrote to Antic in despair. He had read many articles on player/missile graphics but still couldn't write the game he wanted: four tanks on screen, moving and firing from BASIC. Fred Pinho's two-part tutorial, starting in June 1984, was the answer. As he explained, BASIC knows nothing about P/M graphics. Horizontal movement is a single POKE, but moving a player vertically means moving its bytes in memory, and that is usually far too slow in BASIC. With the right tricks, though, BASIC can manage "a passable job", fast enough for a simple game.
The game: each tank is steered by its own joystick in ports 1 to 4. Tanks move and fire only horizontally or vertically, and you can fire only while moving. Each tank has 30 shells and a reload time of two or three seconds. The first tank to score 10 hits wins. If all shells are used up, the game is a stalemate.
What you need
32K and Atari BASIC. Four joysticks for the full game on a 400/800. XL owners: XL machines have only two joystick ports, so delete lines 1170 and 1180. The article noted, a little puzzled, that removing the lines for the other two tanks stopped the remaining tanks from firing.
Typing it in
The four shell shapes in line 1460 are 13-character strings of {CTRL-,} (CTRL and comma, a zero byte), with one middle character that sets that missile's bit: {CTRL-B} (2), {CTRL-H} (8), a space (32) and an inverse {CTRL-,} (128). Count them exactly. The routines for the four tanks (lines 30–1140) are nearly identical blocks with different register numbers. Copy carefully from the right block.
How to play
Push a stick to move. Press the trigger while moving to fire in that direction. Scores are shown along the bottom. When someone reaches 10 hits, or all shells are gone, the winner is announced.
How it works
- Strings on top of player memory. Lines 1290–1320 find the variable value table (location 134) and rewrite the entries for
T0$toT3$andMSL$. Their addresses are changed to point at the four player areas and the missile area of P/M memory, and their lengths are set to 128. After that,T0$(T0,T0+13)=DW$copies a 14-byte tank shape into player 0 in one fast string operation, which moves the tank vertically. - Four tank shapes.
UP$,DW$,LF$andRT$hold the tank facing each way, so turning is the same string copy. - Joysticks without STICK. Lines 1160–1190 PEEK the shadow registers 632–635 directly and use
ON ... GOSUBto choose among four routines per tank. - Collisions. Each move is tried and then undone if the player-to-player (53260–53263) or player-to-playfield (53252–53255) register shows contact. A shell scores when the missile-to-player register shows a hit on another tank.
Listing
5 REM PLAYER/MISSILE TANKS
6 REM BY FRED PINHO
7 REM ANTIC MAGAZINE
10 DIM T0$(1),T1$(1),T2$(1),T3$(1),MSL$(1),UP$(14),DW$(14),LF$(14),RT$(14),MSL0$(13),MSL1$(13),MSL2$(13),MSL3$(13)
20 GOSUB 1290:GOTO 1150
30 H0=H0+4:POKE 53248,H0:T0$(T0,T0+13)=RT$:FOR T=1 TO 5:NEXT T:IF PEEK(53260) THEN H0=H0-4:POKE 53248,H0:RETURN
40 IF PEEK(53252) THEN H0=H0-4:POKE 53248,H0:RETURN
50 IF PEEK(644) OR M0=0 OR D0<10 THEN RETURN
60 D0=0:M0=M0-1:POKE 53252,H0+8:MSL$(T0+6,T0+6)=CHR$(3):FOR X=H0+8 TO H0+95 STEP 6:POKE 53252,X
70 IF PEEK(53256)>1 THEN POP :S0=S0+1:POKE 657,10:? S0;:MSL$(T0+6,T0+6)=CHR$(0):RETURN
80 IF PEEK(53248) OR X>194 THEN POP :MSL$(T0+6,T0+6)=CHR$(0):RETURN
90 NEXT X:MSL$(T0+6,T0+6)=CHR$(0):RETURN
100 H0=H0-4:POKE 53248,H0:T0$(T0,T0+13)=LF$:FOR T=1 TO 5:NEXT T:IF PEEK(53260) THEN H0=H0+4:POKE 53248,H0:RETURN
110 IF PEEK(53252) THEN H0=H0+4:POKE 53248,H0:RETURN
120 IF PEEK(644) OR M0=0 OR D0<10 THEN RETURN
130 D0=0:M0=M0-1:MSL$(T0+6,T0+6)=CHR$(3):FOR X=H0 TO H0-87 STEP -6:POKE 53252,X
140 IF PEEK(53256)>1 THEN POP :S0=S0+1:POKE 657,10:? S0;:MSL$(T0+6,T0+6)=CHR$(0):RETURN
150 IF PEEK(53248) OR X<46 THEN POP :MSL$(T0+6,T0+6)=CHR$(0):RETURN
160 NEXT X:MSL$(T0+6,T0+6)=CHR$(0):RETURN
170 T0=T0+3:T0$(T0,T0+13)=DW$:FOR T=1 TO 7:NEXT T:IF PEEK(53260) THEN T0=T0-3:T0$(T0,T0+13)=DW$:RETURN
180 IF PEEK(53252) THEN T0=T0-3:T0$(T0,T0+13)=DW$:RETURN
190 IF PEEK(644) OR M0=0 OR T0>74 OR D0<10 THEN RETURN
200 D0=0:M0=M0-1:POKE 53252,H0+4:FOR X=T0+14 TO 88 STEP 6:MSL$(X,X+6)=MSL0$(1,7)
210 IF PEEK(53256)>1 THEN POP :S0=S0+1:POKE 657,10:? S0;:MSL$(X+6,X+6)=CHR$(0):RETURN
220 IF PEEK(53248) THEN POP :MSL$(X+6,X+6)=CHR$(0):RETURN
230 NEXT X:MSL$(X,X)=CHR$(0):RETURN
240 T0=T0-3:T0$(T0,T0+13)=UP$:FOR T=1 TO 7:NEXT T:IF PEEK(53260) THEN T0=T0+3:T0$(T0,T0+13)=UP$:RETURN
250 IF PEEK(53252) THEN T0=T0+3:T0$(T0,T0+13)=UP$:RETURN
260 IF PEEK(644) OR M0=0 OR D0<10 THEN RETURN
270 D0=0:M0=M0-1:POKE 53252,H0+4:FOR X=T0-2 TO 16 STEP -6:MSL$(X,X+6)=MSL0$(7,13)
280 IF PEEK(53256)>1 THEN POP :S0=S0+1:POKE 657,10:? S0;:MSL$(X,X)=CHR$(0):RETURN
290 IF PEEK(53248) THEN POP :MSL$(X,X)=CHR$(0):RETURN
300 NEXT X:MSL$(X+6,X+6)=CHR$(0):RETURN
310 H1=H1+4:POKE 53249,H1:T1$(T1,T1+13)=RT$:FOR T=1 TO 5:NEXT T:IF PEEK(53261) THEN H1=H1-4:POKE 53249,H1:RETURN
320 IF PEEK(53253) THEN H1=H1-4:POKE 53249,H1:RETURN
330 IF PEEK(645) OR M1=0 OR D1<10 THEN RETURN
340 D1=0:M1=M1-1:POKE 53253,H1+8:MSL$(T1+6,T1+6)=CHR$(12):FOR X=H1+8 TO H1+95 STEP 6:POKE 53253,X
350 IF PEEK(53257)>0 AND PEEK(53257)<>2 THEN POP :S1=S1+1:POKE 657,18:? S1;:MSL$(T1+6,T1+6)=CHR$(0):RETURN
360 IF PEEK(53249) OR X>194 THEN POP :MSL$(T1+6,T1+6)=CHR$(0):RETURN
370 NEXT X:MSL$(T1+6,T1+6)=CHR$(0):RETURN
380 H1=H1-4:POKE 53249,H1:T1$(T1,T1+13)=LF$:FOR T=1 TO 5:NEXT T:IF PEEK(53261) THEN H1=H1+4:POKE 53249,H1:RETURN
390 IF PEEK(53253) THEN H1=H1+4:POKE 53249,H1:RETURN
400 IF PEEK(645) OR M1=0 OR D1<10 THEN RETURN
410 D1=0:M1=M1-1:MSL$(T1+6,T1+6)=CHR$(12):FOR X=H1 TO H1-87 STEP -6:POKE 53253,X
420 IF PEEK(53257)>0 AND PEEK(53257)<>2 THEN POP :S1=S1+1:POKE 657,18:? S1;:MSL$(T1+6,T1+6)=CHR$(0):RETURN
430 IF PEEK(53249) OR X<46 THEN POP :MSL$(T1+6,T1+6)=CHR$(0):RETURN
440 NEXT X:MSL$(T1+6,T1+6)=CHR$(0):RETURN
450 T1=T1+3:T1$(T1,T1+13)=DW$:FOR T=1 TO 7:NEXT T:IF PEEK(53261) THEN T1=T1-3:T1$(T1,T1+13)=DW$:RETURN
460 IF PEEK(53253) THEN T1=T1-3:T1$(T1,T1+13)=DW$:RETURN
470 IF PEEK(645) OR M1=0 OR T1>74 OR D1<10 THEN RETURN
480 D1=0:M1=M1-1:POKE 53253,H1+4:FOR X=T1+14 TO 88 STEP 6:MSL$(X,X+6)=MSL1$(1,7)
490 IF PEEK(53257)>0 AND PEEK(53257)<>2 THEN POP :S1=S1+1:POKE 657,18:? S1;:MSL$(X+6,X+6)=CHR$(0):RETURN
500 IF PEEK(53249) THEN POP :MSL$(X+6,X+6)=CHR$(0):RETURN
510 NEXT X:MSL$(X,X)=CHR$(0):RETURN
520 T1=T1-3:T1$(T1,T1+13)=UP$:FOR T=1 TO 7:NEXT T:IF PEEK(53261) THEN T1=T1+3:T1$(T1,T1+13)=UP$:RETURN
530 IF PEEK(53253) THEN T1=T1+3:T1$(T1,T1+13)=UP$:RETURN
540 IF PEEK(645) OR M1=0 OR D1<10 THEN RETURN
550 D1=0:M1=M1-1:POKE 53253,H1+4:FOR X=T1-2 TO 16 STEP -6:MSL$(X,X+6)=MSL1$(7,13)
560 IF PEEK(53257)>0 AND PEEK(53257)<>2 THEN POP :S1=S1+1:POKE 657,18:? S1;:MSL$(X,X)=CHR$(0):RETURN
570 IF PEEK(53249) THEN POP :MSL$(X,X)=CHR$(0):RETURN
580 NEXT X:MSL$(X+6,X+6)=CHR$(0):RETURN
590 H2=H2+4:POKE 53250,H2:T2$(T2,T2+13)=RT$:FOR T=1 TO 5:NEXT T:IF PEEK(53262) THEN H2=H2-4:POKE 53250,H2:RETURN
600 IF PEEK(53254) THEN H2=H2-4:POKE 53250,H2:RETURN
610 IF PEEK(646) OR M2=0 OR D2<10 THEN RETURN
620 D2=0:M2=M2-1:POKE 53254,H2+8:MSL$(T2+6,T2+6)=CHR$(48):FOR X=H2+8 TO H2+95 STEP 6:POKE 53254,X
630 IF PEEK(53258)>0 AND PEEK(53258)<>4 THEN POP :S2=S2+1:POKE 657,27:? S2;:MSL$(T2+6,T2+6)=CHR$(0):RETURN
640 IF PEEK(53250) OR X>194 THEN POP :MSL$(T2+6,T2+6)=CHR$(0):RETURN
650 NEXT X:MSL$(T2+6,T2+6)=CHR$(0):RETURN
660 H2=H2-4:POKE 53250,H2:T2$(T2,T2+13)=LF$:FOR T=1 TO 5:NEXT T:IF PEEK(53262) THEN H2=H2+4:POKE 53250,H2:RETURN
670 IF PEEK(53254) THEN H2=H2+4:POKE 53250,H2:RETURN
680 IF PEEK(646) OR M2=0 OR D2<10 THEN RETURN
690 D2=0:M2=M2-1:MSL$(T2+6,T2+6)=CHR$(48):FOR X=H2 TO H2-87 STEP -6:POKE 53254,X
700 IF PEEK(53258)>0 AND PEEK(53258)<>4 THEN POP :S2=S2+1:POKE 657,27:? S2;:MSL$(T2+6,T2+6)=CHR$(0):RETURN
710 IF PEEK(53250) OR X<46 THEN POP :MSL$(T2+6,T2+6)=CHR$(0):RETURN
720 NEXT X:MSL$(T2+6,T2+6)=CHR$(0):RETURN
730 T2=T2+3:T2$(T2,T2+13)=DW$:FOR T=1 TO 7:NEXT T:IF PEEK(53262) THEN T2=T2-3:T2$(T2,T2+13)=DW$:RETURN
740 IF PEEK(53254) THEN T2=T2-3:T2$(T2,T2+13)=DW$:RETURN
750 IF PEEK(646) OR M2=0 OR T2>74 OR D2<10 THEN RETURN
760 D2=0:M2=M2-1:POKE 53254,H2+4:FOR X=T2+14 TO 88 STEP 6:MSL$(X,X+6)=MSL2$(1,7)
770 IF PEEK(53258)>0 AND PEEK(53258)<>4 THEN POP :S2=S2+1:POKE 657,27:? S2;:MSL$(X+6,X+6)=CHR$(0):RETURN
780 IF PEEK(53250) THEN POP :MSL$(X+6,X+6)=CHR$(0):RETURN
790 NEXT X:MSL$(X,X)=CHR$(0):RETURN
800 T2=T2-3:T2$(T2,T2+13)=UP$:FOR T=1 TO 7:NEXT T:IF PEEK(53262) THEN T2=T2+3:T2$(T2,T2+13)=UP$:RETURN
810 IF PEEK(53254) THEN T2=T2+3:T2$(T2,T2+13)=UP$:RETURN
820 IF PEEK(646) OR M2=0 OR D2<10 THEN RETURN
830 D2=0:M2=M2-1:POKE 53254,H2+4:FOR X=T2-2 TO 16 STEP -6:MSL$(X,X+6)=MSL2$(7,13)
840 IF PEEK(53258)>0 AND PEEK(53258)<>4 THEN POP :S2=S2+1:POKE 657,27:? S2;:MSL$(X,X)=CHR$(0):RETURN
850 IF PEEK(53250) THEN POP :MSL$(X,X)=CHR$(0):RETURN
860 NEXT X:MSL$(X+6,X+6)=CHR$(0):RETURN
870 H3=H3+4:POKE 53251,H3:T3$(T3,T3+13)=RT$:FOR T=1 TO 5:NEXT T:IF PEEK(53263) THEN H3=H3-4:POKE 53251,H3:RETURN
880 IF PEEK(53255) THEN H3=H3-4:POKE 53251,H3:RETURN
890 IF PEEK(647) OR M3=0 OR D3<10 THEN RETURN
900 D3=0:M3=M3-1:POKE 53255,H3+8:MSL$(T3+6,T3+6)=CHR$(192):FOR X=H3+8 TO H3+95 STEP 6:POKE 53255,X
910 IF PEEK(53259)>0 AND PEEK(53259)<>8 THEN POP :S3=S3+1:POKE 657,37:? S3;:MSL$(T3+6,T3+6)=CHR$(0):RETURN
920 IF PEEK(53251) OR X>194 THEN POP :MSL$(T3+6,T3+6)=CHR$(0):RETURN
930 NEXT X:MSL$(T3+6,T3+6)=CHR$(0):RETURN
940 H3=H3-4:POKE 53251,H3:T3$(T3,T3+13)=LF$:FOR T=1 TO 5:NEXT T:IF PEEK(53263) THEN H3=H3+4:POKE 53251,H3:RETURN
950 IF PEEK(53255) THEN H3=H3+4:POKE 53251,H3:RETURN
960 IF PEEK(647) OR M3=0 OR D3<10 THEN RETURN
970 D3=0:M3=M3-1:MSL$(T3+6,T3+6)=CHR$(192):FOR X=H3 TO H3-87 STEP -6:POKE 53255,X
980 IF PEEK(53259)>0 AND PEEK(53259)<>8 THEN POP :S3=S3+1:POKE 657,37:? S3;:MSL$(T3+6,T3+6)=CHR$(0):RETURN
990 IF PEEK(53251) OR X<46 THEN POP :MSL$(T3+6,T3+6)=CHR$(0):RETURN
1000 NEXT X:MSL$(T3+6,T3+6)=CHR$(0):RETURN
1010 T3=T3+3:T3$(T3,T3+13)=DW$:FOR T=1 TO 7:NEXT T:IF PEEK(53263) THEN T3=T3-3:T3$(T3,T3+13)=DW$:RETURN
1020 IF PEEK(53255) THEN T3=T3-3:T3$(T3,T3+13)=DW$:RETURN
1030 IF PEEK(647) OR M3=0 OR T3>74 OR D3<10 THEN RETURN
1040 D3=0:M3=M3-1:POKE 53255,H3+4:FOR X=T3+14 TO 88 STEP 6:MSL$(X,X+6)=MSL3$(1,7)
1050 IF PEEK(53259)>0 AND PEEK(53259)<>8 THEN POP :S3=S3+1:POKE 657,37:? S3;:MSL$(X+6,X+6)=CHR$(0):RETURN
1060 IF PEEK(53251) THEN POP :MSL$(X+6,X+6)=CHR$(0):RETURN
1070 NEXT X:MSL$(X,X)=CHR$(0):RETURN
1080 T3=T3-3:T3$(T3,T3+13)=UP$:FOR T=1 TO 7:NEXT T:IF PEEK(53263) THEN T3=T3+3:T3$(T3,T3+13)=UP$:RETURN
1090 IF PEEK(53255) THEN T3=T3+3:T3$(T3,T3+13)=UP$:RETURN
1100 IF PEEK(647) OR M3=0 OR D3<10 THEN RETURN
1110 D3=0:M3=M3-1:POKE 53255,H3+4:FOR X=T3-2 TO 16 STEP -6:MSL$(X,X+6)=MSL3$(7,13)
1120 IF PEEK(53259)>0 AND PEEK(53259)<>8 THEN POP :S3=S3+1:POKE 657,37:? S3;:MSL$(X,X)=CHR$(0):RETURN
1130 IF PEEK(53251) THEN POP :MSL$(X,X)=CHR$(0):RETURN
1140 NEXT X:MSL$(X+6,X+6)=CHR$(0):RETURN
1150 SOUND 0,180,2,7
1160 D0=D0+1:A=PEEK(635):ON ((A=7)+2*(A=11)+3*(A=13)+4*(A=14)) GOSUB 870,940,1010,1080:POKE 53278,1
1170 D1=D1+1:A=PEEK(634):ON ((A=7)+2*(A=11)+3*(A=13)+4*(A=14)) GOSUB 590,660,730,800:POKE 53278,1
1180 D2=D2+1:A=PEEK(633):ON ((A=7)+2*(A=11)+3*(A=13)+4*(A=14)) GOSUB 310,380,450,520:POKE 53278,1
1190 D3=D3+1:A=PEEK(632):ON ((A=7)+2*(A=11)+3*(A=13)+4*(A=14)) GOSUB 30,100,170,240:POKE 53278,1
1200 IF S0>9 OR S1>9 OR S2>9 OR S3>9 OR M0+M1+M2+M3=0 THEN ? "{BELL}":POKE 656,1:POKE 657,2:GOTO 1220
1210 POKE 77,0:GOTO 1160
1220 IF S0>9 THEN ? "BROWN COMMANDER!":GOSUB 1270:END
1230 IF S1>9 THEN ? "RED COMMANDER!":GOSUB 1270:END
1240 IF S2>9 THEN ? "BLUE COMMANDER!":GOSUB 1270:END
1250 IF S3>9 THEN ? "GREEN COMMANDER!":GOSUB 1270:END
1260 ? "STALEMATE!";:GOSUB 1280:END
1270 ? "CONGRATULATIONS ON YOUR VICTORY!";
1280 FOR T=1 TO 2000:NEXT T:FOR X=0 TO 4:POKE 53261+X,0:NEXT X:POKE 53277,0:RETURN
1290 GRAPHICS 24:GRAPHICS 5:PM=PEEK(106)-12:POKE 54279,PM:PMBASE=256*PM:VT=PEEK(134)+256*PEEK(135)
1300 SAT=PEEK(140)+256*PEEK(141):S0=0:S1=0:S2=0:S3=0
1310 Z=PMBASE-SAT:RESTORE 1520:FOR X=0 TO 4:VVT=VT+(8*X):READ Y:OFS=Z+Y:V3=INT(OFS/256):V2=OFS-256*V3
1320 POKE VVT+2,V2:POKE VVT+3,V3:POKE VVT+4,128:POKE VVT+5,0:POKE VVT+6,128:POKE VVT+7,0:NEXT X:Z=1
1330 FOR X=1 TO 14:READ Y:ON Z GOSUB 1480,1490,1500,1510:NEXT X
1340 Z=Z+1:IF Z<5 THEN GOTO 1330
1350 POKE 53248,55:POKE 53249,55:POKE 53250,192:POKE 53251,192:H0=55:H1=55:H2=192:H3=192
1360 FOR X=0 TO 3:POKE 53252+X,0:NEXT X:M0=30:M1=30:M2=30:M3=30:D0=0:D1=0:D2=0:D3=0
1370 T0$(28,37)=RT$:T1$(74,83)=RT$:T2$(28,37)=LF$:T3$(74,83)=LF$:T0=28:T1=74:T2=28:T3=74
1380 FOR X=0 TO 3:POKE 53256+X,0:NEXT X:POKE 53260,0
1390 POKE 704,40:POKE 705,72:POKE 706,136:POKE 707,200:POKE 712,0
1400 POKE 752,1:POKE 656,0:POKE 657,3
1410 ? "BROWN 0 RED 0 BLUE 0 GREEN 0";
1420 COLOR 1:PLOT 0,0:DRAWTO 79,0:DRAWTO 79,39:DRAWTO 0,39:DRAWTO 0,0
1430 FOR X=0 TO 2:PLOT 14+X,6:DRAWTO 14+X,12:PLOT 63+X,6:DRAWTO 63+X,12:PLOT 63+X,27:DRAWTO 63+X,33
1440 PLOT 14+X,27:DRAWTO 14+X,33:PLOT 38+X,14:DRAWTO 38+X,24
1450 PLOT 6,18+X:DRAWTO 12,18+X:PLOT 66,18+X:DRAWTO 72,18+X:NEXT X
1460 MSL0$="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-B}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}":MSL1$="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-H}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}":MSL2$="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,} {CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}":MSL3$="{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{inv}{CTRL-,}{/inv}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}{CTRL-,}"
1470 POKE 559,46:POKE 53277,3:RETURN
1480 UP$(X,X)=CHR$(Y):RETURN
1490 DW$(X,X)=CHR$(Y):RETURN
1500 LF$(X,X)=CHR$(Y):RETURN
1510 RT$(X,X)=CHR$(Y):RETURN
1520 DATA 512,640,768,896,384
1530 DATA 0,0,0,8,73,93,127,127,127,93,65,0,0,0,0,0,0,65,93,127,127,127,93,73,8,0,0,0,0,0,0,127,28,62,254,62
1540 DATA 28,127,0,0,0,0,0,0,0,254,56,124,127,124,56,254,0,0,0,0
Download
The original program from the Antic disk, to LOAD or ENTER instead of typing it: PMTANKS.BAS.
Credits
- Program listing: Tank Battle (Use BASIC to Animate) — program listing (Antic, June 1984 (Vol. 3, No. 2), "Use BASIC to Animate" (part 1 of 2)) — Fred Pinho
- Picture: The battlefield at the start, with one tank in each corner. — Fred Pinho (program); screenshot by the site
- Antic Software Archive — disk files (June 1984 - Vol. 3 No. 2): PMTANKS.BAS — J. D. Casten, 1984
- Antic magazine scan (OCR text layer): Antic_Vol_3-02_1984-06_Exploring_the_Atari_XL_text.pdf — Internet Archive
