Spyder, drawing program (SPYDER.BAS)
Spyder, drawing program
Description
Spyder, drawing program
From the Antic disk of Best of Antic Book — disk B.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.9 KB
- Dialect
- Atari BASIC
- Lines
- 89
- Variables
SPIDER$,SSPIDER$,ERASE$,MEMTOP,I,PMBASE,XSPIDER,YSPIDER,DAT,ATAB,VTAB,OFFSET,M3,M2,C,XLINE,YLINE,DEL,ST
BASIC listing (89 lines)
10 REM ******** SPYDER ********
20 REM BY JOHN AND MARY HARRISON
40 REM FOR ANTIC JUNE 1982
60 DIM SPIDER$(1),SSPIDER$(8),ERASE$(10)
70 REM SET ASIDE MEMORY FOR PLAYER
80 REM AND SET GRAPHICS MODE.
90 MEMTOP=PEEK(106)-16
100 POKE 106,MEMTOP
110 REM CLEAR MEMORY FOR PLAYER
120 POKE 88,0:FOR I=0 TO 4:POKE 89,MEMTOP+8+I:? CHR$(125):NEXT I
130 GRAPHICS 7+16
140 MEMTOP=MEMTOP+8
150 REM START OF PLAYER MEMORY
160 POKE 54279,MEMTOP
170 REM DECIMAL ADDRESS OF PLAYER MEMORY
180 PMBASE=256*MEMTOP
190 REM SINGLE LINE PLAYER DOUBLE WIDTH
200 POKE 559,46:POKE 53256,1
210 REM ENABLE PM GRAPHICS
220 POKE 53277,3
230 REM INITIAL PLAYER POSITION
240 XSPIDER=119
250 YSPIDER=48
260 REM CLEAR STRING FOR VERITCAL MOVEMENT
270 ERASE$="♥♥♥♥♥♥♥♥♥♥"
280 REM POSITION PLAYER
290 POKE 53248,XSPIDER
300 REM DRAW PLAYER
310 FOR I=PMBASE+511+YSPIDER TO PMBASE+518+YSPIDER
320 READ DAT
330 POKE I,DAT
340 NEXT I
350 DATA 36,36,90,60,60,90,36,36
360 REM ADDRESS OF ARRAY AND VARIABLE
370 REM TABLES. THIS SECTION OF CODE
380 REM ALLOWS YOU TO USE 128 BYTES
390 REM FOR SPIDER$ WITHOUT RESERVING
400 REM THAT MUCH MEMORY IN THE DIM.
410 ATAB=PEEK(140)+256*PEEK(141)
420 VTAB=PEEK(134)+256*PEEK(135)
430 OFFSET=256*MEMTOP+512-ATAB
440 M3=INT(OFFSET/256)
450 M2=OFFSET-256*M3
460 POKE VTAB+2,M2:POKE VTAB+3,M3
470 POKE VTAB+4,128:POKE VTAB+5,0
480 POKE VTAB+6,128:POKE VTAB+7,0
490 REM SET UP SHADOW FOR SPIDER
500 SSPIDER$(1,8)=SPIDER$(YSPIDER,YSPIDER+7)
510 REM INITIALIZE COLOR AND LINE CO-
520 REM ORDINATES.
530 C=0:XLINE=79:YLINE=35
540 SETCOLOR 4,0,0:POKE 704,8
542 SETCOLOR 0,3,8:SETCOLOR 1,6,8
544 SETCOLOR 2,9,8
550 GOSUB 880
560 COLOR C
570 PLOT XLINE,YLINE
580 REM CHANGE COLOR ROUTINE
590 IF STRIG(0)=1 THEN 660
600 C=C+1
610 IF C>3 THEN C=0
620 COLOR C:POKE 704,C*48+8
630 FOR DEL=1 TO 20:NEXT DEL
640 REM READ JOYSTICK AND SET PLAYER
650 REM PARAMETERS APPROPRIATELY.
660 ST=STICK(0)
670 IF ST=15 THEN 590
680 IF ST=6 OR ST=10 OR ST=14 THEN YSPIDER=YSPIDER-1:YLINE=YLINE-1
690 IF ST>4 AND ST<8 THEN XSPIDER=XSPIDER+1:XLINE=XLINE+1
700 IF ST=5 OR ST=13 OR ST=9 THEN YSPIDER=YSPIDER+1:YLINE=YLINE+1
710 IF ST>8 AND ST<12 THEN XSPIDER=XSPIDER-1:XLINE=XLINE-1
720 REM VERTICAL MOTION OF PLAYER
730 SPIDER$(YSPIDER,YSPIDER+7)=SSPIDER$
740 SPIDER$(YSPIDER-8,YSPIDER-1)=ERASE$
750 SPIDER$(YSPIDER+8,YSPIDER+15)=ERASE$
760 REM CHECK FOR CURSOR OUT OF RANGE
770 IF XSPIDER<41 THEN XSPIDER=41:XLINE=XLINE+1
780 IF XSPIDER>199 THEN XSPIDER=199:XLINE=XLINE-1
790 IF YSPIDER<14 THEN YSPIDER=14:YLINE=YLINE+1
800 IF YSPIDER>108 THEN YSPIDER=108:YLINE=YLINE-1
810 REM HORIZONTAL MOTION OF PLAYER
820 POKE 53248,XSPIDER
830 REM DRAW SPIDER TRAIL
840 DRAWTO XLINE,YLINE
850 GOTO 590
860 REM ROUTINE TO DRAW FRAME. THIS
870 REM SHOWS LIMITS OF SCREEN.
880 COLOR 1
890 PLOT 0,0:DRAWTO 0,95:DRAWTO 159,95:DRAWTO 159,0:DRAWTO 0,0:RETURN
