AMP Octave Shifter and Music Transposer (SHIFTER.BAS)
AMP Octave Shifter and Music Transposer by Joe Cabuk, 45
Description
AMP Octave Shifter and Music Transposer by Joe Cabuk, 45
From the Antic disk of Antic: June/July 1990 - Vol. 9 No. 2 — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.4 KB
- Dialect
- Atari BASIC
- Lines
- 64
- Variables
FN$,MU$,I,Y,A,ERR,DELAY,KEY$,KEYSIG$,OFFSET$,K,OFFSET1,OFFSET2,OFFSET,Q,Q$,MUS,MUS(,M,VOICE,OFF,Z,B,AN$
BASIC listing (64 lines)
10 REM MUSIC OCTAVE SHIFTER
20 REM BY JOE CABUK
25 REM (c)1990, ANTIC PUBLISHING, INC.
30 REM FOR ANTIC MUSIC PROCESSOR
40 REM FROM ANTIC, JUNE 89 & DEC 88
50 OFF=40000
60 DIM FN$(15),MU$(29000),AN$(1),Q$(1)
100 ? :? "↰ ANTIC MUSIC PROCESSOR OCTAVE SHIFTER"
105 TRAP 110
110 ? :? " Enter Source Song File Name (Include Drive #)"
120 ? :? " e.g. D2:MYSONG.EXT ";:INPUT FN$
130 ? :? " Loading... ";FN$
140 CLOSE #1
150 OPEN #1,4,0,FN$
160 TRAP 230
170 I=0
180 GET #1,A
190 I=I+1
200 MU$(I)=CHR$(A):REM READ THE SONG INTO THE STRING MU$
210 GOTO 180
229 REM GET ERROR NUMBER
230 ERR=PEEK(195)
240 IF ERR=136 THEN 260:REM END-OF-FILE ERROR ALLOWS CONTINUATION
250 ? "ERROR NUMBER ";ERR;" HAS OCCURRED":CLOSE #1:STOP :REM OTHER ERRORS STOP EXECUTION
260 CLOSE #1
265 TRAP 300
300 ? :? "Do you want the song shifted Up or Down? (Type U or D RETURN )"
310 INPUT AN$
320 IF AN$(1,1)="U" THEN OFFSET=12:GOTO 340
325 TRAP 300
330 IF AN$(1,1)="D" THEN OFFSET=-12:GOTO 340
335 GOTO 300
340 ? :? " Working..."
550 VOICE=1
600 FOR Q=17 TO LEN(MU$) STEP 3
610 IF ASC(MU$(Q,Q))>65 AND ASC(MU$(Q,Q))<255 THEN 680
620 IF MU$(Q,Q+2)="▶▶▶" THEN VOICE=VOICE+1:GOTO 670:REM INVERSE ESCAPE-CONTROL-INSERT
630 A=ASC(MU$(Q)):A=A+OFFSET
640 IF A<0 THEN A=A+12
650 IF A>64 THEN A=A-12
660 Q$=CHR$(A):MU$(Q,Q)=Q$
670 IF VOICE=5 THEN 800
680 NEXT Q
735 TRAP 800
800 ? "↰":? :? "ENTER THE FILENAME FOR THE SHIFTED SONG (INCLUDE DRIVE #) e.g. D:NEWKEY.EXT"
810 ? " ";:INPUT FN$
820 CLOSE #1
830 ? :? " Saving... ";FN$
840 OPEN #1,8,0,FN$
850 PRINT #1;MU$
860 CLOSE #1
900 ? :? "TO MAKE A BACKUP DISK OF THE SHIFTED SONG, ENTER THE DRIVE # AND FILENAME."
910 ? "e.g. D2:FILENAME.EXT":? :? "IF NO BACKUP IS DESIRED, ENTER AN N."
915 TRAP 900
920 ? " ";:INPUT FN$
930 IF FN$="N" THEN 990
940 CLOSE #1
950 ? :? " Saving... ";FN$
960 OPEN #1,8,0,FN$
970 PRINT #1;MU$
980 CLOSE #1
985 TRAP OFF
990 ? :? " FINISHED"
1000 END
