Star Venture

Type
Game
Category
Maze action game
Author
Ronald Saari
Published in
Antic, July 1985 (Vol. 4, No. 3)
Year
1985
Language
Atari BASIC
Requirements
Any Atari 8-bit computer, any memory size, Atari BASIC, joystick in port 1; disk or cassette
Star Venture first chamber: a walled room with the ship at the left gate, five spiky death pods and nine small crystal crosses, score, shield energy 15 and 3 ships at the top

About the program

Antic sold Star Venture as a "bonus game" that newcomers would find easy to type in. All its graphics come from four redefined characters on the ordinary GRAPHICS 0 text screen. The story is pure space opera. You're shipwrecked in the Antroni star cluster and need cash for repairs (and for the planet's "Existence Taxes"), so you fly into the abandoned Ghost Station to collect its priceless Quontex crystals.

Each chamber holds nine crystals and a scattering of deadly Kirollian death pods. Collect all nine and the exit gate on the right opens. After five chambers the layout starts over, but with more pods.

Typing it in

Most of the special characters are control characters. {CTRL-S} (your ship facing right), {CTRL-Y} (facing left) and {CTRL-I} (a death pod) mean hold CTRL and press the letter. {CTRL-,} (a crystal) is CTRL and the comma key. {inv}{CTRL-.}{/inv} is an inverse CTRL-full-stop, used for the walls: press the Atari (inverse) key, then CTRL-., then the Atari key again. {CLEAR} in line 640 is ESC followed by SHIFT-CLEAR. Line 380 has been corrected here: as published it jumped to a line 205 that doesn't exist, so pressing START during a game stopped the program with ERROR 12.

How to play

Press START. Your ship enters from the left side of a walled chamber. Push the joystick left or right to set the direction you fly in (the ship keeps moving), and up or down to change height. Fly over crystals to collect them for 100 points each. Hitting a wall, a barrier or a pod destroys a ship, and you have three. Holding the fire button switches on your shields, which let you pass through a pod. Each step with the shield on uses one unit of energy, and you start with 15. When all nine crystals are gone, the gate opens and you can leave on the right. Pressing START during a game abandons it and starts a new one.

How it works

  • Lines 780–930 copy the 1,024-byte ROM character set to RAM just under the screen. While that happens the "Refueling" message flashes with a falling tone. Then four characters are replaced from DATA, giving the pod, the crystal and the two ship images. POKE 756 switches to the new set.
  • Walls are drawn with PLOT/DRAWTO using a character code as the "colour", a GRAPHICS 0 trick (lines 140, 940–970).
  • Collisions are found with LOCATE on the square ahead (line 460). ATASCII 0 is a crystal, 9 is a pod and 32 is empty space. Anything else counts as a wall.
  • ON SCREEN GOSUB picks one of four barrier layouts. The fifth step (line 980) loops back, adds five pods (up to a limit) and gives you five more units of shield energy.

Changes from the published listing

Line As published Now Why
380 …SOUND 0,0,0,0:GOTO 205 …SOUND 0,0,0,0:GOTO 80 There is no line 205 (in print or on disk), so START stopped the program with ERROR 12. START silences the sound and restarts, so it now goes to line 80, which starts a new game.

Listing

10 REM STAR VENTURE
20 REM BY RONALD SAARI
30 REM (c) 1985, ANTIC PUBLISHING
40 POKE 106,PEEK(740)
50 GOSUB 780
60 DIM S$(1):S$="{CTRL-S}"
70 GOSUB 520
80 SH=3:SC=0:SCREEN=0:MA=5:E=15
90 GRAPHICS 0:POKE 756,STARTLIST/256:W=0:X=3:Y=12:N=9
100 ST=15:S$="{CTRL-S}"
110 POKE 710,0:POKE 752,1
120 ? "{inv}SCORE{/inv}:"
130 POSITION 30,0:? "{CTRL-S} ";SH
140 COLOR ASC("{inv}{CTRL-.}{/inv}"):PLOT 2,2:DRAWTO 38,2:DRAWTO 38,22:DRAWTO 2,22:DRAWTO 2,3
150 POSITION 2,3:? "{inv}{CTRL-.}{/inv}"
160 ON SCREEN GOSUB 940,950,960,970,980
170 A=INT(RND(0)*33)+4:B=INT(RND(0)*19)+3
180 LOCATE A,B,L:IF L<>32 THEN 170
190 POSITION A,B:? "{CTRL-I}"
200 W=W+1:IF W=MA THEN 220
210 GOTO 170
220 W=0
230 A=INT(RND(0)*33)+4:B=INT(RND(0)*19)+3
240 LOCATE A,B,L:IF L<>32 THEN 230
250 W=W+1:IF W=10 THEN 270
260 POSITION A,B:? "{CTRL-,}":GOTO 230
270 COLOR ASC("|"):PLOT 38,11:DRAWTO 38,13:COLOR 32:PLOT 2,11:DRAWTO 2,13
280 SOUND 0,100,10,5:SOUND 1,101,10,5
290 FOR T=0 TO 3
300 POSITION T,12:? "{CTRL-S}":FOR D=1 TO 30:NEXT D:POSITION T,12:? " ":NEXT T:SOUND 0,0,0,0:SOUND 1,0,0,0
310 COLOR ASC("|"):PLOT 2,11:DRAWTO 2,13
320 POSITION 2,13:? "|"
330 POSITION X,Y:? S$
340 IF X=39 THEN SCREEN=SCREEN+1:GOTO 90
350 POSITION 8,0:? SC
360 SOUND 0,5,0,1
370 POSITION 20,0:? E;" "
380 IF PEEK(53279)=6 THEN SOUND 0,0,0,0:GOTO 80
390 FOR T=1 TO 10:NEXT T:POSITION X,Y:? " "
400 IF STICK(0)=14 THEN Y=Y-1
410 IF STICK(0)=13 THEN Y=Y+1
420 IF STICK(0)=7 THEN ST=7
430 IF STICK(0)=11 THEN ST=11
440 IF ST=7 THEN X=X+1:S$="{CTRL-S}"
450 IF ST=11 THEN X=X-1:S$="{CTRL-Y}"
460 LOCATE X,Y,L:POKE 77,0
470 IF L<>32 AND L<>0 AND L<>9 THEN 570
480 IF STRIG(0)=0 AND E>0 THEN E=E-1:SOUND 0,100,10,15:GOTO 500
490 IF L=9 THEN 570
500 IF L=0 THEN GOSUB 610
510 GOTO 330
520 GOSUB 700
530 POSITION 11,19:? "    PRESS {inv}START{/inv}        "
540 POKE 53279,8:SOUND 0,0,0,0
550 IF PEEK(53279)=6 THEN POKE 53279,8:RETURN
560 GOTO 550
570 POKE 710,52:POSITION X,Y:? "X":FOR T=5 TO 0 STEP -1:SOUND 0,T+20,0,T:NEXT T:POKE 710,0
580 POSITION X,Y:? " ":FOR T=15 TO 0 STEP -0.4:SOUND 0,T+10,0,T:SOUND 1,T,12,T/2:NEXT T
590 SH=SH-1:IF SH=0 THEN 640
600 GOTO 90
610 POSITION X,Y:? S$:FOR T=15 TO 0 STEP -1:SOUND 0,121,10,T:SOUND 1,60,10,T:SOUND 2,243,10,T:NEXT T
620 N=N-1:SC=SC+100:IF N=0 THEN 680
630 RETURN
640 ? "{CLEAR}":POSITION 17,9:? "{inv}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{/inv}":POSITION 17,10:? "{inv}{CTRL-.}{/inv} GAME {inv}{CTRL-.}{/inv}"
650 POSITION 17,11:? "{inv}{CTRL-.}{/inv} OVER {inv}{CTRL-.}{/inv}":POSITION 17,12:? "{inv}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{/inv}"
660 POSITION 2,0:? "{inv}SCORE{/inv}:";SC
670 GOSUB 530:GOTO 80
680 FOR T=15 TO 0 STEP -1:SOUND 0,150,10,T:NEXT T:FOR T=11 TO 13:POSITION 38,T:? " ":NEXT T
690 RETURN
700 GRAPHICS 0:POKE 710,0:POKE 752,1:POKE 712,165
710 POSITION 11,6:? "{inv}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{/inv}"
720 POSITION 11,7:? "{inv}{CTRL-.}{/inv}                 {inv}{CTRL-.}{/inv}"
730 POSITION 11,8:? "{inv}{CTRL-.}{/inv}  STAR  VENTURE  {inv}{CTRL-.}{/inv}"
740 POSITION 11,9:? "{inv}{CTRL-.}{/inv}                 {inv}{CTRL-.}{/inv}"
750 POSITION 11,10:? "{inv}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{CTRL-.}{/inv}"
760 POSITION 13,13:? "By Ronald Saari"
770 POSITION 7,16:? "(c) 1985, Antic Publishing":RETURN
780 POKE 106,PEEK(106)-5:GRAPHICS 17
790 POKE 755,1
800 STARTLIST=(PEEK(106)+1)*256
810 POKE 752,1
820 GOSUB 700:POSITION 7,19:? "Refueling, Please stand by...":FOR MOVEME=0 TO 1023
830 POKE 709,PEEK(20):SOUND 0,(INT(-0.24*MOVEME+255)),8,4
840 POKE STARTLIST+MOVEME,PEEK(57344+MOVEME):NEXT MOVEME
850 RESTORE 890
860 READ KY:IF KY=-1 THEN RETURN
870 FOR MOVEME=0 TO 7:READ VALUE:POKE KY+STARTLIST+MOVEME,VALUE:NEXT MOVEME
880 GOTO 860
890 DATA 512,0,0,36,24,24,36,0,0
900 DATA 584,24,90,60,255,255,60,90,24
910 DATA 712,63,31,56,254,254,56,31,63
920 DATA 664,252,248,28,127,127,28,248,252
930 DATA -1
940 PLOT 20,7:DRAWTO 20,18:RETURN
950 PLOT 12,7:DRAWTO 12,18:PLOT 28,7:DRAWTO 28,18:RETURN
960 PLOT 12,4:DRAWTO 28,20:PLOT 28,4:DRAWTO 12,20:RETURN
970 PLOT 18,7:DRAWTO 12,7:DRAWTO 12,18:DRAWTO 28,18:DRAWTO 28,7:DRAWTO 22,7:RETURN
980 SCREEN=0:E=E+5:IF MA<20 THEN MA=MA+5
990 RETURN

Download

The original program from the Antic disk, to LOAD or ENTER instead of typing it: STARVENT.BAS.

Credits