Scrolling demos (SCROLL3.BAS)

Scrolling demos

Description

Scrolling demos

From the Antic disk of Best of Antic Book — disk B.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.3 KB

Dialect
Atari BASIC
Lines
36
Variables
DLST, DMEM, DLIST, SKIPH, SKIPL, VALL, VALH, Y, X
BASIC listing (36 lines)
10 REM FINE SCROLLING HORIZONTALLY AND VERICALLY
20 DLST=PEEK(560)+256*PEEK(561)
25 DMEM=PEEK(DLIST+4)+PEEK(DLST+5)*256
30 SKIPH=INT((DMEM+280)/256):SKIPL=DMEM+280-SKIPH*256
35 VALL=0:VALH=2
40 POKE DLST+12,119:POKE DLST+13,VALL:POKE DLST+14,VALH
45 POKE DLST+15,66:POKE DLST+16,SKIPL:POKE DLST+17,SKIPH
50 IF PEEK(764)=255 THEN GOTO 50:REM SCAN KEYBOARD
55 IF PEEK(764)=14 THEN POKE 764,255:GOTO 200:REM UP ARROW ?
60 IF PEEK(764)=15 THEN POKE 764,255:GOTO 250:REM DOWN ARROW ?
65 IF PEEK(764)=6 THEN GOTO 300:REM LEFT ARROW ?
70 IF PEEK(764)=7 THEN GOTO 350:REM RIGHT ARROW ?
75 GOTO 50:REM IGNORE OTHER RESPONSES
200 Y=Y+1:IF Y<16 THEN GOTO 500
210 Y=0
215 VALL=VALL+40
220 IF VALL>240 THEN VALL=0:VALH=VALH+1
230 GOTO 450
250 Y=Y-1
255 IF Y>-1 THEN GOTO 500
260 Y=15
265 VALL=VALL-40
280 GOTO 445
300 X=X-1:IF X>-1 THEN GOTO 505
305 X=15
310 VALL=PEEK(DLST+13)+2
325 GOTO 445
350 X=X+1:IF X<16 THEN GOTO 505
355 X=0
360 VALL=PEEK(DLST+13)-2
440 IF VALL<0 THEN VALL=0:VALH=VALH-1
445 IF VALH<0 THEN VALH=0
450 POKE DLST+12,119:POKE DLST+13,VALL:POKE DLST+14,VALH
500 POKE 54277,Y:REM VERTICAL SCROLL REGISTER
505 POKE 54276,X:REM HORIZONTAL SCROLL REGISTER
510 GOTO 50