Christmas Mailing Lister (XMASLIST.BAS)

Christmas Mailing Lister

Description

Christmas Mailing Lister

From the Antic disk of Best of Antic Book — disk B.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 12.5 KB

Dialect
Atari BASIC
Lines
268
Variables
BK$, L, MSL, MAIN$, NAME$, TEMP$, SEARCHNAME$, SEARCHCITY$, FIRM$, ADD$, CITY$, ZIP$, PHONE$, Q2$, CAT$, C$, CAT1$, CAT2$, CAT3$, CAT4$, CAT5$, CAT6$, CIV$, CIV2$, NAME2$, B4$, B$, FLAG1, FLAG3, FLAG6, S, OOPS, MENU, DISBRK, REBRK, TITLE, L0, Q1, DUMMY, MARK, NL, L2, FLAG4, FLAG2, L3, XN, XS, L4, Q2, LABEL, L7, CR, L9, Q5, FLAG5, STR, STR2, ENND, L15, L16, L21, L22, Q3, PAGE, L12, LNL, KEY, L18, L19, L20, L10, Q4, L11, L14, IVC, L5, LE, L6, L1, T1, ERR, ERRLN, VV, ERRQ, XX, YY, BB
BASIC listing (268 lines)
10 REM ** CHRISTMAS MAILING LIST **
20 REM BY BILL LUKEROTH
100 REM REVISION 0.3,WRITTEN 10/07/82
150 REM
160 REM MEMORY USED:32K
180 REM DESCRIPTION:mailing list,prints labels or address books
190 DIM BK$(28):FOR L=1 TO 28:BK$(L,L)="_":NEXT L:MSL=15400:REM allows for 140 names
200 DIM MAIN$(MSL),NAME$(110),TEMP$(110),SEARCHNAME$(28),SEARCHCITY$(28),FIRM$(28),ADD$(28),CITY$(28)
210 DIM ZIP$(10),PHONE$(14),Q2$(1),CAT$(1),C$(10),CAT1$(25),CAT2$(25),CAT3$(25),CAT4$(25),CAT5$(25),CAT6$(25)
220 DIM CIV$(1),CIV2$(1),NAME2$(110),B4$(6),B$(1):B4$="      ":B$=" "
230 FLAG1=0:C$="CATAGORY #":FLAG3=0:FLAG6=0:S=0
240 OOPS=9000:MENU=300:TRAP OOPS:DISBRK=9600:REBRK=9650
250 GRAPHICS 2+16:SETCOLOR 2,3,S:SETCOLOR 4,14,0:SETCOLOR 0,3,0:? #6:? #6;"  MERRY CHRISTMAS!":? #6
260 ? #6;"    MAILING LIST":? #6:? #6:? #6:? #6
280 FOR TITLE=1 TO 30:IF PEEK(53279)=6 THEN POP :GOTO 300:REM check start  button
285 FOR L0=1 TO 100:NEXT L0:IF S=0 THEN S=8:GOTO 288
287 S=0
288 SETCOLOR 2,3,S
290 NEXT TITLE
300 CLOSE #1:CLOSE #2:GRAPHICS 0
310 ? :? "CHOOSE ONE:":?
320 ? "  1.SEARCH FOR A LISTING(IN ORDER TO       PRINT A MAILING LABEL,OR CHANGE";
330 ? "       OR DELETE A LISTING)."
340 ? "  2.ADD A LISTING."
350 ? "  3.PRINT A COMPLETE 'ADDRESS BOOK'."
360 ? "  4.PRINT MAILING LABELS FOR EVERYONE      ON THE LIST."
370 ? "  5.CREATE A COMPLETELY NEW ADDRESS        LIST(A NEW DATA BASE)."
380 ? "  6.CREATE A BACK-UP TAPE."
390 ? "  7.END."
400 ? :? "TYPE 1,2,3,4,5,6 OR 7":GOSUB DISBRK
410 INPUT Q1:GRAPHICS 0:IF Q1<1 OR Q1>7 THEN ? "ANSWER MUST BE BETWEEN 1 AND 7.":? :GOTO 310
420 GOSUB DISBRK:ON Q1 GOTO 430,430,430,430,1100,2020,2000
430 FLAG6=FLAG6+1:IF FLAG6>1 THEN 500
440 ? "INSERT THE DATA CASSETTE,REWIND TO    START,PRESS 'PLAY' AND HIT 'RETURN'"
445 OPEN #1,4,0,"C:":REM get data from cassette file
450 FOR L=1 TO 128:GET #1,DUMMY:NEXT L:REM this loop does nothing but is required by Atari BASIC
460 INPUT #1;CAT1$:INPUT #1;CAT2$:INPUT #1;CAT3$:INPUT #1;CAT4$:INPUT #1;CAT5$:INPUT #1;CAT6$
470 INPUT #1;TEMP$:IF TEMP$=CHR$(253) THEN 490
480 MAIN$(LEN(MAIN$)+1)=TEMP$:TEMP$="":GOTO 470
490 SOUND 0,60,10,14:FOR L=1 TO 250:NEXT L:SOUND 0,0,0,0:? :? "TURN RECORDER OFF,THEN PRESS 'START'  TO CONTINUE."
495 IF PEEK(53279)<>6 THEN 495
497 CLOSE #1:GRAPHICS 0:GOSUB DISBRK
500 ON Q1 GOTO 520,1210,1400,1870
520 ? "WHAT NAME ARE YOU LOOKING FOR?"
530 INPUT TEMP$:MARK=28:GOSUB 8500
540 SEARCHNAME$=TEMP$:TEMP$=""
550 ? "WHAT CITY?(OPTIONAL.IF NOT NEEDED TYPE'N')";
560 INPUT TEMP$:MARK=28:GOSUB 8500
570 SEARCHCITY$=TEMP$:TEMP$=""
575 NL=1
580 FOR L2=NL TO LEN(MAIN$)-109 STEP 110
585 GOSUB 7800:IF FLAG4=1 THEN POP :GOTO 300
590 NAME$=MAIN$(L2,L2+109):FLAG2=0
595 REM line 600 compares name$ and search$ character by character
600 FOR L3=1 TO LEN(SEARCHNAME$):CIV$=NAME$(L3,L3):CIV2$=SEARCHNAME$(L3,L3):XN=ASC(CIV$):XS=ASC(CIV2$)
605 IF XN<>XS AND XN<>XS+128 THEN FLAG2=1
610 NEXT L3:IF FLAG2=1 THEN 630
620 NL=L2+110:POP :GOTO 680:REM names match
630 NEXT L2
640 ? "NO RECORD FOUND.ARE YOU SURE THAT"
650 ? SEARCHNAME$:? "IS THE CORRECT SPELLING?":GOTO 310
680 IF SEARCHCITY$="N" THEN 750
690 CITY$=NAME$(57,84):FLAG3=0
700 FOR L4=1 TO LEN(SEARCHCITY$)
705 GOSUB 7800:IF FLAG4=1 THEN 300
710 IF SEARCHCITY$(L4,L4)<>CITY$(L4,L4) THEN FLAG3=1
720 NEXT L4:IF FLAG3=0 THEN 750
730 ? "FOUND ONE IN:":? CITY$:? "STILL SEARCHING FOR THE RIGHT ONE.":? :GOTO 580
750 FIRM$=NAME$(1,28):ADD$=NAME$(29,56):CITY$=NAME$(57,84):ZIP$=NAME$(85,94):PHONE$=NAME$(95,108)
755 CAT$=NAME$(109,110)
770 GRAPHICS 0:SETCOLOR 2,5,2:GOSUB DISBRK:? B$;FIRM$:? B$;ADD$:? B$;CITY$:? B$;ZIP$:? B$;PHONE$:? B$;CAT$
780 POSITION 2,8:? "DO YOU WANT TO:":? " 1.PRINT A LABEL":? " 2.DELETE THIS LISTING":? " 3.CHANGE THIS LISTING"
790 ? " 4.RETURN TO MENU"
800 ? "CHOOSE 1,2,3 OR 4";:INPUT Q2
810 IF Q2<1 OR Q2>4 THEN 780
820 ON Q2 GOTO 840,900,950,300
835 REM label printing routine
840 GOSUB 7000
850 OPEN #2,8,0,"P:":LABEL=0
860 GOSUB 7200
870 GOTO 300
895 REM file deletion routine
900 ? :? "ARE YOU SURE THAT YOU WANT TO DELETE  THIS(ENTER Y OR N)";:INPUT Q2$
920 IF Q2$<>"Y" THEN 780
930 GOSUB 7500
940 GOTO 300
950 RESTORE :NAME$="":? "IF LINE IS O.K. PRESS RETURN.IF NOT    MAKE CHANGES AND THEN PRESS RETURN"
960 ? "(HERE ARE YOUR CATAGORIES:)":GOSUB 6200
970 POSITION 2,0
980 FOR L7=1 TO 6:INPUT TEMP$
990 GOSUB 7800:IF FLAG4=1 THEN 770
1000 READ CR,MARK
1010 IF LEN(TEMP$)>MARK THEN ? CHR$(253):RESTORE :POP :GOTO 770
1040 IF LEN(TEMP$)<MARK THEN TEMP$(LEN(TEMP$)+1)=" ":GOTO 1040
1045 GOSUB 8500
1050 NAME$(LEN(NAME$)+1)=TEMP$
1060 NEXT L7
1070 MAIN$(NL-110,NL-1)=NAME$:GOTO 300
1090 REM new data base creation routine
1100 SETCOLOR 2,6,6:? "THIS IS GOING TO ERASE ANY ADDRESSES  NOW IN MEMORY.IS THAT O.K.?"
1110 ? "(ENTER Y OR N)";:INPUT Q2$
1120 IF Q2$<>"Y" THEN 300
1130 GOSUB DISBRK:MAIN$="":? "YOU'RE GOING TO HAVE TO FURNISH THE   NAMES FOR 6 CATAGORIES.IF YOU DON'T"
1140 ? "WANT TO NAME A PARTICULAR CATAGORY    JUST PRESS 'RETURN'"
1150 ? :? C$;"1";:INPUT CAT1$
1160 ? C$;"2";:INPUT CAT2$
1170 ? C$;"3";:INPUT CAT3$
1180 ? C$;"4";:INPUT CAT4$
1190 ? C$;"5";:INPUT CAT5$
1200 ? C$;"6";:INPUT CAT6$
1205 ? :? "DOUBLE CHECK THE CATAGORIES,IF THEY   ARE O.K. ENTER 'Y',IF NOT ENTER 'N'.";:INPUT Q2$
1206 IF Q2$<>"Y" THEN GRAPHICS 0:? "LET'S TRY IT AGAIN:":GOTO 1130
1209 REM add a file routine
1210 GRAPHICS 0:SETCOLOR 2,6,2:FLAG1=1:FLAG6=1:NAME$="":RESTORE :GOSUB DISBRK
1220 IF LEN(MAIN$)=MSL THEN ? "ALL FILES FULL":GOTO 310
1230 ? "YOU MAY NOW ADD UP TO ";(MSL-LEN(MAIN$))/110;" ADDRESSES"
1240 ? "NAME:";BK$:? "STREET:";BK$:? "CITY/ST:";BK$:? "ZIP CODE:";BK$(1,10):? "PHONE #:";BK$(1,14)
1243 ? "CATAGORY:";BK$(1,1)
1245 ? :? :? :GOSUB 6200
1250 OPEN #1,4,0,"K:"
1260 FOR L9=1 TO 6
1265 GOSUB 7800:IF FLAG4=1 THEN RESTORE :GOTO 300
1270 READ CR,MARK:POSITION CR,L9:? ":";:REM move cursor to correct position
1280 GOSUB 5000
1290 NAME$(LEN(NAME$)+1)=TEMP$
1300 NEXT L9
1305 CLOSE #1
1310 MAIN$(LEN(MAIN$)+1)=NAME$:? :? "WANT TO ADD ANOTHER(ENTER Y OR N)";:INPUT Q2$
1320 RESTORE :IF Q2$="Y" THEN 1210
1330 GOTO 300
1390 REM address book routine
1400 SETCOLOR 2,13,2:? "DO YOU WANT THE BOOK SORTED ALPHA-    BETICALLY BY:"
1410 ? "1.LAST NAME":? "2.CITY":? "OR":? "3.UNSORTED"
1420 ? "(ENTER 1,2 OR 3)";:INPUT Q5
1425 GOSUB 7800:IF FLAG4=1 THEN 300
1430 GRAPHICS 0:SETCOLOR 2,13,2:GOSUB DISBRK:? "DO YOU WANT:":GOSUB 6200:GOSUB 6210
1435 GRAPHICS 0:? :? :? "         PLEASE STAND BY":GOSUB DISBRK
1440 FLAG5=1:STR=1:STR2=1:ENND=28:ON Q5 GOTO 1460,1450,1800
1450 STR=57:STR2=57:ENND=84:REM city$
1460 FOR L15=LEN(MAIN$)-219 TO 1 STEP -110
1465 SETCOLOR 2,L15/110,L16
1470 IF FLAG5=0 THEN POP :GOTO 1800
1480 FLAG5=0
1490 FOR L16=1 TO L15 STEP 110
1500 NAME$=MAIN$(L16,L16+109):NAME2$=MAIN$(L16+110,L16+219):IF Q5=2 THEN 1510
1503 FOR L21=1 TO 28:CIV$=NAME$(L21,L21):IF ASC(CIV$)>159 THEN STR=L21
1504 NEXT L21
1505 FOR L22=1 TO 28:CIV$=NAME2$(L22,L22):IF ASC(CIV$)>159 THEN STR2=L22
1506 NEXT L22
1510 IF NAME$(STR,ENND)<=NAME2$(STR2,ENND) THEN 1530
1520 MAIN$(L16,L16+109)=NAME2$:MAIN$(L16+110,L16+219)=NAME$:FLAG5=1
1530 NEXT L16
1540 NEXT L15
1550 REM sorting completed
1800 GRAPHICS 0:Q3=1:Q2$="Y":PAGE=-1:FLAG4=0:OPEN #2,8,0,"P:":GOSUB 5200:GOSUB 6500
1810 ? :? "DO YOU WANT ANOTHER COPY?":IF FLAG4=1 THEN 300
1820 ? "(ENTER Y OR N)";:INPUT Q2$
1830 IF Q2$="Y" THEN 1800
1840 GOTO 300
1860 REM mass mailing routine
1870 SETCOLOR 2,4,4:? "DO YOU WANT MAILING LABELS FOR:"
1880 GOSUB 6200:GOSUB 6210
1890 GOSUB 7000
1900 PAGE=-1000:OPEN #2,8,0,"P:":GOSUB 6500
1910 GOTO 300
2000 SETCOLOR 2,13,4:TEMP$="":IF FLAG1=0 THEN 4999
2010 ? "SINCE YOU HAVE CHANGED SOME FILES(OR  CREATED NEW ONES)YOU MUST NOW SAVE    THE DATA ON TAPE."
2020 ? "INSERT THE DATA CASSETTE,REWIND TO    START,PRESS 'PLAY' AND 'RECORD' AND   HIT 'RETURN'."
2025 ? "MAKE SURE THAT YOU USE THE DATA TAPE, NOT THE PROGRAM TAPE.":GOSUB 5500
2030 OPEN #1,8,0,"C:"
2040 FOR L=1 TO 128:PUT #1,0:NEXT L
2050 ? #1;CAT1$:? #1;CAT2$:? #1;CAT3$:? #1;CAT4$:? #1;CAT5$:? #1;CAT6$
2055 IF INT(LEN(MAIN$)/110)<>LEN(MAIN$)/110 THEN MAIN$=MAIN$(1,LEN(MAIN$)-1):GOTO 2055
2060 FOR L12=1 TO LEN(MAIN$)-109 STEP 110
2070 TEMP$=MAIN$(L12,L12+109):IF TEMP$(1,1)="@" THEN 2075
2073 ? #1;TEMP$
2075 NEXT L12
2080 ? #1;CHR$(253):CLOSE #1
2090 ? :? "DO YOU WANT TO MAKE A/ANOTHER BACK-UP TAPE(ENTER Y OR N)";:INPUT Q2$
2100 IF Q2$="Y" THEN 2020
2110 IF Q1=6 THEN 300
4999 GRAPHICS 0:? :? "PROGRAM TERMINATED.":END
5000 TEMP$="":LNL=1
5010 GET #1,KEY:IF KEY=155 THEN 5080:REM check return button
5020 IF KEY=126 AND LNL>1 THEN LNL=LNL-1:TEMP$(LNL,LNL)="":? CHR$(KEY);:REM backspace
5030 IF KEY>96 AND KEY<123 THEN KEY=KEY-32:REM convert lower case to upper
5040 IF KEY<32 OR KEY>223 THEN 5010:REM mask out bad input
5050 IF KEY>122 AND KEY<160 THEN 5010:REM ditto
5060 TEMP$(LNL,LNL)=CHR$(KEY):? CHR$(KEY);:LNL=LNL+1:IF LNL>MARK THEN 5080
5070 GOTO 5010
5080 IF LEN(TEMP$)<MARK THEN TEMP$(LEN(TEMP$)+1)=" ":GOTO 5080
5090 RETURN
5200 ? #2;"             CATAGORY INDEX":? #2
5210 ? #2;"1.";CAT1$:? #2;"2.";CAT2$:? #2;"3.";CAT3$:? #2;"4.";CAT4$:? #2;"5.";CAT5$:? #2;"6.";CAT6$
5220 FOR L18=1 TO 20:? #2:NEXT L18:FOR L19=1 TO 40:? #2;"-";:NEXT L19:FOR L20=1 TO 5:? #2:NEXT L20
5230 RETURN
5500 POKE 53775,35:POKE 53768,40:POKE 53764,0:POKE 53766,0:POKE 53773,225
5510 RETURN :REM per Atari this routine is necessary to help prevent tape errors
6000 FOR L10=1 TO CR:? CHR$(31);:NEXT L10:REM move cursor to right
6010 RETURN
6200 ? "1.";CAT1$:? "2.";CAT2$:? "3.";CAT3$:? "4.";CAT4$:? "5.";CAT5$:? "6.";CAT6$
6205 RETURN
6210 ? "7.ALL OF THE ABOVE.":? "(ENTER 1,2,3,4,5,6 OR 7)";:INPUT Q4
6220 RETURN
6500 LABEL=0:REM printing control routine
6510 FOR L11=1 TO LEN(MAIN$)-109 STEP 110
6515 GOSUB 7800:IF FLAG4=1 THEN POP :RETURN
6520 NAME$=MAIN$(L11,L11+109)
6525 IF NAME$(1,1)="@" THEN 6560
6530 IF Q4=7 THEN 6550
6540 IF VAL(NAME$(109,109))<>Q4 THEN 6560
6550 PAGE=PAGE+1:IF PAGE=7 THEN PAGE=0:FOR L14=1 TO 40:? #2;"-";:NEXT L14:FOR L15=1 TO 5:? #2:NEXT L15
6553 FOR L19=1 TO LEN(NAME$):CIV$=NAME$(L19,L19):IVC=ASC(CIV$):IF IVC>159 THEN NAME$(L19,L19)=CHR$(IVC-128)
6554 NEXT L19:REM this changes inverse characters back to normal,so we can print them
6555 GOSUB 7200
6560 NEXT L11
6570 CLOSE #2:RETURN
7000 ? :? "DO YOU WANT THE PHONE NUMBER ON THE   LABEL(ENTER Y OR N)";:INPUT Q2$
7010 ? "HOW MANY COPIES";:INPUT Q3
7020 RETURN
7200 FOR L5=1 TO Q3
7205 GOSUB 7800:IF FLAG4=1 THEN POP :RETURN
7210 ? #2;B4$;NAME$(1,28):? #2;B4$;NAME$(29,56):? #2;B4$;NAME$(57,84):? #2;B4$;NAME$(85,94)
7220 LE=4
7230 IF Q2$="Y" THEN ? #2;B4$;NAME$(95,108),NAME$(109,109):LE=3
7235 IF Q1=3 THEN LE=3
7240 FOR L6=1 TO LE:? #2:NEXT L6
7250 NEXT L5:RETURN
7500 FLAG1=1:MAIN$(L2,L2)="@":REM delete file
7510 RETURN
7800 FLAG4=0:IF PEEK(53279)=3 THEN FLAG4=1:REM check option button
7810 RETURN
8495 REM routine to convert lower case letters to upper case
8500 FOR L1=1 TO LEN(TEMP$):T1=ASC(TEMP$(L1,L1)):IF T1>96 THEN TEMP$(L1,L1)=CHR$(T1-32):NEXT L1
8505 IF LEN(TEMP$)>MARK THEN TEMP$=TEMP$(1,MARK)
8510 RETURN
9000 REM error trapping routine
9010 ERR=PEEK(195):REM error # stored in location 195
9020 ERRLN=PEEK(187)*256+PEEK(186):VV=0:REM error line # stored at these locations,low byte first
9030 SETCOLOR 2,3,4:? CHR$(253):TRAP OOPS:REM turn screen pink,sound buzzer,reset trap
9040 IF ERR>8 AND ERR<138 THEN 9200
9050 IF ERR=141 THEN 9200
9060 IF ERR<>3 AND ERR<>8 THEN 9080
9070 ? "INPUT ERROR.EITHER THE VALUE WAS      OUTSIDE THE EXPECTED RANGE OR YOU"
9075 ? "INPUT A LETTER WHERE A NUMBER WAS     CALLED FOR.":? :GOTO ERRLN-10
9080 IF ERR<>138 THEN 9110
9090 ? "PRINTER OR TAPE ERROR.MAKE SURE THAT  THE DEVICE IS TURNED ON AND ALL CABLE"
9100 ? "CONNECTIONS SECURE,AND THEN CHOOSE:":GOTO 9130
9110 IF ERR<140 OR ERR>143 THEN 9200
9120 ? "TAPE ERROR.REWIND AND THEN CHOOSE:"
9130 ? "  1.RETURN TO MAIN MENU"
9140 ? "  2.END"
9150 ? :? "(ENTER 1 OR 2)":TRAP OOPS:INPUT ERRQ:REM reset trap before returning to main program
9160 ON ERRQ GOTO 9170,9190
9170 FLAG6=0:CLOSE #1:CLOSE #2:CLOSE #3:GOTO MENU
9190 GRAPHICS 0:END
9200 GRAPHICS 0:SETCOLOR 2,3,0:POKE 752,1:FOR XX=1 TO 5:REM turn screen red,turn cursor off;all hope is lost
9210 POSITION 14,10:? "FATAL ERROR":SOUND 0,47,10,10:REM make warbler sound
9220 FOR YY=1 TO 25:NEXT YY
9230 POSITION 14,10:? "FATAL ERROR":SOUND 0,64,10,10
9240 FOR YY=1 TO 25:NEXT YY
9250 NEXT XX
9260 ? :? "FATAL ERROR ";ERR;" AT LINE ";ERRLN:? "DEBUG AND RESTART":? :LIST ERRLN:END
9600 REM routine to disable break key
9610 BB=PEEK(16):IF BB>127 THEN BB=BB-128:POKE 16,BB:POKE 53774,BB
9620 RETURN
10000 REM supplies data for line 1270
10010 DATA 6,28,8,28,9,28,10,10,9,14,10,2