AMP Octave Shifter and Music Transposer (TRANSPOZ.BAS)
AMP Octave Shifter and Music Transposer by Joe Cabuk, 45
Description
AMP Octave Shifter and Music Transposer by Joe Cabuk, 45
From the Antic disk of Antic: June/July 1990 - Vol. 9 No. 2 — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.1 KB
- Dialect
- Atari BASIC
- Lines
- 87
- Variables
OFF,FN$,MU$,KEYSIG$,OFFSET$,KEY$,Q$,I,A,ERR,K,OFFSET1,OFFSET2,OFFSET,VOICE,Q,B
BASIC listing (87 lines)
10 REM MUSIC TRANSPOSER
20 REM BY JOE CABUK
25 REM (c)1990, ANTIC PUBLISHING, INC.
30 REM FOR ANTIC MUSIC PROCESSOR
40 REM FROM ANTIC, JUNE 89 & DEC 88
50 OFF=40000
60 DIM FN$(15),MU$(25600),KEYSIG$(34),OFFSET$(34),KEY$(2),Q$(1)
100 ? "↰ ANTIC MUSIC PROCESSOR TRANSPOSER"
105 TRAP 110
110 ? :? " Enter Source Song File Name (Include Drive #)"
120 ? :? " e.g. D2:MYSONG.EXT ";:INPUT FN$
130 ? :? " Loading... ";FN$
140 CLOSE #1
150 OPEN #1,4,0,FN$
160 TRAP 230
170 I=0
180 GET #1,A
190 I=I+1
200 MU$(I)=CHR$(A):REM READ THE SONG INTO THE STRING MU$
210 GOTO 180
229 REM GET ERROR NUMBER
230 ERR=PEEK(195)
240 IF ERR=136 THEN 260:REM END-OF-FILE ERROR ALLOWS CONTINUATION
250 ? "ERROR NUMBER ";ERR;" HAS OCCURRED":CLOSE #1:STOP :REM OTHER ERRORS STOP EXECUTION
260 CLOSE #1
265 TRAP 300
300 ? :? "Enter the number of sharps or flats in the key signature of the piece you are transposing."
310 ? "e.g. 2#, 2S, 2b, or 3F"
320 INPUT KEY$
325 TRAP 300
330 IF KEY$(2,2)="S" THEN KEY$(2,2)="#"
340 IF KEY$(2,2)="b" THEN KEY$(2,2)="F"
350 KEYSIG$="0#1#2#3#4#5#6#7#0F1F2F3F4F5F6F7FXX"
360 OFFSET$="0007020904110601000510030801061199"
370 FOR K=1 TO 34 STEP 2
380 IF KEY$(1,2)=KEYSIG$(K,K+1) OR KEYSIG$(K,K+1)="XX" THEN OFFSET1=VAL(OFFSET$(K,K+1)):GOTO 400
390 NEXT K
400 IF OFFSET1=99 THEN ? " Please try again ... ":? :GOTO 300
405 TRAP 410
410 ? :? "Enter the number of sharps or flats in the key signature you are"
420 ? "transposing into."
430 ? "e.g. 2#, 2S, 2b, or 2F"
440 INPUT KEY$
450 IF KEY$(2,2)="S" THEN KEY$(2,2)="#"
460 IF KEY$(2,2)="b" THEN KEY$(2,2)="F"
465 TRAP OFF
470 ? :? " Working..."
500 FOR K=1 TO 34 STEP 2
510 IF KEY$(1,2)=KEYSIG$(K,K+1) OR KEYSIG$(K,K+1)="XX" THEN OFFSET2=VAL(OFFSET$(K,K+1)):GOTO 530
520 NEXT K
530 IF OFFSET2=99 THEN ? " Please try again ...":GOTO 410
540 OFFSET=OFFSET2-OFFSET1
550 VOICE=1
600 FOR Q=17 TO LEN(MU$) STEP 3
610 IF ASC(MU$(Q,Q))>65 AND ASC(MU$(Q,Q))<255 THEN 680
620 IF MU$(Q,Q+2)="▶▶▶" THEN VOICE=VOICE+1:GOTO 670:REM INVERSE ESCAPE-CONTROL-INSERT
630 A=ASC(MU$(Q)):A=A+OFFSET
640 IF A<0 THEN A=A+12
650 IF A>64 THEN A=A-12
660 Q$=CHR$(A):MU$(Q,Q)=Q$
670 IF VOICE=5 THEN 700
680 NEXT Q
700 IF K<17 THEN MU$(Q+4,Q+4)="♥":REM CONTROL COMMA
710 IF K>16 THEN MU$(Q+4,Q+4)="├":REM CONTROL A
720 B=VAL(KEY$(1,1))
730 MU$(Q+5,Q+5)=CHR$(B)
735 TRAP 800
800 ? "↰":? :? "ENTER THE FILENAME FOR THE TRANSPOSED SONG (INCLUDE DRIVE #) e.g. D:NEWKEY.EXT"
810 ? " ";:INPUT FN$
820 CLOSE #1
830 ? :? " Saving... ";FN$
840 OPEN #1,8,0,FN$
850 PRINT #1;MU$
860 CLOSE #1
900 ? :? "TO MAKE A BACKUP DISK OF THE TRANSPOSED SONG, ENTER THE DRIVE # AND FILENAME."
910 ? "e.g. D2:FILENAME.EXT":? :? "IF NO BACKUP IS DESIRED, ENTER AN N."
915 TRAP 900
920 ? " ";:INPUT FN$
930 IF FN$="N" THEN 990
940 CLOSE #1
950 ? :? " Saving... ";FN$
960 OPEN #1,8,0,FN$
970 PRINT #1;MU$
980 CLOSE #1
985 TRAP OFF
990 ? :? " FINISHED"
1000 END
