Drop (DROP.BAS)
Drop
Description
Drop
From the Antic disk of Best of Antic Book — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.5 KB
- Dialect
- Atari BASIC
- Lines
- 80
- Variables
X,SA(,C,HI,N,Y,DL,PY,DLA,DY,DX,DX2,DY2,DX3,DY3,S,SC,I,D,LD
BASIC listing (80 lines)
1 REM ******** DROP ********
2 REM BY JOHN ZAKOUR
5 GOTO 100
10 IF X=2 THEN X=3:RETURN
20 IF X=15 THEN X=14:RETURN
30 RETURN
100 DIM SA(15)
105 GOSUB 1000:C=1:HI=0
110 FOR N=1 TO 15:SA(X)=0:NEXT N:SA(7)=1:SA(11)=-1
115 GRAPHICS 1+16:SETCOLOR 4,4,0
116 POSITION 2,5:PRINT #6;"d":POSITION 2,7:PRINT #6;"r":POSITION 2,9:PRINT #6;"o":POSITION 2,11:PRINT #6;"p"
117 POKE 756,64
120 Y=19:X=10:DL=1
121 FOR PY=2 TO 18
122 POSITION 4,PY:PRINT #6;"&":POSITION 17,PY:PRINT #6;"&"
123 NEXT PY
124 DLA=10
125 DY=1:DX=INT(12*RND(1)+5)
127 DX2=INT(12*RND(1)+5):DY2=1
130 DX3=INT(9*RND(1)+5):DY3=1
160 POSITION X,Y:PRINT #6;" #$% "
200 S=SA(PEEK(632))
210 IF S<>0 THEN X=X+S:GOSUB 10:POSITION X,Y:PRINT #6;" #$% "
220 POSITION DX,DY:PRINT #6;"!"
230 DL=DL+1
235 IF DL<DLA THEN 200
236 IF C=1 THEN POKE 756,64:C=2:GOTO 240
238 POKE 756,68:C=1
240 DL=1:POSITION DX,DY:PRINT #6;" ":DY=DY+1:POSITION DX,DY:PRINT #6;"!":POKE 53762,DY+10:POKE 53763,163
245 IF DY>9 THEN POSITION DX2,DY2:PRINT #6;" ":DY2=DY2+1:POSITION DX2,DY2:PRINT #6;"!"
247 IF DY>15 THEN POSITION DX3,DY3:PRINT #6;" ":DY3=DY3+1:POSITION DX3,DY3:PRINT #6;"!"
250 IF DY<>19 THEN 200
255 IF DX=X+1 OR DX=X+2 OR DX=X+3 THEN 260
257 GOTO 266
260 SC=SC+INT(11-DLA):DLA=DLA-0.35:POSITION 1,1:PRINT #6;SC:DX=DX2:DY=DY2:DX2=DX3:DY2=DY3:GOTO 130
265 DX=DX2:DY=DY2:GOTO 130
266 GOSUB 2000
267 SOUND 0,164,10,8:FOR S=1 TO 150:NEXT S:SOUND 0,0,0,0:FOR S=1 TO 5:NEXT S:SOUND 0,164,10,8:FOR S=1 TO 150:NEXT S
268 SOUND 0,0,0,0:FOR S=1 TO 5:NEXT S:SOUND 0,217,10,10:FOR S=1 TO 300:NEXT S:SOUND 0,0,0,0
270 POSITION 6,8:PRINT #6;"game over":SOUND 1,0,0,0:POKE 77,0
275 IF SC>HI THEN HI=SC
277 POSITION 5,9:PRINT #6;"hit <button>":POSITION 6,12:PRINT #6;"HIGH ";HI
279 IF STRIG(0)<>0 THEN 270
280 SC=0:GRAPHICS 1+16:SETCOLOR 4,4,0:GOTO 120
400 GOTO 200
1000 GRAPHICS 2+16:POSITION 6,8:PRINT #6;"PLEASE":POSITION 7,9:PRINT #6;"WAIT"
1002 POSITION 2,2:PRINT #6;"catch the falling":POSITION 4,4:PRINT #6;"faces!!!!!"
1005 FOR I=96 TO 720
1010 POKE 16384+I,PEEK(57344+I)
1020 POKE 17408+I,PEEK(57344+I)
1030 NEXT I
1100 FOR I=16392 TO 16439
1110 READ D
1120 POKE I,D
1130 NEXT I
1140 FOR I=17416 TO 17463
1150 READ D
1160 POKE I,D
1170 NEXT I
1180 DATA 126,129,165,129,165,189,129,126
1182 DATA 24,24,24,24,24,24,24,24
1184 DATA 0,0,0, 63,64,64,63,31
1186 DATA 0,0,0,255,0,0,255,255
1188 DATA 0,0,0,252,2,2,252,248
1189 DATA 0,0,0,0,24,24,24,24
1190 DATA 0,0,255,153,255,189,129,255
1192 DATA 0,0,0,0,24,24,24,24
1194 DATA 0,0,0, 63,64,64,63,31
1196 DATA 0,0,0,255,0,0,255,255
1198 DATA 0,0,0,252,2,2,252,248
1199 DATA 24,24,24,24,0,0,0,0
1200 POKE 756,64
1205 SOUND 0,31,10,8:FOR S=1 TO 50:NEXT S:SOUND 0,0,0,0
1210 RETURN
2000 FOR LD=1 TO 15:SOUND 2,75,8,14:SOUND 3,76,8,14:POKE 712,PEEK(53770)
2010 POSITION X,Y:PRINT #6;"#$%":FOR S=1 TO 10:NEXT S:POSITION 4,Y:PRINT #6;"# $ %"
2020 NEXT LD
2025 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0:SETCOLOR 4,4,0
2030 RETURN
3000 REM THANKS:PAM C,JB,JBJ,ED,DAVID,LARRY,& COREY
